source: LATMOS-Accounts/lib/LATMOS/Accounts/Bases/Sql/User.pm @ 158

package LATMOS::Accounts::Bases::Sql::User;

use 5.010000;
use strict;
use warnings;

use base qw(LATMOS::Accounts::Bases::Sql::objects);

our $VERSION = (q$Rev$ =~ /^Rev: (\d+) /)[0];

=head1 NAME

LATMOS::Ad - Perl extension for blah blah blah

=head1 SYNOPSIS

  use LATMOS::Accounts::Bases;
  my $base = LATMOS::Accounts::Bases->new('sql');
  ...

=head1 DESCRIPTION

Account base access over standard unix file format.

=head1 FUNCTIONS

=cut

=head2 new(%options)

Create a new LATMOS::Ad object for windows AD $domain.

domain / server: either the Ad domain or directly the server

ldap_args is an optionnal list of arguments to pass to L<Net::LDAP>.

=cut

sub object_table { 'user' }

sub key_field { 'uid' }

sub has_extended_attributes { 1 }

sub _delayed_fields {
    my ($self)= @_;
    return qw(memberOf manager);
}

sub _inline_fields {
    my ($self, $for, $base) = @_;
    return {
        %{ $self->_initial_fields($for, $base) },
        memberOf        => 'memberOf',
        uidNumber => 'uidnumber',
        gidNumber => 'gidnumber',
        (($for !~ /w/) ? (
        gecos        => 'gecos',
        displayName  => 'displayName',
        sAMAccountName  => 'sAMAccountName',
        accountExpires => 'accountExpires',
        shadowExpire => 'shadowExpire',
        ) : ()),
    }
}

sub get_field {
    my ($self, $field) = @_;
    if ($field eq 'gecos' || $field eq 'displayName') {
        return join(' ', grep { $_ } ($self->get_c_field('givenName'), ($self->get_c_field('sn'))));
    } elsif ($field =~ /^(sAMAccountName)$/) {
        return $self->id,
    } elsif ($field eq 'memberOf') {
        my $sth = $self->db->prepare_cached(
            q{
            select value from user_attributes_groups
            join user_attributes_list on
            user_attributes_groups.attr = user_attributes_list.ikey
            where id = ? and canonical = ?
            }
        );
        $sth->execute($self->id, 'memberOf');
        my @res;
        while (my $res = $sth->fetchrow_hashref) {
            push(@res, $res->{value});
        }
        return \@res;
    } elsif ($field eq 'accountExpires') {
        my $sth = $self->db->prepare_cached(
            sprintf(
                q{select extract(epoch from expire) + 11644474161 as expire
                from %s where %s = ?},
                $self->db->quote_identifier($self->object_table),
                $self->db->quote_identifier($self->key_field),
            )
        );
        $sth->execute($self->id);
        my $res = $sth->fetchrow_hashref;
        $sth->finish;
        return $res->{expire} ? sprintf("%.f", $res->{expire} * 1E7) : '9223372036854775807';
    } elsif ($field eq 'shadowExpire') {
        my $sth = $self->db->prepare_cached(
            sprintf(
                q{select justify_hours(expire - '1/1/1970'::timestamp) as expire
                from %s where %s = ?},
                $self->db->quote_identifier($self->object_table),
                $self->db->quote_identifier($self->key_field),
            )
        );
        $sth->execute($self->id);
        my $res = $sth->fetchrow_hashref;
        $sth->finish;
        return -1 unless($res->{expire});
        $res->{expire} =~ /(\d+) days\s*(\w)?/;
        return $1 + ($2 ? 1 : 0);
    } else {
        return $self->SUPER::get_field($field);
    }
}

sub set_fields {
    my ($self, %data) = @_;
    my %fdata;
    foreach my $attr (keys %data) {
        $attr =~ /^memberOf$/ and do {
            my $attrid = $self->_get_field_name_db('memberOf', $self->base) or next;
            my %member;
            foreach (@{ $self->get_field('memberOf') }) {
                $member{$_}{c} = 1;
            }
            foreach (@{ $data{$attr} || []}) {
                $member{$_}{n} = 1;
            }

            foreach (keys %member) {
                $member{$_}{c} && $member{$_}{n} and next; # no change !
                my $group = $self->base->get_object('group', $_) or next;
                if ($member{$_}{n}) {
                    my $sth = $self->db->prepare_cached(
                        q{insert into user_attributes_groups (id, attr, value) values (?,?,?)}
                    );
                    $sth->execute($self->id, $attrid, $_);
                } elsif ($member{$_}{c}) {
                    my $sth = $self->db->prepare_cached(
                        q{delete from user_attributes_groups where id = ? and attr = ? and value = ?}
                    );
                    $sth->execute($self->id, $attrid, $_);
                } # else {} # can't happend
            }
            next;
        };
        $fdata{$attr} = $data{$attr};
    }
    if (keys %fdata) {
        $self->SUPER::set_fields(%fdata);
    }
}


1;

__END__

=head1 SEE ALSO

=head1 AUTHOR

Olivier Thauvin, E<lt>olivier.thauvin@latmos.ipsl.frE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2008, 2009 CNRS SA/CETP/LATMOS

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself, either Perl version 5.10.0 or,
at your option, any later version of Perl 5 you may have available.


=cut