source: trunk/LATMOS-Accounts/lib/LATMOS/Accounts/SyncManager.pm @ 1023

package LATMOS::Accounts::SyncManager;

use strict;
use warnings;
use LATMOS::Accounts::Log;
use LATMOS::Accounts;

=head1 NAME

LATMOS::Accounts::SyncManager - Routine task manager

=head1 DESCRIPTION

Handle Task process run by L<la-sync-manager>

=head1 FUNCTIONS

=cut

=head2 new($config)

Instaciate object. 

C<$config> is a path to an alternative configuration file to default one.

=cut

sub new {
    my ($class, $config) = @_;

    my $ini = Config::IniFiles->new(
        -file => join('/', ($config || '/etc/latmos-accounts'),
            'la-sync-manager.ini'),
    ) or do {
        la_log LA_ERR, "Cannot load config";
        return;
    };

    bless {
        ini => $ini,
        config => $config,
        lastrev => 0,
    }, $class;
}

=head2 ini

Return a reference to the L<Ini::Files> object handling configuration.

=cut

sub ini { $_[0]->{ini} }

=head2 dbrev

Return the current base revision

=cut

sub dbrev { $_[0]->{lastrev} }

=head2 updrev

Update status file with with current base revision as restart point

=cut

sub updrev {
    my ($self) = @_;
    my $LA = LATMOS::Accounts->new($self->{config}, noacl => 1);
    my $base = $LA->default_base;
    my $newrev = $base->current_rev;
    $self->{lastrev} = $newrev;
    return $newrev;
}

=head2 list_modules

List configured task module

=cut

sub list_modules {
    my ($self) = @_;
    $self->ini->Sections;
}

=head2 process_module($module, $dbrev)

Process C<$module>.

=cut

# TODO what is $dbrev, why is it need here ??

sub process_module {
    my ($self, $module, $dbrev) = @_;

    eval {
        if (!$self->ini->SectionExists($module)) {
            la_log LA_ERR, "Cannot run inexistant module %s", $module;
            return;
        }

        my $modtype = $self->ini->val($module, 'type', $module);
        my $task = LATMOS::Accounts::Task->new(
            $modtype,
            config => $self->{config},
        )
            or do {
            la_log(LA_ERR, 'Cannot load module %s', $modtype);
            return;
        };
        la_log LA_NOTICE, "Processing sync module %s (%s)", $module, $modtype;
        if (!$task->init) {
            la_log(LA_ERR, 'init() failed for module %s', $module);
            return;
        }

        if (!$task->needupd($dbrev, $self)) {
            la_log LA_DEBUG, "No change on main base, aborting";
            return 1;
        }


        my $res = $task->run;
        if (!$res) {
            la_log LA_ERR, "Task %s did not end successfully", $module;
        }
        $task->post if ($res);
        la_log LA_DEBUG, "end process $module";
        return $res;
    };

    if ($@) {
        la_log(LA_CRIT, 'Fatal Perl Error: %s', $@);
        return;
    } else {
        return 1;
    }
}

1;

__END__

=head1 SEE ALSO

L<LATMOS::Accountsi::Task>

=head1 AUTHOR

Olivier Thauvin, E<lt>olivier.thauvin@latmos.ipsl.frE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2012 CNRS SA/CETP/LATMOS

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself, either Perl version 5.10.0 or,
at your option, any later version of Perl 5 you may have available.

=cut