!$Id: aerosol_meteo_calc.F90 163 2010-02-22 15:41:45Z acosce $
!! =========================================================================
!! INCA - INteraction with Chemistry and Aerosols
!! 
!! Copyright Laboratoire des Sciences du Climat et de l'Environnement (LSCE)
!! 	     Unite mixte CEA-CNRS-UVSQ
!! 
!! Contributors to this INCA subroutine:
!! 
!! Michael Schulz, LSCE, Michael.Schulz@cea.fr
!! S. Bauer, LSCE
!! Y. Balkanski, LSCE, Yves.Balkanski@cea.fr
!!
!! Anne Cozic, LSCE, anne.cozic@cea.fr
!! Yann Meurdesoif, LSCE, yann.meurdesoif@cea.fr
!! 
!! This software is a computer program whose purpose is to simulate the 
!! atmospheric gas phase and aerosol composition. The model is designed to be
!! used within a transport model or a general circulation model. This version 
!! of INCA was designed to be coupled to the LMDz GCM. LMDz-INCA accounts
!! for emissions, transport (resolved and sub-grid scale), photochemical 
!! transformations, and scavenging (dry deposition and washout) of chemical 
!! species and aerosols interactively in the GCM. Several versions of the INCA
!! model are currently used depending on the envisaged applications with the 
!! chemistry-climate model. 
!! 
!! This software is governed by the CeCILL  license under French law and
!! abiding by the rules of distribution of free software.  You can  use, 
!! modify and/ or redistribute the software under the terms of the CeCILL
!! license as circulated by CEA, CNRS and INRIA at the following URL
!! "http://www.cecill.info". 
!! 
!! As a counterpart to the access to the source code and  rights to copy,
!! modify and redistribute granted by the license, users are provided only
!! with a limited warranty  and the software's author,  the holder of the
!! economic rights,  and the successive licensors  have only  limited
!! liability. 
!! 
!! In this respect, the user's attention is drawn to the risks associated
!! with loading,  using,  modifying and/or developing or reproducing the
!! software by the user in light of its specific status of free software,
!! that may mean  that it is complicated to manipulate,  and  that  also
!! therefore means  that it is reserved for developers  and  experienced
!! professionals having in-depth computer knowledge. Users are therefore
!! encouraged to load and test the software's suitability as regards their
!! requirements in conditions enabling the security of their systems and/or 
!! data to be ensured and,  more generally, to use and operate it in the 
!! same conditions as regards security. 
!! 
!! The fact that you are presently reading this means that you have had
!! knowledge of the CeCILL license and that you accept its terms.
!! =========================================================================


SUBROUTINE AEROSOL_METEO_CALC (          &
   calday,delt,pmid,pfull,t_seri,        &
   flxrcv,flxscv,flxrst,flxsst,pctsrf,   &
   area,rlat,rlon, u10m, v10m)
  !     -----------------------------------------------------------------------
  !
  !     **** calculation of meterological info used in aerosol calculations
  !     
  !     Author
  !     Michael Schulz  
  !     June 2002
  !
  !     interface
  !     ---------
  !      input 
  !       see below intent(in)
  !

  USE CHEM_CONS, ONLY : gravit    
  USE AEROSOL_METEO, ONLY : zspeed,zspeed2, &
     zcalday,zprecip,landmask,zdens,zdp1, &
     airm,zheight,ztempc,zvis,zlair,zlat, &
     zlon,seawind,landwind
  USE INCA_DIM
  USE CONST_MOD
  USE CONST_LMDZ
  USE TIME_MOD_INCA
  USE PARAM_CHEM


  IMPLICIT NONE


  REAL, INTENT(in) ::     calday
  REAL, INTENT(in) ::     delt                ! [s]
  REAL, INTENT(in) ::     pmid(PLON,PLEV)     ! [Pa]
  REAL, INTENT(in) ::     pfull(PLON,PLEV+1)  ! [Pa]
  REAL, INTENT(in) ::     t_seri(PLON,PLEV)   ! [K]
  REAL, INTENT(in) ::     flxrst(PLON,PLEV+1) ! liquid water flux (stratiform) kgH2O/m2/s
  REAL, INTENT(in) ::     flxrcv(PLON,PLEV+1) ! liquid  water flux (convection ) kgH2O/m2/s
  REAL, INTENT(in) ::     flxsst(PLON,PLEV+1) ! solid  water flux (stratiform) kgH2O/m2/s
  REAL, INTENT(in) ::     flxscv(PLON,PLEV+1) ! solid  water flux (convection) kgH2O/m2/s
  REAL, INTENT(in) ::     pctsrf(PLON,nbsrf)  ! subsurface fraction (0..1)
  REAL, INTENT(in) ::     area(PLON)          ! surface area of grid box [m2]
  REAL, INTENT(in) ::     rlon(PLON)          ! longitude
  REAL, INTENT(in) ::     rlat(PLON)          ! latitude
  REAL, INTENT(in) ::     u10m(PLON,nbsrf)    ! vents a 10m 
  REAL, INTENT(in) ::     v10m(PLON,nbsrf)    ! vents a 10m 

  REAL :: pdel(PLON,PLEV)                     ! PRESSURE diff across midpoints (T+DT) [Pa]
  REAL :: radry = 287.054                     ! dry air mass constant
  INTEGER :: l,k,j



  landmask=pctsrf(:,3)

  ! pressure difference 
  DO k = 1, PLEV
    pdel(:,k) = pfull(:,k) - pfull(:,k+1)
  END DO

  ! calculation of air density zdens [kg/m^3], 
  zdens=pmid/(radry*t_seri)

  ! air mass auxiliary  variable --> zdp1 [kg/(m^2 *s)]
  zdp1=pdel/(gravit*delt) 

  ! air mass calculation 
  DO L=1,PLEV
    airm(:,L)=zdp1(:,L)*area*delt ! --> kg
  ENDDO

  ! computation of the layer height zheight in meters
  zheight=pdel/(gravit*zdens)

  ! dynamic viscosity of air after Prup.Klett in [Pa s]
  ztempc = t_seri - 273.15
  WHERE (ztempc .GE. 0.)
      zvis=(1.718 + 0.0049*ztempc)*1.E-5
  ELSEWHERE
      zvis=(1.718 + 0.0049*ztempc - 1.2E-05*(ztempc**2))*1.E-5
  END WHERE

  ! mean free path of air (Prupp. Klett) in [10^-6 m] 
  zlair = 0.066 *(1.01325E+5/pmid)*(t_seri/293.15)*1.E-06 

END SUBROUTINE AEROSOL_METEO_CALC