source: LATMOS-Accounts/bin/la-sync-list @ 834

#!/usr/bin/perl

use strict;
use warnings;
use LATMOS::Accounts;
use Getopt::Long;
use Pod::Usage;
use Config::IniFiles;

=head1 NAME

    la-sync-list - Tools to sync mailing list

=head1 SYNOPSIS

    la-sync-list

=head1 OPTIONS

=over 4

=item --config configfile

Use this configuration file instead default

=item --base basename

Perform search in this specific base instead default

=item --lc cfg

la-list-sync config file

=back

=cut

GetOptions(
    'c|config=s' => \my $config,
    'lc=s'       => \my $listconfig,
    'b|base=s'   => \my $base,
    'help'       => sub { pod2usage(0) },
) or pod2usage();

my $listcfg = Config::IniFiles->new(
    -file => $listconfig,
    -default => '_default_',
) or die "Cannot open list config file\n";

my $LA = LATMOS::Accounts->new($config);
my $labase = $base ? $LA->base($base) : $LA->default_base;
$labase && $labase->load or die "Cannot load base";

my %cache;

foreach my $list ($listcfg->Sections) {
    my %content = ();
    $list eq '_default_' and next;
    $listcfg->val($list, 'ignore') and next;
    my $fmt = $listcfg->val($list, 'fmt', '%{mail}');
    my $otype = $listcfg->val($list, 'objects', 'user');
    foreach (grep { $_ } $listcfg->val($list, 'addtolist')) {
        $content{$_} = 1;
    }
    my %ids;
    foreach my $param ($listcfg->Parameters($list)) {
        $param =~ /^filter/ or next;

        foreach my $id (sort $labase->search_objects(
                $listcfg->val($list, 'objects', 'user'),
                $listcfg->val($list, $param),)) {
            $ids{$id} = 1;
        }
    }
    foreach my $id (sort keys %ids) {
        if (!$cache{$otype}{$fmt}{$id}) {
            my $obj = $labase->get_object(
                $otype,
                $id,
            );

            $cache{$otype}{$fmt}{$id} = $obj->queryformat($fmt);
        }
        $content{ $cache{$otype}{$fmt}{$id} } = 1;
    }
    my $cmd = $listcfg->val($list, 'cmd', 'cat');
    $cmd =~ s/%%/$list/g;
    if (open(my $handle, '|' . $cmd)) {
        foreach (keys %content) {
            print $handle $_ ."\n";
        }
        close($handle);
    }
}

exit(0);