source: trunk/NEMOGCM/NEMO/OPA_SRC/step.F90 @ 37

Last change on this file since 37 was 36, checked in by cholod, 12 years ago

start_date and nit000 for XIOS automatically managed by nemo
File size: 16.5 KB
Line 
1MODULE step
2   !!======================================================================
3   !!                       ***  MODULE step  ***
4   !! Time-stepping    : manager of the ocean, tracer and ice time stepping
5   !!======================================================================
6   !! History :  OPA  !  1991-03  (G. Madec)  Original code
7   !!             -   !  1991-11  (G. Madec)
8   !!             -   !  1992-06  (M. Imbard)  add a first output record
9   !!             -   !  1996-04  (G. Madec)  introduction of dynspg
10   !!             -   !  1996-04  (M.A. Foujols)  introduction of passive tracer
11   !!            8.0  !  1997-06  (G. Madec)  new architecture of call
12   !!            8.2  !  1997-06  (G. Madec, M. Imbard, G. Roullet)  free surface
13   !!             -   !  1999-02  (G. Madec, N. Grima)  hpg implicit
14   !!             -   !  2000-07  (J-M Molines, M. Imbard)  Open Bondary Conditions
15   !!   NEMO     1.0  !  2002-06  (G. Madec)  free form, suppress macro-tasking
16   !!             -   !  2004-08  (C. Talandier) New trends organization
17   !!             -   !  2005-01  (C. Ethe) Add the KPP closure scheme
18   !!             -   !  2005-11  (G. Madec)  Reorganisation of tra and dyn calls
19   !!             -   !  2006-01  (L. Debreu, C. Mazauric)  Agrif implementation
20   !!             -   !  2006-07  (S. Masson)  restart using iom
21   !!            3.2  !  2009-02  (G. Madec, R. Benshila)  reintroduicing z*-coordinate
22   !!             -   !  2009-06  (S. Masson, G. Madec)  TKE restart compatible with key_cpl
23   !!            3.3  !  2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
24   !!             -   !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
25   !!            3.4  !  2011-04  (G. Madec, C. Ethe) Merge of dtatem and dtasal
26   !!----------------------------------------------------------------------
27
28   !!----------------------------------------------------------------------
29   !!   stp             : OPA system time-stepping
30   !!----------------------------------------------------------------------
31   USE step_oce         ! time stepping definition modules
32#if defined key_top
33   USE trcstp           ! passive tracer time-stepping      (trc_stp routine)
34#endif
35#if defined key_agrif
36   USE agrif_opa_sponge ! Momemtum and tracers sponges
37#endif
38
39   IMPLICIT NONE
40   PRIVATE
41
42   PUBLIC   stp   ! called by opa.F90
43
44   !! * Substitutions
45#  include "domzgr_substitute.h90"
46#  include "zdfddm_substitute.h90"
47   !!----------------------------------------------------------------------
48   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
49   !! $Id: step.F90 3217 2011-12-13 09:07:25Z cbricaud $
50   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54#if defined key_agrif
55   SUBROUTINE stp( )
56      INTEGER             ::   kstp   ! ocean time-step index
57#else
58   SUBROUTINE stp( kstp )
59      INTEGER, INTENT(in) ::   kstp   ! ocean time-step index
60#endif
61      !!----------------------------------------------------------------------
62      !!                     ***  ROUTINE stp  ***
63      !!                     
64      !! ** Purpose : - Time stepping of OPA (momentum and active tracer eqs.)
65      !!              - Time stepping of LIM (dynamic and thermodynamic eqs.)
66      !!              - Tme stepping  of TRC (passive tracer eqs.)
67      !!
68      !! ** Method  : -1- Update forcings and data 
69      !!              -2- Update ocean physics
70      !!              -3- Compute the t and s trends
71      !!              -4- Update t and s
72      !!              -5- Compute the momentum trends
73      !!              -6- Update the horizontal velocity
74      !!              -7- Compute the diagnostics variables (rd,N2, div,cur,w)
75      !!              -8- Outputs and diagnostics
76      !!----------------------------------------------------------------------
77      INTEGER ::   jk       ! dummy loop indice
78      INTEGER ::   indic    ! error indicator if < 0
79     
80      INTEGER :: inb_period_initial, inb_period_final, inb_period_sec, inb_period_max, inb_period
81      !! ---------------------------------------------------------------------
82
83      CALL SYSTEM_CLOCK(count_rate=inb_period_sec, count_max=inb_period_max)
84      CALL SYSTEM_CLOCK(count=inb_period_initial)
85#if defined key_agrif
86      kstp = nit000 + Agrif_Nb_Step()
87!      IF ( Agrif_Root() .and. lwp) Write(*,*) '---'
88!      IF (lwp) Write(*,*) 'Grid Number',Agrif_Fixed(),' time step ',kstp
89# if defined key_iomput
90      IF( Agrif_Nbstepint() == 0 )   CALL iom_swap
91# endif   
92#endif   
93                             indic = 0                ! reset to no error condition
94      IF( kstp /= nit000 )   CALL day( kstp )         ! Calendar (day was already called at nit000 in day_init)
95                             CALL iom_setkt( kstp -nit000 + 1 )   ! say to iom that we are at time step kstp
96
97      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
98      ! Update data, open boundaries, surface boundary condition (including sea-ice)
99      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
100                         CALL sbc    ( kstp )         ! Sea Boundary Condition (including sea-ice)
101      IF( lk_tide    )   CALL sbc_tide( kstp )
102      IF( lk_obc     )   CALL obc_dta( kstp )         ! update dynamic and tracer data at open boundaries
103      IF( lk_obc     )   CALL obc_rad( kstp )         ! compute phase velocities at open boundaries
104      IF( lk_bdy     )   CALL bdy_dta( kstp, time_offset=+1 ) ! update dynamic and tracer data at open boundaries
105
106      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
107      !  Ocean dynamics : ssh, wn, hdiv, rot                                 !
108      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
109                         CALL ssh_wzv( kstp )         ! after ssh & vertical velocity
110
111      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
112      ! Ocean physics update                (ua, va, tsa used as workspace)
113      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
114                         CALL bn2( tsb, rn2b )        ! before Brunt-Vaisala frequency
115                         CALL bn2( tsn, rn2  )        ! now    Brunt-Vaisala frequency
116      !
117      !  VERTICAL PHYSICS   
118                         CALL zdf_bfr( kstp )         ! bottom friction
119                         
120      !                                               ! Vertical eddy viscosity and diffusivity coefficients
121      IF( lk_zdfric  )   CALL zdf_ric( kstp )            ! Richardson number dependent Kz
122      IF( lk_zdftke  )   CALL zdf_tke( kstp )            ! TKE closure scheme for Kz
123      IF( lk_zdfgls  )   CALL zdf_gls( kstp )            ! GLS closure scheme for Kz
124      IF( lk_zdfkpp  )   CALL zdf_kpp( kstp )            ! KPP closure scheme for Kz
125      IF( lk_zdfcst  )   THEN                            ! Constant Kz (reset avt, avm[uv] to the background value)
126         avt (:,:,:) = rn_avt0 * tmask(:,:,:)
127         avmu(:,:,:) = rn_avm0 * umask(:,:,:)
128         avmv(:,:,:) = rn_avm0 * vmask(:,:,:)
129      ENDIF
130      IF( ln_rnf_mouth ) THEN                         ! increase diffusivity at rivers mouths
131         DO jk = 2, nkrnf   ;   avt(:,:,jk) = avt(:,:,jk) + 2.e0 * rn_avt_rnf * rnfmsk(:,:) * tmask(:,:,jk)   ;   END DO
132      ENDIF
133      IF( ln_zdfevd  )   CALL zdf_evd( kstp )         ! enhanced vertical eddy diffusivity
134
135      IF( lk_zdftmx  )   CALL zdf_tmx( kstp )         ! tidal vertical mixing
136
137      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
138         &               CALL zdf_ddm( kstp )         ! double diffusive mixing
139         
140                         CALL zdf_mxl( kstp )         ! mixed layer depth
141
142                                                      ! write TKE or GLS information in the restart file
143      IF( lrst_oce .AND. lk_zdftke )   CALL tke_rst( kstp, 'WRITE' )
144      IF( lrst_oce .AND. lk_zdfgls )   CALL gls_rst( kstp, 'WRITE' )
145      !
146      !  LATERAL  PHYSICS
147      !
148      IF( lk_ldfslp ) THEN                            ! slope of lateral mixing
149                         CALL eos( tsb, rhd )                ! before in situ density
150         IF( ln_zps )    CALL zps_hde( kstp, jpts, tsb, gtsu, gtsv,  &    ! Partial steps: before horizontal gradient
151            &                                      rhd, gru , grv  )      ! of t, s, rd at the last ocean level
152         IF( ln_traldf_grif ) THEN                           ! before slope for Griffies operator
153                         CALL ldf_slp_grif( kstp )
154         ELSE
155                         CALL ldf_slp( kstp, rhd, rn2b )     ! before slope for Madec operator
156         ENDIF
157      ENDIF
158#if defined key_traldf_c2d
159      IF( lk_traldf_eiv )   CALL ldf_eiv( kstp )      ! eddy induced velocity coefficient
160#endif
161
162      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
163      ! diagnostics and outputs             (ua, va, tsa used as workspace)
164      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
165      IF( lk_floats  )   CALL flo_stp( kstp )         ! drifting Floats
166      IF( lk_diahth  )   CALL dia_hth( kstp )         ! Thermocline depth (20 degres isotherm depth)
167      IF( lk_diafwb  )   CALL dia_fwb( kstp )         ! Fresh water budget diagnostics
168      IF( ln_diaptr  )   CALL dia_ptr( kstp )         ! Poleward TRansports diagnostics
169      IF( lk_diadct  )   CALL dia_dct( kstp )         ! Transports
170      IF( lk_diaar5  )   CALL dia_ar5( kstp )         ! ar5 diag
171      IF( lk_diaharm )   CALL dia_harm( kstp )        ! Tidal harmonic analysis
172                         CALL dia_wri( kstp )         ! ocean model: outputs
173
174#if defined key_top
175      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
176      ! Passive Tracer Model
177      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
178                         CALL trc_stp( kstp )         ! time-stepping
179#endif
180
181      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
182      ! Active tracers                              (ua, va used as workspace)
183      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
184                             tsa(:,:,:,:) = 0.e0            ! set tracer trends to zero
185
186      IF(  ln_asmiau .AND. &
187         & ln_trainc     )   CALL tra_asm_inc( kstp )       ! apply tracer assimilation increment
188                             CALL tra_sbc    ( kstp )       ! surface boundary condition
189      IF( ln_traqsr      )   CALL tra_qsr    ( kstp )       ! penetrative solar radiation qsr
190      IF( ln_trabbc      )   CALL tra_bbc    ( kstp )       ! bottom heat flux
191      IF( lk_trabbl      )   CALL tra_bbl    ( kstp )       ! advective (and/or diffusive) bottom boundary layer scheme
192      IF( ln_tradmp      )   CALL tra_dmp    ( kstp )       ! internal damping trends
193                             CALL tra_adv    ( kstp )       ! horizontal & vertical advection
194      IF( lk_zdfkpp      )   CALL tra_kpp    ( kstp )       ! KPP non-local tracer fluxes
195                             CALL tra_ldf    ( kstp )       ! lateral mixing
196#if defined key_agrif
197      IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_tra          ! tracers sponge
198#endif
199                             CALL tra_zdf    ( kstp )       ! vertical mixing and after tracer fields
200
201      IF( ln_dynhpg_imp  ) THEN                             ! semi-implicit hpg (time stepping then eos)
202         IF( ln_zdfnpc   )   CALL tra_npc( kstp )                ! update after fields by non-penetrative convection
203                             CALL tra_nxt( kstp )                ! tracer fields at next time step
204                             CALL eos    ( tsa, rhd, rhop )      ! Time-filtered in situ density for hpg computation
205         IF( ln_zps      )   CALL zps_hde( kstp, jpts, tsa, gtsu, gtsv,  &    ! zps: time filtered hor. derivative
206            &                                          rhd, gru , grv  )      ! of t, s, rd at the last ocean level
207         
208      ELSE                                                  ! centered hpg  (eos then time stepping)
209                             CALL eos    ( tsn, rhd, rhop )      ! now in situ density for hpg computation
210         IF( ln_zps      )   CALL zps_hde( kstp, jpts, tsn, gtsu, gtsv,  &    ! zps: now hor. derivative
211            &                                          rhd, gru , grv  )      ! of t, s, rd at the last ocean level
212         IF( ln_zdfnpc   )   CALL tra_npc( kstp )                ! update after fields by non-penetrative convection
213                             CALL tra_nxt( kstp )                ! tracer fields at next time step
214      ENDIF 
215
216      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
217      ! Dynamics                                    (tsa used as workspace)
218      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
219                               ua(:,:,:) = 0.e0             ! set dynamics trends to zero
220                               va(:,:,:) = 0.e0
221
222      IF(  ln_asmiau .AND. &
223         & ln_dyninc       )   CALL dyn_asm_inc( kstp )     ! apply dynamics assimilation increment
224      IF( ln_neptsimp )        CALL dyn_nept_cor( kstp )    ! subtract Neptune velocities (simplified)
225                               CALL dyn_adv( kstp )         ! advection (vector or flux form)
226                               CALL dyn_vor( kstp )         ! vorticity term including Coriolis
227                               CALL dyn_ldf( kstp )         ! lateral mixing
228      IF( ln_neptsimp )        CALL dyn_nept_cor( kstp )    ! add Neptune velocities (simplified)
229#if defined key_agrif
230      IF(.NOT. Agrif_Root())   CALL Agrif_Sponge_dyn        ! momemtum sponge
231#endif
232                               CALL dyn_hpg( kstp )         ! horizontal gradient of Hydrostatic pressure
233                               CALL dyn_bfr( kstp )         ! bottom friction   
234                               CALL dyn_zdf( kstp )         ! vertical diffusion
235                               CALL dyn_spg( kstp, indic )  ! surface pressure gradient
236                               CALL dyn_nxt( kstp )         ! lateral velocity at next time step
237
238                               CALL ssh_nxt( kstp )         ! sea surface height at next time step
239
240      IF( ln_diahsb        )   CALL dia_hsb( kstp )         ! - ML - global conservation diagnostics
241      IF( lk_diaobs  )         CALL dia_obs( kstp )         ! obs-minus-model (assimilation) diagnostics (call after dynamics update)
242
243      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
244      ! Control and restarts
245      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
246                               CALL stp_ctl( kstp, indic )
247      IF( indic < 0        )   THEN
248                               CALL ctl_stop( 'step: indic < 0' )
249                               CALL dia_wri_state( 'output.abort', kstp )
250      ENDIF
251      IF( kstp == nit000   )   CALL iom_close( numror )     ! close input  ocean restart file
252      IF( lrst_oce         )   CALL rst_write    ( kstp )   ! write output ocean restart file
253      IF( lk_obc           )   CALL obc_rst_write( kstp )   ! write open boundary restart file
254
255      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
256      ! Trends                              (ua, va, tsa used as workspace)
257      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
258      IF( nstop == 0 ) THEN                         
259         IF( lk_trddyn     )   CALL trd_dwr( kstp )         ! trends: dynamics
260         IF( lk_trdtra     )   CALL trd_twr( kstp )         ! trends: active tracers
261         IF( lk_trdmld     )   CALL trd_mld( kstp )         ! trends: Mixed-layer
262         IF( lk_trdvor     )   CALL trd_vor( kstp )         ! trends: vorticity budget
263      ENDIF
264
265      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
266      ! Coupled mode
267      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
268      IF( lk_cpl           )   CALL sbc_cpl_snd( kstp )     ! coupled mode : field exchanges
269      !
270      IF( nn_timing == 1 .AND.  kstp == nit000  )   CALL timing_reset
271      !
272      CALL SYSTEM_CLOCK(count=inb_period_final)
273      inb_period = inb_period_final - inb_period_initial
274      IF( inb_period_final < inb_period_initial ) inb_period = inb_period + inb_period_max
275      IF( lwp ) WRITE(numout,'(a, i6, f10.5)') 'step timing', kstp, REAL(inb_period,wp) / REAL(inb_period_sec,wp)
276      !
277   END SUBROUTINE stp
278
279   !!======================================================================
280END MODULE step
Note: See TracBrowser for help on using the repository browser.