source: LATMOS-Accounts-Web/lib/LATMOS/Accounts/Web/Controller/Ajax.pm @ 585

package LATMOS::Accounts::Web::Controller::Ajax;

use strict;
use warnings;
use base 'LATMOS::Accounts::Web::Controller';

=head1 NAME

LATMOS::Accounts::Web::Controller::Ajax - Catalyst Controller

=head1 DESCRIPTION

Catalyst Controller.

=head1 METHODS

=cut


=head2 index 

=cut

sub index : Private {
    my ( $self, $c ) = @_;

    $c->response->body('Matched LATMOS::Accounts::Web::Controller::Ajax in Ajax.');
}

sub rawattr : Local {
    my ($self, $c, $otype) = @_;

    my $base = $c->model('Accounts')->db;

    if (!$c->req->param('id')) {
        $c->stash->{value} = '';
        return;
    }

    my $obj = $base->get_object($otype, $c->req->param('id')) or do {
        $c->stash->{value} = 'N/A';
        return;
    };
    $c->stash->{value} = $obj->get_c_field($c->req->param('attr')) || 'N/A';
}

sub attrvalues : Local {
    my ($self, $c, $otype, $attr) = @_;

    my $base = $c->model('Accounts')->db;
    my $val = $c->req->param('val');
    $c->stash->{'complete'} = $c->prototype->auto_complete_result([
        grep { /^\Q$val\E/ } $base->attributes_summary($otype, $attr)
    ]);

}

sub objexist : Local {
    my ($self, $c, $otype) = @_;
    my $base = $c->model('Accounts')->db;
    my $val = $c->req->param('val');
    my $obj = $base->get_object($otype, $val);

    $c->stash->{'exists'} = join(', ', $obj->get_attributes($c->req->param('attr') ||
            'displayName')) if($obj);
}

sub objattrexist : Local {
    my ($self, $c, $otype, $attr) = @_;
    my $base = $c->model('Accounts')->db;
    my $val = $c->req->param('val');
    my @obj = $val ? $base->search_objects($otype, "$attr=$val") : ();

    if (my $filter = $c->req->param('exclude')) {
        @obj = grep { $_ ne $filter } @obj;
    }
    $c->stash->{'exists'} = join(', ', @obj);
}

sub cracklib : Local {
    my ( $self, $c, $login ) = @_;
    my $base = $c->model('Accounts')->db;
    my ($password)  = $c->req->param('passwd');
    my ($cpassword) = $c->req->param('cpasswd');
    if ($password && $cpassword && $password ne $cpassword) {
        $c->stash->{cracklib} = "Mot de passe différents";
    } elsif ($password && (my $obj = $base->get_object('user', $login))) {
        $c->stash->{cracklib} = $obj->check_password($password);
    }
}

sub end : Private {
    my ( $self, $c ) = @_;
    $c->forward($c->view('TTpart'));
}

=head1 AUTHOR

Thauvin Olivier

=head1 LICENSE

This library is free software, you can redistribute it and/or modify
it under the same terms as Perl itself.

=cut

1;