source: trunk/SOURCES/Hudson_files/dragging_hwatermax_hudson_mod.f90 @ 21

!> \file dragging_hwatstream_sedim_hudson.f90
!! Defini les zones de stream
!<

!> \namespace  dragging_hwatstream_sedim_hudson
!! Defini les zones de stream
!! @note On applique un critere sur la hauteur d'eau
!! \author ...
!! \date ...
!! @note Used module
!! @note   - use module3D_phy
!! @note   - use sedim_declar
!<

module dragging_hwatstream_sedim_hudson
! Defini les zones de stream avec un critere sur la hauteur d'eau
! modification pour ajouter un frottement faible dans les zones sediments

  USE module3D_phy
  USE sedim_declar


  implicit none
  real :: tostick
  real :: Cfs           !< coefficient du frottement des zones sediments
  real :: seuil_sedim   !< seuil sur hw_mx pour avoir du glissement
  real :: coefmax
  real :: coefslid
  real :: coefdrag
  real, dimension(nx,ny) :: hw_mx
  real, dimension(nx,ny) :: hw_my

contains
!-------------------------------------------------------------------------------
subroutine init_dragging      !< Cette routine fait l'initialisation du dragging.

  implicit none
 
  namelist/drag_hwat_stream/hwatstream,cf,betamax,toblim,tostick,Cfs,seuil_sedim,coefmax    

  if (itracebug.eq.1)  call tracebug(' Dragging avec hwatermax')


! formats pour les ecritures dans 42
428 format(A)
  
! lecture des parametres du run                block drag_hwat_stream
!--------------------------------------------------------------------

  rewind(num_param)        ! pour revenir au debut du fichier param_list.dat
  read(num_param,drag_hwat_stream)

  write(num_rep_42,428)'!___________________________________________________________' 
  write(num_rep_42,428) '&drag_hwat_stream           ! nom du bloc drag_hwat_stream '
  write(num_rep_42,*)
  write(num_rep_42,*) 'hwatstream     = ', hwatstream 
  write(num_rep_42,*) 'cf             = ', cf
  write(num_rep_42,*) 'betamax         = ', betamax
  write(num_rep_42,*) 'toblim         = ', toblim
  write(num_rep_42,*) 'Cfs            = ', Cfs
  write(num_rep_42,*) 'seuil_sedim    = ', seuil_sedim
  write(num_rep_42,*) 'coefmax        = ', coefmax
  write(num_rep_42,*)'/'                            
  write(num_rep_42,428) '! hwatstream (m) :  critere de passage en stream si hwater > hwatstream '
  write(num_rep_42,428) '! cf coefficient de la loi de frottement fonction Neff'
  write(num_rep_42,428) '! betamax : (Pa) frottement maxi '
  write(num_rep_42,428) '! toblim : (Pa) tes pour les iles '
  write(num_rep_42,428) '! Cfs : coefficient de la loi de frottement sediment'
  write(num_rep_42,428) '! seuil_sedim : seuil pour passer en stream si zone sediment'
  write(num_rep_42,428) '! coefmax : hauteur d eau max dans le sediment (=hwatermax)'
  write(num_rep_42,*)

  tostick=1.e5   ! valeurs pour les points non flgzmx

  coefmax=hwatermax
!-------------------------------------------------------------------
! masque stream

  mstream_mx(:,:)=1
  mstream_my(:,:)=1

! coefficient permettant de modifier le basal drag.
  drag_mx(:,:)=1.
  drag_my(:,:)=1.
   
  coefdrag=rog/Cfs
  Cfs=0.
  write(42,*) 'dragging_hwatermax_heino'
  write(42,*) 'coeff frottement zone sediment (Pa/m) Coefdrag=',coefdrag

  return
end subroutine init_dragging


! defini la localisation des streams et le frottement basal
subroutine dragging   


!         les iles n'ont pas de condition neff mais ont la condition toblim
!         (ce bloc etait avant dans flottab)

call moy_mxmy(nx,ny,Hwater,hw_mx,hw_my)

  do j=2,ny
     do i=2,nx
        ilemx(i,j)=ilemx(i,j).and.(abs(tobmx(i,j)).lt.toblim)
        ilemy(i,j)=ilemy(i,j).and.(abs(tobmy(i,j)).lt.toblim)
     end do
  end do


  gzm_x: do j=1,ny  ! 2,ny
     do i=2,nx ! -1
   
! gzmx pour les hauteurs d'eau superieures a un seuil
! attention, il semble qu'il y avait une erreur dans la precedente
! formulation car le test etait seulement sur hwater(i,j).
! le gzmx initial a ete calculé dans flottab pour les points a cheval sur la grounding line

! mais gzmx peut être quand même vrai selon une conditon sur la pression effective 
        gzmx(i,j)=gzmx(i,j).or.((Neffmx(i,j).lt.neffratio*hmx(i,j))  &
             .and..not.flotmx(i,j))  

! ce cas est un ilemx traité plus loin
! if (i.gt.2.AND.i.lt.nx)   gzmx(i,j)=gzmx(i,j).or.(.not.flot(i,j).and. & 
!             .not.flot(i-1,j).and.flot(i+1,j).and.flot(i-2,j))     !    F    P    P    F

!      On rajoute une condition sur la contrainte basale
!      si tobmx(i,j) > toblim (de l'ordre de 1 bar), passage a pose

        gzmx(i,j)=gzmx(i,j).and.(abs(tobmx(i,j)).lt.toblim)
        gzmx(i,j)=gzmx(i,j).or.((hwater(i,j).gt.hwatstream).and..not.flotmx(i,j))

! calcul du frottement basal (ce bloc etait avant dans neffect)
        if (mkxsedim(i,j).eq.2) then  ! loi sediment
           if (hw_mx(i,j).ge.seuil_sedim) then
              if (.not.flot(i,j)) then
                 gzmx(i,j)=.true.
                 coefslid=hw_mx(i,j)
                 coefslid=max(coefslid,seuil_sedim)
                 coefslid=min(coefslid/coefmax,1.)
                 betamx(i,j)=min(coefdrag/coefslid,1.e5)
                 flgzmx(i,j)=.true.
                 mslid_mx(i,j)=5
                 shelfy=.true.
              endif
           endif
        else if (gzmx(i,j)) then                          ! stream
           betamx(i,j)=cf*neffmx(i,j) 
        else if (flotmx(i,j).or.ilemx(i,j)) then     ! flottant ou ile
           betamx(i,j)=0.
        else                                         ! grounded, SIA
           betamx(i,j)=tostick                       ! frottement glace posee (1 bar)
        endif

     end do
  end do gzm_x

  gzm_y: do j=2,ny  !-1
     do i=1,nx  ! 2,nx
   
! gzmy pour les hauteurs d'eau superieures a un seuil
! attention, il semble qu'il y avait une erreur dans la precedente
! formulation car le test etait seulement sur hwater(i,j).

! mais gzmx peut être quand même vrai selon une conditon sur la pression effective 
        gzmy(i,j)=gzmy(i,j).or.((Neffmy(i,j).lt.neffratio*hmy(i,j))  &
             .and..not.flotmy(i,j))

! ce cas est un ilemy traité plus loin
!          if (j.gt.2.AND.j.lt.ny) gzmy(i,j)=gzmy(i,j).or.(flot(i,j).and.      &
!             .not.flot(i,j-1).and.flot(i,j+1).and.flot(i,j-2))
               
!      On rajoute une condition sur la contrainte basale
!      si tobmy(i,j) > toblim (de l'ordre de 1 bar), passage a pose
        gzmy(i,j)=gzmy(i,j).and.(abs(tobmy(i,j)).lt.toblim)
        gzmy(i,j)=gzmy(i,j).or.((hwater(i,j).gt.hwatstream).and..not.flotmy(i,j))

 ! calcul du frottement basal (ce bloc etait avant dans neffect)
        if (mkysedim(i,j).eq.2) then  ! loi sediment
           if (hw_my(i,j).ge.seuil_sedim) then
               if (.not.flot(i,j)) then
                  gzmy(i,j)=.true.
                  coefslid=hw_my(i,j)
                  coefslid=max(coefslid,seuil_sedim)
                  coefslid=min(coefslid/coefmax,1.)
                  betamy(i,j)=min(coefdrag/coefslid,1.e5)
                  flgzmy(i,j)=.true.
                  mslid_my(i,j)=5
                  shelfy=.true.
               endif
            endif
         else if (gzmy(i,j)) then                ! stream
            betamy(i,j)=cf*neffmy(i,j) 
         else if (flotmy(i,j).or.ilemy(i,j)) then     ! flottant ou ile
            betamy(i,j)=0.
         else                               ! grounded, SIA
            betamy(i,j)=tostick             ! frottement glace posee
         endif

      end do
   end do gzm_y

   return
 end subroutine dragging

end module dragging_hwatstream_sedim_hudson