source: LATMOS-Accounts/lib/LATMOS/Accounts/Synchro.pm @ 60

package LATMOS::Accounts::Synchro;

use 5.010000;
use strict;
use warnings;
use base qw(Config::IniFiles);
use LATMOS::Accounts::Bases;

=head1 NAME

LATMOS::Accounts::Synchro - Perl extension for blah blah blah

=head1 SYNOPSIS

  use LATMOS::Accounts;
  blah blah blah

=head1 DESCRIPTION

Stub documentation for LATMOS::Accounts, created by h2xs. It looks like the
author of the extension was negligent enough to leave the stub
unedited.

Blah blah blah.

=head1 FUNCTIONS

=cut

our $VERSION = (q$Rev$ =~ /^Rev: (\d+) /)[0];

=head2 new($from, $to, %options)

Create a new synchronisation where $from and $to are LATMOS::Accounts::Base
based objects. $to can be an array ref of objects.

=cut

sub new {
    my ($class, $from, $to, %options) = @_;

    if ($options{state_file} && ! -w $options{state_file}) {
        # don't exists, we have to create it
        open(my $handle, '>', $options{state_file}) or return;
        print $handle "[_default_]\n";
        close($handle);
    }

    my $self = Config::IniFiles->new(
        $options{state_file}
        ? (-file => $options{state_file})
        : (),
    );

    if ($options{state_file} && !$self->GetFileName) {
        $self->SetFileName($options{state_file});
    }
    
    $self->{from} = $from;

    # allow ref and array ref of, eg
    # to = $foo and $to = [ $foo, $bar ]
    foreach (ref($to) eq 'ARRAY' ? @{ $to || []} : ($to)) {
        push(@{$self->{to}}, $_);
    }
    bless($self, $class)
}

sub from {
    my ($self) = @_;
    return $self->{from}
}

sub to {
    my ($self) = @_;
    return @{$self->{to} || []};
}

=head2 load_dest

Try to loaded all base, return the count of filtrered base which cannot
be loaded

=cut

sub load_dest {
    my ($self) = @_;
    my @loaded;
    my $unloaded = 0;
    foreach ($self->to) {
        if($_->load) {
            push(@loaded, $_);
        } else {
            $unloaded++;
        }
    }
    $self->{to} = \@loaded;
    return $unloaded;
}

sub _common_fields {
    my ($self, $from, $to, $otype) = @_;
    my %fields = ();
    foreach my $base ($from, $to) {
        foreach ($base->list_canonicals_fields($otype)) {
            $fields{$_} ||= 0; # avoid 
            $fields{$_}++;
        }
    }
    # field having value are in both
    grep { $fields{$_} == 2 } keys %fields;
}

sub _traverse {
    my ($self, $attr_cb, %options) = @_;
    
    # listing existing obj one time:
    foreach my $otype ($self->from->list_supported_objects) {
        
        # If no dest support $otype, we skip
        my @obj_dest_base = grep {
            $_->is_supported_object($otype)
        } $self->to or next;

        # loading object list one time for all
        # TODO optimize this, using rev of objects

        warn "Sync objects $otype\n";
        foreach my $destbase (@obj_dest_base) {
            my @lobjfrom = $self->from->list_objects_from_rev(
                $otype,
                $self->val($self->from->label, $destbase->label),
            );
            warn "objects $otype => " . $destbase->type . "\n";
            my @common_fields = $attr_cb->($self->from, $destbase, $otype) or next;
            my %exists = map { $_ => 1 } $destbase->list_objects($otype);
            foreach my $uid (@lobjfrom) {
                my $sobj = $self->from->get_object($otype, $uid);
                my %fields = map { $_ => $sobj->get_c_field($_, 'r') } @common_fields;
                if (!$exists{$uid}) {
                    $destbase->create_c_object($otype, $uid, %fields);
                    warn "  $otype $uid: created\n";
                } else {
                    my $dobj = $destbase->get_object($otype, $uid);
                    $dobj->set_c_fields(%fields);
                    warn "  $otype $uid: synched\n";
                }
            }
        }
    }
}

sub process {
    my ($self, %options) = @_;

    $self->from->load or return;
    # if any cannot be loaded, return,
    # TODO we need a way to force if some still can be sync
    $self->load_dest and return;
    
    # tracking current base revision:
    $self->{current_rev} = $self->from->current_rev;

    my %delayed;
    $self->_traverse(
        sub {
            my ($from, $to, $otype) = @_;
            my %fields = ();
            my %delayed = map { $_ => 1 } $to->delayed_fields($otype);
            foreach my $base ($from, $to) {
                foreach ($base->list_canonicals_fields($otype)) {
                    $delayed{$_} and next;
                    $fields{$_} ||= 0; # avoid 
                    $fields{$_}++;
                }
            }
            # field having value are in both
            grep { $fields{$_} == 2 } keys %fields;
        },
        %options
    );
    $self->_traverse(
        sub {
            my ($from, $to, $otype) = @_;
            my %fields = ();
            my %delayed = map { $_ => 1 } $to->delayed_fields($otype);
            foreach my $base ($from, $to) {
                foreach ($base->list_canonicals_fields($otype)) {
                    $delayed{$_} or next;
                    $fields{$_} ||= 0; # avoid 
                    $fields{$_}++;
                }
            }
            # field having value are in both
            grep { $fields{$_} == 2 } keys %fields;
        },
        %options
    );

    foreach ($self->to) {
        $_->commit or next;
        $self->newval($self->from->label, $_->label, $self->{current_rev}) if($self->{current_rev});
    }

    $self->RewriteConfig if($self->GetFileName);
    
    1;
}

1;

__END__
# Below is stub documentation for your module. You'd better edit it!

=head1 SEE ALSO

Mention other useful documentation such as the documentation of
related modules or operating system documentation (such as man pages
in UNIX), or any relevant external documentation such as RFCs or
standards.

If you have a mailing list set up for your module, mention it here.

If you have a web site set up for your module, mention it here.

=head1 AUTHOR

Thauvin Olivier, E<lt>olivier.thauvin@latmosipsl.frE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2009 by Thauvin Olivier

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself, either Perl version 5.10.0 or,
at your option, any later version of Perl 5 you may have available.


=cut