source: CONFIG/publications/ICOLMDZORINCA_CO2_Transport_GMD_2023/INCA/build/ppsrc/INCA_SRC/prate_inti.f90 @ 6610

!$Id: prate_inti.F90 104 2008-12-23 10:28:51Z acosce $
!! =========================================================================
!! INCA - INteraction with Chemistry and Aerosols
!! 
!! Copyright Laboratoire des Sciences du Climat et de l'Environnement (LSCE)
!!           Unite mixte CEA-CNRS-UVSQ
!! 
!! Contributors to this INCA subroutine:
!! 
!! Stacy Walters, NCAR, stacy@ucar.edu 
!! 
!! Anne Cozic, LSCE, anne.cozic@cea.fr
!! Yann Meurdesoif, LSCE, yann.meurdesoif@cea.fr
!!
!! This software is a computer program whose purpose is to simulate the 
!! atmospheric gas phase and aerosol composition. The model is designed to be
!! used within a transport model or a general circulation model. This version 
!! of INCA was designed to be coupled to the LMDz GCM. LMDz-INCA accounts
!! for emissions, transport (resolved and sub-grid scale), photochemical 
!! transformations, and scavenging (dry deposition and washout) of chemical 
!! species and aerosols interactively in the GCM. Several versions of the INCA
!! model are currently used depending on the envisaged applications with the 
!! chemistry-climate model. 
!! 
!! This software is governed by the CeCILL  license under French law and
!! abiding by the rules of distribution of free software.  You can  use, 
!! modify and/ or redistribute the software under the terms of the CeCILL
!! license as circulated by CEA, CNRS and INRIA at the following URL
!! "http://www.cecill.info". 
!! 
!! As a counterpart to the access to the source code and  rights to copy,
!! modify and redistribute granted by the license, users are provided only
!! with a limited warranty  and the software's author,  the holder of the
!! economic rights,  and the successive licensors  have only  limited
!! liability. 
!! 
!! In this respect, the user's attention is drawn to the risks associated
!! with loading,  using,  modifying and/or developing or reproducing the
!! software by the user in light of its specific status of free software,
!! that may mean  that it is complicated to manipulate,  and  that  also
!! therefore means  that it is reserved for developers  and  experienced
!! professionals having in-depth computer knowledge. Users are therefore
!! encouraged to load and test the software's suitability as regards their
!! requirements in conditions enabling the security of their systems and/or 
!! data to be ensured and,  more generally, to use and operate it in the 
!! same conditions as regards security. 
!! 
!! The fact that you are presently reading this means that you have had
!! knowledge of the CeCILL license and that you accept its terms.
!! =========================================================================

SUBROUTINE PRATE_INTI( unit )
  !----------------------------------------------------------------------
  !     ... Read in the photorate tables and arrays
  !         Results are "returned" via the module PHT_TABLES
  ! Stacy Walters, NCAR, 1998.
  !----------------------------------------------------------------------

  USE PHT_TABLES
  USE MOD_INCA_PARA
  USE PRINT_INCA
  USE CHEM_CONS

  IMPLICIT NONE
  
  !----------------------------------------------------------------------
  !        ... Dummy args
  !----------------------------------------------------------------------
  INTEGER, INTENT(in) :: unit

  !----------------------------------------------------------------------
  !        ... Local variables
  !----------------------------------------------------------------------
  INTEGER    :: it500, it200, izen, ialb, idob
  INTEGER    :: ios, is
  REAL       :: jinput(jdim,altdim,zangdim,o3ratdim, &
     albdim,t500dim,t200dim)
  
!$OMP MASTER
  IF (is_mpi_root) THEN
      
      OPEN( unit   = unit              ,&
         file   = 'phototable.dat'  ,&
         status = 'old'             ,&
         form   = 'formatted'       ,&
         iostat = ios )
      IF( ios /= 0 ) THEN
          !----------------------------------------------------------------------
          !     ... Open error exit
          !----------------------------------------------------------------------
          call print_err(3, "PRATE_INTI", 'Error opening phototable.dat', '', '')
      END IF
      
!----------------------------------------------------------------------
!        ... Readin the reference o3 column and photorate table
!----------------------------------------------------------------------
      READ(unit,*,iostat=ios) vo3
      IF( ios /= 0 ) THEN
          CALL print_err(3, ' PRATE_INTI','Failed to read o3 column', '', '')
      END IF

      DO it500 = 1,t500dim
        DO it200 = 1,t200dim
          DO izen = 1,zangdim
            DO ialb = 1,albdim
              DO idob = 1,o3ratdim
                READ(unit,*,iostat=ios)        & 
                   jinput(:,:,izen,idob,ialb,it500,it200)
                IF( ios /= 0 ) THEN
                    CALL print_err(3, ' PRATE_INTI', ' Failed to read phototable', '', '')
                END IF
              END DO
            END DO
          END DO
        END DO
      END DO
      ajl = RESHAPE( jinput, (/tabdim/) )
      CLOSE( unit )
      
  ENDIF ! is_root_prc
!$OMP END MASTER
      
  CALL bcast(vo3)
  CALL bcast(ajl)
  
  !----------------------------------------------------------------------
  ! ... Calculates secant based on input zenith angle
  !----------------------------------------------------------------------
  DO is = 1, zangdim
    vsec(is) = 1. / COS(dsza(is)*d2r)
  END DO

  !----------------------------------------------------------------------
  !     ... Set module variables
  !----------------------------------------------------------------------
  delz(:altdim-1) = 1. / (zz(2:altdim) - zz(:altdim-1))
  delang(:zangdim-1) = 1. / (vsec(2:zangdim) - vsec(:zangdim-1))
  delv(:o3ratdim-1) = 1. / (xv3(2:o3ratdim) - xv3(:o3ratdim-1))
  delalb(:albdim-1)  = 1. / (albev(2:albdim) - albev(:albdim-1))
  delt500(:t500dim-1) = 1. / (t500(2:t500dim) - t500(:t500dim-1))
  delt200(:t200dim-1) = 1. / (t200(2:t200dim) - t200(:t200dim-1))
  
  offset(1) = jdim
  offset(2) = offset(1)*altdim
  offset(3) = offset(2)*zangdim
  offset(4) = offset(3)*o3ratdim
  offset(5) = offset(4)*albdim
  offset(6) = offset(5)*t500dim
  offset(7) = SUM( offset(1:6) )
  
END SUBROUTINE PRATE_INTI