New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traqsr.F90 on Ticket #688 – Attachment – NEMO

Ticket #688: traqsr.F90

File traqsr.F90, 22.0 KB (added by molines, 14 years ago)
Line 
1MODULE traqsr
2   !!======================================================================
3   !!                       ***  MODULE  traqsr  ***
4   !! Ocean physics: solar radiation penetration in the top ocean levels
5   !!======================================================================
6   !! History :  OPA  !  1990-10  (B. Blanke)  Original code
7   !!            7.0  !  1991-11  (G. Madec)
8   !!                 !  1996-01  (G. Madec)  s-coordinates
9   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
10   !!             -   !  2005-11  (G. Madec) zco, zps, sco coordinate
11   !!            3.2  !  2009-04  (G. Madec & NEMO team)
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_qsr      : trend due to the solar radiation penetration
16   !!   tra_qsr_init : solar radiation penetration initialization
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and active tracers
19   USE dom_oce         ! ocean space and time domain
20   USE sbc_oce         ! surface boundary condition: ocean
21   USE trc_oce         ! share SMS/Ocean variables
22   USE trdmod_oce      ! ocean variables trends
23   USE trdmod          ! ocean active tracers trends
24   USE in_out_manager  ! I/O manager
25   USE phycst          ! physical constants
26   USE prtctl          ! Print control
27   USE iom             ! I/O manager
28   USE fldread         ! read input fields
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   tra_qsr        ! routine called by step.F90 (ln_traqsr=T)
34
35   !                                           !!* Namelist namtra_qsr: penetrative solar radiation
36   LOGICAL , PUBLIC ::   ln_traqsr  = .TRUE.    !: light absorption (qsr) flag
37   LOGICAL , PUBLIC ::   ln_qsr_rgb = .FALSE.   !: Red-Green-Blue light absorption flag 
38   LOGICAL , PUBLIC ::   ln_qsr_2bd = .TRUE.    !: 2 band         light absorption flag
39   LOGICAL , PUBLIC ::   ln_qsr_bio = .FALSE.   !: bio-model      light absorption flag
40   INTEGER , PUBLIC ::   nn_chldta  = 0         !: use Chlorophyll data (=1) or not (=0)
41   REAL(wp), PUBLIC ::   rn_abs     = 0.58_wp   !: fraction absorbed in the very near surface (RGB & 2 bands)
42   REAL(wp), PUBLIC ::   rn_si0     = 0.35_wp   !: very near surface depth of extinction      (RGB & 2 bands)
43   REAL(wp), PUBLIC ::   rn_si1     = 23.0_wp   !: deepest depth of extinction (water type I)       (2 bands)
44   REAL(wp), PUBLIC ::   rn_si2     = 61.8_wp   !: deepest depth of extinction (blue & 0.01 mg.m-3)     (RGB)
45   
46   ! Module variables
47!$AGRIF_DO_NOT_TREAT
48   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_chl   ! structure of input Chl (file informations, fields read)
49   INTEGER ::   nksr   ! levels below which the light cannot penetrate ( depth larger than 391 m)
50   REAL(wp), DIMENSION(3,61) ::   rkrgb   !: tabulated attenuation coefficients for RGB absorption
51!$AGRIF_END_DO_NOT_TREAT
52
53   !! * Substitutions
54#  include "domzgr_substitute.h90"
55#  include "vectopt_loop_substitute.h90"
56   !!----------------------------------------------------------------------
57   !! NEMO/OPA 3.2 , LOCEAN-IPSL (2009)
58   !! $Id: traqsr.F90 1756 2009-11-25 14:15:20Z smasson $
59   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
60   !!----------------------------------------------------------------------
61
62CONTAINS
63
64   SUBROUTINE tra_qsr( kt )
65      !!----------------------------------------------------------------------
66      !!                  ***  ROUTINE tra_qsr  ***
67      !!
68      !! ** Purpose :   Compute the temperature trend due to the solar radiation
69      !!      penetration and add it to the general temperature trend.
70      !!
71      !! ** Method  : The profile of the solar radiation within the ocean is defined
72      !!      through 2 wavebands (rn_si0,rn_si1) or 3 wavebands (RGB) and a ratio rn_abs
73      !!      Considering the 2 wavebands case:
74      !!         I(k) = Qsr*( rn_abs*EXP(z(k)/rn_si0) + (1.-rn_abs)*EXP(z(k)/rn_si1) )
75      !!         The temperature trend associated with the solar radiation penetration
76      !!         is given by : zta = 1/e3t dk[ I ] / (rau0*Cp)
77      !!         At the bottom, boudary condition for the radiation is no flux :
78      !!      all heat which has not been absorbed in the above levels is put
79      !!      in the last ocean level.
80      !!         In z-coordinate case, the computation is only done down to the
81      !!      level where I(k) < 1.e-15 W/m2. In addition, the coefficients
82      !!      used for the computation are calculated one for once as they
83      !!      depends on k only.
84      !!
85      !! ** Action  : - update ta with the penetrative solar radiation trend
86      !!              - save the trend in ttrd ('key_trdtra')
87      !!
88      !! Reference  : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
89      !!              Lengaigne et al. 2007, Clim. Dyn., V28, 5, 503-516.
90      !!----------------------------------------------------------------------
91      USE oce, ONLY :   ztrdt => ua   ! use ua as 3D workspace   
92      USE oce, ONLY :   ztrds => va   ! use va as 3D workspace   
93      !!
94      INTEGER, INTENT(in) ::   kt     ! ocean time-step
95      !!
96      INTEGER  ::   ji, jj, jk           ! dummy loop indices
97      INTEGER  ::   irgb                 ! temporary integers
98      REAL(wp) ::   zchl, zcoef, zsi0r   ! temporary scalars
99      REAL(wp) ::   zc0, zc1, zc2, zc3   !    -         -
100      REAL(wp), DIMENSION(jpi,jpj)     ::   zekb, zekg, zekr            ! 2D workspace
101      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   ze0, ze1 , ze2, ze3, zea    ! 3D workspace
102      !!----------------------------------------------------------------------
103
104      IF( kt == nit000 ) THEN
105         IF(lwp) WRITE(numout,*)
106         IF(lwp) WRITE(numout,*) 'tra_qsr : penetration of the surface solar radiation'
107         IF(lwp) WRITE(numout,*) '~~~~~~~'
108         CALL tra_qsr_init
109         IF( .NOT.ln_traqsr )   RETURN
110      ENDIF
111
112      IF( l_trdtra ) THEN      ! Save ta and sa trends
113         ztrdt(:,:,:) = ta(:,:,:) 
114         ztrds(:,:,:) = 0.e0
115      ENDIF
116
117     
118      !                                           ! ============================================== !
119      IF( lk_qsr_bio .AND. ln_qsr_bio ) THEN      !  bio-model fluxes  : all vertical coordinates  !
120         !                                        ! ============================================== !
121         DO jk = 1, jpkm1
122            DO jj = 2, jpjm1
123               DO ji = fs_2, fs_jpim1   ! vector opt.
124                  ta(ji,jj,jk) = ta(ji,jj,jk) + ro0cpr * ( etot3(ji,jj,jk) - etot3(ji,jj,jk+1) ) / fse3t(ji,jj,jk) 
125               END DO
126            END DO
127         END DO
128         CALL iom_put( 'qsr3d', etot3 )   ! Shortwave Radiation 3D distribution
129         !                                        ! ============================================== !
130      ELSE                                        !  Ocean alone :
131         !                                        ! ============================================== !
132         !
133         !                                                ! ------------------------- !
134         IF( ln_qsr_rgb) THEN                             !  R-G-B  light penetration !
135            !                                             ! ------------------------- !
136            ! Set chlorophyl concentration
137            IF( nn_chldta ==1 ) THEN                             !*  Variable Chlorophyll
138               !
139               CALL fld_read( kt, 1, sf_chl )                         ! Read Chl data and provides it at the current time step
140               !         
141!CDIR COLLAPSE
142!CDIR NOVERRCHK
143               DO jj = 1, jpj                                         ! Separation in R-G-B depending of the surface Chl
144!CDIR NOVERRCHK
145                  DO ji = 1, jpi
146                     zchl = MIN( 10. , MAX( 0.03, sf_chl(1)%fnow(ji,jj) ) )
147                     irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
148                     zekb(ji,jj) = rkrgb(1,irgb)
149                     zekg(ji,jj) = rkrgb(2,irgb)
150                     zekr(ji,jj) = rkrgb(3,irgb)
151                  END DO
152               END DO
153               !
154               zsi0r = 1.e0 / rn_si0
155               zcoef  = ( 1. - rn_abs ) / 3.e0                        ! equi-partition in R-G-B
156               ze0(:,:,1) = rn_abs  * qsr(:,:)
157               ze1(:,:,1) = zcoef * qsr(:,:)
158               ze2(:,:,1) = zcoef * qsr(:,:)
159               ze3(:,:,1) = zcoef * qsr(:,:)
160               zea(:,:,1) =         qsr(:,:)
161               !
162               DO jk = 2, nksr+1
163!CDIR NOVERRCHK
164                  DO jj = 1, jpj
165!CDIR NOVERRCHK   
166                     DO ji = 1, jpi
167                        zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zsi0r     )
168                        zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) )
169                        zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) )
170                        zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) )
171                        ze0(ji,jj,jk) = zc0
172                        ze1(ji,jj,jk) = zc1
173                        ze2(ji,jj,jk) = zc2
174                        ze3(ji,jj,jk) = zc3
175                        zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
176                     END DO
177                  END DO
178               END DO
179               !
180               DO jk = 1, nksr                                        ! compute and add qsr trend to ta
181                  ta(:,:,jk) = ta(:,:,jk) + ro0cpr * ( zea(:,:,jk) - zea(:,:,jk+1) ) / fse3t(:,:,jk)
182               END DO
183               zea(:,:,nksr+1:jpk) = 0.e0     ! below 400m set to zero
184               CALL iom_put( 'qsr3d', zea )   ! Shortwave Radiation 3D distribution
185               !
186            ELSE                                                 !*  Constant Chlorophyll
187               DO jk = 1, nksr
188                  ta(:,:,jk) = ta(:,:,jk) + etot3(:,:,jk) * qsr(:,:)
189               END DO
190            ENDIF
191
192         ENDIF
193         !                                                ! ------------------------- !
194         IF( ln_qsr_2bd ) THEN                            !  2 band light penetration !
195            !                                             ! ------------------------- !
196            !
197            DO jk = 1, nksr
198               DO jj = 2, jpjm1
199                  DO ji = fs_2, fs_jpim1   ! vector opt.
200                     ta(ji,jj,jk) = ta(ji,jj,jk) + etot3(ji,jj,jk) * qsr(ji,jj)
201                  END DO
202               END DO
203            END DO
204            !
205         ENDIF
206         !
207      ENDIF
208
209      IF( l_trdtra ) THEN     ! qsr tracers trends saved for diagnostics
210         ztrdt(:,:,:) = ta(:,:,:) - ztrdt(:,:,:)
211         CALL trd_mod( ztrdt, ztrds, jptra_trd_qsr, 'TRA', kt )
212      ENDIF
213      !                       ! print mean trends (used for debugging)
214      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ta, clinfo1=' qsr  - Ta: ', mask1=tmask, clinfo3='tra-ta' )
215      !
216   END SUBROUTINE tra_qsr
217
218
219   SUBROUTINE tra_qsr_init
220      !!----------------------------------------------------------------------
221      !!                  ***  ROUTINE tra_qsr_init  ***
222      !!
223      !! ** Purpose :   Initialization for the penetrative solar radiation
224      !!
225      !! ** Method  :   The profile of solar radiation within the ocean is set
226      !!      from two length scale of penetration (rn_si0,rn_si1) and a ratio
227      !!      (rn_abs). These parameters are read in the namtra_qsr namelist. The
228      !!      default values correspond to clear water (type I in Jerlov'
229      !!      (1968) classification.
230      !!         called by tra_qsr at the first timestep (nit000)
231      !!
232      !! ** Action  : - initialize rn_si0, rn_si1 and rn_abs
233      !!
234      !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
235      !!----------------------------------------------------------------------
236      INTEGER  ::   ji, jj, jk            ! dummy loop indices
237      INTEGER  ::   irgb, ierror          ! temporary integer
238      INTEGER  ::   ioptio, nqsr          ! temporary integer
239      REAL(wp) ::   zc0  , zc1            ! temporary scalars
240      REAL(wp) ::   zc2  , zc3  , zchl    !    -         -
241      REAL(wp) ::   zsi0r, zsi1r, zcoef   !    -         -
242      REAL(wp), DIMENSION(jpi,jpj)     ::   zekb, zekg, zekr              ! 2D workspace
243      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   ze0 , ze1 , ze2 , ze3 , zea   ! 3D workspace
244      !!
245      CHARACTER(len=100) ::   cn_dir   ! Root directory for location of ssr files
246      TYPE(FLD_N)        ::   sn_chl   ! informations about the chlorofyl field to be read
247      NAMELIST/namtra_qsr/  sn_chl, cn_dir, ln_traqsr, ln_qsr_rgb, ln_qsr_2bd, ln_qsr_bio,   &
248         &                  nn_chldta, rn_abs, rn_si0, rn_si1, rn_si2
249      !!----------------------------------------------------------------------
250
251      cn_dir = './'       ! directory in which the model is executed
252      ! ... default values (NB: frequency positive => hours, negative => months)
253      !            !     file       ! frequency !  variable  ! time interp !  clim   ! 'yearly' or ! weights  ! rotation   !
254      !            !     name       !  (hours)  !    name    !    (T/F)    !  (T/F)  ! 'monthly'   ! filename ! pairs      !
255      sn_chl = FLD_N( 'chlorophyll' ,    -1     ,  'CHLA'    ,  .true.     , .true.  ,   'yearly'  , ''       , ''         )
256      !
257      REWIND( numnam )            ! Read Namelist namtra_qsr : ratio and length of penetration
258      READ  ( numnam, namtra_qsr )
259      !
260      IF(lwp) THEN                ! control print
261         WRITE(numout,*)
262         WRITE(numout,*) 'tra_qsr_init : penetration of the surface solar radiation'
263         WRITE(numout,*) '~~~~~~~~~~~~'
264         WRITE(numout,*) '   Namelist namtra_qsr : set the parameter of penetration'
265         WRITE(numout,*) '      Light penetration (T) or not (F)         ln_traqsr  = ', ln_traqsr
266         WRITE(numout,*) '      RGB (Red-Green-Blue) light penetration   ln_qsr_rgb = ', ln_qsr_rgb
267         WRITE(numout,*) '      2 band               light penetration   ln_qsr_2bd = ', ln_qsr_2bd
268         WRITE(numout,*) '      bio-model            light penetration   ln_qsr_bio = ', ln_qsr_bio
269         WRITE(numout,*) '      RGB : Chl data (=1) or cst value (=0)    nn_chldta  = ', nn_chldta
270         WRITE(numout,*) '      RGB & 2 bands: fraction of light (rn_si1)    rn_abs = ', rn_abs
271         WRITE(numout,*) '      RGB & 2 bands: shortess depth of extinction  rn_si0 = ', rn_si0
272         WRITE(numout,*) '      2 bands: longest depth of extinction         rn_si1 = ', rn_si1
273         WRITE(numout,*) '      3 bands: longest depth of extinction         rn_si2 = ', rn_si2
274      ENDIF
275
276      IF( ln_traqsr ) THEN     ! control consistency
277         !                     
278         IF( .NOT.lk_qsr_bio .AND. ln_qsr_bio )   THEN
279            CALL ctl_warn( 'No bio model : force ln_qsr_bio = FALSE ' )
280            ln_qsr_bio = .FALSE.
281         ENDIF
282         !
283         ioptio = 0                      ! Parameter control
284         IF( ln_qsr_rgb  )   ioptio = ioptio + 1
285         IF( ln_qsr_2bd  )   ioptio = ioptio + 1
286         IF( ln_qsr_bio  )   ioptio = ioptio + 1
287         !
288         IF( ioptio /= 1 ) THEN
289            ln_qsr_rgb = .TRUE.
290            nn_chldta  = 0
291            ln_qsr_2bd = .FALSE.
292            ln_qsr_bio = .FALSE.
293            CALL ctl_warn( '          Choose ONE type of light penetration in namelist namtra_qsr',   &
294           &               ' otherwise, we force the model to run with RGB light penetration' )
295         ENDIF
296         !
297         IF( ln_qsr_rgb .AND. nn_chldta == 0 )   nqsr =  1 
298         IF( ln_qsr_rgb .AND. nn_chldta == 1 )   nqsr =  2
299         IF( ln_qsr_2bd                      )   nqsr =  3
300         IF( ln_qsr_bio                      )   nqsr =  4
301         !
302         IF(lwp) THEN                   ! Print the choice
303            WRITE(numout,*)
304            IF( nqsr ==  1 )   WRITE(numout,*) '         R-G-B  light penetration - Constant Chlorophyll'
305            IF( nqsr ==  2 )   WRITE(numout,*) '         R-G-B  light penetration - Chl data '
306            IF( nqsr ==  3 )   WRITE(numout,*) '         2 band light penetration'
307            IF( nqsr ==  4 )   WRITE(numout,*) '         bio-model light penetration'
308         ENDIF
309         !
310      ENDIF
311      !                          ! ===================================== !
312      IF( ln_traqsr  ) THEN      !  Initialisation of Light Penetration  ! 
313         !                       ! ===================================== !
314         !
315         zsi0r = 1.e0 / rn_si0
316         zsi1r = 1.e0 / rn_si1
317         !                                ! ---------------------------------- !
318         IF( ln_qsr_rgb ) THEN            !  Red-Green-Blue light penetration  !
319            !                             ! ---------------------------------- !
320            !
321            !                                ! level of light extinction
322            nksr = trc_oce_ext_lev( rn_si2, 0.33e2 )
323            IF(lwp) THEN
324               WRITE(numout,*)
325               WRITE(numout,*) '        level max of computation of qsr = ', nksr, ' ref depth = ', gdepw_0(nksr+1), ' m'
326            ENDIF
327            !
328            CALL trc_oce_rgb( rkrgb )           !* tabulated attenuation coef.
329!!gm            CALL trc_oce_rgb_read( rkrgb )           !* tabulated attenuation coef.
330            !
331            IF( nn_chldta == 1 ) THEN           !* Chl data : set sf_chl structure
332               IF(lwp) WRITE(numout,*)
333               IF(lwp) WRITE(numout,*) '        Chlorophyll read in a file'
334               ALLOCATE( sf_chl(1), STAT=ierror )
335               IF( ierror > 0 ) THEN
336                  CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_chl structure' )   ;   RETURN
337               ENDIF
338               ALLOCATE( sf_chl(1)%fnow(jpi,jpj)   )
339               ALLOCATE( sf_chl(1)%fdta(jpi,jpj,2) )
340               !                                        ! fill sf_chl with sn_chl and control print
341               CALL fld_fill( sf_chl, (/ sn_chl /), cn_dir, 'tra_qsr_init',   &
342                  &                                         'Solar penetration function of read chlorophyll', 'namtra_qsr' )
343               !
344            ELSE                                !* constant Chl : compute once for all the distribution of light (etot3)
345               IF(lwp) WRITE(numout,*)
346               IF(lwp) WRITE(numout,*) '        Constant Chlorophyll concentration = 0.05'
347               IF(lwp) WRITE(numout,*) '        light distribution computed once for all'
348               !
349               zchl = 0.05                                 ! constant chlorophyll
350               irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
351               zekb(:,:) = rkrgb(1,irgb)                   ! Separation in R-G-B depending of the chlorophyl concentration
352               zekg(:,:) = rkrgb(2,irgb)
353               zekr(:,:) = rkrgb(3,irgb)
354               !
355               zcoef = ( 1. - rn_abs ) / 3.e0              ! equi-partition in R-G-B
356               ze0(:,:,1) = rn_abs
357               ze1(:,:,1) = zcoef
358               ze2(:,:,1) = zcoef 
359               ze3(:,:,1) = zcoef
360               zea(:,:,1) = tmask(:,:,1)                   ! = ( ze0+ze1+z2+ze3 ) * tmask
361               
362               DO jk = 2, nksr+1
363!CDIR NOVERRCHK
364                  DO jj = 1, jpj
365!CDIR NOVERRCHK   
366                     DO ji = 1, jpi
367                        zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zsi0r     )
368                        zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) )
369                        zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) )
370                        zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) )
371                        ze0(ji,jj,jk) = zc0                 
372                        ze1(ji,jj,jk) = zc1
373                        ze2(ji,jj,jk) = zc2     
374                        ze3(ji,jj,jk) = zc3
375                        zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
376                     END DO
377                  END DO
378               END DO 
379               !
380               DO jk = 1, nksr
381                  etot3(:,:,jk) = ro0cpr * ( zea(:,:,jk) - zea(:,:,jk+1) ) / fse3t(:,:,jk)
382               END DO
383               etot3(:,:,nksr+1:jpk) = 0.e0                ! below 400m set to zero
384            ENDIF
385            !
386         ENDIF
387            !                             ! ---------------------------------- !
388         IF( ln_qsr_2bd ) THEN            !    2 bands    light penetration    !
389            !                             ! ---------------------------------- !
390            !
391            !                                ! level of light extinction
392            nksr = trc_oce_ext_lev( rn_si1, 1.e2 )
393            IF(lwp) THEN
394               WRITE(numout,*)
395               WRITE(numout,*) '        level max of computation of qsr = ', nksr, ' ref depth = ', gdepw_0(nksr+1), ' m'
396            ENDIF
397            !
398            DO jk = 1, nksr                    !*  solar heat absorbed at T-point computed once for all
399               DO jj = 1, jpj                              ! top 400 meters
400                  DO ji = 1, jpi
401                     zc0 = rn_abs * EXP( -fsdepw(ji,jj,jk  )*zsi0r ) + (1.-rn_abs) * EXP( -fsdepw(ji,jj,jk  )*zsi1r )
402                     zc1 = rn_abs * EXP( -fsdepw(ji,jj,jk+1)*zsi0r ) + (1.-rn_abs) * EXP( -fsdepw(ji,jj,jk+1)*zsi1r )
403                     etot3(ji,jj,jk) = ro0cpr * (  zc0 * tmask(ji,jj,jk) - zc1 * tmask(ji,jj,jk+1)  ) / fse3t(ji,jj,jk)
404                  END DO
405               END DO
406            END DO
407            etot3(:,:,nksr+1:jpk) = 0.e0                   ! below 400m set to zero
408            !
409         ENDIF
410         !                       ! ===================================== !
411      ELSE                       !        No light penetration           !                   
412         !                       ! ===================================== !
413         IF(lwp) THEN
414            WRITE(numout,*)
415            WRITE(numout,*) 'tra_qsr_init : NO solar flux penetration'
416            WRITE(numout,*) '~~~~~~~~~~~~'
417         ENDIF
418      ENDIF
419      !
420   END SUBROUTINE tra_qsr_init
421
422   !!======================================================================
423END MODULE traqsr