source: LATMOS-Accounts/lib/LATMOS/Accounts.pm @ 178

package LATMOS::Accounts;

use 5.010000;
use strict;
use warnings;
use base qw(Config::IniFiles);
use LATMOS::Accounts::Bases;
use LATMOS::Accounts::Synchro;
use LATMOS::Accounts::SynchAccess;

our $VERSION = (q$Rev$ =~ /^Rev: (\d+) /)[0];

sub new {
    my ($class, $config) = @_;

    $config ||= '/etc/latmos-account.ini';

    my $self = Config::IniFiles->new(
        -file => $config,
        '-default' => '_default_',
    );

    bless($self, $class)
}

sub base {
    my ($self, $section) = @_;
    # this method perform a cache
    $self->{_bases}{$section} and return $self->{_bases}{$section};
    $self->load_base($section) ? $self->{_bases}{$section} : undef;
}

sub default_base {
    my ($self) = @_;
    my $default = $self->default_base_name or return;
    $self->base($default);
}

# load or a if need base
sub load_base {
    my ($self, $section) = @_;
    return ($self->{_bases}{$section} ||= $self->_load_base($section))
        ? 1
        : 0;
}

# do the bad work
sub _load_base {
    my ($self, $section) = @_;
    my $type = $self->val($section, 'type') or return;
    my %params = (
        map { $_ => ($self->val($section, $_)) } $self->Parameters($section),
        defattr => { map { $_ => ($self->val('_defattr_', $_)) } $self->Parameters('_defattr_') },
    );
    my $base = LATMOS::Accounts::Bases->new($type, %params, label => $section);
    $base->load or return;
    $base;
}

sub default_base_name {
    my ($self) = @_;
    $self->val('_default_', 'base', ($self->list_bases)[0]);
}

sub default_synchro_name {
    my ($self) = @_;
    $self->val('_default_', 'sync');
}

sub list_bases {
    my ($self) = @_;
    grep {
        !m/^_.*_$/ &&
        !m/^sync:/
    } $self->Sections
}

sub list_synchro {
    my ($self) = @_;
    grep { $_ } map { /^sync:(.*)$/; $1 } $self->Sections
}

sub load_all_base {
    my ($self) = @_;
    foreach ($self->list_bases) {
        $self->load_base($_) or do {
            warn "Cannot load base $_\n";
            return 0;
        };
    }
    1;
}

sub default_synchro {
    my ($self, %options) = @_;
    my $syncname = $self->default_synchro_name or return;
    $self->create_synchro($syncname, %options);
}

sub sync_from_name {
    my ($self, $syncname) = @_;
    return if (!$syncname);
    $self->val("sync:$syncname", 'from', $self->default_base_name);
}

sub create_synchro {
    my ($self, $name, %options) = @_;

    # taking options from config
    if ($name) {
        foreach my $param ($self->Parameters("sync:$name")) {
            if (!defined($options{$param})) {
                my @args = $self->val("sync:$name", $param);
                $options{$param} = ($args[1] || $param eq 'to')
                    ? [ @args ]
                    : $args[0];
            }
        }
    }

    my $labfrom = $options{from} ? $self->base($options{from}) : $self->default_base;

    my @labto = map { $self->base($_) } @{ $options{to} || []} or return;

    my $sync = LATMOS::Accounts::Synchro->new(
        $labfrom, [ @labto ],
        state_file => $self->val('_default_', 'state_file'),
        %options,
        name => $name,
    );
}

sub sync_access {
    my ($self, $name, %options) = @_;

    my @obases;
    if ($name) {
        @obases =
        (map { $self->base($_) } ($self->sync_from_name($name), $self->val("sync:$name", 'to')));
    } elsif(@{ $options{bases} || []}) {
        @obases = map { $self->base($_) } @{ $options{bases} || []};
    } elsif (my $sname = $self->default_synchro_name) {
        @obases = (map { $self->base($_) }
            ($self->sync_from_name($sname), $self->val("sync:$sname", 'to'))
        );
    }

    LATMOS::Accounts::SynchAccess->new([ @obases ]);
}

1;

__END__
# Below is stub documentation for your module. You'd better edit it!

=head1 NAME

LATMOS::Accounts - Perl extension for blah blah blah

=head1 SYNOPSIS

  use LATMOS::Accounts;
  blah blah blah

=head1 DESCRIPTION

Stub documentation for LATMOS::Accounts, created by h2xs. It looks like the
author of the extension was negligent enough to leave the stub
unedited.

Blah blah blah.

=head2 EXPORT

None by default.



=head1 SEE ALSO

Mention other useful documentation such as the documentation of
related modules or operating system documentation (such as man pages
in UNIX), or any relevant external documentation such as RFCs or
standards.

If you have a mailing list set up for your module, mention it here.

If you have a web site set up for your module, mention it here.

=head1 AUTHOR

Thauvin Olivier, E<lt>olivier.thauvin@latmosipsl.frE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2009 by Thauvin Olivier

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself, either Perl version 5.10.0 or,
at your option, any later version of Perl 5 you may have available.


=cut