source: LATMOS-Accounts/lib/LATMOS/Accounts/SynchAccess/base.pm @ 861

package LATMOS::Accounts::SynchAccess::base;

use strict;
use warnings;
use vars qw($AUTOLOAD);
use Carp;
use LATMOS::Accounts::Log;

our $VERSION = (q$Rev$ =~ /^Rev: (\d+) /)[0];

sub AUTOLOAD {
    my ($self, @args) = @_;
    my ($constname, $sub) = $AUTOLOAD =~ m/(.*)::([^:]+)/;
    if ($sub =~ /^(wexported)/) {
        $self->_no_trap($sub, @args);
    } elsif ($sub =~ /^(check_password)$/) {
        $self->_run_first($sub, @args);
    } else {
        $self->_trap_false($sub, @args);
    }
}

sub new {
    my ($class, $bases) = @_;
    bless {
        bases => [ @{ $bases } ],
    }, $class;
}

sub bases {
    my ($self) = @_;
    @{ $self->{bases} || []}
}

sub _return_all {
    my ($self, $sub, @args) = @_;
    map { $_->$sub(@args) } $self->bases
}

sub _run_first {
    my ($self, $sub, @args) = @_;
    my ($fbase) = $self->bases;
    $fbase->$sub(@args);
}

sub _no_trap {
    my ($self, $sub, @args) = @_;
    foreach ($self->bases) {
        $_->$sub(@args);
    }
}

sub _trap_false {
    my ($self, $sub, @args) = @_;
    my $failure = 0;
    foreach ($self->bases) {
        $_->$sub(@args) or do {
                    la_log(LA_ERR, "SyncA: Erreur call $sub() for %s", $_);
                $failure = 1;
        };
    }
    $failure ? 0 : 1;
}

sub _trap_true {
    my ($self, $sub, @args) = @_;
    my $failure = 0;
    foreach ($self->bases) {
        $_->$sub(@args) and $failure = 1;
    }
    $failure ? 0 : 1;
}

sub DESTROY {}

1;

__END__