source: LATMOS-Accounts/lib/LATMOS/Accounts/Bases/Sql/Aliases.pm @ 462

package LATMOS::Accounts::Bases::Sql::Aliases;

use 5.010000;
use strict;
use warnings;

use base qw(LATMOS::Accounts::Bases::Sql::objects);
use LATMOS::Accounts::Log;

our $VERSION = (q$Rev: 341 $ =~ /^Rev: (\d+) /)[0];

=head1 NAME

LATMOS::Ad - Perl extension for blah blah blah

=head1 SYNOPSIS

  use LATMOS::Accounts::Bases;
  my $base = LATMOS::Accounts::Bases->new('sql');
  ...

=head1 DESCRIPTION

Account base access over standard unix file format.

=head1 FUNCTIONS

=cut

=head2 new(%options)

Create a new LATMOS::Ad object for windows AD $domain.

domain / server: either the Ad domain or directly the server

ldap_args is an optionnal list of arguments to pass to L<Net::LDAP>.

=cut

sub object_table { 'aliases' }

sub key_field { 'name' }

sub has_extended_attributes { 0 }

sub _managed_fields {
    my ($class, $for, $base) = @_;
    return(
        $for !~ /w/
        ? (
            finalpoint => 'finalpoint',
            parents => 'parents',
            anyparents => 'anyparents',
            sameforward => 'sameforward',
            samedestination => 'samedestination',
        )
        : ()
    );
}

sub _create {
    my ($class, $base, $id, %data) = @_;
    my $sth = $base->db->prepare_cached(q{
        select name from aliases where lower(name) = lower(?)
        limit 1
        });
    $sth->execute($id);
    my $res = $sth->fetchrow_hashref;
    $sth->finish;
    if ($res) {
        $base->log(LA_ERR, "Aliases %s already exists as %s",
            $id, $res->{name});
        return;
    } else {
        return $class->SUPER::_create($base, $id, %data);
    }
}

sub get_field {
    my ($self, $field) = @_; 
    if ($field eq 'finalpoint') {
        my $sth = $self->db->prepare_cached(q{
        select forward from aliases where lower(name) = lower(?)
        limit 1
        });
        my $next = $self->get_field('forward');
        while (1) {
            $sth->execute($next);
            if (my $res = $sth->fetchrow_hashref) {
                $next = $res->{forward};
                $next = ref $next
                    ? join(',', @$next)
                    : $next;
                next;
            } else {
                last;
            }
        }
        $sth->finish;
        return $next;
    }
    if ($field =~ /^(parents|anyparents|sameforward|samedestination)$/) {
        my $sth = $self->db->prepare_cached(q{
            select name from aliases where array[lower($1)] <@
                string_to_array(lower(array_to_string("forward", ',')), ',')
            });
        my @tocheck = ($field =~ /^sameforward$/
            ? $self->get_field('forward')
            : ($field =~ /^samedestination$/ 
                ? $self->get_field('finalpoint')
                : $self->id));
        my @results;
        my @already;
        while (my $next = shift(@tocheck)) {
            # endless loop detection
            grep { $next eq $_ } @already and do {
                push(@results, 'LOOP');
                next;
            };
            push(@already, $next);
            $sth->execute($next);
            while (my $res = $sth->fetchrow_hashref) {
                push(@tocheck, $res->{name});
                $res->{name} eq $self->id and next;
                push(@results, $res->{name});
            }
            $field =~ /^(parents|sameforward)$/ and last; # No recursive search
        }
        return scalar(@results) <= 1 ? $results[0] : \@results;
    }
    $self->SUPER::get_field($field);
}

1;

__END__

=head1 SEE ALSO

=head1 AUTHOR

Olivier Thauvin, E<lt>olivier.thauvin@latmos.ipsl.frE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2008, 2009 CNRS SA/CETP/LATMOS

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself, either Perl version 5.10.0 or,
at your option, any later version of Perl 5 you may have available.


=cut