Ticket #1340: zdfgls.F90

File zdfgls.F90, 58.4 KB (added by rbourdal, 6 years ago)
Line 
1MODULE zdfgls
2   !!======================================================================
3   !!                       ***  MODULE  zdfgls  ***
4   !! Ocean physics:  vertical mixing coefficient computed from the gls
5   !!                 turbulent closure parameterization
6   !!======================================================================
7   !! History :   3.0  !  2009-09  (G. Reffray)  Original code
8   !!             3.3  !  2010-10  (C. Bricaud)  Add in the reference
9   !!----------------------------------------------------------------------
10#if defined key_zdfgls   ||   defined key_esopa
11   !!----------------------------------------------------------------------
12   !!   'key_zdfgls'                 Generic Length Scale vertical physics
13   !!----------------------------------------------------------------------
14   !!   zdf_gls      : update momentum and tracer Kz from a gls scheme
15   !!   zdf_gls_init : initialization, namelist read, and parameters control
16   !!   gls_rst      : read/write gls restart in ocean restart file
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE dom_oce        ! ocean space and time domain
20   USE domvvl         ! ocean space and time domain : variable volume layer
21   USE zdf_oce        ! ocean vertical physics
22   USE zdfbfr         ! bottom friction (only for rn_bfrz0)
23   USE sbc_oce        ! surface boundary condition: ocean
24   USE phycst         ! physical constants
25   USE zdfmxl         ! mixed layer
26   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
27   USE lib_mpp        ! MPP manager
28   USE wrk_nemo       ! work arrays
29   USE prtctl         ! Print control
30   USE in_out_manager ! I/O manager
31   USE iom            ! I/O manager library
32   USE timing         ! Timing
33   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   zdf_gls        ! routine called in step module
39   PUBLIC   zdf_gls_init   ! routine called in opa module
40   PUBLIC   gls_rst        ! routine called in step module
41
42   LOGICAL , PUBLIC, PARAMETER ::   lk_zdfgls = .TRUE.   !: TKE vertical mixing flag
43   !
44   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   en      !: now turbulent kinetic energy
45   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   mxln    !: now mixing length
46   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   zwall   !: wall function
47   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   avt_k   ! not enhanced Kz
48   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   avm_k   ! not enhanced Kz
49   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   avmu_k  ! not enhanced Kz
50   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   avmv_k  ! not enhanced Kz
51   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ustars2 !: Squared surface velocity scale at T-points
52   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ustarb2 !: Squared bottom  velocity scale at T-points
53
54   !                                !!! ** Namelist  namzdf_gls  **
55   LOGICAL  ::   ln_length_lim      ! use limit on the dissipation rate under stable stratification (Galperin et al. 1988)
56   LOGICAL  ::   ln_sigpsi          ! Activate Burchard (2003) modification for k-eps closure & wave breaking mixing
57   INTEGER  ::   nn_bc_surf         ! surface boundary condition (=0/1)
58   INTEGER  ::   nn_bc_bot          ! bottom boundary condition (=0/1)
59   INTEGER  ::   nn_z0_met          ! Method for surface roughness computation
60   INTEGER  ::   nn_stab_func       ! stability functions G88, KC or Canuto (=0/1/2)
61   INTEGER  ::   nn_clos            ! closure 0/1/2/3 MY82/k-eps/k-w/gen
62   REAL(wp) ::   rn_clim_galp       ! Holt 2008 value for k-eps: 0.267
63   REAL(wp) ::   rn_epsmin          ! minimum value of dissipation (m2/s3)
64   REAL(wp) ::   rn_emin            ! minimum value of TKE (m2/s2)
65   REAL(wp) ::   rn_charn           ! Charnock constant for surface breaking waves mixing : 1400. (standard) or 2.e5 (Stacey value)
66   REAL(wp) ::   rn_crban           ! Craig and Banner constant for surface breaking waves mixing
67   REAL(wp) ::   rn_hsro            ! Minimum surface roughness
68   REAL(wp) ::   rn_frac_hs         ! Fraction of wave height as surface roughness (if nn_z0_met > 1)
69   !!!!!!
70   REAL(wp) ::   rcm_sf        =  0.73_wp     ! Shear free turbulence parameters
71   REAL(wp) ::   ra_sf         = -2.0_wp      ! Must be negative -2 < ra_sf < -1
72   REAL(wp) ::   rl_sf         =  0.2_wp      ! 0 <rl_sf<vkarmn   
73   REAL(wp) ::   rghmin        = -0.28_wp
74   REAL(wp) ::   rgh0          =  0.0329_wp
75   REAL(wp) ::   rghcri        =  0.03_wp
76   REAL(wp) ::   ra1           =  0.92_wp
77   REAL(wp) ::   ra2           =  0.74_wp
78   REAL(wp) ::   rb1           = 16.60_wp
79   REAL(wp) ::   rb2           = 10.10_wp         
80   REAL(wp) ::   re2           =  1.33_wp         
81   REAL(wp) ::   rl1           =  0.107_wp
82   REAL(wp) ::   rl2           =  0.0032_wp
83   REAL(wp) ::   rl3           =  0.0864_wp
84   REAL(wp) ::   rl4           =  0.12_wp
85   REAL(wp) ::   rl5           = 11.9_wp
86   REAL(wp) ::   rl6           =  0.4_wp
87   REAL(wp) ::   rl7           =  0.0_wp
88   REAL(wp) ::   rl8           =  0.48_wp
89   REAL(wp) ::   rm1           =  0.127_wp
90   REAL(wp) ::   rm2           =  0.00336_wp
91   REAL(wp) ::   rm3           =  0.0906_wp
92   REAL(wp) ::   rm4           =  0.101_wp
93   REAL(wp) ::   rm5           = 11.2_wp
94   REAL(wp) ::   rm6           =  0.4_wp
95   REAL(wp) ::   rm7           =  0.0_wp
96   REAL(wp) ::   rm8           =  0.318_wp
97   REAL(wp) ::   rtrans        =  0.1_wp
98   REAL(wp) ::   rc02, rc02r, rc03, rc04                          ! coefficients deduced from above parameters
99   REAL(wp) ::   rsbc_tke1, rsbc_tke2, rfact_tke                  !     -           -           -        -
100   REAL(wp) ::   rsbc_psi1, rsbc_psi2, rfact_psi                  !     -           -           -        -
101   REAL(wp) ::   rsbc_zs1, rsbc_zs2                               !     -           -           -        -
102   REAL(wp) ::   rc0, rc2, rc3, rf6, rcff, rc_diff                !     -           -           -        -
103   REAL(wp) ::   rs0, rs1, rs2, rs4, rs5, rs6                     !     -           -           -        -
104   REAL(wp) ::   rd0, rd1, rd2, rd3, rd4, rd5                     !     -           -           -        -
105   REAL(wp) ::   rsc_tke, rsc_psi, rpsi1, rpsi2, rpsi3, rsc_psi0  !     -           -           -        -
106   REAL(wp) ::   rpsi3m, rpsi3p, rpp, rmm, rnn                    !     -           -           -        -
107
108   !! * Substitutions
109#  include "domzgr_substitute.h90"
110#  include "vectopt_loop_substitute.h90"
111   !!----------------------------------------------------------------------
112   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
113   !! $Id: zdfgls.F90 4624 2014-04-28 12:09:03Z acc $
114   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
115   !!----------------------------------------------------------------------
116CONTAINS
117
118   INTEGER FUNCTION zdf_gls_alloc()
119      !!----------------------------------------------------------------------
120      !!                ***  FUNCTION zdf_gls_alloc  ***
121      !!----------------------------------------------------------------------
122      ALLOCATE( en(jpi,jpj,jpk),  mxln(jpi,jpj,jpk), zwall(jpi,jpj,jpk) ,     &
123         &      avt_k (jpi,jpj,jpk) , avm_k (jpi,jpj,jpk),                    &
124         &      avmu_k(jpi,jpj,jpk) , avmv_k(jpi,jpj,jpk),                    &
125         &      ustars2(jpi,jpj), ustarb2(jpi,jpj)                      , STAT= zdf_gls_alloc )
126         !
127      IF( lk_mpp             )   CALL mpp_sum ( zdf_gls_alloc )
128      IF( zdf_gls_alloc /= 0 )   CALL ctl_warn('zdf_gls_alloc: failed to allocate arrays')
129   END FUNCTION zdf_gls_alloc
130
131
132   SUBROUTINE zdf_gls( kt )
133      !!----------------------------------------------------------------------
134      !!                   ***  ROUTINE zdf_gls  ***
135      !!
136      !! ** Purpose :   Compute the vertical eddy viscosity and diffusivity
137      !!              coefficients using the GLS turbulent closure scheme.
138      !!----------------------------------------------------------------------
139      INTEGER, INTENT(in) ::   kt ! ocean time step
140      INTEGER  ::   ji, jj, jk, ibot, ibotm1, dir  ! dummy loop arguments
141      REAL(wp) ::   zesh2, zsigpsi, zcoef, zex1, zex2   ! local scalars
142      REAL(wp) ::   ztx2, zty2, zup, zdown, zcof        !   -      -
143      REAL(wp) ::   zratio, zrn2, zflxb, sh             !   -      -
144      REAL(wp) ::   prod, buoy, diss, zdiss, sm         !   -      -
145      REAL(wp) ::   gh, gm, shr, dif, zsqen, zav        !   -      -
146      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zdep
147      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zkar
148      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zflxs       ! Turbulence fluxed induced by internal waves
149      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zhsro       ! Surface roughness (surface waves)
150      REAL(wp), POINTER, DIMENSION(:,:,:) ::   eb          ! tke at time before
151      REAL(wp), POINTER, DIMENSION(:,:,:) ::   mxlb        ! mixing length at time before
152      REAL(wp), POINTER, DIMENSION(:,:,:) ::   shear       ! vertical shear
153      REAL(wp), POINTER, DIMENSION(:,:,:) ::   eps         ! dissipation rate
154      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwall_psi   ! Wall function use in the wb case (ln_sigpsi)
155      REAL(wp), POINTER, DIMENSION(:,:,:) ::   psi         ! psi at time now
156      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_a    ! element of the first  matrix diagonal
157      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_b    ! element of the second matrix diagonal
158      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_c    ! element of the third  matrix diagonal
159      !!--------------------------------------------------------------------
160      !
161      IF( nn_timing == 1 )  CALL timing_start('zdf_gls')
162      !
163      CALL wrk_alloc( jpi,jpj, zdep, zkar, zflxs, zhsro )
164      CALL wrk_alloc( jpi,jpj,jpk, eb, mxlb, shear, eps, zwall_psi, z_elem_a, z_elem_b, z_elem_c, psi  )
165     
166      ! Preliminary computing
167
168      ustars2 = 0._wp   ;   ustarb2 = 0._wp   ;   psi  = 0._wp   ;   zwall_psi = 0._wp
169
170      IF( kt /= nit000 ) THEN   ! restore before value to compute tke
171         avt (:,:,:) = avt_k (:,:,:)
172         avm (:,:,:) = avm_k (:,:,:)
173         avmu(:,:,:) = avmu_k(:,:,:)
174         avmv(:,:,:) = avmv_k(:,:,:) 
175      ENDIF
176
177      ! Compute surface and bottom friction at T-points
178!CDIR NOVERRCHK
179      DO jj = 2, jpjm1
180!CDIR NOVERRCHK
181         DO ji = fs_2, fs_jpim1   ! vector opt.
182            !
183            ! surface friction
184            ustars2(ji,jj) = r1_rau0 * taum(ji,jj) * tmask(ji,jj,1)
185            !
186            ! bottom friction (explicit before friction)
187            ! Note that we chose here not to bound the friction as in dynbfr)
188            ztx2 = (  bfrua(ji,jj)  * ub(ji,jj,mbku(ji,jj)) + bfrua(ji-1,jj) * ub(ji-1,jj,mbku(ji-1,jj))  )   &
189               & * ( 1._wp - 0.5_wp * umask(ji,jj,1) * umask(ji-1,jj,1)  )
190            zty2 = (  bfrva(ji,jj)  * vb(ji,jj,mbkv(ji,jj)) + bfrva(ji,jj-1) * vb(ji,jj-1,mbkv(ji,jj-1))  )   &
191               & * ( 1._wp - 0.5_wp * vmask(ji,jj,1) * vmask(ji,jj-1,1)  )
192            ustarb2(ji,jj) = SQRT( ztx2 * ztx2 + zty2 * zty2 ) * tmask(ji,jj,1)
193         END DO
194      END DO 
195
196      ! Set surface roughness length
197      SELECT CASE ( nn_z0_met )
198      !
199      CASE ( 0 )             ! Constant roughness         
200         zhsro(:,:) = rn_hsro
201      CASE ( 1 )             ! Standard Charnock formula
202         zhsro(:,:) = MAX(rsbc_zs1 * ustars2(:,:), rn_hsro)
203      CASE ( 2 )             ! Roughness formulae according to Rascle et al., Ocean Modelling (2008)
204         zdep(:,:)  = 30.*TANH(2.*0.3/(28.*SQRT(MAX(ustars2(:,:),rsmall))))             ! Wave age (eq. 10)
205         zhsro(:,:) = MAX(rsbc_zs2 * ustars2(:,:) * zdep(:,:)**1.5, rn_hsro) ! zhsro = rn_frac_hs * Hsw (eq. 11)
206      !
207      END SELECT
208
209      ! Compute shear and dissipation rate
210      DO jk = 2, jpkm1
211         DO jj = 2, jpjm1
212            DO ji = fs_2, fs_jpim1   ! vector opt.
213               avmu(ji,jj,jk) = avmu(ji,jj,jk) * ( un(ji,jj,jk-1) - un(ji,jj,jk) )   &
214                  &                            * ( ub(ji,jj,jk-1) - ub(ji,jj,jk) )   &
215                  &                            / (  fse3uw_n(ji,jj,jk)               &
216                  &                            *    fse3uw_b(ji,jj,jk) )
217               avmv(ji,jj,jk) = avmv(ji,jj,jk) * ( vn(ji,jj,jk-1) - vn(ji,jj,jk) )   &
218                  &                            * ( vb(ji,jj,jk-1) - vb(ji,jj,jk) )   &
219                  &                            / (  fse3vw_n(ji,jj,jk)               &
220                  &                            *    fse3vw_b(ji,jj,jk) )
221               eps(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT(en(ji,jj,jk)) / mxln(ji,jj,jk)
222            END DO
223         END DO
224      END DO
225      !
226      ! Lateral boundary conditions (avmu,avmv) (sign unchanged)
227      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )
228
229      ! Save tke at before time step
230      eb  (:,:,:) = en  (:,:,:)
231      mxlb(:,:,:) = mxln(:,:,:)
232
233      IF( nn_clos == 0 ) THEN    ! Mellor-Yamada
234         DO jk = 2, jpkm1
235            DO jj = 2, jpjm1 
236               DO ji = fs_2, fs_jpim1   ! vector opt.
237                  zup   = mxln(ji,jj,jk) * fsdepw(ji,jj,mbkt(ji,jj)+1)
238                  zdown = vkarmn * fsdepw(ji,jj,jk) * ( -fsdepw(ji,jj,jk) + fsdepw(ji,jj,mbkt(ji,jj)+1) )
239                  zcoef = ( zup / MAX( zdown, rsmall ) )
240                  zwall (ji,jj,jk) = ( 1._wp + re2 * zcoef*zcoef ) * tmask(ji,jj,jk)
241               END DO
242            END DO
243         END DO
244      ENDIF
245
246      !!---------------------------------!!
247      !!   Equation to prognostic k      !!
248      !!---------------------------------!!
249      !
250      ! Now Turbulent kinetic energy (output in en)
251      ! -------------------------------
252      ! Resolution of a tridiagonal linear system by a "methode de chasse"
253      ! computation from level 2 to jpkm1  (e(1) computed after and e(jpk)=0 ).
254      ! The surface boundary condition are set after
255      ! The bottom boundary condition are also set after. In standard e(bottom)=0.
256      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
257      ! Warning : after this step, en : right hand side of the matrix
258
259      DO jk = 2, jpkm1
260         DO jj = 2, jpjm1
261            DO ji = fs_2, fs_jpim1   ! vector opt.
262               !
263               ! shear prod. at w-point weightened by mask
264               shear(ji,jj,jk) =  ( avmu(ji-1,jj,jk) + avmu(ji,jj,jk) ) / MAX( 1.e0 , umask(ji-1,jj,jk) + umask(ji,jj,jk) )   &
265                  &             + ( avmv(ji,jj-1,jk) + avmv(ji,jj,jk) ) / MAX( 1.e0 , vmask(ji,jj-1,jk) + vmask(ji,jj,jk) )
266               !
267               ! stratif. destruction
268               buoy = - avt(ji,jj,jk) * rn2(ji,jj,jk)
269               !
270               ! shear prod. - stratif. destruction
271               diss = eps(ji,jj,jk)
272               !
273               dir = 0.5_wp + SIGN( 0.5_wp, shear(ji,jj,jk) + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
274               !
275               zesh2 = dir*(shear(ji,jj,jk)+buoy)+(1._wp-dir)*shear(ji,jj,jk)          ! production term
276               zdiss = dir*(diss/en(ji,jj,jk))   +(1._wp-dir)*(diss-buoy)/en(ji,jj,jk) ! dissipation term
277               !
278               ! Compute a wall function from 1. to rsc_psi*zwall/rsc_psi0
279               ! Note that as long that Dirichlet boundary conditions are NOT set at the first and last levels (GOTM style)
280               ! there is no need to set a boundary condition for zwall_psi at the top and bottom boundaries.
281               ! Otherwise, this should be rsc_psi/rsc_psi0
282               IF( ln_sigpsi ) THEN
283                  zsigpsi = MIN( 1._wp, zesh2 / eps(ji,jj,jk) )     ! 0. <= zsigpsi <= 1.
284                  zwall_psi(ji,jj,jk) = rsc_psi /   & 
285                     &     (  zsigpsi * rsc_psi + (1._wp-zsigpsi) * rsc_psi0 / MAX( zwall(ji,jj,jk), 1._wp )  )
286               ELSE
287                  zwall_psi(ji,jj,jk) = 1._wp
288               ENDIF
289               !
290               ! building the matrix
291               zcof = rfact_tke * tmask(ji,jj,jk)
292               !
293               ! lower diagonal
294               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
295                  &                      / ( fse3t(ji,jj,jk-1) * fse3w(ji,jj,jk  ) )
296               !
297               ! upper diagonal
298               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
299                  &                      / ( fse3t(ji,jj,jk  ) * fse3w(ji,jj,jk) )
300               !
301               ! diagonal
302               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
303                  &                       + rdt * zdiss * tmask(ji,jj,jk) 
304               !
305               ! right hand side in en
306               en(ji,jj,jk) = en(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
307            END DO
308         END DO
309      END DO
310      !
311      z_elem_b(:,:,jpk) = 1._wp
312      !
313      ! Set surface condition on zwall_psi (1 at the bottom)
314      zwall_psi(:,:,1) = zwall_psi(:,:,2)
315      zwall_psi(:,:,jpk) = 1.
316      !
317      ! Surface boundary condition on tke
318      ! ---------------------------------
319      !
320      SELECT CASE ( nn_bc_surf )
321      !
322      CASE ( 0 )             ! Dirichlet case
323      ! First level
324      en(:,:,1) = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1)**(2._wp/3._wp)
325      en(:,:,1) = MAX(en(:,:,1), rn_emin) 
326      z_elem_a(:,:,1) = en(:,:,1)
327      z_elem_c(:,:,1) = 0._wp
328      z_elem_b(:,:,1) = 1._wp
329      !
330      ! One level below
331      en(:,:,2) = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1 * ((zhsro(:,:)+fsdepw(:,:,2))/zhsro(:,:) )**(1.5_wp*ra_sf))**(2._wp/3._wp)
332      en(:,:,2) = MAX(en(:,:,2), rn_emin )
333      z_elem_a(:,:,2) = 0._wp 
334      z_elem_c(:,:,2) = 0._wp
335      z_elem_b(:,:,2) = 1._wp
336      !
337      !
338      CASE ( 1 )             ! Neumann boundary condition on d(e)/dz
339      !
340      ! Dirichlet conditions at k=1
341      en(:,:,1)       = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1)**(2._wp/3._wp)
342      en(:,:,1)       = MAX(en(:,:,1), rn_emin)     
343      z_elem_a(:,:,1) = en(:,:,1)
344      z_elem_c(:,:,1) = 0._wp
345      z_elem_b(:,:,1) = 1._wp
346      !
347      ! at k=2, set de/dz=Fw
348      z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
349      z_elem_a(:,:,2) = 0._wp
350      zkar(:,:)       = (rl_sf + (vkarmn-rl_sf)*(1.-exp(-rtrans*fsdept(:,:,1)/zhsro(:,:)) ))
351      zflxs(:,:)      = rsbc_tke2 * ustars2(:,:)**1.5_wp * zkar(:,:) * ((zhsro(:,:)+fsdept(:,:,1))/zhsro(:,:) )**(1.5_wp*ra_sf)
352
353      en(:,:,2) = en(:,:,2) + zflxs(:,:)/fse3w(:,:,2)
354      !
355      !
356      END SELECT
357
358      ! Bottom boundary condition on tke
359      ! --------------------------------
360      !
361      SELECT CASE ( nn_bc_bot )
362      !
363      CASE ( 0 )             ! Dirichlet
364         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = rn_lmin
365         !                      ! Balance between the production and the dissipation terms
366!CDIR NOVERRCHK
367         DO jj = 2, jpjm1
368!CDIR NOVERRCHK
369            DO ji = fs_2, fs_jpim1   ! vector opt.
370               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
371               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
372               !
373               ! Bottom level Dirichlet condition:
374               z_elem_a(ji,jj,ibot  ) = 0._wp
375               z_elem_c(ji,jj,ibot  ) = 0._wp
376               z_elem_b(ji,jj,ibot  ) = 1._wp
377               en(ji,jj,ibot  ) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
378               !
379               ! Just above last level, Dirichlet condition again
380               z_elem_a(ji,jj,ibotm1) = 0._wp
381               z_elem_c(ji,jj,ibotm1) = 0._wp
382               z_elem_b(ji,jj,ibotm1) = 1._wp
383               en(ji,jj,ibotm1) = MAX( rc02r * ustarb2(ji,jj), rn_emin ) 
384            END DO
385         END DO
386         !
387      CASE ( 1 )             ! Neumman boundary condition
388         !                     
389!CDIR NOVERRCHK
390         DO jj = 2, jpjm1
391!CDIR NOVERRCHK
392            DO ji = fs_2, fs_jpim1   ! vector opt.
393               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
394               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
395               !
396               ! Bottom level Dirichlet condition:
397               z_elem_a(ji,jj,ibot) = 0._wp
398               z_elem_c(ji,jj,ibot) = 0._wp
399               z_elem_b(ji,jj,ibot) = 1._wp
400               en(ji,jj,ibot) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
401               !
402               ! Just above last level: Neumann condition
403               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1)   ! Remove z_elem_c from z_elem_b
404               z_elem_c(ji,jj,ibotm1) = 0._wp
405            END DO
406         END DO
407         !
408      END SELECT
409
410      ! Matrix inversion (en prescribed at surface and the bottom)
411      ! ----------------------------------------------------------
412      !
413      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
414         DO jj = 2, jpjm1
415            DO ji = fs_2, fs_jpim1    ! vector opt.
416               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
417            END DO
418         END DO
419      END DO
420      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
421         DO jj = 2, jpjm1
422            DO ji = fs_2, fs_jpim1    ! vector opt.
423               z_elem_a(ji,jj,jk) = en(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
424            END DO
425         END DO
426      END DO
427      DO jk = jpk-1, 2, -1                         ! thrid recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
428         DO jj = 2, jpjm1
429            DO ji = fs_2, fs_jpim1    ! vector opt.
430               en(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * en(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
431            END DO
432         END DO
433      END DO
434      !                                            ! set the minimum value of tke
435      en(:,:,:) = MAX( en(:,:,:), rn_emin )
436
437      !!----------------------------------------!!
438      !!   Solve prognostic equation for psi    !!
439      !!----------------------------------------!!
440
441      ! Set psi to previous time step value
442      !
443      SELECT CASE ( nn_clos )
444      !
445      CASE( 0 )               ! k-kl  (Mellor-Yamada)
446         DO jk = 2, jpkm1
447            DO jj = 2, jpjm1
448               DO ji = fs_2, fs_jpim1   ! vector opt.
449                  psi(ji,jj,jk)  = eb(ji,jj,jk) * mxlb(ji,jj,jk)
450               END DO
451            END DO
452         END DO
453         !
454      CASE( 1 )               ! k-eps
455         DO jk = 2, jpkm1
456            DO jj = 2, jpjm1
457               DO ji = fs_2, fs_jpim1   ! vector opt.
458                  psi(ji,jj,jk)  = eps(ji,jj,jk)
459               END DO
460            END DO
461         END DO
462         !
463      CASE( 2 )               ! k-w
464         DO jk = 2, jpkm1
465            DO jj = 2, jpjm1
466               DO ji = fs_2, fs_jpim1   ! vector opt.
467                  psi(ji,jj,jk)  = SQRT( eb(ji,jj,jk) ) / ( rc0 * mxlb(ji,jj,jk) )
468               END DO
469            END DO
470         END DO
471         !
472      CASE( 3 )               ! generic
473         DO jk = 2, jpkm1
474            DO jj = 2, jpjm1
475               DO ji = fs_2, fs_jpim1   ! vector opt.
476                  psi(ji,jj,jk)  = rc02 * eb(ji,jj,jk) * mxlb(ji,jj,jk)**rnn 
477               END DO
478            END DO
479         END DO
480         !
481      END SELECT
482      !
483      ! Now gls (output in psi)
484      ! -------------------------------
485      ! Resolution of a tridiagonal linear system by a "methode de chasse"
486      ! computation from level 2 to jpkm1  (e(1) already computed and e(jpk)=0 ).
487      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
488      ! Warning : after this step, en : right hand side of the matrix
489
490      DO jk = 2, jpkm1
491         DO jj = 2, jpjm1
492            DO ji = fs_2, fs_jpim1   ! vector opt.
493               !
494               ! psi / k
495               zratio = psi(ji,jj,jk) / eb(ji,jj,jk) 
496               !
497               ! psi3+ : stable : B=-KhN²<0 => N²>0 if rn2>0 dir = 1 (stable) otherwise dir = 0 (unstable)
498               dir = 0.5_wp + SIGN( 0.5_wp, rn2(ji,jj,jk) )
499               !
500               rpsi3 = dir * rpsi3m + ( 1._wp - dir ) * rpsi3p
501               !
502               ! shear prod. - stratif. destruction
503               prod = rpsi1 * zratio * shear(ji,jj,jk)
504               !
505               ! stratif. destruction
506               buoy = rpsi3 * zratio * (- avt(ji,jj,jk) * rn2(ji,jj,jk) )
507               !
508               ! shear prod. - stratif. destruction
509               diss = rpsi2 * zratio * zwall(ji,jj,jk) * eps(ji,jj,jk)
510               !
511               dir = 0.5_wp + SIGN( 0.5_wp, prod + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
512               !
513               zesh2 = dir * ( prod + buoy )          + (1._wp - dir ) * prod                        ! production term
514               zdiss = dir * ( diss / psi(ji,jj,jk) ) + (1._wp - dir ) * (diss-buoy) / psi(ji,jj,jk) ! dissipation term
515               !                                                       
516               ! building the matrix
517               zcof = rfact_psi * zwall_psi(ji,jj,jk) * tmask(ji,jj,jk)
518               ! lower diagonal
519               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
520                  &                      / ( fse3t(ji,jj,jk-1) * fse3w(ji,jj,jk  ) )
521               ! upper diagonal
522               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
523                  &                      / ( fse3t(ji,jj,jk  ) * fse3w(ji,jj,jk) )
524               ! diagonal
525               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
526                  &                       + rdt * zdiss * tmask(ji,jj,jk)
527               !
528               ! right hand side in psi
529               psi(ji,jj,jk) = psi(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
530            END DO
531         END DO
532      END DO
533      !
534      z_elem_b(:,:,jpk) = 1._wp
535
536      ! Surface boundary condition on psi
537      ! ---------------------------------
538      !
539      SELECT CASE ( nn_bc_surf )
540      !
541      CASE ( 0 )             ! Dirichlet boundary conditions
542      !
543      ! Surface value
544      zdep(:,:)       = zhsro(:,:) * rl_sf ! Cosmetic
545      psi (:,:,1)     = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
546      z_elem_a(:,:,1) = psi(:,:,1)
547      z_elem_c(:,:,1) = 0._wp
548      z_elem_b(:,:,1) = 1._wp
549      !
550      ! One level below
551      zkar(:,:)       = (rl_sf + (vkarmn-rl_sf)*(1._wp-exp(-rtrans*fsdepw(:,:,2)/zhsro(:,:) )))
552      zdep(:,:)       = (zhsro(:,:) + fsdepw(:,:,2)) * zkar(:,:)
553      psi (:,:,2)     = rc0**rpp * en(:,:,2)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
554      z_elem_a(:,:,2) = 0._wp
555      z_elem_c(:,:,2) = 0._wp
556      z_elem_b(:,:,2) = 1._wp
557      !
558      !
559      CASE ( 1 )             ! Neumann boundary condition on d(psi)/dz
560      !
561      ! Surface value: Dirichlet
562      zdep(:,:)       = zhsro(:,:) * rl_sf
563      psi (:,:,1)     = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
564      z_elem_a(:,:,1) = psi(:,:,1)
565      z_elem_c(:,:,1) = 0._wp
566      z_elem_b(:,:,1) = 1._wp
567      !
568      ! Neumann condition at k=2
569      z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
570      z_elem_a(:,:,2) = 0._wp
571      !
572      ! Set psi vertical flux at the surface:
573      zkar(:,:) = rl_sf + (vkarmn-rl_sf)*(1._wp-exp(-rtrans*fsdept(:,:,1)/zhsro(:,:) )) ! Lengh scale slope
574      zdep(:,:) = ((zhsro(:,:) + fsdept(:,:,1)) / zhsro(:,:))**(rmm*ra_sf)
575      zflxs(:,:) = (rnn + rsbc_tke1 * (rnn + rmm*ra_sf) * zdep(:,:))*(1._wp + rsbc_tke1*zdep(:,:))**(2._wp*rmm/3._wp-1_wp)
576      zdep(:,:) =  rsbc_psi1 * (zwall_psi(:,:,1)*avm(:,:,1)+zwall_psi(:,:,2)*avm(:,:,2)) * &
577             & ustars2(:,:)**rmm * zkar(:,:)**rnn * (zhsro(:,:) + fsdept(:,:,1))**(rnn-1.)
578      zflxs(:,:) = zdep(:,:) * zflxs(:,:)
579      psi(:,:,2) = psi(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
580
581      !   
582      !
583      END SELECT
584
585      ! Bottom boundary condition on psi
586      ! --------------------------------
587      !
588      SELECT CASE ( nn_bc_bot )
589      !
590      !
591      CASE ( 0 )             ! Dirichlet
592         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = vkarmn * rn_bfrz0
593         !                      ! Balance between the production and the dissipation terms
594!CDIR NOVERRCHK
595         DO jj = 2, jpjm1
596!CDIR NOVERRCHK
597            DO ji = fs_2, fs_jpim1   ! vector opt.
598               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
599               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
600               zdep(ji,jj) = vkarmn * rn_bfrz0
601               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
602               z_elem_a(ji,jj,ibot) = 0._wp
603               z_elem_c(ji,jj,ibot) = 0._wp
604               z_elem_b(ji,jj,ibot) = 1._wp
605               !
606               ! Just above last level, Dirichlet condition again (GOTM like)
607               zdep(ji,jj) = vkarmn * ( rn_bfrz0 + fse3t(ji,jj,ibotm1) )
608               psi (ji,jj,ibotm1) = rc0**rpp * en(ji,jj,ibot  )**rmm * zdep(ji,jj)**rnn
609               z_elem_a(ji,jj,ibotm1) = 0._wp
610               z_elem_c(ji,jj,ibotm1) = 0._wp
611               z_elem_b(ji,jj,ibotm1) = 1._wp
612            END DO
613         END DO
614         !
615      CASE ( 1 )             ! Neumman boundary condition
616         !                     
617!CDIR NOVERRCHK
618         DO jj = 2, jpjm1
619!CDIR NOVERRCHK
620            DO ji = fs_2, fs_jpim1   ! vector opt.
621               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
622               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
623               !
624               ! Bottom level Dirichlet condition:
625               zdep(ji,jj) = vkarmn * rn_bfrz0
626               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
627               !
628               z_elem_a(ji,jj,ibot) = 0._wp
629               z_elem_c(ji,jj,ibot) = 0._wp
630               z_elem_b(ji,jj,ibot) = 1._wp
631               !
632               ! Just above last level: Neumann condition with flux injection
633               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1) ! Remove z_elem_c from z_elem_b
634               z_elem_c(ji,jj,ibotm1) = 0.
635               !
636               ! Set psi vertical flux at the bottom:
637               zdep(ji,jj) = rn_bfrz0 + 0.5_wp*fse3t(ji,jj,ibotm1)
638               zflxb = rsbc_psi2 * ( avm(ji,jj,ibot) + avm(ji,jj,ibotm1) )   &
639                  &  * (0.5_wp*(en(ji,jj,ibot)+en(ji,jj,ibotm1)))**rmm * zdep(ji,jj)**(rnn-1._wp)
640               psi(ji,jj,ibotm1) = psi(ji,jj,ibotm1) + zflxb / fse3w(ji,jj,ibotm1)
641            END DO
642         END DO
643         !
644      END SELECT
645
646      ! Matrix inversion
647      ! ----------------
648      !
649      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
650         DO jj = 2, jpjm1
651            DO ji = fs_2, fs_jpim1    ! vector opt.
652               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
653            END DO
654         END DO
655      END DO
656      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
657         DO jj = 2, jpjm1
658            DO ji = fs_2, fs_jpim1    ! vector opt.
659               z_elem_a(ji,jj,jk) = psi(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
660            END DO
661         END DO
662      END DO
663      DO jk = jpk-1, 2, -1                         ! Third recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
664         DO jj = 2, jpjm1
665            DO ji = fs_2, fs_jpim1    ! vector opt.
666               psi(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * psi(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
667            END DO
668         END DO
669      END DO
670
671      ! Set dissipation
672      !----------------
673
674      SELECT CASE ( nn_clos )
675      !
676      CASE( 0 )               ! k-kl  (Mellor-Yamada)
677         DO jk = 1, jpkm1
678            DO jj = 2, jpjm1
679               DO ji = fs_2, fs_jpim1   ! vector opt.
680                  eps(ji,jj,jk) = rc03 * en(ji,jj,jk) * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / MAX( psi(ji,jj,jk), rn_epsmin)
681               END DO
682            END DO
683         END DO
684         !
685      CASE( 1 )               ! k-eps
686         DO jk = 1, jpkm1
687            DO jj = 2, jpjm1
688               DO ji = fs_2, fs_jpim1   ! vector opt.
689                  eps(ji,jj,jk) = psi(ji,jj,jk)
690               END DO
691            END DO
692         END DO
693         !
694      CASE( 2 )               ! k-w
695         DO jk = 1, jpkm1
696            DO jj = 2, jpjm1
697               DO ji = fs_2, fs_jpim1   ! vector opt.
698                  eps(ji,jj,jk) = rc04 * en(ji,jj,jk) * psi(ji,jj,jk) 
699               END DO
700            END DO
701         END DO
702         !
703      CASE( 3 )               ! generic
704         zcoef = rc0**( 3._wp  + rpp/rnn )
705         zex1  =      ( 1.5_wp + rmm/rnn )
706         zex2  = -1._wp / rnn
707         DO jk = 1, jpkm1
708            DO jj = 2, jpjm1
709               DO ji = fs_2, fs_jpim1   ! vector opt.
710                  eps(ji,jj,jk) = zcoef * en(ji,jj,jk)**zex1 * psi(ji,jj,jk)**zex2
711               END DO
712            END DO
713         END DO
714         !
715      END SELECT
716
717      ! Limit dissipation rate under stable stratification
718      ! --------------------------------------------------
719      DO jk = 1, jpkm1 ! Note that this set boundary conditions on mxln at the same time
720         DO jj = 2, jpjm1
721            DO ji = fs_2, fs_jpim1    ! vector opt.
722               ! limitation
723               eps(ji,jj,jk)  = MAX( eps(ji,jj,jk), rn_epsmin )
724               mxln(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / eps(ji,jj,jk)
725               ! Galperin criterium (NOTE : Not required if the proper value of C3 in stable cases is calculated)
726               zrn2 = MAX( rn2(ji,jj,jk), rsmall )
727               IF (ln_length_lim) mxln(ji,jj,jk) = MIN(  rn_clim_galp * SQRT( 2._wp * en(ji,jj,jk) / zrn2 ), mxln(ji,jj,jk) )
728            END DO
729         END DO
730      END DO 
731
732!#if defined key_c1d
733!      CALL iom_put("kinetic", en(:,:,:) )
734!      CALL iom_put("dissip", eps(:,:,:) )
735!      CALL iom_put("Brunt", rn2(:,:,:) )
736!      CALL iom_put("long_mel", mxln(:,:,:))
737!#endif   
738
739      !
740      ! Stability function and vertical viscosity and diffusivity
741      ! ---------------------------------------------------------
742      !
743      SELECT CASE ( nn_stab_func )
744      !
745      CASE ( 0 , 1 )             ! Galperin or Kantha-Clayson stability functions
746         DO jk = 2, jpkm1
747            DO jj = 2, jpjm1
748               DO ji = fs_2, fs_jpim1   ! vector opt.
749                  ! zcof =  l²/q²
750                  zcof = mxlb(ji,jj,jk) * mxlb(ji,jj,jk) / ( 2._wp*eb(ji,jj,jk) )
751                  ! Gh = -N²l²/q²
752                  gh = - rn2(ji,jj,jk) * zcof
753                  gh = MIN( gh, rgh0   )
754                  gh = MAX( gh, rghmin )
755                  ! Stability functions from Kantha and Clayson (if C2=C3=0 => Galperin)
756                  sh = ra2*( 1._wp-6._wp*ra1/rb1 ) / ( 1.-3.*ra2*gh*(6.*ra1+rb2*( 1._wp-rc3 ) ) )
757                  sm = ( rb1**(-1._wp/3._wp) + ( 18._wp*ra1*ra1 + 9._wp*ra1*ra2*(1._wp-rc2) )*sh*gh ) / (1._wp-9._wp*ra1*ra2*gh)
758                  !
759                  ! Store stability function in avmu and avmv
760                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
761                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
762               END DO
763            END DO
764         END DO
765         !
766      CASE ( 2, 3 )               ! Canuto stability functions
767         DO jk = 2, jpkm1
768            DO jj = 2, jpjm1
769               DO ji = fs_2, fs_jpim1   ! vector opt.
770                  ! zcof =  l²/q²
771                  zcof = mxlb(ji,jj,jk)*mxlb(ji,jj,jk) / ( 2._wp * eb(ji,jj,jk) )
772                  ! Gh = -N²l²/q²
773                  gh = - rn2(ji,jj,jk) * zcof
774                  gh = MIN( gh, rgh0   )
775                  gh = MAX( gh, rghmin )
776                  gh = gh * rf6
777                  ! Gm =  M²l²/q² Shear number
778                  shr = shear(ji,jj,jk) / MAX( avm(ji,jj,jk), rsmall )
779                  gm = MAX( shr * zcof , 1.e-10 )
780                  gm = gm * rf6
781                  gm = MIN ( (rd0 - rd1*gh + rd3*gh*gh) / (rd2-rd4*gh) , gm )
782                  ! Stability functions from Canuto
783                  rcff = rd0 - rd1*gh +rd2*gm + rd3*gh*gh - rd4*gh*gm + rd5*gm*gm
784                  sm = (rs0 - rs1*gh + rs2*gm) / rcff
785                  sh = (rs4 - rs5*gh + rs6*gm) / rcff
786                  !
787                  ! Store stability function in avmu and avmv
788                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
789                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
790               END DO
791            END DO
792         END DO
793         !
794      END SELECT
795
796      ! Boundary conditions on stability functions for momentum (Neumann):
797      ! Lines below are useless if GOTM style Dirichlet conditions are used
798
799      avmv(:,:,1) = avmv(:,:,2)
800
801      DO jj = 2, jpjm1
802         DO ji = fs_2, fs_jpim1   ! vector opt.
803            avmv(ji,jj,mbkt(ji,jj)+1) = avmv(ji,jj,mbkt(ji,jj))
804         END DO
805      END DO
806
807      ! Compute diffusivities/viscosities
808      ! The computation below could be restrained to jk=2 to jpkm1 if GOTM style Dirichlet conditions are used
809      DO jk = 1, jpk
810         DO jj = 2, jpjm1
811            DO ji = fs_2, fs_jpim1   ! vector opt.
812               zsqen         = SQRT( 2._wp * en(ji,jj,jk) ) * mxln(ji,jj,jk)
813               zav           = zsqen * avmu(ji,jj,jk)
814               avt(ji,jj,jk) = MAX( zav, avtb(jk) )*tmask(ji,jj,jk) ! apply mask for zdfmxl routine
815               zav           = zsqen * avmv(ji,jj,jk)
816               avm(ji,jj,jk) = MAX( zav, avmb(jk) ) ! Note that avm is not masked at the surface and the bottom
817            END DO
818         END DO
819      END DO
820      !
821      ! Lateral boundary conditions (sign unchanged)
822      avt(:,:,1)  = 0._wp
823      CALL lbc_lnk( avm, 'W', 1. )   ;   CALL lbc_lnk( avt, 'W', 1. )
824
825      DO jk = 2, jpkm1            !* vertical eddy viscosity at u- and v-points
826         DO jj = 2, jpjm1
827            DO ji = fs_2, fs_jpim1   ! vector opt.
828               avmu(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji+1,jj  ,jk) ) * umask(ji,jj,jk)
829               avmv(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji  ,jj+1,jk) ) * vmask(ji,jj,jk)
830            END DO
831         END DO
832      END DO
833      avmu(:,:,1) = 0._wp             ;   avmv(:,:,1) = 0._wp                 ! set surface to zero
834      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )       ! Lateral boundary conditions
835
836      IF(ln_ctl) THEN
837         CALL prt_ctl( tab3d_1=en  , clinfo1=' gls  - e: ', tab3d_2=avt, clinfo2=' t: ', ovlap=1, kdim=jpk)
838         CALL prt_ctl( tab3d_1=avmu, clinfo1=' gls  - u: ', mask1=umask,                   &
839            &          tab3d_2=avmv, clinfo2=       ' v: ', mask2=vmask, ovlap=1, kdim=jpk )
840      ENDIF
841      !
842      avt_k (:,:,:) = avt (:,:,:)
843      avm_k (:,:,:) = avm (:,:,:)
844      avmu_k(:,:,:) = avmu(:,:,:)
845      avmv_k(:,:,:) = avmv(:,:,:)
846      !
847      CALL wrk_dealloc( jpi,jpj, zdep, zkar, zflxs, zhsro )
848      CALL wrk_dealloc( jpi,jpj,jpk, eb, mxlb, shear, eps, zwall_psi, z_elem_a, z_elem_b, z_elem_c, psi )
849      !
850      IF( nn_timing == 1 )  CALL timing_stop('zdf_gls')
851      !
852      !
853   END SUBROUTINE zdf_gls
854
855
856   SUBROUTINE zdf_gls_init
857      !!----------------------------------------------------------------------
858      !!                  ***  ROUTINE zdf_gls_init  ***
859      !!                     
860      !! ** Purpose :   Initialization of the vertical eddy diffivity and
861      !!      viscosity when using a gls turbulent closure scheme
862      !!
863      !! ** Method  :   Read the namzdf_gls namelist and check the parameters
864      !!      called at the first timestep (nit000)
865      !!
866      !! ** input   :   Namlist namzdf_gls
867      !!
868      !! ** Action  :   Increase by 1 the nstop flag is setting problem encounter
869      !!
870      !!----------------------------------------------------------------------
871      USE dynzdf_exp
872      USE trazdf_exp
873      !
874      INTEGER ::   jk    ! dummy loop indices
875      INTEGER ::   ios   ! Local integer output status for namelist read
876      REAL(wp)::   zcr   ! local scalar
877      !!
878      NAMELIST/namzdf_gls/rn_emin, rn_epsmin, ln_length_lim, &
879         &            rn_clim_galp, ln_sigpsi, rn_hsro,      &
880         &            rn_crban, rn_charn, rn_frac_hs,        &
881         &            nn_bc_surf, nn_bc_bot, nn_z0_met,      &
882         &            nn_stab_func, nn_clos
883      !!----------------------------------------------------------
884      !
885      IF( nn_timing == 1 )  CALL timing_start('zdf_gls_init')
886      !
887      REWIND( numnam_ref )              ! Namelist namzdf_gls in reference namelist : Vertical eddy diffivity and viscosity using gls turbulent closure scheme
888      READ  ( numnam_ref, namzdf_gls, IOSTAT = ios, ERR = 901)
889901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_gls in reference namelist', lwp )
890
891      REWIND( numnam_cfg )              ! Namelist namzdf_gls in configuration namelist : Vertical eddy diffivity and viscosity using gls turbulent closure scheme
892      READ  ( numnam_cfg, namzdf_gls, IOSTAT = ios, ERR = 902 )
893902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_gls in configuration namelist', lwp )
894      IF(lwm) WRITE ( numond, namzdf_gls )
895
896      IF(lwp) THEN                     !* Control print
897         WRITE(numout,*)
898         WRITE(numout,*) 'zdf_gls_init : gls turbulent closure scheme'
899         WRITE(numout,*) '~~~~~~~~~~~~'
900         WRITE(numout,*) '   Namelist namzdf_gls : set gls mixing parameters'
901         WRITE(numout,*) '      minimum value of en                           rn_emin        = ', rn_emin
902         WRITE(numout,*) '      minimum value of eps                          rn_epsmin      = ', rn_epsmin
903         WRITE(numout,*) '      Limit dissipation rate under stable stratif.  ln_length_lim  = ', ln_length_lim
904         WRITE(numout,*) '      Galperin limit (Standard: 0.53, Holt: 0.26)   rn_clim_galp   = ', rn_clim_galp
905         WRITE(numout,*) '      TKE Surface boundary condition                nn_bc_surf     = ', nn_bc_surf
906         WRITE(numout,*) '      TKE Bottom boundary condition                 nn_bc_bot      = ', nn_bc_bot
907         WRITE(numout,*) '      Modify psi Schmidt number (wb case)           ln_sigpsi      = ', ln_sigpsi
908         WRITE(numout,*) '      Craig and Banner coefficient                  rn_crban       = ', rn_crban
909         WRITE(numout,*) '      Charnock coefficient                          rn_charn       = ', rn_charn
910         WRITE(numout,*) '      Surface roughness formula                     nn_z0_met      = ', nn_z0_met
911         WRITE(numout,*) '      Wave height frac. (used if nn_z0_met=2)       rn_frac_hs     = ', rn_frac_hs
912         WRITE(numout,*) '      Stability functions                           nn_stab_func   = ', nn_stab_func
913         WRITE(numout,*) '      Type of closure                               nn_clos        = ', nn_clos
914         WRITE(numout,*) '      Surface roughness (m)                         rn_hsro        = ', rn_hsro
915         WRITE(numout,*) '      Bottom roughness (m) (nambfr namelist)        rn_bfrz0       = ', rn_bfrz0
916      ENDIF
917
918      !                                !* allocate gls arrays
919      IF( zdf_gls_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_gls_init : unable to allocate arrays' )
920
921      !                                !* Check of some namelist values
922      IF( nn_bc_surf < 0 .OR. nn_bc_surf > 1 ) CALL ctl_stop( 'bad flag: nn_bc_surf is 0 or 1' )
923      IF( nn_bc_surf < 0 .OR. nn_bc_surf > 1 ) CALL ctl_stop( 'bad flag: nn_bc_surf is 0 or 1' )
924      IF( nn_z0_met < 0 .OR. nn_z0_met > 2 ) CALL ctl_stop( 'bad flag: nn_z0_met is 0, 1 or 2' )
925      IF( nn_stab_func  < 0 .OR. nn_stab_func  > 3 ) CALL ctl_stop( 'bad flag: nn_stab_func is 0, 1, 2 and 3' )
926      IF( nn_clos       < 0 .OR. nn_clos       > 3 ) CALL ctl_stop( 'bad flag: nn_clos is 0, 1, 2 or 3' )
927
928      SELECT CASE ( nn_clos )          !* set the parameters for the chosen closure
929      !
930      CASE( 0 )                              ! k-kl  (Mellor-Yamada)
931         !
932         IF(lwp) WRITE(numout,*) 'The choosen closure is k-kl closed to the classical Mellor-Yamada'
933         rpp     = 0._wp
934         rmm     = 1._wp
935         rnn     = 1._wp
936         rsc_tke = 1.96_wp
937         rsc_psi = 1.96_wp
938         rpsi1   = 0.9_wp
939         rpsi3p  = 1._wp
940         rpsi2   = 0.5_wp
941         !
942         SELECT CASE ( nn_stab_func )
943         CASE( 0, 1 )   ;   rpsi3m = 2.53_wp       ! G88 or KC stability functions
944         CASE( 2 )      ;   rpsi3m = 2.62_wp       ! Canuto A stability functions
945         CASE( 3 )      ;   rpsi3m = 2.38          ! Canuto B stability functions (caution : constant not identified)
946         END SELECT
947         !
948      CASE( 1 )                              ! k-eps
949         !
950         IF(lwp) WRITE(numout,*) 'The choosen closure is k-eps'
951         rpp     =  3._wp
952         rmm     =  1.5_wp
953         rnn     = -1._wp
954         rsc_tke =  1._wp
955         rsc_psi =  1.2_wp  ! Schmidt number for psi
956         rpsi1   =  1.44_wp
957         rpsi3p  =  1._wp
958         rpsi2   =  1.92_wp
959         !
960         SELECT CASE ( nn_stab_func )
961         CASE( 0, 1 )   ;   rpsi3m = -0.52_wp      ! G88 or KC stability functions
962         CASE( 2 )      ;   rpsi3m = -0.629_wp     ! Canuto A stability functions
963         CASE( 3 )      ;   rpsi3m = -0.566        ! Canuto B stability functions
964         END SELECT
965         !
966      CASE( 2 )                              ! k-omega
967         !
968         IF(lwp) WRITE(numout,*) 'The choosen closure is k-omega'
969         rpp     = -1._wp
970         rmm     =  0.5_wp
971         rnn     = -1._wp
972         rsc_tke =  2._wp
973         rsc_psi =  2._wp
974         rpsi1   =  0.555_wp
975         rpsi3p  =  1._wp
976         rpsi2   =  0.833_wp
977         !
978         SELECT CASE ( nn_stab_func )
979         CASE( 0, 1 )   ;   rpsi3m = -0.58_wp       ! G88 or KC stability functions
980         CASE( 2 )      ;   rpsi3m = -0.64_wp       ! Canuto A stability functions
981         CASE( 3 )      ;   rpsi3m = -0.64_wp       ! Canuto B stability functions caution : constant not identified)
982         END SELECT
983         !
984      CASE( 3 )                              ! generic
985         !
986         IF(lwp) WRITE(numout,*) 'The choosen closure is generic'
987         rpp     = 2._wp
988         rmm     = 1._wp
989         rnn     = -0.67_wp
990         rsc_tke = 0.8_wp
991         rsc_psi = 1.07_wp
992         rpsi1   = 1._wp
993         rpsi3p  = 1._wp
994         rpsi2   = 1.22_wp
995         !
996         SELECT CASE ( nn_stab_func )
997         CASE( 0, 1 )   ;   rpsi3m = 0.1_wp         ! G88 or KC stability functions
998         CASE( 2 )      ;   rpsi3m = 0.05_wp        ! Canuto A stability functions
999         CASE( 3 )      ;   rpsi3m = 0.05_wp        ! Canuto B stability functions caution : constant not identified)
1000         END SELECT
1001         !
1002      END SELECT
1003
1004      !
1005      SELECT CASE ( nn_stab_func )     !* set the parameters of the stability functions
1006      !
1007      CASE ( 0 )                             ! Galperin stability functions
1008         !
1009         IF(lwp) WRITE(numout,*) 'Stability functions from Galperin'
1010         rc2     =  0._wp
1011         rc3     =  0._wp
1012         rc_diff =  1._wp
1013         rc0     =  0.5544_wp
1014         rcm_sf  =  0.9884_wp
1015         rghmin  = -0.28_wp
1016         rgh0    =  0.0233_wp
1017         rghcri  =  0.02_wp
1018         !
1019      CASE ( 1 )                             ! Kantha-Clayson stability functions
1020         !
1021         IF(lwp) WRITE(numout,*) 'Stability functions from Kantha-Clayson'
1022         rc2     =  0.7_wp
1023         rc3     =  0.2_wp
1024         rc_diff =  1._wp
1025         rc0     =  0.5544_wp
1026         rcm_sf  =  0.9884_wp
1027         rghmin  = -0.28_wp
1028         rgh0    =  0.0233_wp
1029         rghcri  =  0.02_wp
1030         !
1031      CASE ( 2 )                             ! Canuto A stability functions
1032         !
1033         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto A'
1034         rs0 = 1.5_wp * rl1 * rl5*rl5
1035         rs1 = -rl4*(rl6+rl7) + 2._wp*rl4*rl5*(rl1-(1._wp/3._wp)*rl2-rl3) + 1.5_wp*rl1*rl5*rl8
1036         rs2 = -(3._wp/8._wp) * rl1*(rl6*rl6-rl7*rl7)
1037         rs4 = 2._wp * rl5
1038         rs5 = 2._wp * rl4
1039         rs6 = (2._wp/3._wp) * rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.5_wp * rl5*rl1 * (3._wp*rl3-rl2)   &
1040            &                                                    + 0.75_wp * rl1 * ( rl6 - rl7 )
1041         rd0 = 3._wp * rl5*rl5
1042         rd1 = rl5 * ( 7._wp*rl4 + 3._wp*rl8 )
1043         rd2 = rl5*rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.75_wp*(rl6*rl6 - rl7*rl7 )
1044         rd3 = rl4 * ( 4._wp*rl4 + 3._wp*rl8)
1045         rd4 = rl4 * ( rl2 * rl6 - 3._wp*rl3*rl7 - rl5*(rl2*rl2 - rl3*rl3 ) ) + rl5*rl8 * ( 3._wp*rl3*rl3 - rl2*rl2 )
1046         rd5 = 0.25_wp * ( rl2*rl2 - 3._wp *rl3*rl3 ) * ( rl6*rl6 - rl7*rl7 )
1047         rc0 = 0.5268_wp
1048         rf6 = 8._wp / (rc0**6._wp)
1049         rc_diff = SQRT(2._wp) / (rc0**3._wp)
1050         rcm_sf  =  0.7310_wp
1051         rghmin  = -0.28_wp
1052         rgh0    =  0.0329_wp
1053         rghcri  =  0.03_wp
1054         !
1055      CASE ( 3 )                             ! Canuto B stability functions
1056         !
1057         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto B'
1058         rs0 = 1.5_wp * rm1 * rm5*rm5
1059         rs1 = -rm4 * (rm6+rm7) + 2._wp * rm4*rm5*(rm1-(1._wp/3._wp)*rm2-rm3) + 1.5_wp * rm1*rm5*rm8
1060         rs2 = -(3._wp/8._wp) * rm1 * (rm6*rm6-rm7*rm7 )
1061         rs4 = 2._wp * rm5
1062         rs5 = 2._wp * rm4
1063         rs6 = (2._wp/3._wp) * rm5 * (3._wp*rm3*rm3-rm2*rm2) - 0.5_wp * rm5*rm1*(3._wp*rm3-rm2) + 0.75_wp * rm1*(rm6-rm7)
1064         rd0 = 3._wp * rm5*rm5
1065         rd1 = rm5 * (7._wp*rm4 + 3._wp*rm8)
1066         rd2 = rm5*rm5 * (3._wp*rm3*rm3 - rm2*rm2) - 0.75_wp * (rm6*rm6 - rm7*rm7)
1067         rd3 = rm4 * ( 4._wp*rm4 + 3._wp*rm8 )
1068         rd4 = rm4 * ( rm2*rm6 -3._wp*rm3*rm7 - rm5*(rm2*rm2 - rm3*rm3) ) + rm5 * rm8 * ( 3._wp*rm3*rm3 - rm2*rm2 )
1069         rd5 = 0.25_wp * ( rm2*rm2 - 3._wp*rm3*rm3 ) * ( rm6*rm6 - rm7*rm7 )
1070         rc0 = 0.5268_wp            !!       rc0 = 0.5540_wp (Warner ...) to verify !
1071         rf6 = 8._wp / ( rc0**6._wp )
1072         rc_diff = SQRT(2._wp)/(rc0**3.)
1073         rcm_sf  =  0.7470_wp
1074         rghmin  = -0.28_wp
1075         rgh0    =  0.0444_wp
1076         rghcri  =  0.0414_wp
1077         !
1078      END SELECT
1079   
1080      !                                !* Set Schmidt number for psi diffusion in the wave breaking case
1081      !                                     ! See Eq. (13) of Carniel et al, OM, 30, 225-239, 2009
1082      !                                     !  or Eq. (17) of Burchard, JPO, 31, 3133-3145, 2001
1083      IF( ln_sigpsi ) THEN
1084         ra_sf = -1.5 ! Set kinetic energy slope, then deduce rsc_psi and rl_sf
1085         ! Verification: retrieve Burchard (2001) results by uncomenting the line below:
1086         ! Note that the results depend on the value of rn_cm_sf which is constant (=rc0) in his work
1087         ! ra_sf = -SQRT(2./3.*rc0**3./rn_cm_sf*rn_sc_tke)/vkarmn
1088         rsc_psi0 = rsc_tke/(24.*rpsi2)*(-1.+(4.*rnn + ra_sf*(1.+4.*rmm))**2./(ra_sf**2.))
1089      ELSE
1090         rsc_psi0 = rsc_psi
1091      ENDIF
1092 
1093      !                                !* Shear free turbulence parameters
1094      !
1095      ra_sf  = -4._wp*rnn*SQRT(rsc_tke) / ( (1._wp+4._wp*rmm)*SQRT(rsc_tke) &
1096               &                              - SQRT(rsc_tke + 24._wp*rsc_psi0*rpsi2 ) )
1097
1098      IF ( rn_crban==0._wp ) THEN
1099         rl_sf = vkarmn
1100      ELSE
1101         rl_sf = rc0 * SQRT(rc0/rcm_sf) * SQRT( ( (1._wp + 4._wp*rmm + 8._wp*rmm**2_wp)*rsc_tke          &
1102                 &                                       + 12._wp * rsc_psi0*rpsi2 - (1._wp + 4._wp*rmm) &
1103                 &                                                *SQRT(rsc_tke*(rsc_tke                 &
1104                 &                                                   + 24._wp*rsc_psi0*rpsi2)) )         &
1105                 &                                         /(12._wp*rnn**2.)                             &
1106                 &                                       )
1107      ENDIF
1108
1109      !
1110      IF(lwp) THEN                     !* Control print
1111         WRITE(numout,*)
1112         WRITE(numout,*) 'Limit values'
1113         WRITE(numout,*) '~~~~~~~~~~~~'
1114         WRITE(numout,*) 'Parameter  m = ',rmm
1115         WRITE(numout,*) 'Parameter  n = ',rnn
1116         WRITE(numout,*) 'Parameter  p = ',rpp
1117         WRITE(numout,*) 'rpsi1   = ',rpsi1
1118         WRITE(numout,*) 'rpsi2   = ',rpsi2
1119         WRITE(numout,*) 'rpsi3m  = ',rpsi3m
1120         WRITE(numout,*) 'rpsi3p  = ',rpsi3p
1121         WRITE(numout,*) 'rsc_tke = ',rsc_tke
1122         WRITE(numout,*) 'rsc_psi = ',rsc_psi
1123         WRITE(numout,*) 'rsc_psi0 = ',rsc_psi0
1124         WRITE(numout,*) 'rc0     = ',rc0
1125         WRITE(numout,*)
1126         WRITE(numout,*) 'Shear free turbulence parameters:'
1127         WRITE(numout,*) 'rcm_sf  = ',rcm_sf
1128         WRITE(numout,*) 'ra_sf   = ',ra_sf
1129         WRITE(numout,*) 'rl_sf   = ',rl_sf
1130         WRITE(numout,*)
1131      ENDIF
1132
1133      !                                !* Constants initialization
1134      rc02  = rc0  * rc0   ;   rc02r = 1. / rc02
1135      rc03  = rc02 * rc0
1136      rc04  = rc03 * rc0
1137      rsbc_tke1 = -3._wp/2._wp*rn_crban*ra_sf*rl_sf                      ! Dirichlet + Wave breaking
1138      rsbc_tke2 = rdt * rn_crban / rl_sf                                 ! Neumann + Wave breaking
1139      zcr = MAX(rsmall, rsbc_tke1**(1./(-ra_sf*3._wp/2._wp))-1._wp )
1140      rtrans = 0.2_wp / zcr                                              ! Ad. inverse transition length between log and wave layer
1141      rsbc_zs1  = rn_charn/grav                                          ! Charnock formula for surface roughness
1142      rsbc_zs2  = rn_frac_hs / 0.85_wp / grav * 665._wp                  ! Rascle formula for surface roughness
1143      rsbc_psi1 = -0.5_wp * rdt * rc0**(rpp-2._wp*rmm) / rsc_psi
1144      rsbc_psi2 = -0.5_wp * rdt * rc0**rpp * rnn * vkarmn**rnn / rsc_psi ! Neumann + NO Wave breaking
1145
1146      rfact_tke = -0.5_wp / rsc_tke * rdt                                ! Cst used for the Diffusion term of tke
1147      rfact_psi = -0.5_wp / rsc_psi * rdt                                ! Cst used for the Diffusion term of tke
1148
1149      !                                !* Wall proximity function
1150      zwall (:,:,:) = 1._wp * tmask(:,:,:)
1151
1152      !                                !* set vertical eddy coef. to the background value
1153      DO jk = 1, jpk
1154         avt (:,:,jk) = avtb(jk) * tmask(:,:,jk)
1155         avm (:,:,jk) = avmb(jk) * tmask(:,:,jk)
1156         avmu(:,:,jk) = avmb(jk) * umask(:,:,jk)
1157         avmv(:,:,jk) = avmb(jk) * vmask(:,:,jk)
1158      END DO
1159      !                             
1160      CALL gls_rst( nit000, 'READ' )   !* read or initialize all required files
1161      !
1162      IF( nn_timing == 1 )  CALL timing_stop('zdf_gls_init')
1163      !
1164   END SUBROUTINE zdf_gls_init
1165
1166
1167   SUBROUTINE gls_rst( kt, cdrw )
1168      !!---------------------------------------------------------------------
1169      !!                   ***  ROUTINE ts_rst  ***
1170      !!                     
1171      !! ** Purpose :   Read or write TKE file (en) in restart file
1172      !!
1173      !! ** Method  :   use of IOM library
1174      !!                if the restart does not contain TKE, en is either
1175      !!                set to rn_emin or recomputed (nn_igls/=0)
1176      !!----------------------------------------------------------------------
1177      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1178      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1179      !
1180      INTEGER ::   jit, jk   ! dummy loop indices
1181      INTEGER ::   id1, id2, id3, id4, id5, id6
1182      INTEGER ::   ji, jj, ikbu, ikbv
1183      REAL(wp)::   cbx, cby
1184      !!----------------------------------------------------------------------
1185      !
1186      IF( TRIM(cdrw) == 'READ' ) THEN        ! Read/initialise
1187         !                                   ! ---------------
1188         IF( ln_rstart ) THEN                   !* Read the restart file
1189            id1 = iom_varid( numror, 'en'   , ldstop = .FALSE. )
1190            id2 = iom_varid( numror, 'avt'  , ldstop = .FALSE. )
1191            id3 = iom_varid( numror, 'avm'  , ldstop = .FALSE. )
1192            id4 = iom_varid( numror, 'avmu' , ldstop = .FALSE. )
1193            id5 = iom_varid( numror, 'avmv' , ldstop = .FALSE. )
1194            id6 = iom_varid( numror, 'mxln' , ldstop = .FALSE. )
1195            !
1196            IF( MIN( id1, id2, id3, id4, id5, id6 ) > 0 ) THEN        ! all required arrays exist
1197               CALL iom_get( numror, jpdom_autoglo, 'en'    , en     )
1198               CALL iom_get( numror, jpdom_autoglo, 'avt'   , avt    )
1199               CALL iom_get( numror, jpdom_autoglo, 'avm'   , avm    )
1200               CALL iom_get( numror, jpdom_autoglo, 'avmu'  , avmu   )
1201               CALL iom_get( numror, jpdom_autoglo, 'avmv'  , avmv   )
1202               CALL iom_get( numror, jpdom_autoglo, 'mxln'  , mxln   )
1203            ELSE                       
1204               IF(lwp) WRITE(numout,*) ' ===>>>> : previous run without gls scheme, en and mxln computed by iterative loop'
1205               en  (:,:,:) = rn_emin
1206               mxln(:,:,:) = 0.05       
1207               DO jit = nit000 + 1, nit000 + 10   ;   CALL zdf_gls( jit )   ;   END DO
1208            ENDIF
1209         ELSE                                   !* Start from rest
1210            IF(lwp) WRITE(numout,*) ' ===>>>> : Initialisation of en and mxln by background values'
1211            en  (:,:,:) = rn_emin
1212            mxln(:,:,:) = 0.05       
1213         ENDIF
1214         !
1215      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN   ! Create restart file
1216         !                                   ! -------------------
1217         IF(lwp) WRITE(numout,*) '---- gls-rst ----'
1218         CALL iom_rstput( kt, nitrst, numrow, 'en'   , en    )
1219         CALL iom_rstput( kt, nitrst, numrow, 'avt'  , avt_k )
1220         CALL iom_rstput( kt, nitrst, numrow, 'avm'  , avm_k )
1221         CALL iom_rstput( kt, nitrst, numrow, 'avmu' , avmu_k) 
1222         CALL iom_rstput( kt, nitrst, numrow, 'avmv' , avmv_k)
1223         CALL iom_rstput( kt, nitrst, numrow, 'mxln' , mxln  )
1224         !
1225      ENDIF
1226      !
1227   END SUBROUTINE gls_rst
1228
1229#else
1230   !!----------------------------------------------------------------------
1231   !!   Dummy module :                                        NO TKE scheme
1232   !!----------------------------------------------------------------------
1233   LOGICAL, PUBLIC, PARAMETER ::   lk_zdfgls = .FALSE.   !: TKE flag
1234CONTAINS
1235   SUBROUTINE zdf_gls_init           ! Empty routine
1236      WRITE(*,*) 'zdf_gls_init: You should not have seen this print! error?'
1237   END SUBROUTINE zdf_gls_init
1238   SUBROUTINE zdf_gls( kt )          ! Empty routine
1239      WRITE(*,*) 'zdf_gls: You should not have seen this print! error?', kt
1240   END SUBROUTINE zdf_gls
1241   SUBROUTINE gls_rst( kt, cdrw )          ! Empty routine
1242      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1243      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1244      WRITE(*,*) 'gls_rst: You should not have seen this print! error?', kt, cdrw
1245   END SUBROUTINE gls_rst
1246#endif
1247
1248   !!======================================================================
1249END MODULE zdfgls
1250