source: trunk/LATMOS-Accounts-Web/lib/LATMOS/Accounts/Web/Controller/Json/Timeline.pm @ 1678

package LATMOS::Accounts::Web::Controller::Json::Timeline;
use Moose;
use namespace::autoclean;

use DateTime;
use Date::Parse;

BEGIN { extends 'Catalyst::Controller'; }

=head1 NAME

LATMOS::Accounts::Web::Controller::Json::Timeline - Catalyst Controller

=head1 DESCRIPTION

Catalyst Controller.

=head1 METHODS

=cut


=head2 index

=cut

sub index :Path :Args(1) {
    my ( $self, $c, $user ) = @_;

    my $base = $c->model('Accounts')->db;
    my $ouser = $base->get_object('user', $user)
        or return;

    my @colors = qw(black silver green blue red);
    my %colorset;


    my $var = {
        start => $ouser->get_attributes('create'),
        end => undef,
        employments => {
            name => 'Employment',
            color => '#000000',
            spans => [],
            events => [],
        },
    };

    foreach my $emp ($ouser->listEmployment) {
        my $employment = $base->get_object('employment', $emp);

        my $vemp = {
            name => ($employment->get_attributes('contratType') || ''),
            start => $employment->get_attributes('firstday'),
            end => $employment->get_attributes('lastday') || undef,
        };

        if (!$colorset{$vemp->{name}}) {
            $colorset{$vemp->{name}} = $colors[0];
            push(@colors, shift(@colors));
        }
        $vemp->{color} =  $colorset{$vemp->{name}};

        if (!$vemp->{end}) {
            my $dt = DateTime->now();
            $dt->add(days => 3 * 365);
            $vemp->{end} = $dt->ymd('-') . ' ' . $dt->hms;
        }

        $vemp->{start} .= ' 00:00:00';
        $vemp->{end}   .= ' 23:59:59';

        push(@{$var->{employments}{spans}}, $vemp);
    }

    my $dtnow = DateTime->now;
    push(@{$var->{employments}{events}}, {
            name => $c->loc('Today'),
            date => $dtnow->ymd . ' ' . $dtnow->hms,
    });
    push(@{$var->{employments}{events}}, {
            name => $c->loc('Created'),
            date => $ouser->get_attributes('create'),
    });
    if (my $expire = $ouser->get_attributes('expire')) {
        push(@{$var->{employments}{events}}, {
                name => $c->loc('Expire'),
                date => $expire,
                options => {
                    type => 'alarm',
                }
        });
    }
    if (my $endcircuit = $ouser->get_attributes('endcircuit')) {
        push(@{$var->{employments}{events}}, {
                name => $c->loc('End of entrance'),
                date => $endcircuit,
                options => {
                    type => 'alarm',
                }
        });
    }
    if (my $date = $ouser->get_attributes('startEmployment')) {
        push(@{$var->{employments}{events}}, {
                name => $c->loc('Activity start'),
                date => $date,
                options => {
                    type => 'employment',
                    showdate => 1,
                }
        });
    }
    if (my $date = $ouser->get_attributes('endEmployment')) {
        push(@{$var->{employments}{events}}, {
                name => $c->loc('Activity end'),
                date => $date,
                options => {
                    type => 'employment',
                    showdate => 1,
                }
        });
    }

    foreach (@{ $var->{employments}{spans} }) {
        $var->{end}   = $_->{end}   if ((!$var->{end})   || $_->{end} gt $var->{end});
        $var->{start} = $_->{start} if ((!$var->{start}) || $_->{start} lt $var->{start});
    }
    foreach (@{ $var->{employments}{events} }) {
        $var->{end}   = $_->{date}   if ((!$var->{end})   || $_->{date} gt $var->{end});
        $var->{start} = $_->{date}   if ((!$var->{start}) || $_->{date} lt $var->{start});
    }

    $c->stash->{data} = $var;
}



=encoding utf8

=head1 AUTHOR

Olivier Thauvin,Guyancourt - B1428,+33 1 80285052,

=head1 LICENSE

This library is free software. You can redistribute it and/or modify
it under the same terms as Perl itself.

=cut

__PACKAGE__->meta->make_immutable;

1;