source: trunk/LATMOS-Accounts-Web/lib/LATMOS/Accounts/Web/Controller/Summary/Offices.pm @ 1694

package LATMOS::Accounts::Web::Controller::Summary::Offices;
use Moose;
use namespace::autoclean;

BEGIN {extends 'Catalyst::Controller'; }

=head1 NAME

LATMOS::Accounts::Web::Controller::Summary::Offices - Catalyst Controller

=head1 DESCRIPTION

Catalyst Controller.

=head1 METHODS

=cut


=head2 index

=cut

sub index :Path :Args(0) {
    my ( $self, $c ) = @_;

    my $base = $c->model('Accounts')->base;

    my $users = $base->fetchObjectInfo(
        'user',
        [ qw(sn givenName) ],
        'active=1'
    );

    my $sites = $base->fetchObjectInfo(
        'site',
        [ qw(l description) ],
        'exported=true'
    );

    my $addresses = $base->fetchObjectInfo(
        'address',
        [ qw(user site physicalDeliveryOfficeName telephoneNumber l isMainAddress) ],
        'exported=true'
    );

    foreach my $ad (keys %$addresses) {
        my $sitename = $addresses->{$ad}{site}[0] || $c->loc('(other)');

        my $loc = $addresses->{$ad}{site}[0]
            ? $sites->{ $addresses->{$ad}{site}[0] }{l}[0]
            : $addresses->{$ad}{l}[0];

        my $office = $addresses->{$ad}{physicalDeliveryOfficeName}[0] || '';

        my $user = $users->{ $addresses->{$ad}{user}[0] } or next;

        $c->stash->{sites} = $sites;

        push (
            @{$c->stash->{office}{$sitename}{$office}},
            {
                displayName => sprintf('%s %s', $user->{givenName}[0], $user->{sn}[0]),
                phone => $addresses->{$ad}{telephoneNumber}[0],
                isMainAddress => $addresses->{$ad}{isMainAddress}[0],
                id => $ad,
                user => $addresses->{$ad}{user}[0],
                l => $loc,
                site => $sitename,
            }
        );
    }
}


=head1 AUTHOR

olivier

=head1 LICENSE

This library is free software. You can redistribute it and/or modify
it under the same terms as Perl itself.

=cut

__PACKAGE__->meta->make_immutable;

1;