source: CONFIG/UNIFORM/v6/IPSLCM5A2/SOURCES/NEMO/PALEO/diaar5.F90

Last change on this file was 5879, checked in by snguyen, 3 years ago

Modified Makefile to add configuration PALEOIPSLCM5A2-VLR while retaining IPSLCM5A2-VLR as default configuration for compilation. Moved NEMO SOURCES of IPSLCM5A2-VLR to SOURCES/NEMO/STANDARD and created SOURCES/NEMO/PALEO for PALEOIPSLCM5A2-VLR configuration. Created paleolmdz in Makefile to compile LMDZ sources in SOURCES/LMDZ/PALEO. Added experiments IPSLCM/paleo and LMDZOR/paleo. Added file_def_nemo-lim2_paleo.xml file_def_histmth_lmdz_paleo.xml file_def_nemo-opa_paleo.xml file_def_nemo-pisces_rivers_paleo.xml file_def_nemo-pisces_paleo.xml file_def_orchidee_paleo.xml namelist_ORCA2_cfg_paleo namelist_pisces_ORCA2_cfg_paleo to GENERAL/PARAM for paleo configurations. Set day_step=720 in GENERAL/PARAM/gcm.def_96x95 for paleo configurations. Modified GENERAL/DRIVER/opa9.driver to use namelist_ORCA2_cfg_paleo for paleo configurations.
File size: 12.2 KB
Line 
1MODULE diaar5
2   !!======================================================================
3   !!                       ***  MODULE  diaar5  ***
4   !! AR5 diagnostics
5   !!======================================================================
6   !! History :  3.2  !  2009-11  (S. Masson)  Original code
7   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
8   !!----------------------------------------------------------------------
9#if defined key_diaar5   || defined key_esopa
10   !!----------------------------------------------------------------------
11   !!   'key_diaar5'  :                           activate ar5 diagnotics
12   !!----------------------------------------------------------------------
13   !!   dia_ar5       : AR5 diagnostics
14   !!   dia_ar5_init  : initialisation of AR5 diagnostics
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and active tracers
17   USE dom_oce        ! ocean space and time domain
18   USE eosbn2         ! equation of state                (eos_bn2 routine)
19   USE lib_mpp        ! distribued memory computing library
20   USE iom            ! I/O manager library
21   USE timing         ! preformance summary
22   USE wrk_nemo       ! working arrays
23   USE fldread        ! type FLD_N
24   USE phycst         ! physical constant
25   USE in_out_manager  ! I/O manager
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   dia_ar5        ! routine called in step.F90 module
31   PUBLIC   dia_ar5_init   ! routine called in opa.F90 module
32   PUBLIC   dia_ar5_alloc  ! routine called in nemogcm.F90 module
33
34   LOGICAL, PUBLIC, PARAMETER :: lk_diaar5 = .TRUE.   ! coupled flag
35
36   REAL(wp)                         ::   vol0         ! ocean volume (interior domain)
37   REAL(wp)                         ::   area_tot     ! total ocean surface (interior domain)
38   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:  ) ::   area         ! cell surface (interior domain)
39   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:  ) ::   thick0       ! ocean thickness (interior domain)
40   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sn0          ! initial salinity
41     
42   !! * Substitutions
43#  include "domzgr_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
46   !! $Id: diaar5.F90 6664 2016-06-03 13:42:46Z cetlod $
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   FUNCTION dia_ar5_alloc()
52      !!----------------------------------------------------------------------
53      !!                    ***  ROUTINE dia_ar5_alloc  ***
54      !!----------------------------------------------------------------------
55      INTEGER :: dia_ar5_alloc
56      !!----------------------------------------------------------------------
57      !
58      ALLOCATE( area(jpi,jpj), thick0(jpi,jpj) , sn0(jpi,jpj,jpk) , STAT=dia_ar5_alloc )
59      !
60      IF( lk_mpp             )   CALL mpp_sum ( dia_ar5_alloc )
61      IF( dia_ar5_alloc /= 0 )   CALL ctl_warn('dia_ar5_alloc: failed to allocate arrays')
62      !
63   END FUNCTION dia_ar5_alloc
64
65
66   SUBROUTINE dia_ar5( kt )
67      !!----------------------------------------------------------------------
68      !!                    ***  ROUTINE dia_ar5  ***
69      !!
70      !! ** Purpose :   compute and output some AR5 diagnostics
71      !!----------------------------------------------------------------------
72      !
73      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
74      !
75      INTEGER  ::   ji, jj, jk                      ! dummy loop arguments
76      REAL(wp) ::   zvolssh, zvol, zssh_steric, zztmp, zarho, ztemp, zsal, zmass
77      !
78      REAL(wp), POINTER, DIMENSION(:,:)     :: zarea_ssh , zbotpres       ! 2D workspace
79      REAL(wp), POINTER, DIMENSION(:,:,:)   :: zrhd , z3d, zrhop               ! 3D workspace
80      REAL(wp), POINTER, DIMENSION(:,:,:,:) :: ztsn                       ! 4D workspace
81      !!--------------------------------------------------------------------
82      IF( nn_timing == 1 )   CALL timing_start('dia_ar5')
83 
84      CALL wrk_alloc( jpi , jpj              , zarea_ssh , zbotpres )
85      CALL wrk_alloc( jpi , jpj , jpk        , zrhd      , z3d, zrhop    )
86      CALL wrk_alloc( jpi , jpj , jpk , jpts , ztsn                 )
87
88      zarea_ssh(:,:) = area(:,:) * sshn(:,:)
89
90      !                                         ! total volume of liquid seawater
91      zvolssh = SUM( zarea_ssh(:,:) ) 
92      IF( lk_mpp )   CALL mpp_sum( zvolssh )
93      zvol = vol0 + zvolssh
94
95      z3d(:,:,jpk) = 0._wp        ! ocean volume
96      DO jk = 1, jpkm1
97         z3d (:,:,jk) = area(:,:) * fse3t(:,:,jk) * tmask(:,:,jk)
98      END DO
99
100      CALL iom_put( "bathy"     , bathy(:,:) )
101      CALL iom_put( "areacello" , area (:,:) )
102      CALL iom_put( "volcello"  , z3d(:,:,:)         )     ! WARNING not consistent with CMIP DR where volcello is at ca. 2000
103      CALL iom_put( "masscello" , rau0 * fse3t(:,:,:) * tmask(:,:,:) )  ! ocean mass
104
105
106      CALL iom_put( 'voltot', zvol               )
107      CALL iom_put( 'sshtot', zvolssh / area_tot )
108
109      !                     
110      ztsn(:,:,:,jp_tem) = tsn(:,:,:,jp_tem)                    ! thermosteric ssh
111      ztsn(:,:,:,jp_sal) = sn0(:,:,:)
112      CALL eos( ztsn, zrhd, fsdept_n(:,:,:) )                       ! now in situ density using initial salinity
113      !
114      zbotpres(:,:) = 0._wp                        ! no atmospheric surface pressure, levitating sea-ice
115      DO jk = 1, jpkm1
116         zbotpres(:,:) = zbotpres(:,:) + fse3t(:,:,jk) * zrhd(:,:,jk)
117      END DO
118      IF( .NOT.lk_vvl ) THEN
119         IF ( ln_isfcav ) THEN
120            DO ji=1,jpi
121               DO jj=1,jpj
122                  zbotpres(ji,jj) = zbotpres(ji,jj) + sshn(ji,jj) * zrhd(ji,jj,mikt(ji,jj)) + riceload(ji,jj)
123               END DO
124            END DO
125         ELSE
126            zbotpres(:,:) = zbotpres(:,:) + sshn(:,:) * zrhd(:,:,1)
127         END IF
128      END IF
129      !                                         
130      zarho = SUM( area(:,:) * zbotpres(:,:) ) 
131      IF( lk_mpp )   CALL mpp_sum( zarho )
132      zssh_steric = - zarho / area_tot
133      CALL iom_put( 'sshthster', zssh_steric )
134     
135      !                                         ! steric sea surface height
136      CALL eos( tsn, zrhd, zrhop, fsdept_n(:,:,:) )                 ! now in situ and potential density
137      zrhop(:,:,jpk) = 0._wp
138      CALL iom_put( 'rhop', zrhop )
139      !
140      zbotpres(:,:) = 0._wp                        ! no atmospheric surface pressure, levitating sea-ice
141      DO jk = 1, jpkm1
142         zbotpres(:,:) = zbotpres(:,:) + fse3t(:,:,jk) * zrhd(:,:,jk)
143      END DO
144      IF( .NOT.lk_vvl ) THEN
145         IF ( ln_isfcav ) THEN
146            DO ji=1,jpi
147               DO jj=1,jpj
148                  zbotpres(ji,jj) = zbotpres(ji,jj) + sshn(ji,jj) * zrhd(ji,jj,mikt(ji,jj)) + riceload(ji,jj)
149               END DO
150            END DO
151         ELSE
152            zbotpres(:,:) = zbotpres(:,:) + sshn(:,:) * zrhd(:,:,1)
153         END IF
154      END IF
155      !   
156      zarho = SUM( area(:,:) * zbotpres(:,:) ) 
157      IF( lk_mpp )   CALL mpp_sum( zarho )
158      zssh_steric = - zarho / area_tot
159      CALL iom_put( 'sshsteric', zssh_steric )
160     
161      !                                         ! ocean bottom pressure
162      zztmp = rau0 * grav * 1.e-4_wp               ! recover pressure from pressure anomaly and cover to dbar = 1.e4 Pa
163      zbotpres(:,:) = zztmp * ( zbotpres(:,:) + sshn(:,:) + thick0(:,:) )
164      CALL iom_put( 'botpres', zbotpres )
165
166      !                                         ! Mean density anomalie, temperature and salinity
167      ztemp = 0._wp
168      zsal  = 0._wp
169      DO jk = 1, jpkm1
170         DO jj = 1, jpj
171            DO ji = 1, jpi
172               zztmp = area(ji,jj) * fse3t(ji,jj,jk)
173               ztemp = ztemp + zztmp * tsn(ji,jj,jk,jp_tem)
174               zsal  = zsal  + zztmp * tsn(ji,jj,jk,jp_sal)
175            END DO
176         END DO
177      END DO
178      IF( .NOT.lk_vvl ) THEN
179         IF ( ln_isfcav ) THEN
180            DO ji=1,jpi
181               DO jj=1,jpj
182                  ztemp = ztemp + zarea_ssh(ji,jj) * tsn(ji,jj,mikt(ji,jj),jp_tem) 
183                  zsal  = zsal  + zarea_ssh(ji,jj) * tsn(ji,jj,mikt(ji,jj),jp_sal) 
184               END DO
185            END DO
186         ELSE
187            ztemp = ztemp + SUM( zarea_ssh(:,:) * tsn(:,:,1,jp_tem) )
188            zsal  = zsal  + SUM( zarea_ssh(:,:) * tsn(:,:,1,jp_sal) )
189         END IF
190      ENDIF
191      IF( lk_mpp ) THEN 
192         CALL mpp_sum( ztemp )
193         CALL mpp_sum( zsal  )
194      END IF
195      !
196      zmass = rau0 * ( zarho + zvol )                 ! total mass of liquid seawater
197      ztemp = ztemp / zvol                            ! potential temperature in liquid seawater
198      zsal  = zsal  / zvol                            ! Salinity of liquid seawater
199      !
200      CALL iom_put( 'masstot', zmass )
201      CALL iom_put( 'temptot', ztemp )
202      CALL iom_put( 'saltot' , zsal  )
203      !
204      CALL wrk_dealloc( jpi , jpj              , zarea_ssh , zbotpres    )
205      CALL wrk_dealloc( jpi , jpj , jpk        , zrhd      , z3d , zrhop )
206      CALL wrk_dealloc( jpi , jpj , jpk , jpts , ztsn                    )
207      !
208      IF( nn_timing == 1 )   CALL timing_stop('dia_ar5')
209      !
210   END SUBROUTINE dia_ar5
211
212
213   SUBROUTINE dia_ar5_init
214      !!----------------------------------------------------------------------
215      !!                  ***  ROUTINE dia_ar5_init  ***
216      !!                   
217      !! ** Purpose :   initialization for AR5 diagnostic computation
218      !!----------------------------------------------------------------------
219      INTEGER  ::   inum
220      INTEGER  ::   ik
221      INTEGER  ::   ji, jj, jk  ! dummy loop indices
222      REAL(wp) ::   zztmp 
223      REAL(wp), POINTER, DIMENSION(:,:,:,:) ::   zsaldta   ! Jan/Dec levitus salinity
224      !
225      !!----------------------------------------------------------------------
226      !
227      IF( nn_timing == 1 )   CALL timing_start('dia_ar5_init')
228      !
229      CALL wrk_alloc( jpi, jpj, jpk, 2, zsaldta )
230      !                                      ! allocate dia_ar5 arrays
231      IF( dia_ar5_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'dia_ar5_init : unable to allocate arrays' )
232
233      area(:,:) = e1t(:,:) * e2t(:,:) * tmask_i(:,:)
234
235      area_tot = SUM( area(:,:) )   ;   IF( lk_mpp )   CALL mpp_sum( area_tot )
236
237      vol0        = 0._wp
238      thick0(:,:) = 0._wp
239      DO jk = 1, jpkm1
240         vol0        = vol0        + SUM( area (:,:) * tmask(:,:,jk) * e3t_0(:,:,jk) )
241         thick0(:,:) = thick0(:,:) +    tmask_i(:,:) * tmask(:,:,jk) * e3t_0(:,:,jk)
242      END DO
243      IF( lk_mpp )   CALL mpp_sum( vol0 )
244
245      CALL iom_open ( 'sali_ref_clim_monthly', inum )
246      CALL iom_get  ( inum, jpdom_data, 'vosaline' , zsaldta(:,:,:,1), 1  )
247      CALL iom_get  ( inum, jpdom_data, 'vosaline' , zsaldta(:,:,:,2), 12 )
248      CALL iom_close( inum )
249
250      sn0(:,:,:) = 0.5_wp * ( zsaldta(:,:,:,1) + zsaldta(:,:,:,2) )       
251      sn0(:,:,:) = sn0(:,:,:) * tmask(:,:,:)
252      IF( ln_zps ) THEN               ! z-coord. partial steps
253         DO jj = 1, jpj               ! interpolation of salinity at the last ocean level (i.e. the partial step)
254            DO ji = 1, jpi
255               ik = mbkt(ji,jj)
256               IF( ik > 1 ) THEN
257                  zztmp = ( gdept_1d(ik) - gdept_0(ji,jj,ik) ) / ( gdept_1d(ik) - gdept_1d(ik-1) )
258                  sn0(ji,jj,ik) = ( 1._wp - zztmp ) * sn0(ji,jj,ik) + zztmp * sn0(ji,jj,ik-1)
259               ENDIF
260            END DO
261         END DO
262      ENDIF
263      !
264      CALL wrk_dealloc( jpi, jpj, jpk, 2, zsaldta )
265      !
266      IF( nn_timing == 1 )   CALL timing_stop('dia_ar5_init')
267      !
268   END SUBROUTINE dia_ar5_init
269
270#else
271   !!----------------------------------------------------------------------
272   !!   Default option :                                         NO diaar5
273   !!----------------------------------------------------------------------
274   LOGICAL, PUBLIC, PARAMETER :: lk_diaar5 = .FALSE.   ! coupled flag
275CONTAINS
276   SUBROUTINE dia_ar5_init    ! Dummy routine
277   END SUBROUTINE dia_ar5_init
278   SUBROUTINE dia_ar5( kt )   ! Empty routine
279      INTEGER ::   kt
280      WRITE(*,*) 'dia_ar5: You should not have seen this print! error?', kt
281   END SUBROUTINE dia_ar5
282#endif
283
284   !!======================================================================
285END MODULE diaar5
Note: See TracBrowser for help on using the repository browser.