1 | SUBROUTINE pminm (kflag, psurf, |
---|
2 | $ p2xi, p2xs, p2yi, p2ys, |
---|
3 | $ p1xi, p1xs, p1yi, p1ys) |
---|
4 | C**** |
---|
5 | C ***************************** |
---|
6 | C * OASIS ROUTINE - LEVEL 3 * |
---|
7 | C * ------------- ------- * |
---|
8 | C ***************************** |
---|
9 | C |
---|
10 | C**** *pminm* - calculate intersection between two meshes |
---|
11 | C |
---|
12 | C Purpose: |
---|
13 | C ------- |
---|
14 | C For two meshes defined by their inf. and sup. latitude and |
---|
15 | C longitude (p1xi,p1xs,p1yi,p1ys) and (p2xi,p2xs,p2yi,p2ys), checks |
---|
16 | C if they have any intersection and calculates the surface, psurf, |
---|
17 | C of that intersection. The 2 grids considered may be periodic |
---|
18 | C or non-periodic. |
---|
19 | C |
---|
20 | C N.B: Intersection surface is given by the following formula: |
---|
21 | C Si = r*r * (sin(lat2)-sin(lat1)) * (phi2-phi1) |
---|
22 | C with lat2, lat1 sup. and inf. latitudes |
---|
23 | C phi2, phi1 sup. and inf. longitudes |
---|
24 | C This results from the integration of dS=r*r*cos(lat)*d(lat)*d(phi) |
---|
25 | C |
---|
26 | C** Interface: |
---|
27 | C --------- |
---|
28 | C *CALL* *pminm(kflag, psurf, |
---|
29 | C p2xi, p2xs, p2yi, p2ys, |
---|
30 | C p1xi, p1xs, p1yi, p1ys)* |
---|
31 | C |
---|
32 | C Input: |
---|
33 | C ----- |
---|
34 | C p2xi : target grid square inferior longitude |
---|
35 | C p2xs : target grid square superior longitude |
---|
36 | C p2yi : target grid square inferior latitude |
---|
37 | C p2ys : target grid square superior latitude |
---|
38 | C p1xi : source grid square inferior longitude |
---|
39 | C p1xs : source grid square superior longitude |
---|
40 | C p1yi : source grid square inferior latitude |
---|
41 | C p1ys : source grid square superior latitude |
---|
42 | C |
---|
43 | C Output: |
---|
44 | C ------ |
---|
45 | C psurf : the intersection's surface |
---|
46 | C kflag : 1 if intersection is not empty, 0 otherwise |
---|
47 | C |
---|
48 | C Workspace: |
---|
49 | C --------- |
---|
50 | C None |
---|
51 | C |
---|
52 | C External: |
---|
53 | C -------- |
---|
54 | C None |
---|
55 | C |
---|
56 | C References: |
---|
57 | C ---------- |
---|
58 | C O. Thual, Simple ocean-atmosphere interpolation. |
---|
59 | C Part A: The method, EPICOA 0629 (1992) |
---|
60 | C Part B: Software implementation, EPICOA 0630 (1992) |
---|
61 | C See also OASIS manual (1995) |
---|
62 | C |
---|
63 | C History: |
---|
64 | C ------- |
---|
65 | C Version Programmer Date Description |
---|
66 | C ------- ---------- ---- ----------- |
---|
67 | C 1.1 O. Thual 93/04/15 created |
---|
68 | C 2.0 L. Terray 95/10/01 modified: new structure |
---|
69 | C |
---|
70 | C %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% |
---|
71 | C |
---|
72 | C* ---------------------------- Include files --------------------------- |
---|
73 | C |
---|
74 | USE mod_kinds_oasis |
---|
75 | USE mod_unit |
---|
76 | C |
---|
77 | C* ---------------------------- Poema verses ---------------------------- |
---|
78 | C |
---|
79 | C %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% |
---|
80 | C |
---|
81 | C* 1. Initialization |
---|
82 | C -------------- |
---|
83 | C |
---|
84 | kflag = 0 |
---|
85 | psurf = 0. |
---|
86 | z2pi = 2. * acos(-1.) |
---|
87 | zconv = 1.74532925199432957692e-2 |
---|
88 | C |
---|
89 | C* Assign local variables |
---|
90 | C |
---|
91 | zfi1i = p1xi |
---|
92 | zfi1s = p1xs |
---|
93 | zfi2i = p2xi |
---|
94 | zfi2s = p2xs |
---|
95 | C |
---|
96 | C* Put longitudes in the [0-360] interval to avoid problem in |
---|
97 | C surface calculation. |
---|
98 | C |
---|
99 | IF (p1xi .GE. 360.0) zfi1i = zfi1i - 360.0 |
---|
100 | IF (p1xi .LT. 0. ) zfi1i = zfi1i + 360.0 |
---|
101 | IF (p1xs .GT. 360.0) zfi1s = zfi1s - 360.0 |
---|
102 | IF (p1xs .LE. 0. ) zfi1s = zfi1s + 360.0 |
---|
103 | IF (p2xi .GE. 360.0) zfi2i = zfi2i - 360.0 |
---|
104 | IF (p2xi .LT. 0. ) zfi2i = zfi2i + 360.0 |
---|
105 | IF (p2xs .GT. 360.0) zfi2s = zfi2s - 360.0 |
---|
106 | IF (p2xs .LE. 0. ) zfi2s = zfi2s + 360.0 |
---|
107 | C |
---|
108 | C* Conversion degrees to radians |
---|
109 | C |
---|
110 | zfi1i = zfi1i * zconv |
---|
111 | zfi1s = zfi1s * zconv |
---|
112 | zth1i = p1yi * zconv |
---|
113 | zth1s = p1ys * zconv |
---|
114 | zfi2i = zfi2i * zconv |
---|
115 | zfi2s = zfi2s * zconv |
---|
116 | zth2i = p2yi * zconv |
---|
117 | zth2s = p2ys * zconv |
---|
118 | C |
---|
119 | C |
---|
120 | C* 2. Check and calculation of intersection |
---|
121 | C ------------------------------------- |
---|
122 | C |
---|
123 | C* Check of latitudinal intersection |
---|
124 | C |
---|
125 | IF (zth2s .GT. zth1i .AND. zth2i .LT. zth1s) THEN |
---|
126 | C |
---|
127 | C* Calculate the delta(latitude) |
---|
128 | C |
---|
129 | C* Latitude inf. |
---|
130 | C |
---|
131 | zlati = amax1(zth2i,zth1i) |
---|
132 | C |
---|
133 | C* Latitude sup. |
---|
134 | C |
---|
135 | zlats = amin1(zth2s,zth1s) |
---|
136 | C |
---|
137 | C* sin(lat_sup) - sin(lat_inf) |
---|
138 | C |
---|
139 | zdth = sin(zlats) - sin(zlati) |
---|
140 | C |
---|
141 | C* Check of longitudinal intersection |
---|
142 | C |
---|
143 | zfi1ir = zfi1i - z2pi |
---|
144 | zfi2ir = zfi2i - z2pi |
---|
145 | zfi2sr = zfi2s - z2pi |
---|
146 | C |
---|
147 | C* Case of a mesh 1 whose minimal longitude zfi1i is less than the |
---|
148 | C maximal one zfi1s (normal case). The opposite can occur only for |
---|
149 | C a periodic grid. |
---|
150 | C |
---|
151 | IF (zfi1i .LT. zfi1s) THEN |
---|
152 | C |
---|
153 | C - Check if it is similar for mesh 2 |
---|
154 | C |
---|
155 | IF (zfi2i .LT. zfi2s) THEN |
---|
156 | C |
---|
157 | C - If yes, find the intersection |
---|
158 | C |
---|
159 | IF (zfi2s .GT. zfi1i .AND. zfi2i .LT. zfi1s) THEN |
---|
160 | kflag = 1 |
---|
161 | zdfi = amin1(zfi2s,zfi1s) - amax1(zfi2i,zfi1i) |
---|
162 | psurf = zdth * zdfi |
---|
163 | ENDIF |
---|
164 | C |
---|
165 | C - If not, mesh 2 is periodic |
---|
166 | C |
---|
167 | ELSE IF (zfi2i .GT. zfi2s) THEN |
---|
168 | C |
---|
169 | C - Find intersection in that case |
---|
170 | C |
---|
171 | IF (zfi2s .GT. zfi1i .AND. zfi2ir .LT. zfi1s) THEN |
---|
172 | kflag = 1 |
---|
173 | zdfi = amin1(zfi2s,zfi1s) - zfi1i |
---|
174 | psurf = zdth * zdfi |
---|
175 | ENDIF |
---|
176 | IF (zfi2s .GT. zfi1ir .AND. zfi2i .LT. zfi1s) THEN |
---|
177 | kflag = 1 |
---|
178 | zdfi = amin1(zfi2i,zfi1s) - zfi1i |
---|
179 | psurf = zdth * zdfi |
---|
180 | ENDIF |
---|
181 | ENDIF |
---|
182 | ENDIF |
---|
183 | C |
---|
184 | C* Case of a mesh 1 whose minimal longitude zfi1i is located |
---|
185 | C on the right of the grid and whose maximum longitude zfi1s |
---|
186 | C is on the left of the grid. This occurs only for a periodic mesh |
---|
187 | C |
---|
188 | IF (zfi1i .GT. zfi1s) THEN |
---|
189 | C |
---|
190 | C - Check for mesh 2 |
---|
191 | C |
---|
192 | IF (zfi2i .LT. zfi2s) THEN |
---|
193 | C |
---|
194 | C - Find intersection |
---|
195 | C |
---|
196 | IF (zfi2s .GT. zfi1ir .AND. zfi2i .LT. zfi1s) THEN |
---|
197 | kflag = 1 |
---|
198 | zdfi = amin1(zfi2s,zfi1s) - zfi2i |
---|
199 | psurf = zdth * zdfi |
---|
200 | ELSE IF (zfi2sr .GT. zfi1ir .AND. |
---|
201 | $ zfi2ir .LT. zfi1s) THEN |
---|
202 | kflag = 1 |
---|
203 | zdfi = zfi2s - amin1(zfi2i,zfi1i) |
---|
204 | psurf = zdth * zdfi |
---|
205 | ENDIF |
---|
206 | C |
---|
207 | C - Mesh 2 is periodic |
---|
208 | C |
---|
209 | ELSE IF (zfi2i .GT. zfi2s) THEN |
---|
210 | C |
---|
211 | C - Find intersection |
---|
212 | C |
---|
213 | IF (zfi2s .GT. zfi1ir .AND. zfi2ir .LT. zfi1s) THEN |
---|
214 | kflag = 1 |
---|
215 | zdfi = amin1(zfi2s,zfi1s) - amax1(zfi2ir,zfi1ir) |
---|
216 | psurf = zdth * zdfi |
---|
217 | ENDIF |
---|
218 | ENDIF |
---|
219 | ENDIF |
---|
220 | ENDIF |
---|
221 | C |
---|
222 | C* End of routine |
---|
223 | C |
---|
224 | RETURN |
---|
225 | END |
---|
226 | |
---|