source: CPL/oasis3/trunk/src/mod/oasis3/src/mod_bilin.f @ 1677

      MODULE mod_bilin
      CONTAINS
      SUBROUTINE bilin ( pout, px, py, kndx, kndy, pax, pay, kpts
     $                 , pin, ki, kj)
C****
C               *****************************
C               * OASIS ROUTINE  -  LEVEL 3 *
C               * -------------     ------- *
C               *****************************
C
C**** *bilin* - Bilinear interpolation
C
C     Purpose: Proceed to a bilinear interpolation
C     -------
C
C
C**   Interface:
C     ---------
C     *CALL* *bilin* ( zo, px, py, kndx, kndy, pax, pay, kpts
C     $                 , z, ki, kj)
C
C**   Method
C     ------
C
C     *   *   *   *
C
C     *   *   *   *
C           #        ==>   pt (x,y)
C     *  (=)  *   *  ==> = pt (kndx, kndy)
C
C     *   *   *   *
C
C     Input:
C     -----
C                px      : longitudes of target grid
C                py      : latitudes of target grid
C                kndx    : index of source point in source longitude
C                kndy    : index of source point in source latitude
C                pax     : longitudes of source grid
C                pay     : latitudes of source grid
C                kpts    : dimension of target grid
C                pin     : input field on source grid
C                ki, kj  : dimension of source grid
C
C     Output:
C     ------
C                pout    : interpolated field on target grid
C
C     Workspace:
C     ---------
C     Local variables
C          zy1, zy2, zy3, zy4, i, j, zdx, zdy ,z1, z2, z3, z4
C     Statement function
C          cubic
C
C     Externals:
C     ---------
C     None
C
C     Reference:
C     ---------
C     See OASIS manual (1995)
C
C     History:
C     -------
C       Version   Programmer     Date      Description
C       -------   ----------     ----      -----------  
C       2.0       O. Marti       96/07/15  Created
C
C %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
C
C *
      IMPLICIT NONE
C
C* ---------------------------- Argument declarations -------------------
C
      INTEGER, INTENT ( in) :: kpts, ki, kj
      REAL, DIMENSION ( kpts), INTENT ( in) :: px, py
      REAL, DIMENSION ( 0: ki + 1), INTENT ( in) :: pax
      REAL, DIMENSION ( 0: kj + 1), INTENT ( in) :: pay
      REAL, DIMENSION ( 0: ki + 1, 0: kj + 1), INTENT ( in) :: pin 
      INTEGER, DIMENSION ( kpts), INTENT ( in) :: kndx, kndy
      REAL, DIMENSION ( kpts), INTENT ( out) :: pout
C
C* ---------------------------- Local declarations ----------------------
C
      REAL    :: zy1, zy2
      INTEGER :: jn, ji, jj
C
C* ---------------------------- Statement fucntions----------------------
C
      REAL  ::  zlinear, zdx, zdy , z1, z2
C
      zlinear ( z1, z2, zdx) = ( 1.0  - zdx) * z1 + zdx * z2
C
C* ---------------------------- Poema verses ----------------------------
C
C %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
C
C*    1. Interpolation
C        -------------
C
      DO jn = 1, kpts
        ji  = kndx ( jn) ; jj  = kndy ( jn)
        zdx = ( px ( jn) - pax ( ji)) / ( pax ( ji + 1) - pax ( ji))
        zdy = ( py ( jn) - pay ( jj)) / ( pay ( jj + 1) - pay ( jj))
        zy1 = zlinear ( pin ( ji, jj  ), pin ( ji+1, jj  ), zdx)
        zy2 = zlinear ( pin ( ji, jj+1), pin ( ji+1, jj+1), zdx)
        pout ( jn) = zlinear ( zy1, zy2, zdy)
      END DO
C
C
C*    3. End of routine
C        --------------
C
      RETURN
      END SUBROUTINE bilin
      END MODULE mod_bilin