source: CONFIG/UNIFORM/v6/IPSLCM5A2/SOURCES/NEMO/PALEO/traadv.F90 @ 5879

Last change on this file since 5879 was 5879, checked in by snguyen, 3 years ago

Modified Makefile to add configuration PALEOIPSLCM5A2-VLR while retaining IPSLCM5A2-VLR as default configuration for compilation. Moved NEMO SOURCES of IPSLCM5A2-VLR to SOURCES/NEMO/STANDARD and created SOURCES/NEMO/PALEO for PALEOIPSLCM5A2-VLR configuration. Created paleolmdz in Makefile to compile LMDZ sources in SOURCES/LMDZ/PALEO. Added experiments IPSLCM/paleo and LMDZOR/paleo. Added file_def_nemo-lim2_paleo.xml file_def_histmth_lmdz_paleo.xml file_def_nemo-opa_paleo.xml file_def_nemo-pisces_rivers_paleo.xml file_def_nemo-pisces_paleo.xml file_def_orchidee_paleo.xml namelist_ORCA2_cfg_paleo namelist_pisces_ORCA2_cfg_paleo to GENERAL/PARAM for paleo configurations. Set day_step=720 in GENERAL/PARAM/gcm.def_96x95 for paleo configurations. Modified GENERAL/DRIVER/opa9.driver to use namelist_ORCA2_cfg_paleo for paleo configurations.
File size: 14.3 KB
Line 
1MODULE traadv
2   !!==============================================================================
3   !!                       ***  MODULE  traadv  ***
4   !! Ocean active tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  2005-11  (G. Madec)  Original code
7   !!            3.3  !  2010-09  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
8   !!            4.0  !  2011-06  (G. Madec)  Addition of Mixed Layer Eddy parameterisation
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   tra_adv      : compute ocean tracer advection trend
13   !!   tra_adv_ctl  : control the different options of advection scheme
14   !!----------------------------------------------------------------------
15   USE oce             ! ocean dynamics and active tracers
16   USE dom_oce         ! ocean space and time domain
17   USE domvvl          ! variable vertical scale factors
18   USE traadv_cen2     ! 2nd order centered scheme (tra_adv_cen2   routine)
19   USE traadv_tvd      ! TVD      scheme           (tra_adv_tvd    routine)
20   USE traadv_muscl    ! MUSCL    scheme           (tra_adv_muscl  routine)
21   USE traadv_muscl2   ! MUSCL2   scheme           (tra_adv_muscl2 routine)
22   USE traadv_ubs      ! UBS      scheme           (tra_adv_ubs    routine)
23   USE traadv_qck      ! QUICKEST scheme           (tra_adv_qck    routine)
24   USE traadv_eiv      ! eddy induced velocity     (tra_adv_eiv    routine)
25   USE traadv_mle      ! ML eddy induced velocity  (tra_adv_mle    routine)
26   USE cla             ! cross land advection      (cla_traadv     routine)
27   USE ldftra_oce      ! lateral diffusion coefficient on tracers
28   !
29   USE in_out_manager  ! I/O manager
30   USE iom             ! I/O module
31   USE prtctl          ! Print control
32   USE lib_mpp         ! MPP library
33   USE wrk_nemo        ! Memory Allocation
34   USE timing          ! Timing
35   USE sbc_oce
36   USE diaptr          ! Poleward heat transport
37
38
39   IMPLICIT NONE
40   PRIVATE
41
42   PUBLIC   tra_adv        ! routine called by step module
43   PUBLIC   tra_adv_init   ! routine called by opa module
44
45   !                              !!* Namelist namtra_adv *
46   LOGICAL ::   ln_traadv_cen2     ! 2nd order centered scheme flag
47   LOGICAL ::   ln_traadv_tvd      ! TVD scheme flag
48   LOGICAL ::   ln_traadv_tvd_zts  ! TVD scheme flag with vertical sub time-stepping
49   LOGICAL ::   ln_traadv_muscl    ! MUSCL scheme flag
50   LOGICAL ::   ln_traadv_muscl2   ! MUSCL2 scheme flag
51   LOGICAL ::   ln_traadv_ubs      ! UBS scheme flag
52   LOGICAL ::   ln_traadv_qck      ! QUICKEST scheme flag
53   LOGICAL ::   ln_traadv_msc_ups  ! use upstream scheme within muscl
54
55
56   INTEGER ::   nadv   ! choice of the type of advection scheme
57
58   !! * Substitutions
59#  include "domzgr_substitute.h90"
60#  include "vectopt_loop_substitute.h90"
61   !!----------------------------------------------------------------------
62   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
63   !! $Id: traadv.F90 5147 2015-03-13 10:01:32Z cetlod $
64   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
65   !!----------------------------------------------------------------------
66CONTAINS
67
68   SUBROUTINE tra_adv( kt )
69      !!----------------------------------------------------------------------
70      !!                  ***  ROUTINE tra_adv  ***
71      !!
72      !! ** Purpose :   compute the ocean tracer advection trend.
73      !!
74      !! ** Method  : - Update (ua,va) with the advection term following nadv
75      !!----------------------------------------------------------------------
76      !
77      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
78      !
79      INTEGER ::   jk   ! dummy loop index
80      REAL(wp), POINTER, DIMENSION(:,:,:) :: zun, zvn, zwn
81      !!----------------------------------------------------------------------
82      !
83      IF( nn_timing == 1 )  CALL timing_start('tra_adv')
84      !
85      CALL wrk_alloc( jpi, jpj, jpk, zun, zvn, zwn )
86      !                                          ! set time step
87      IF( neuler == 0 .AND. kt == nit000 ) THEN     ! at nit000
88         r2dtra(:) =  rdttra(:)                          ! = rdtra (restarting with Euler time stepping)
89      ELSEIF( kt <= nit000 + 1) THEN                ! at nit000 or nit000+1
90         r2dtra(:) = 2._wp * rdttra(:)                   ! = 2 rdttra (leapfrog)
91      ENDIF
92      !
93      ! Add PALEORCA2 configuration -- JBL 08.02.2017
94      IF( nn_cla == 1 .AND. cp_cfg == 'orca' .AND. jp_cfg == 2 )   CALL cla_traadv( kt )       !==  Cross Land Advection  ==! (hor. advection)
95      IF( nn_cla == 1 .AND. cp_cfg == 'paleorca' .AND. jp_cfg == 2 )   CALL cla_traadv( kt )       !==  Cross Land Advection if needed ==! (hor. advection)
96      !
97      !                                               !==  effective transport  ==!
98      DO jk = 1, jpkm1
99         zun(:,:,jk) = e2u(:,:) * fse3u(:,:,jk) * un(:,:,jk)                  ! eulerian transport only
100         zvn(:,:,jk) = e1v(:,:) * fse3v(:,:,jk) * vn(:,:,jk)
101         zwn(:,:,jk) = e1t(:,:) * e2t(:,:)      * wn(:,:,jk)
102      END DO
103      !
104      IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN
105         zun(:,:,:) = zun(:,:,:) + un_td(:,:,:)
106         zvn(:,:,:) = zvn(:,:,:) + vn_td(:,:,:)
107      ENDIF
108      !
109      zun(:,:,jpk) = 0._wp                                                     ! no transport trough the bottom
110      zvn(:,:,jpk) = 0._wp                                                     ! no transport trough the bottom
111      zwn(:,:,jpk) = 0._wp                                                     ! no transport trough the bottom
112      !
113      IF( lk_traldf_eiv .AND. .NOT. ln_traldf_grif )   &
114         &              CALL tra_adv_eiv( kt, nit000, zun, zvn, zwn, 'TRA' )    ! add the eiv transport (if necessary)
115      !
116      IF( ln_mle    )   CALL tra_adv_mle( kt, nit000, zun, zvn, zwn, 'TRA' )    ! add the mle transport (if necessary)
117      !
118      CALL iom_put( "uocetr_eff", zun )                                         ! output effective transport     
119      CALL iom_put( "vocetr_eff", zvn )
120      CALL iom_put( "wocetr_eff", zwn )
121      !
122      IF( ln_diaptr )   CALL dia_ptr( zvn )                                     ! diagnose the effective MSF
123      !
124   
125      SELECT CASE ( nadv )                            !==  compute advection trend and add it to general trend  ==!
126      CASE ( 1 )   ;    CALL tra_adv_cen2   ( kt, nit000, 'TRA',         zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  2nd order centered
127      CASE ( 2 )   ;    CALL tra_adv_tvd    ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  TVD
128      CASE ( 3 )   ;    CALL tra_adv_muscl  ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb,      tsa, jpts, ln_traadv_msc_ups )   !  MUSCL
129      CASE ( 4 )   ;    CALL tra_adv_muscl2 ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  MUSCL2
130      CASE ( 5 )   ;    CALL tra_adv_ubs    ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  UBS
131      CASE ( 6 )   ;    CALL tra_adv_qck    ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  QUICKEST
132      CASE ( 7 )   ;    CALL tra_adv_tvd_zts( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  TVD ZTS
133      !
134      CASE (-1 )                                      !==  esopa: test all possibility with control print  ==!
135         CALL tra_adv_cen2  ( kt, nit000, 'TRA',         zun, zvn, zwn, tsb, tsn, tsa, jpts )         
136         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv0 - Ta: ', mask1=tmask,               &
137            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
138         CALL tra_adv_tvd   ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
139         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv1 - Ta: ', mask1=tmask,               &
140            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
141         CALL tra_adv_muscl ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb,      tsa, jpts, ln_traadv_msc_ups )         
142         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv3 - Ta: ', mask1=tmask,               &
143            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
144         CALL tra_adv_muscl2( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
145         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv4 - Ta: ', mask1=tmask,               &
146            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
147         CALL tra_adv_ubs   ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
148         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv5 - Ta: ', mask1=tmask,               &
149            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
150         CALL tra_adv_qck   ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
151         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv6 - Ta: ', mask1=tmask,               &
152            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
153      END SELECT
154      !
155      !                                              ! print mean trends (used for debugging)
156      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv  - Ta: ', mask1=tmask,               &
157         &                       tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
158      !
159      IF( nn_timing == 1 )  CALL timing_stop( 'tra_adv' )
160      !
161      CALL wrk_dealloc( jpi, jpj, jpk, zun, zvn, zwn )
162      !                                         
163   END SUBROUTINE tra_adv
164
165
166   SUBROUTINE tra_adv_init
167      !!---------------------------------------------------------------------
168      !!                  ***  ROUTINE tra_adv_init  ***
169      !!               
170      !! ** Purpose :   Control the consistency between namelist options for
171      !!              tracer advection schemes and set nadv
172      !!----------------------------------------------------------------------
173      INTEGER ::   ioptio
174      INTEGER ::   ios                 ! Local integer output status for namelist read
175      !!
176      NAMELIST/namtra_adv/ ln_traadv_cen2 , ln_traadv_tvd,     &
177         &                 ln_traadv_muscl, ln_traadv_muscl2,  &
178         &                 ln_traadv_ubs  , ln_traadv_qck,     &
179         &                 ln_traadv_msc_ups, ln_traadv_tvd_zts
180      !!----------------------------------------------------------------------
181
182      REWIND( numnam_ref )              ! Namelist namtra_adv in reference namelist : Tracer advection scheme
183      READ  ( numnam_ref, namtra_adv, IOSTAT = ios, ERR = 901)
184901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_adv in reference namelist', lwp )
185
186      REWIND( numnam_cfg )              ! Namelist namtra_adv in configuration namelist : Tracer advection scheme
187      READ  ( numnam_cfg, namtra_adv, IOSTAT = ios, ERR = 902 )
188902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_adv in configuration namelist', lwp )
189      IF(lwm) WRITE ( numond, namtra_adv )
190
191      IF(lwp) THEN                    ! Namelist print
192         WRITE(numout,*)
193         WRITE(numout,*) 'tra_adv_init : choice/control of the tracer advection scheme'
194         WRITE(numout,*) '~~~~~~~~~~~'
195         WRITE(numout,*) '   Namelist namtra_adv : chose a advection scheme for tracers'
196         WRITE(numout,*) '      2nd order advection scheme     ln_traadv_cen2    = ', ln_traadv_cen2
197         WRITE(numout,*) '      TVD advection scheme           ln_traadv_tvd     = ', ln_traadv_tvd
198         WRITE(numout,*) '      MUSCL  advection scheme        ln_traadv_muscl   = ', ln_traadv_muscl
199         WRITE(numout,*) '      MUSCL2 advection scheme        ln_traadv_muscl2  = ', ln_traadv_muscl2
200         WRITE(numout,*) '      UBS    advection scheme        ln_traadv_ubs     = ', ln_traadv_ubs
201         WRITE(numout,*) '      QUICKEST advection scheme      ln_traadv_qck     = ', ln_traadv_qck
202         WRITE(numout,*) '      upstream scheme within muscl   ln_traadv_msc_ups = ', ln_traadv_msc_ups
203         WRITE(numout,*) '      TVD advection scheme with zts  ln_traadv_tvd_zts = ', ln_traadv_tvd_zts
204      ENDIF
205
206      ioptio = 0                      ! Parameter control
207      IF( ln_traadv_cen2   )   ioptio = ioptio + 1
208      IF( ln_traadv_tvd    )   ioptio = ioptio + 1
209      IF( ln_traadv_muscl  )   ioptio = ioptio + 1
210      IF( ln_traadv_muscl2 )   ioptio = ioptio + 1
211      IF( ln_traadv_ubs    )   ioptio = ioptio + 1
212      IF( ln_traadv_qck    )   ioptio = ioptio + 1
213      IF( ln_traadv_tvd_zts)   ioptio = ioptio + 1
214      IF( lk_esopa         )   ioptio =          1
215
216      IF( ( ln_traadv_muscl .OR. ln_traadv_muscl2 .OR. ln_traadv_ubs .OR. ln_traadv_qck .OR. ln_traadv_tvd_zts )   &
217         .AND. ln_isfcav )   CALL ctl_stop( 'Only traadv_cen2 and traadv_tvd is compatible with ice shelf cavity')
218
219      IF( ioptio /= 1 )   CALL ctl_stop( 'Choose ONE advection scheme in namelist namtra_adv' )
220
221      !                              ! Set nadv
222      IF( ln_traadv_cen2   )   nadv =  1
223      IF( ln_traadv_tvd    )   nadv =  2
224      IF( ln_traadv_muscl  )   nadv =  3
225      IF( ln_traadv_muscl2 )   nadv =  4
226      IF( ln_traadv_ubs    )   nadv =  5
227      IF( ln_traadv_qck    )   nadv =  6
228      IF( ln_traadv_tvd_zts)   nadv =  7
229      IF( lk_esopa         )   nadv = -1
230
231      IF(lwp) THEN                   ! Print the choice
232         WRITE(numout,*)
233         IF( nadv ==  1 )   WRITE(numout,*) '         2nd order scheme is used'
234         IF( nadv ==  2 )   WRITE(numout,*) '         TVD       scheme is used'
235         IF( nadv ==  3 )   WRITE(numout,*) '         MUSCL     scheme is used'
236         IF( nadv ==  4 )   WRITE(numout,*) '         MUSCL2    scheme is used'
237         IF( nadv ==  5 )   WRITE(numout,*) '         UBS       scheme is used'
238         IF( nadv ==  6 )   WRITE(numout,*) '         QUICKEST  scheme is used'
239         IF( nadv ==  7 )   WRITE(numout,*) '         TVD ZTS   scheme is used'
240         IF( nadv == -1 )   WRITE(numout,*) '         esopa test: use all advection scheme'
241      ENDIF
242      !
243      CALL tra_adv_mle_init          ! initialisation of the Mixed Layer Eddy parametrisation (MLE)
244      !
245   END SUBROUTINE tra_adv_init
246
247  !!======================================================================
248END MODULE traadv
Note: See TracBrowser for help on using the repository browser.