source: LATMOS-Accounts/lib/LATMOS/Accounts/Bases/Attributes.pm @ 857

package LATMOS::Accounts::Bases::Attributes;

# $Id$

use strict;
use warnings;
use LATMOS::Accounts::Log;

=head1 NAME

    LATMOS::Accounts::Bases::Attributes - Object to handle attribute schema

=head1 FUNCTIONS

=head2 new($attributes, $base_or_object, $maybe_otype)

=cut

sub new {
    my ($class, $attributes, $base_or_object, $maybe_otype) = @_;
    
    my ($object, $base, $otype) =
    $base_or_object->isa('LATMOS::Accounts::Bases::Objects')
        ? ($base_or_object, $base_or_object->base, $base_or_object->type)
        : (undef, $base_or_object, $maybe_otype);

    my $attr_info = $base->get_attr_schema($otype, $attributes);

    $attr_info->{_base} = $base;
    $attr_info->{_object} = $object;
    $attr_info->{_name} = $attributes;
    $attr_info->{_otype} = $otype;

    bless($attr_info, $class);
}

sub base  { $_[0]->{_base}  }
sub name  { $_[0]->{_name}  }
sub otype { $_[0]->{_otype} }

=head2

Return internal name of attributes

=cut

sub iname { $_[0]->{iname} || $_[0]->name }

sub label { $_[0]->{label} || $_[0]->{_name} }

sub can_values {
    my ($self) = @_;
    if (my @values = $self->base->obj_attr_allowed_values(
            $self->otype,
            $self->name)) {
        return @values;
    } elsif ($self->{can_values}) {
        if (ref $self->{can_values} eq 'ARRAY') {
            return @{$self->{can_values}};
        } elsif (ref $self->{can_values} eq 'CODE') {
            $self->{can_values}->($self);
        } else {
            return;
        }
    } else { return }
}

sub ro { $_[0]->{ro} || 0 }

sub readonly { 
    my ($self) = @_;
    return 1 if ($self->ro);
    
    return ! $self->base->check_acl($self->object
        ? ($self->object, $self->name, 'w')
        : ($self->otype, '@CREATE', 'w'));
}

=head2 form_type

Return the way the fields must be show in GUI:

=over 4

=item LABEL

=item TEXT

=item DATE

=item LIST

=item CHECKBOX

=back

=cut

sub form_type { $_[0]->ro ? 'LABEL' : ($_[0]->{formtype} || 'TEXT') }

sub uniq { $_[0]->{uniq} || 0 }

sub multiple { $_[0]->{multiple} || 0 }

1;