source: trunk/LATMOS-Accounts-Web/lib/LATMOS/Accounts/Web/Controller/Tools/CSV.pm @ 1991

package LATMOS::Accounts::Web::Controller::Tools::CSV;
use Moose;
use namespace::autoclean;
use LATMOS::Accounts::Utils;
use LATMOS::Accounts::Log;

BEGIN { extends 'Catalyst::Controller'; }

=head1 NAME

LATMOS::Accounts::Web::Controller::Tools::MassCreation - Catalyst Controller

=head1 DESCRIPTION

Catalyst Controller.

=head1 METHODS

=cut


=head2 index

=cut

sub index :Path :Args(0) {
    my ( $self, $c ) = @_;

    if ($c->req->upload('csv')) {
        $c->go('parseCSV');
    }
}

sub parseCSV : Private {
    my ( $self, $c ) = @_;

    my $upload = $c->req->upload('csv');
    my $otype = $c->req->param('otype');
    $c->stash->{otype} = $otype;

    my $error = 0;
    loadCSV(
        $upload->fh,
        cb => sub {
            my ($res, $count) = @_;

            my $ochelper = $c->model('Accounts')->db->ochelper($otype);

            my $info = {
                contents => $res
            };

            if ($res->{name}) {
                $info->{name}{content} = $res->{name};
            }

            if ($ochelper->Automate($info)) {
                push(@{ $c->stash->{results} },
                    {
                        objectName => $info->{name}{content},
                        info => $res,
                    }
                );
                push(@{ $c->session->{selectedObjects} }, $info->{name}{content});
                $c->session->{selectedOtype} = $otype;
            } else {
                $error = 1;
                push(@{ $c->stash->{failures} },
                    {
                        line => $count,
                        error => LATMOS::Accounts::Log::lastmessage,
                    }
                );
            }
            return 1;
        },
        initcb => sub {
            my ($csv) = @_;
            @{ $c->stash->{attrs} } = $csv->column_names;
        },
    );

    if ($error) {
        $c->stash->{failure} = 1;
        $c->model('Accounts')->db->rollback;
    } else {
        $c->model('Accounts')->db->commit;
    }
    
}



=encoding utf8

=head1 AUTHOR

Olivier Thauvin,Guyancourt - B1428,+33 1 80285052,

=head1 LICENSE

This library is free software. You can redistribute it and/or modify
it under the same terms as Perl itself.

=cut

__PACKAGE__->meta->make_immutable;

1;