source: CONFIG_DEVT/LMDZOR_V6.2_work_ENSEMBLES/modeles/LMDZ/libf/dyn3dmem/mod_const_mpi.F90 @ 5488

! 
! $Id: mod_const_mpi.F90 2055 2014-06-04 12:33:27Z acaubel $
!
MODULE mod_const_mpi
  IMPLICIT NONE
  INTEGER,SAVE :: COMM_LMDZ
  INTEGER,SAVE :: MPI_REAL_LMDZ
  INTEGER,SAVE :: COMM_LMDZ_ENSEMBLE

CONTAINS 

  SUBROUTINE Init_const_mpi
#ifdef CPP_IOIPSL
    USE IOIPSL, ONLY: getin
#else
! if not using IOIPSL, we still need to use (a local version of) getin
    USE ioipsl_getincom, only: getin
#endif
! Use of Oasis-MCT coupler 
#ifdef CPP_OMCT
    USE mod_prism
#endif
#ifdef CPP_XIOS
    USE wxios, only: wxios_init
#endif
    IMPLICIT NONE
#ifdef CPP_MPI
    INCLUDE 'mpif.h'
#endif

    INTEGER             :: ierr
    INTEGER             :: comp_id
    INTEGER             :: thread_required
    INTEGER             :: thread_provided
    CHARACTER(len = 6)  :: type_ocean
    

!$OMP MASTER
    type_ocean = 'force '
    CALL getin('type_ocean', type_ocean)
!$OMP END MASTER
!$OMP BARRIER

    IF (type_ocean=='couple') THEN
#ifdef CPP_COUPLE
!$OMP MASTER
#ifdef CPP_XIOS
      CALL wxios_init("LMDZ", outcom=COMM_LMDZ, type_ocean=type_ocean)
#else
       CALL prism_init_comp_proto (comp_id, 'LMDZ', ierr)
       CALL prism_get_localcomm_proto(COMM_LMDZ,ierr)
#endif
!$OMP END MASTER
#endif
#ifdef CPP_MPI
      MPI_REAL_LMDZ=MPI_REAL8
#endif
    ELSE
      CALL init_mpi
    ENDIF

  END SUBROUTINE Init_const_mpi
  
  SUBROUTINE Init_mpi
#ifdef CPP_XIOS
    USE wxios, only: wxios_init
#endif

#ifdef CPP_IOIPSL
    USE IOIPSL, ONLY: getin
#else
! if not using IOIPSL, we still need to use (a local version of) getin
    USE ioipsl_getincom, only: getin
#endif

  IMPLICIT NONE
#ifdef CPP_MPI
     INCLUDE 'mpif.h'
#endif
    INTEGER             :: ierr
    INTEGER             :: thread_required
    INTEGER             :: thread_provided
    INTEGER             :: ensemble_pool_size
    INTEGER             :: ensemble_comm_size
    INTEGER             :: ensemble_comm_rank
    INTEGER             :: ensemble_rank
    INTEGER             :: member_size

#ifdef CPP_MPI
!$OMP MASTER
      thread_required=MPI_THREAD_SERIALIZED

      CALL MPI_INIT_THREAD(thread_required,thread_provided,ierr)
      IF (thread_provided < thread_required) THEN
        PRINT *,'Warning : The multithreaded level of MPI librairy do not provide the requiered level',  &
                ' in mod_const_mpi::Init_const_mpi'
      ENDIF
      COMM_LMDZ_ENSEMBLE=MPI_COMM_WORLD
      MPI_REAL_LMDZ=MPI_REAL8
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! Initialisation de XIOS
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
#ifdef CPP_XIOS
      CALL wxios_init("LMDZ", outcom=COMM_LMDZ_ENSEMBLE)
#endif
!$OMP END MASTER
#else
#ifdef CPP_XIOS
!$OMP MASTER
      CALL wxios_init("LMDZ")
!$OMP END MASTER
#endif
#endif

  !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!  
  !! SPLIT COMMUNICATOR FOR ENSEMBLE         !!!
  !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
     ensemble_pool_size = 1
     CALL getin("ensemble_pool_size", ensemble_pool_size)

     CALL MPI_COMM_SIZE(COMM_LMDZ_ENSEMBLE,ensemble_comm_size,ierr)
     CALL MPI_COMM_RANK(COMM_LMDZ_ENSEMBLE,ensemble_comm_rank,ierr)
     IF (MOD(ensemble_comm_size,ensemble_pool_size)/=0) THEN
      CALL abort_physic('Init_mpi','Nb of MPI processes in whole ensemble is not divisible by the size of ensemble',1)
     ENDIF  
     member_size = ensemble_comm_size/ensemble_pool_size
     ensemble_rank = ensemble_comm_rank/member_size
     CALL MPI_COMM_SPLIT(COMM_LMDZ_ENSEMBLE, ensemble_rank, ensemble_comm_rank,COMM_LMDZ,ierr)
     
     
   END SUBROUTINE Init_mpi
    
END MODULE mod_const_mpi