source: CONFIG_DEVT/IPSLCM6.2.2_ENSEMBLES/config/IPSLCM6/SOURCES/NEMO/ensemble.F90 @ 6205

MODULE ensemble_oce

  
  LOGICAL,SAVE :: ensemble_management         ! true if ensemble is managed
  INTEGER,SAVE :: COMM_ENSEMBLE               ! MPI communicator for the ensemble pool
  INTEGER,SAVE :: whole_ensemble_size         ! number of members in whole ensemble
  INTEGER,SAVE :: whole_ensemble_rank         ! local member number in whole ensemble

  
  INTEGER,SAVE :: ensemble_pool_size, ensemble_pool_rank, ensemble_pool_member_rank
  LOGICAL,SAVE :: namelist_read=.FALSE. 
  CHARACTER(LEN=256) :: str_ensemble_pool_member_rank
  
CONTAINS

  SUBROUTINE init_ensemble(ensemble_communicator, member_communicator)
  USE lib_mpp
  IMPLICIT NONE
#if defined key_mpp_mpi
   INCLUDE 'mpif.h'
#endif

    INTEGER, INTENT(IN)  :: ensemble_communicator          ! communicator of pool ensemble
    INTEGER, INTENT(OUT) :: member_communicator            ! returned communicator for local member
    INTEGER :: ensemble_comm_size, ensemble_comm_rank
    INTEGER :: ierr
   
    CALL read_ensemble_namelist
    COMM_ENSEMBLE=ensemble_communicator

#if defined key_mpp_mpi
     CALL MPI_COMM_SIZE(ensemble_communicator,ensemble_comm_size,ierr)
     CALL MPI_COMM_RANK(ensemble_communicator,ensemble_comm_rank,ierr)
#endif

     IF (MOD(ensemble_comm_size,ensemble_pool_size)/=0) THEN
       CALL ctl_stop('ensemble_oce::init_ensemble  :  Nb of MPI processes in whole ensemble is not divisible by the size of ensemble')
     ENDIF  
    
#if defined key_mpp_mpi
     CALL MPI_COMM_SPLIT(COMM_ENSEMBLE, ensemble_pool_member_rank, ensemble_comm_rank, member_communicator,ierr)
#endif
     whole_ensemble_rank = ensemble_pool_size*ensemble_pool_rank+ensemble_pool_member_rank
     
  END SUBROUTINE init_ensemble
  
  
  SUBROUTINE get_ensemble_code_id(base_code_id, ensemble_code_id)
  IMPLICIT NONE
    CHARACTER(LEN=*), INTENT(IN)  :: base_code_id
    CHARACTER(LEN=*), INTENT(OUT) :: ensemble_code_id
    CHARACTER(LEN=256)            :: str_rank
    
    CALL read_ensemble_namelist
    
    IF (ensemble_management) THEN
      WRITE(str_rank,*) ensemble_pool_member_rank
      ensemble_code_id=TRIM(ADJUSTL(base_code_id))//":"//TRIM(ADJUSTL(str_rank))
    ELSE
      ensemble_code_id=base_code_id
    ENDIF
    
  END SUBROUTINE get_ensemble_code_id

  SUBROUTINE read_ensemble_namelist
  USE lib_mpp
  IMPLICIT NONE
    CHARACTER(LEN=*),PARAMETER :: filename="namelist_ensemble"
    INTEGER          :: ierr, u
    LOGICAL :: exist
    NAMELIST /ensemble/ whole_ensemble_size, ensemble_pool_size, ensemble_pool_rank, ensemble_pool_member_rank

    IF (.NOT.namelist_read) THEN
      ensemble_management=.FALSE.
      ensemble_pool_size = 1
      whole_ensemble_size = ensemble_pool_size
      ensemble_pool_rank=0
      ensemble_pool_member_rank=0
    
      INQUIRE(file=filename, EXIST=exist)
      IF (exist) THEN
        OPEN(action='read', file=filename, iostat=ierr, newunit=u)
        READ(u,nml=ensemble, iostat=ierr)
        IF (ierr /= 0) CALL ctl_stop('ensemble_oce::init_ensemble  :  failed to read ensemble namelist')
        CLOSE(u)
        ensemble_management=.TRUE.
      ELSE
        ensemble_management=.FALSE.
      ENDIF
      IF (whole_ensemble_size>1) ensemble_management=.TRUE.
      namelist_read=.TRUE.
    ENDIF
    str_ensemble_pool_member_rank=""
    WRITE(str_ensemble_pool_member_rank,*) ensemble_pool_member_rank
   END SUBROUTINE read_ensemble_namelist

END MODULE ensemble_oce