source: LATMOS-Accounts/lib/LATMOS/Accounts/Bases/Sql/User.pm @ 201

package LATMOS::Accounts::Bases::Sql::User;

use 5.010000;
use strict;
use warnings;

use LATMOS::Accounts::Utils;
use base qw(LATMOS::Accounts::Bases::Sql::objects);

our $VERSION = (q$Rev$ =~ /^Rev: (\d+) /)[0];

=head1 NAME

LATMOS::Ad - Perl extension for blah blah blah

=head1 SYNOPSIS

  use LATMOS::Accounts::Bases;
  my $base = LATMOS::Accounts::Bases->new('sql');
  ...

=head1 DESCRIPTION

Account base access over standard unix file format.

=head1 FUNCTIONS

=cut

=head2 new(%options)

Create a new LATMOS::Ad object for windows AD $domain.

domain / server: either the Ad domain or directly the server

ldap_args is an optionnal list of arguments to pass to L<Net::LDAP>.

=cut

sub object_table { 'user' }

sub key_field { 'uid' }

sub has_extended_attributes { 1 }

sub _delayed_fields {
    my ($self)= @_;
    return qw(memberOf manager directReports);
}

sub _inline_fields {
    my ($self, $for, $base) = @_;
    return {
        %{ $self->_initial_fields($for, $base) },
        memberOf        => 'memberOf',
        uidNumber => 'uidnumber',
        gidNumber => 'gidnumber',
        (($for !~ /w/) ? (
        gecos        => 'gecos',
        displayName  => 'displayName',
        sAMAccountName  => 'sAMAccountName',
        accountExpires => 'accountExpires',
        shadowExpire => 'shadowExpire',
        directReports => 'directReports',
        managedObjects => 'managedObjects',
        ) : ()),
    }
}

sub get_field {
    my ($self, $field) = @_;
    if ($field eq 'gecos') {
        return to_ascii(
            join(' ', grep { $_ } ($self->get_c_field('givenName'), ($self->get_c_field('sn'))))
        ) || to_ascii($self->get_c_field('description'));
    } elsif ($field eq 'displayName') {
        return join(' ', grep { $_ } ($self->get_c_field('givenName'), ($self->get_c_field('sn'))))
            || $self->id;
    } elsif ($field eq 'sAMAccountName') {
        return $self->id;
    } elsif ($field eq 'memberOf') {
        my $sth = $self->db->prepare_cached(
            q{
            select name from "group" join
            group_attributes_users on group_attributes_users.okey = "group".ikey
            join group_attributes_list on
            group_attributes_users.attr = group_attributes_list.ikey
            where value = ? and canonical = ?
            }
        );
        $sth->execute($self->id, 'memberUID');
        my @res;
        while (my $res = $sth->fetchrow_hashref) {
            push(@res, $res->{name});
        }
        return \@res;
    } elsif ($field eq 'directReports') {
        my $sth = $self->db->prepare_cached(
            q{
            select uid from "user" join
            user_attributes on user_attributes.okey = "user".ikey
            join user_attributes_list
            on user_attributes_list.ikey = user_attributes.attr
            where value = ? and canonical = ?
            }
        );
        $sth->execute($self->id, 'manager');
        my @res;
        while (my $res = $sth->fetchrow_hashref) {
            push(@res, $res->{uid});
        }
        return \@res;
    } elsif ($field eq 'managedObjects') {
        my $sth = $self->db->prepare_cached(
            q{
            select name from "group" join
            group_attributes on group_attributes.okey = "group".ikey
            join group_attributes_list
            on group_attributes_list.ikey = group_attributes.attr
            where value = ? and canonical = ?
            }
        );
        $sth->execute($self->id, 'managedBy');
        my @res;
        while (my $res = $sth->fetchrow_hashref) {
            push(@res, $res->{name});
        }
        return \@res;
    } elsif ($field eq 'accountExpires') {
        my $sth = $self->db->prepare_cached(
            sprintf(
                q{select extract(epoch from expire) + 11644474161 as expire
                from %s where %s = ?},
                $self->db->quote_identifier($self->object_table),
                $self->db->quote_identifier($self->key_field),
            )
        );
        $sth->execute($self->id);
        my $res = $sth->fetchrow_hashref;
        $sth->finish;
        return $res->{expire} ? sprintf("%.f", $res->{expire} * 1E7) : '9223372036854775807';
    } elsif ($field eq 'shadowExpire') {
        my $sth = $self->db->prepare_cached(
            sprintf(
                q{select justify_hours(expire - '1/1/1970'::timestamp) as expire
                from %s where %s = ?},
                $self->db->quote_identifier($self->object_table),
                $self->db->quote_identifier($self->key_field),
            )
        );
        $sth->execute($self->id);
        my $res = $sth->fetchrow_hashref;
        $sth->finish;
        return -1 unless($res->{expire});
        $res->{expire} =~ /(\d+) days\s*(\w)?/;
        return $1 + ($2 ? 1 : 0);
    } else {
        return $self->SUPER::get_field($field);
    }
}

sub set_fields {
    my ($self, %data) = @_;
    my %fdata;
    foreach my $attr (keys %data) {
        $attr =~ /^memberOf$/ and do {
            my $cl = $self->base->_load_obj_class('group') or next;
            my $attrid = $cl->_get_field_name_db('memberUID', $self->base) or next;
            my %member;
            foreach (@{ $self->get_field('memberOf') }) {
                $member{$_}{c} = 1;
            }
            foreach (@{ $data{$attr} || []}) {
                $member{$_}{n} = 1;
            }

            foreach (keys %member) {
                $member{$_}{c} && $member{$_}{n} and next; # no change !
                my $group = $self->base->get_object('group', $_) or next;
                if ($member{$_}{n}) {
                    my $sth = $self->db->prepare_cached(
                        q{insert into group_attributes_users (value, attr, okey) values (?,?,?)}
                    );
                    $sth->execute($self->id, $attrid, $group->_get_ikey);
                } elsif ($member{$_}{c}) {
                    my $sth = $self->db->prepare_cached(
                        q{delete from group_attributes_users where value = ? and attr = ? and okey = ?}
                    );
                    $sth->execute($self->id, $attrid, $group->_get_ikey);
                } # else {} # can't happend
            }
            next;
        };
        $fdata{$attr} = $data{$attr} || undef;
    }
    if (keys %fdata) {
        $self->SUPER::set_fields(%fdata);
    }
}


1;

__END__

=head1 SEE ALSO

=head1 AUTHOR

Olivier Thauvin, E<lt>olivier.thauvin@latmos.ipsl.frE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2008, 2009 CNRS SA/CETP/LATMOS

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself, either Perl version 5.10.0 or,
at your option, any later version of Perl 5 you may have available.


=cut