source: trunk/LATMOS-Accounts-Web/lib/LATMOS/Accounts/Web/Controller/Json/Stat.pm @ 1936

package LATMOS::Accounts::Web::Controller::Json::Stat;
use Moose;
use namespace::autoclean;
use POSIX;

BEGIN { extends 'Catalyst::Controller'; }

=head1 NAME

LATMOS::Accounts::Web::Controller::Json::Stat - Catalyst Controller

=head1 DESCRIPTION

Catalyst Controller.

=head1 METHODS

=cut


=head2 index

=cut

sub index :Path :Args(1) {
    my ( $self, $c, $statname ) = @_;

    my $base = $c->model('Accounts')->db;

    my $ostat = $base->get_object('stat', $statname) or return;

    my $res = $ostat->compute or return;

    $c->stash->{data} = [ map { [ $_, $res->{$_} +0 ] } sort { $res->{$b} <=> $res->{$a} } keys %$res ];
}

sub history :Local :Args(1) {
    my ( $self, $c, $statname ) = @_;

    my $base = $c->model('Accounts')->db;

    my $ostat = $base->get_object('stat', $statname) or return;

    my $data = $ostat->getAllStat or return;

    my $res = $ostat->compute or return;

    my $nowdate = POSIX::strftime('%Y-%m-%d %H:%M', localtime);
    foreach my $val (sort keys %$res) {
        $data->{$nowdate}{$val} = $res->{$val} + 0;
    }

    my $graph = {
        series => [],
        data => [],
    };

    my %lines;

    my @dates = sort keys %$data;

    for (my $i = 0; $i <= $#dates; $i++) {
        my $date = $dates[$i];

        if ($i >= 1) {
            my $tdate = $dates[$i - 1];
            foreach my $val (sort keys %{ $data->{$tdate} }) {
                $data->{$tdate}{$val} or next;
                $data->{$date}{$val} ||= 0;
            }
        }
        if ($i < $#dates) {
            my $tdate = $dates[$i + 1];
            foreach my $val (sort keys %{ $data->{$tdate} }) {
                $data->{$tdate}{$val} or next;
                $data->{$date}{$val} ||= 0;
            }
        }
        foreach my $val (sort keys %{ $data->{$date} }) {
            $res->{ $val } ||= 0;
            push(@{ $lines{$val} }, [ $date, $data->{$date}{$val} + 0 ]);
        }
    }

    foreach (sort { $res->{$b} <=> $res->{$a} } keys %lines) {
        push(@{ $graph->{data} }, $lines{$_});
        push(@{ $graph->{series} }, { label => $_ });
    }

    $c->stash->{data} = $graph;
}


=encoding utf8

=head1 AUTHOR

Olivier Thauvin

=head1 LICENSE

This library is free software. You can redistribute it and/or modify
it under the same terms as Perl itself.

=cut

__PACKAGE__->meta->make_immutable;

1;