source: trunk/SOURCES/BLAS/sormrz.f

Last change on this file was 22, checked in by roche, 9 years ago

Petites adaptations diverses du code pour compilation en gfortran. Ajout d un Makefile flexible a option pour choisir ifort ou gfortran.
File size: 10.3 KB
Line 
1*> \brief \b SORMRZ
2*
3*  =========== DOCUMENTATION ===========
4*
5* Online html documentation available at 
6*            http://www.netlib.org/lapack/explore-html/ 
7*
8*> \htmlonly
9*> Download SORMRZ + dependencies 
10*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/sormrz.f"> 
11*> [TGZ]</a> 
12*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/sormrz.f"> 
13*> [ZIP]</a> 
14*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/sormrz.f"> 
15*> [TXT]</a>
16*> \endhtmlonly 
17*
18*  Definition:
19*  ===========
20*
21*       SUBROUTINE SORMRZ( SIDE, TRANS, M, N, K, L, A, LDA, TAU, C, LDC,
22*                          WORK, LWORK, INFO )
23* 
24*       .. Scalar Arguments ..
25*       CHARACTER          SIDE, TRANS
26*       INTEGER            INFO, K, L, LDA, LDC, LWORK, M, N
27*       ..
28*       .. Array Arguments ..
29*       REAL               A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
30*       ..
31* 
32*
33*> \par Purpose:
34*  =============
35*>
36*> \verbatim
37*>
38*> SORMRZ overwrites the general real M-by-N matrix C with
39*>
40*>                 SIDE = 'L'     SIDE = 'R'
41*> TRANS = 'N':      Q * C          C * Q
42*> TRANS = 'T':      Q**T * C       C * Q**T
43*>
44*> where Q is a real orthogonal matrix defined as the product of k
45*> elementary reflectors
46*>
47*>       Q = H(1) H(2) . . . H(k)
48*>
49*> as returned by STZRZF. Q is of order M if SIDE = 'L' and of order N
50*> if SIDE = 'R'.
51*> \endverbatim
52*
53*  Arguments:
54*  ==========
55*
56*> \param[in] SIDE
57*> \verbatim
58*>          SIDE is CHARACTER*1
59*>          = 'L': apply Q or Q**T from the Left;
60*>          = 'R': apply Q or Q**T from the Right.
61*> \endverbatim
62*>
63*> \param[in] TRANS
64*> \verbatim
65*>          TRANS is CHARACTER*1
66*>          = 'N':  No transpose, apply Q;
67*>          = 'T':  Transpose, apply Q**T.
68*> \endverbatim
69*>
70*> \param[in] M
71*> \verbatim
72*>          M is INTEGER
73*>          The number of rows of the matrix C. M >= 0.
74*> \endverbatim
75*>
76*> \param[in] N
77*> \verbatim
78*>          N is INTEGER
79*>          The number of columns of the matrix C. N >= 0.
80*> \endverbatim
81*>
82*> \param[in] K
83*> \verbatim
84*>          K is INTEGER
85*>          The number of elementary reflectors whose product defines
86*>          the matrix Q.
87*>          If SIDE = 'L', M >= K >= 0;
88*>          if SIDE = 'R', N >= K >= 0.
89*> \endverbatim
90*>
91*> \param[in] L
92*> \verbatim
93*>          L is INTEGER
94*>          The number of columns of the matrix A containing
95*>          the meaningful part of the Householder reflectors.
96*>          If SIDE = 'L', M >= L >= 0, if SIDE = 'R', N >= L >= 0.
97*> \endverbatim
98*>
99*> \param[in] A
100*> \verbatim
101*>          A is REAL array, dimension
102*>                               (LDA,M) if SIDE = 'L',
103*>                               (LDA,N) if SIDE = 'R'
104*>          The i-th row must contain the vector which defines the
105*>          elementary reflector H(i), for i = 1,2,...,k, as returned by
106*>          STZRZF in the last k rows of its array argument A.
107*>          A is modified by the routine but restored on exit.
108*> \endverbatim
109*>
110*> \param[in] LDA
111*> \verbatim
112*>          LDA is INTEGER
113*>          The leading dimension of the array A. LDA >= max(1,K).
114*> \endverbatim
115*>
116*> \param[in] TAU
117*> \verbatim
118*>          TAU is REAL array, dimension (K)
119*>          TAU(i) must contain the scalar factor of the elementary
120*>          reflector H(i), as returned by STZRZF.
121*> \endverbatim
122*>
123*> \param[in,out] C
124*> \verbatim
125*>          C is REAL array, dimension (LDC,N)
126*>          On entry, the M-by-N matrix C.
127*>          On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
128*> \endverbatim
129*>
130*> \param[in] LDC
131*> \verbatim
132*>          LDC is INTEGER
133*>          The leading dimension of the array C. LDC >= max(1,M).
134*> \endverbatim
135*>
136*> \param[out] WORK
137*> \verbatim
138*>          WORK is REAL array, dimension (MAX(1,LWORK))
139*>          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
140*> \endverbatim
141*>
142*> \param[in] LWORK
143*> \verbatim
144*>          LWORK is INTEGER
145*>          The dimension of the array WORK.
146*>          If SIDE = 'L', LWORK >= max(1,N);
147*>          if SIDE = 'R', LWORK >= max(1,M).
148*>          For optimum performance LWORK >= N*NB if SIDE = 'L', and
149*>          LWORK >= M*NB if SIDE = 'R', where NB is the optimal
150*>          blocksize.
151*>
152*>          If LWORK = -1, then a workspace query is assumed; the routine
153*>          only calculates the optimal size of the WORK array, returns
154*>          this value as the first entry of the WORK array, and no error
155*>          message related to LWORK is issued by XERBLA.
156*> \endverbatim
157*>
158*> \param[out] INFO
159*> \verbatim
160*>          INFO is INTEGER
161*>          = 0:  successful exit
162*>          < 0:  if INFO = -i, the i-th argument had an illegal value
163*> \endverbatim
164*
165*  Authors:
166*  ========
167*
168*> \author Univ. of Tennessee 
169*> \author Univ. of California Berkeley 
170*> \author Univ. of Colorado Denver 
171*> \author NAG Ltd. 
172*
173*> \date November 2011
174*
175*> \ingroup realOTHERcomputational
176*
177*> \par Contributors:
178*  ==================
179*>
180*>    A. Petitet, Computer Science Dept., Univ. of Tenn., Knoxville, USA
181*
182*> \par Further Details:
183*  =====================
184*>
185*> \verbatim
186*> \endverbatim
187*>
188*  =====================================================================
189      SUBROUTINE SORMRZ( SIDE, TRANS, M, N, K, L, A, LDA, TAU, C, LDC,
190     $                   WORK, LWORK, INFO )
191*
192*  -- LAPACK computational routine (version 3.4.0) --
193*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
194*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
195*     November 2011
196*
197*     .. Scalar Arguments ..
198      CHARACTER          SIDE, TRANS
199      INTEGER            INFO, K, L, LDA, LDC, LWORK, M, N
200*     ..
201*     .. Array Arguments ..
202      REAL               A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
203*     ..
204*
205*  =====================================================================
206*
207*     .. Parameters ..
208      INTEGER            NBMAX, LDT
209      PARAMETER          ( NBMAX = 64, LDT = NBMAX+1 )
210*     ..
211*     .. Local Scalars ..
212      LOGICAL            LEFT, LQUERY, NOTRAN
213      CHARACTER          TRANST
214      INTEGER            I, I1, I2, I3, IB, IC, IINFO, IWS, JA, JC,
215     $                   LDWORK, LWKOPT, MI, NB, NBMIN, NI, NQ, NW
216*     ..
217*     .. Local Arrays ..
218      REAL               T( LDT, NBMAX )
219*     ..
220*     .. External Functions ..
221      LOGICAL            LSAME
222      INTEGER            ILAENV
223      EXTERNAL           LSAME, ILAENV
224*     ..
225*     .. External Subroutines ..
226      EXTERNAL           SLARZB, SLARZT, SORMR3, XERBLA
227*     ..
228*     .. Intrinsic Functions ..
229      INTRINSIC          MAX, MIN
230*     ..
231*     .. Executable Statements ..
232*
233*     Test the input arguments
234*
235      INFO = 0
236      LEFT = LSAME( SIDE, 'L' )
237      NOTRAN = LSAME( TRANS, 'N' )
238      LQUERY = ( LWORK.EQ.-1 )
239*
240*     NQ is the order of Q and NW is the minimum dimension of WORK
241*
242      IF( LEFT ) THEN
243         NQ = M
244         NW = MAX( 1, N )
245      ELSE
246         NQ = N
247         NW = MAX( 1, M )
248      END IF
249      IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
250         INFO = -1
251      ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'T' ) ) THEN
252         INFO = -2
253      ELSE IF( M.LT.0 ) THEN
254         INFO = -3
255      ELSE IF( N.LT.0 ) THEN
256         INFO = -4
257      ELSE IF( K.LT.0 .OR. K.GT.NQ ) THEN
258         INFO = -5
259      ELSE IF( L.LT.0 .OR. ( LEFT .AND. ( L.GT.M ) ) .OR.
260     $         ( .NOT.LEFT .AND. ( L.GT.N ) ) ) THEN
261         INFO = -6
262      ELSE IF( LDA.LT.MAX( 1, K ) ) THEN
263         INFO = -8
264      ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
265         INFO = -11
266      END IF
267*
268      IF( INFO.EQ.0 ) THEN
269         IF( M.EQ.0 .OR. N.EQ.0 ) THEN
270            LWKOPT = 1
271         ELSE
272*
273*           Determine the block size.  NB may be at most NBMAX, where
274*           NBMAX is used to define the local array T.
275*
276            NB = MIN( NBMAX, ILAENV( 1, 'SORMRQ', SIDE // TRANS, M, N,
277     $                               K, -1 ) )
278            LWKOPT = NW*NB
279         END IF
280         WORK( 1 ) = LWKOPT
281*
282         IF( LWORK.LT.MAX( 1, NW ) .AND. .NOT.LQUERY ) THEN
283            INFO = -13
284         END IF
285      END IF
286*
287      IF( INFO.NE.0 ) THEN
288         CALL XERBLA( 'SORMRZ', -INFO )
289         RETURN
290      ELSE IF( LQUERY ) THEN
291         RETURN
292      END IF
293*
294*     Quick return if possible
295*
296      IF( M.EQ.0 .OR. N.EQ.0 ) THEN
297         RETURN
298      END IF
299*
300      NBMIN = 2
301      LDWORK = NW
302      IF( NB.GT.1 .AND. NB.LT.K ) THEN
303         IWS = NW*NB
304         IF( LWORK.LT.IWS ) THEN
305            NB = LWORK / LDWORK
306            NBMIN = MAX( 2, ILAENV( 2, 'SORMRQ', SIDE // TRANS, M, N, K,
307     $              -1 ) )
308         END IF
309      ELSE
310         IWS = NW
311      END IF
312*
313      IF( NB.LT.NBMIN .OR. NB.GE.K ) THEN
314*
315*        Use unblocked code
316*
317         CALL SORMR3( SIDE, TRANS, M, N, K, L, A, LDA, TAU, C, LDC,
318     $                WORK, IINFO )
319      ELSE
320*
321*        Use blocked code
322*
323         IF( ( LEFT .AND. .NOT.NOTRAN ) .OR.
324     $       ( .NOT.LEFT .AND. NOTRAN ) ) THEN
325            I1 = 1
326            I2 = K
327            I3 = NB
328         ELSE
329            I1 = ( ( K-1 ) / NB )*NB + 1
330            I2 = 1
331            I3 = -NB
332         END IF
333*
334         IF( LEFT ) THEN
335            NI = N
336            JC = 1
337            JA = M - L + 1
338         ELSE
339            MI = M
340            IC = 1
341            JA = N - L + 1
342         END IF
343*
344         IF( NOTRAN ) THEN
345            TRANST = 'T'
346         ELSE
347            TRANST = 'N'
348         END IF
349*
350         DO 10 I = I1, I2, I3
351            IB = MIN( NB, K-I+1 )
352*
353*           Form the triangular factor of the block reflector
354*           H = H(i+ib-1) . . . H(i+1) H(i)
355*
356            CALL SLARZT( 'Backward', 'Rowwise', L, IB, A( I, JA ), LDA,
357     $                   TAU( I ), T, LDT )
358*
359            IF( LEFT ) THEN
360*
361*              H or H**T is applied to C(i:m,1:n)
362*
363               MI = M - I + 1
364               IC = I
365            ELSE
366*
367*              H or H**T is applied to C(1:m,i:n)
368*
369               NI = N - I + 1
370               JC = I
371            END IF
372*
373*           Apply H or H**T
374*
375            CALL SLARZB( SIDE, TRANST, 'Backward', 'Rowwise', MI, NI,
376     $                   IB, L, A( I, JA ), LDA, T, LDT, C( IC, JC ),
377     $                   LDC, WORK, LDWORK )
378   10    CONTINUE
379*
380      END IF
381*
382      WORK( 1 ) = LWKOPT
383*
384      RETURN
385*
386*     End of SORMRZ
387*
388      END
Note: See TracBrowser for help on using the repository browser.