source: trunk/LATMOS-Accounts/lib/LATMOS/Accounts/Task/Employment.pm @ 2286

package LATMOS::Accounts::Task::Employment;

use strict;
use warnings;
use base qw(LATMOS::Accounts::Task);
use LATMOS::Accounts;
use LATMOS::Accounts::Log;
use LATMOS::Accounts::Utils;
use LATMOS::Accounts::Bases::Sql::Employment;
use DateTime;
use DateTime::TimeZone;

=head1 NAME

LATMOS::Accounts::Task::Stats - Store value to perform some statistics

=head1 DESCRIPTION

=cut

sub order { 0 }

sub init {
    my ($self) = @_;
    my $LA = LATMOS::Accounts->new($self->{config}, noacl => 1);
    my $labase = $self->{base} ? $LA->base($self->{base}) : $LA->base;
    $labase && $labase->load or die "Cannot load base";

    $self->{_la} = $LA;
    $self->{_base} = $labase;

    1;
}

# Run it every 10 minutes, not more often
sub runDelay { 10 * 60 }

sub run {
    my ($self) = @_;

    my %users = map { $_ => undef } $self->{_base}->search_objects('user', 'exported=true');
    my %old = $self->{_base}->attributes_summary_by_object('user', 'appliedEmployement');
    foreach (keys %old) {
        exists($users{$_}) or next;
        $users{$_} = $old{$_}->[0] || '';
    }

    my $now = DateTime->now()->iso8601 . 'Z';

    my $listempl = $self->{_base}->db->prepare_cached(q{
        SELECT * FROM employment where firstday <= ?::timestamp and (lastday is null or lastday >= ?::timestamp - '1 days'::interval)
            and exported = true
            order by lastday, firstday
    });
    $listempl->execute($now, $now);
    my %new  = ();
    while (my $res = $listempl->fetchrow_hashref) {
        my $employment = $res->{name};
        my $user = $res->{user};
        exists($users{$user}) or next;
        # avoid undef:
        $users{$user} ||= '';
        if ($employment ne $users{$user}) {
            my $ouser = $self->{_base}->get_object('user', $user) or next;

            $self->{_base}->log(LA_NOTICE, "Updating user $user to match employment `%s'", $employment || '');
            $ouser->applyCurrentEmployment;
            $self->{_base}->commit;
        }
        delete($users{$user});
    }

    # Change has old employment => nothing
    # if user is still active, expired account remains untouched
    foreach my $user ($self->{_base}->search_objects('user', 'exported=true')) {
        if ($users{$user}) {
            my $ouser = $self->{_base}->get_object('user', $user);
            if ($ouser->_resetEmployment) {
                $self->{_base}->commit;
            } else {
                $self->{_base}->rollback;
            }
        }
    }

    return 1;
}

1;

__END__

=head1 SEE ALSO

L<LATMOS::Accounts>, L<LATMOS::Accounts::Task>

=head1 AUTHOR

Olivier Thauvin, E<lt>olivier.thauvin@latmos.ipsl.frE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2012 CNRS SA/CETP/LATMOS

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself, either Perl version 5.10.0 or,
at your option, any later version of Perl 5 you may have available.

=cut