source: trunk/LATMOS-Accounts-Web/lib/LATMOS/Accounts/Web/Controller/Json/EmploymentByPeriod.pm @ 2006

package LATMOS::Accounts::Web::Controller::Json::EmploymentByPeriod;
use Moose;
use namespace::autoclean;

BEGIN { extends 'Catalyst::Controller'; }

=head1 NAME

LATMOS::Accounts::Web::Controller::Json::EmploymentByPeriod - Catalyst Controller

=head1 DESCRIPTION

Catalyst Controller.

=head1 METHODS

=cut


=head2 index

=cut

sub index :Path :Args(0) {
    my ( $self, $c ) = @_;

    my $base = $c->model('Accounts')->db;

    my ($sday, $smonth, $syear) = split('/', $c->req->param('start'));
    my ($eday, $emonth, $eyear) = split('/', $c->req->param('end'));

    my $start = DateTime->new(year => $syear, month => $smonth, day => $sday);
    my $end   = DateTime->new(year => $eyear, month => $emonth, day => $eday);

    my @filteredObj = $base->search_objects(
        'employment', sprintf('firstday<=%s', $end->ymd('-')), sprintf('lastday>=%s', $start->ymd('-')), 'lastday=NULL'
    );
    my %atstart = map { $_ => 1 } $base->search_objects(
        'employment', sprintf('firstday>=%s', $start->ymd('-'))
    );
    my %atend = map { $_ => 1 } $base->search_objects(
        'employment', sprintf('lastday<=%s', $end->ymd('-'))
    );

    my %empusers = $base->attributes_summary_by_object('employment', 'user');
    my %emptypes = $base->attributes_summary_by_object('employment', 'contratType');

    my %results;
    my $atstart = $c->req->param('atstart');
    my $atend =   $c->req->param('atend');

    foreach my $emp (@filteredObj) {
        if ($atstart) {
            $atstart{$emp} or next;
        }
        if ($atend) {
            $atend{$emp} or next;
        }
        my $user = $empusers{$emp}[0];
        my $type = $emptypes{$emp}[0];
        $results{$type}{$user} = 1;
    }

    $c->stash->{data} = [ 
        sort { $b->[1] <=> $a->[1] } 
        map { [ $_, scalar(keys %{$results{$_}}) ] } keys %results
    ];
}

=encoding utf8

=head1 AUTHOR

Olivier Thauvin,Guyancourt - B1428,+33 1 80285052,

=head1 LICENSE

This library is free software. You can redistribute it and/or modify
it under the same terms as Perl itself.

=cut

__PACKAGE__->meta->make_immutable;

1;