source: CONFIG/UNIFORM/v6/IPSLCM6CHT/SOURCES/NEMO/traadv_muscl2.F90 @ 2456

Last change on this file since 2456 was 2456, checked in by acosce, 9 years ago

Add new configuration IPSLCM6CHT

File size: 15.3 KB
Line 
1MODULE traadv_muscl2
2   !!======================================================================
3   !!                       ***  MODULE  traadv_muscl2  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :  1.0  !  2002-06  (G. Madec) from traadv_muscl
7   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   tra_adv_muscl2 : update the tracer trend with the horizontal
12   !!                    and vertical advection trends using MUSCL2 scheme
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and active tracers
15   USE dom_oce         ! ocean space and time domain
16   USE trdmod_oce      ! tracers trends
17   USE trdtra          ! tracers trends
18   USE in_out_manager  ! I/O manager
19   USE dynspg_oce      ! choice/control of key cpp for surface pressure gradient
20   USE trabbl          ! tracers: bottom boundary layer
21   USE lib_mpp         ! distribued memory computing
22   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
23   USE diaptr_oce          ! poleward transport diagnostics
24   USE trc_oce         ! share passive tracers/Ocean variables
25   USE wrk_nemo        ! Memory Allocation
26   USE timing          ! Timing
27   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   tra_adv_muscl2        ! routine called by step.F90
33
34   LOGICAL  :: l_trd       ! flag to compute trends
35
36   !! * Substitutions
37#  include "domzgr_substitute.h90"
38#  include "vectopt_loop_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
41   !! $Id: traadv_muscl2.F90 4499 2014-02-18 15:14:31Z timgraham $
42   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE tra_adv_muscl2( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
47      &                                         ptb, ptn, pta, kjpt )
48      !!----------------------------------------------------------------------
49      !!                   ***  ROUTINE tra_adv_muscl2  ***
50      !!
51      !! ** Purpose :   Compute the now trend due to total advection of T and
52      !!      S using a MUSCL scheme (Monotone Upstream-centered Scheme for
53      !!      Conservation Laws) and add it to the general tracer trend.
54      !!
55      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
56      !!
57      !! ** Action  : - update (pta) with the now advective tracer trends
58      !!              - save trends
59      !!
60      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
61      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
62      !!----------------------------------------------------------------------
63      USE oce     , ONLY:   zwx   => ua    , zwy   => va         ! (ua,va) used as 3D workspace
64      !!
65      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
66      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
67      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
68      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
69      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
70      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
71      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before & now tracer fields
72      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
73      !!
74      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
75      REAL(wp) ::   zu, z0u, zzwx, zw         ! local scalars
76      REAL(wp) ::   zv, z0v, zzwy, z0w        !   -      -
77      REAL(wp) ::   ztra, zbtr, zdt, zalpha   !   -      -
78      REAL(wp), POINTER, DIMENSION(:,:,:) :: zslpx, zslpy
79      !!----------------------------------------------------------------------
80      !
81      IF( nn_timing == 1 )  CALL timing_start('tra_adv_muscl2')
82      !
83      CALL wrk_alloc( jpi, jpj, jpk, zslpx, zslpy )
84      !
85
86      IF( kt == kit000 )  THEN
87         IF(lwp) WRITE(numout,*)
88         IF(lwp) WRITE(numout,*) 'tra_adv_muscl2 : MUSCL2 advection scheme on ', cdtype
89         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~'
90      ENDIF
91      !
92      l_trd = .FALSE.
93      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )   l_trd = .TRUE.
94
95      !                                                          ! ===========
96      DO jn = 1, kjpt                                            ! tracer loop
97         !                                                       ! ===========
98         ! I. Horizontal advective fluxes
99         ! ------------------------------
100         ! first guess of the slopes
101         zwx(:,:,jpk) = 0.e0   ;   zwy(:,:,jpk) = 0.e0        ! bottom values
102         ! interior values
103         DO jk = 1, jpkm1
104            DO jj = 1, jpjm1     
105               DO ji = 1, fs_jpim1   ! vector opt.
106                  zwx(ji,jj,jk) = umask(ji,jj,jk) * ( ptb(ji+1,jj,jk,jn) - ptb(ji,jj,jk,jn) )
107                  zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( ptb(ji,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
108               END DO
109           END DO
110         END DO
111         !
112         CALL lbc_lnk( zwx, 'U', -1. )                        ! lateral boundary conditions on zwx, zwy   (changed sign)
113         CALL lbc_lnk( zwy, 'V', -1. )
114         !                                             !-- Slopes of tracer
115         zslpx(:,:,jpk) = 0.e0   ;   zslpy(:,:,jpk) = 0.e0    ! bottom values
116         DO jk = 1, jpkm1                                     ! interior values
117            DO jj = 2, jpj
118               DO ji = fs_2, jpi   ! vector opt.
119                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
120                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
121                  zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
122                     &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
123               END DO
124            END DO
125         END DO
126         !
127         DO jk = 1, jpkm1                                     ! Slopes limitation
128            DO jj = 2, jpj
129               DO ji = fs_2, jpi   ! vector opt.
130                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
131                     &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
132                     &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
133                  zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
134                     &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
135                     &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
136               END DO
137           END DO
138         END DO             ! interior values
139
140        !                                             !-- MUSCL horizontal advective fluxes
141         DO jk = 1, jpkm1                                     ! interior values
142            zdt  = p2dt(jk)
143            DO jj = 2, jpjm1
144               DO ji = fs_2, fs_jpim1   ! vector opt.
145                  ! MUSCL fluxes
146                  z0u = SIGN( 0.5, pun(ji,jj,jk) )
147                  zalpha = 0.5 - z0u
148                  zu  = z0u - 0.5 * pun(ji,jj,jk) * zdt / ( e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk) )
149                  zzwx = ptb(ji+1,jj,jk,jn) + zu * zslpx(ji+1,jj,jk)
150                  zzwy = ptb(ji  ,jj,jk,jn) + zu * zslpx(ji  ,jj,jk)
151                  zwx(ji,jj,jk) = pun(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
152                  !
153                  z0v = SIGN( 0.5, pvn(ji,jj,jk) )
154                  zalpha = 0.5 - z0v
155                  zv  = z0v - 0.5 * pvn(ji,jj,jk) * zdt / ( e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk) )
156                  zzwx = ptb(ji,jj+1,jk,jn) + zv * zslpy(ji,jj+1,jk)
157                  zzwy = ptb(ji,jj  ,jk,jn) + zv * zslpy(ji,jj  ,jk)
158                  zwy(ji,jj,jk) = pvn(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
159               END DO
160            END DO
161         END DO
162
163         !!  centered scheme at lateral b.C. if off-shore velocity
164         DO jk = 1, jpkm1
165            DO jj = 2, jpjm1
166               DO ji = fs_2, fs_jpim1   ! vector opt.
167                  IF( umask(ji,jj,jk) == 0. ) THEN
168                     IF( pun(ji+1,jj,jk) > 0. .AND. ji /= jpi ) THEN
169                        zwx(ji+1,jj,jk) = 0.5 * pun(ji+1,jj,jk) * ( ptn(ji+1,jj,jk,jn) + ptn(ji+2,jj,jk,jn) )
170                     ENDIF
171                     IF( pun(ji-1,jj,jk) < 0. ) THEN
172                        zwx(ji-1,jj,jk) = 0.5 * pun(ji-1,jj,jk) * ( ptn(ji-1,jj,jk,jn) + ptn(ji,jj,jk,jn) ) 
173                     ENDIF
174                  ENDIF
175                  IF( vmask(ji,jj,jk) == 0. ) THEN
176                     IF( pvn(ji,jj+1,jk) > 0. .AND. jj /= jpj ) THEN
177                        zwy(ji,jj+1,jk) = 0.5 * pvn(ji,jj+1,jk) * ( ptn(ji,jj+1,jk,jn) + ptn(ji,jj+2,jk,jn) )
178                     ENDIF
179                     IF( pvn(ji,jj-1,jk) < 0. ) THEN
180                        zwy(ji,jj-1,jk) = 0.5 * pvn(ji,jj-1,jk) * ( ptn(ji,jj-1,jk,jn) + ptn(ji,jj,jk,jn) ) 
181                     ENDIF
182                  ENDIF
183               END DO
184            END DO
185         END DO
186         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )   ! lateral boundary condition (changed sign)
187
188         ! Tracer flux divergence at t-point added to the general trend
189         DO jk = 1, jpkm1
190            DO jj = 2, jpjm1
191               DO ji = fs_2, fs_jpim1   ! vector opt.
192                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
193                  ! horizontal advective trends
194                  ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
195                  &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )
196                  ! added to the general tracer trends
197                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
198               END DO
199           END DO
200         END DO
201         !                                 ! trend diagnostics (contribution of upstream fluxes)
202         IF( l_trd ) THEN
203            CALL trd_tra( kt, cdtype, jn, jptra_trd_xad, zwx, pun, ptb(:,:,:,jn) )
204            CALL trd_tra( kt, cdtype, jn, jptra_trd_yad, zwy, pvn, ptb(:,:,:,jn) )
205         END IF
206
207         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
208         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN
209            IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) )
210            IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) )
211         ENDIF
212
213         ! II. Vertical advective fluxes
214         ! -----------------------------
215         !                                             !-- first guess of the slopes
216         zwx (:,:, 1 ) = 0.e0    ;    zwx (:,:,jpk) = 0.e0    ! surface & bottom boundary conditions
217         DO jk = 2, jpkm1                                     ! interior values
218            zwx(:,:,jk) = tmask(:,:,jk) * ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) )
219         END DO
220
221         !                                             !-- Slopes of tracer
222         zslpx(:,:,1) = 0.e0                                  ! surface values
223         DO jk = 2, jpkm1                                     ! interior value
224            DO jj = 1, jpj
225               DO ji = 1, jpi
226                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )   &
227                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) ) )
228               END DO
229            END DO
230         END DO
231         !                                             !-- Slopes limitation
232         DO jk = 2, jpkm1                                     ! interior values
233            DO jj = 1, jpj
234               DO ji = 1, jpi
235                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
236                     &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
237                     &                                                 2.*ABS( zwx  (ji,jj,jk  ) )  )
238               END DO
239            END DO
240         END DO
241         !                                             !-- vertical advective flux
242         !                                                    ! surface values  (bottom already set to zero)
243         IF( lk_vvl ) THEN    ;   zwx(:,:, 1 ) = 0.e0                      !  variable volume
244         ELSE                 ;   zwx(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
245         ENDIF
246         !
247         DO jk = 1, jpkm1                                     ! interior values
248            zdt  = p2dt(jk)
249            DO jj = 2, jpjm1
250               DO ji = fs_2, fs_jpim1   ! vector opt.
251                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3w(ji,jj,jk+1) )
252                  z0w = SIGN( 0.5, pwn(ji,jj,jk+1) )
253                  zalpha = 0.5 + z0w
254                  zw  = z0w - 0.5 * pwn(ji,jj,jk+1) * zdt * zbtr
255                  zzwx = ptb(ji,jj,jk+1,jn) + zw * zslpx(ji,jj,jk+1)
256                  zzwy = ptb(ji,jj,jk  ,jn) + zw * zslpx(ji,jj,jk  )
257                  zwx(ji,jj,jk+1) = pwn(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
258               END DO
259            END DO
260         END DO
261         !
262         DO jk = 2, jpkm1        ! centered near the bottom
263            DO jj = 2, jpjm1
264               DO ji = fs_2, fs_jpim1   ! vector opt.
265                  IF( tmask(ji,jj,jk+1) == 0. ) THEN
266                     IF( pwn(ji,jj,jk) > 0. ) THEN
267                        zwx(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk-1,jn) + ptn(ji,jj,jk,jn) ) 
268                     ENDIF
269                  ENDIF
270               END DO
271            END DO
272         END DO
273         !
274         DO jk = 1, jpkm1        ! Compute & add the vertical advective trend
275            DO jj = 2, jpjm1     
276               DO ji = fs_2, fs_jpim1   ! vector opt.
277                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
278                  ! vertical advective trends
279                  ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) )
280                  ! added to the general tracer trends
281                  pta(ji,jj,jk,jn) =  pta(ji,jj,jk,jn) + ztra
282               END DO
283            END DO
284         END DO
285         !                       ! trend diagnostics (contribution of upstream fluxes)
286         IF( l_trd )  CALL trd_tra( kt, cdtype, jn, jptra_trd_zad, zwx, pwn, ptb(:,:,:,jn) )
287         !
288      END DO
289      !
290      CALL wrk_dealloc( jpi, jpj, jpk, zslpx, zslpy )
291      !
292      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_muscl2')
293      !
294   END SUBROUTINE tra_adv_muscl2
295
296   !!======================================================================
297END MODULE traadv_muscl2
Note: See TracBrowser for help on using the repository browser.