source: trunk/SOURCES/Heino_files/climat-heino_mod.f90 @ 159

!> \file climat-heino_mod.f90
!!Module pour la lecture du climat des experience Heino
!<

!> \namespace climat_heino
!! Module pour la lecture du climat
!! \author ...
!! \date ...
!! @note Used module
!! @note   - use module3D_phy
!<


module  climat_heino               ! pour le climat des experiences Heino


use module3d_phy
implicit none

real, dimension(nx,ny) :: dist_heino     !< distance au centre
real,dimension(nx,ny) ::  xcc , ycc      !< coordeonnes en m
real :: bilmin                           !< bilan min
real :: bilmax                           !< bilan max 
real :: coefbil
real :: Rcal                             !< rayon de la calotte
real :: Tsmin                            !< Temperature min
real :: St                               !< gradient horizontal de temperature
real :: time_change                      !< temps apres lequel on met un changement
real :: deltaTann                        !< changement de temeprature
real :: ratiobil                         !< changement de bilan (facteur)


contains
!______________________________________________________________________________

!>SUBROUTINE: input_clim
!!Initialise la distance au centre
!<

  subroutine input_clim                  ! initialise la distance au centre

    real :: xcentre=2000.
    real :: ycentre=2000.
    real :: coefbil

    if (itracebug.eq.1)  call tracebug(' Heino: entree dans routine input_clim')


    do j=1,ny
       do i=1,nx
          xcc(i,j)=(i-1)*dx
          ycc(i,j)=(j-1)*dx
       end do
    end do

    xcc(:,:)=xcc(:,:)/1000.
    ycc(:,:)=ycc(:,:)/1000.


    dist_heino(:,:)=(xcc(:,:)-xcentre)**2+(ycc(:,:)-ycentre)**2
    dist_heino(:,:)=dist_heino(:,:)**0.5
    Rcal=2000.    ! en km mais la distance l'est aussi
    write(num_rep_42,*)
    write(num_rep_42,*)'bilan Heino------------------------------------'
    write(num_rep_42,*)'initialisation distance au centre en km'

    bilmin=0.15   ! en m/an
    bilmax=0.3    ! en m/an

    coefbil=(bilmax-bilmin)/Rcal

    bm(:,:)=bilmin+coefbil*dist_heino(:,:)

    where (mk0.eq.0) bm(:,:)=0.               ! 0 dans l'ocean

    write(num_rep_42,*) 'bilmin,bilmax (m/an)',bilmin,bilmax

    Tsmin=-40.0    ! run standard
    !Tsmin=-50.0    ! run T1
    St=2.5e-9

    write(num_rep_42,*)'Temperature, Tsmin (deg C), gradient (deg/km-3)',Tsmin,St

    Tann(:,:)=Tsmin+St*dist_heino(:,:)**3

    where (mk0.eq.0) Tann(:,:)=0.
    Ts(:,:)=Tann(:,:)

    time_change=1.e6
    deltaTann=0.
    ratiobil=1.

    write(num_rep_42,*)'Ces valeurs sont gardee jusqu a',time_change,'ans'
    write(num_rep_42,*)'apres : T=T+',deltaTann,'        bilan=bilan*',ratiobil

    Acc(:,:)=bm(:,:)

    return
  end subroutine input_clim

!__________________________________________________________________________

!>SUBROUTINE: forclim
!! Clacule du climat au cours du temps
!<
subroutine forclim
if (itracebug.eq.1)  call tracebug(' Heino: entree dans routine forclim')

if (time.gt.time_change) then
   Tann(:,:)=Tann(:,:)+deltaTann
   Ts(:,:)=Tann(:,:)
   bm(:,:)=bm(:,:)*ratiobil
endif


end subroutine forclim

end module climat_heino