New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in NEMO/branches/2018/dev_r10057_ENHANCE03_ZTILDE/src/OCE/SBC – NEMO

source: NEMO/branches/2018/dev_r10057_ENHANCE03_ZTILDE/src/OCE/SBC/sbcssm.F90 @ 10126

Last change on this file since 10126 was 10126, checked in by jchanut, 6 years ago

Merge with trunk

  • Property svn:keywords set to Id
File size: 14.0 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Surface module :  provide time-mean ocean surface variables
5   !!======================================================================
6   !! History :  9.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.3  ! 2010-10  (C. Bricaud, G. Madec)  add the Patm forcing for sea-ice
8   !!            3.7  ! 2015-11  (G. Madec)  non linear free surface by default: e3t_m always computed
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   sbc_ssm       : calculate sea surface mean currents, temperature, 
13   !!                   and salinity over nn_fsbc time-step
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and tracers
16   USE dom_oce        ! ocean space and time domain
17   USE sbc_oce        ! surface boundary condition: ocean fields
18   USE sbcapr         ! surface boundary condition: atmospheric pressure
19   USE eosbn2         ! equation of state and related derivatives
20   !
21   USE in_out_manager ! I/O manager
22   USE prtctl         ! Print control
23   USE iom            ! IOM library
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   sbc_ssm        ! routine called by step.F90
29   PUBLIC   sbc_ssm_init   ! routine called by sbcmod.F90
30
31   LOGICAL, SAVE ::   l_ssm_mean = .FALSE.   ! keep track of whether means have been read from restart file
32   
33   !!----------------------------------------------------------------------
34   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
35   !! $Id$
36   !! Software governed by the CeCILL license (see ./LICENSE)
37   !!----------------------------------------------------------------------
38CONTAINS
39
40   SUBROUTINE sbc_ssm( kt )
41      !!---------------------------------------------------------------------
42      !!                     ***  ROUTINE sbc_oce  ***
43      !!                     
44      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
45      !!                condition computation
46      !!               
47      !! ** Method  :   compute mean surface velocity (2 components at U and
48      !!      V-points) [m/s], temperature [Celsius] and salinity [psu] over
49      !!      the periode (kt - nn_fsbc) to kt
50      !!         Note that the inverse barometer ssh (i.e. ssh associated with Patm)
51      !!      is add to ssh_m when ln_apr_dyn = T. Required for sea-ice dynamics.
52      !!---------------------------------------------------------------------
53      INTEGER, INTENT(in) ::   kt   ! ocean time step
54      !
55      INTEGER  ::   ji, jj               ! loop index
56      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
57      REAL(wp), DIMENSION(jpi,jpj,jpts) :: zts
58      !!---------------------------------------------------------------------
59      !
60      !                                        !* surface T-, U-, V- ocean level variables (T, S, depth, velocity)
61      DO jj = 1, jpj
62         DO ji = 1, jpi
63            zts(ji,jj,jp_tem) = tsn(ji,jj,mikt(ji,jj),jp_tem)
64            zts(ji,jj,jp_sal) = tsn(ji,jj,mikt(ji,jj),jp_sal)
65         END DO
66      END DO
67      !
68      IF( nn_fsbc == 1 ) THEN                             !   Instantaneous surface fields        !
69         !                                                ! ---------------------------------------- !
70         ssu_m(:,:) = ub(:,:,1)
71         ssv_m(:,:) = vb(:,:,1)
72         IF( l_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
73         ELSE                    ;   sst_m(:,:) = zts(:,:,jp_tem)
74         ENDIF
75         sss_m(:,:) = zts(:,:,jp_sal)
76         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
77         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
78         ELSE                    ;   ssh_m(:,:) = sshn(:,:)
79         ENDIF
80         !
81         e3t_m(:,:) = e3t_n(:,:,1)
82         !
83         frq_m(:,:) = fraqsr_1lev(:,:)
84         !
85      ELSE
86         !                                                ! ----------------------------------------------- !
87         IF( kt == nit000 .AND. .NOT. l_ssm_mean ) THEN   !   Initialisation: 1st time-step, no input means !
88            !                                             ! ----------------------------------------------- !
89            IF(lwp) WRITE(numout,*)
90            IF(lwp) WRITE(numout,*) 'sbc_ssm : mean fields initialised to instantaneous values'
91            IF(lwp) WRITE(numout,*) '~~~~~~~   '
92            zcoef = REAL( nn_fsbc - 1, wp )
93            ssu_m(:,:) = zcoef * ub(:,:,1)
94            ssv_m(:,:) = zcoef * vb(:,:,1)
95            IF( l_useCT )  THEN    ;   sst_m(:,:) = zcoef * eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
96            ELSE                    ;   sst_m(:,:) = zcoef * zts(:,:,jp_tem)
97            ENDIF
98            sss_m(:,:) = zcoef * zts(:,:,jp_sal)
99            !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
100            IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = zcoef * ( sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) )
101            ELSE                    ;   ssh_m(:,:) = zcoef * sshn(:,:)
102            ENDIF
103            !
104            e3t_m(:,:) = zcoef * e3t_n(:,:,1)
105            !
106            frq_m(:,:) = zcoef * fraqsr_1lev(:,:)
107            !                                             ! ---------------------------------------- !
108         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
109            !                                             ! ---------------------------------------- !
110            ssu_m(:,:) = 0._wp     ! reset to zero ocean mean sbc fields
111            ssv_m(:,:) = 0._wp
112            sst_m(:,:) = 0._wp
113            sss_m(:,:) = 0._wp
114            ssh_m(:,:) = 0._wp
115            e3t_m(:,:) = 0._wp
116            frq_m(:,:) = 0._wp
117         ENDIF
118         !                                                ! ---------------------------------------- !
119         !                                                !        Cumulate at each time step        !
120         !                                                ! ---------------------------------------- !
121         ssu_m(:,:) = ssu_m(:,:) + ub(:,:,1)
122         ssv_m(:,:) = ssv_m(:,:) + vb(:,:,1)
123         IF( l_useCT )  THEN     ;   sst_m(:,:) = sst_m(:,:) + eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
124         ELSE                    ;   sst_m(:,:) = sst_m(:,:) + zts(:,:,jp_tem)
125         ENDIF
126         sss_m(:,:) = sss_m(:,:) + zts(:,:,jp_sal)
127         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
128         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
129         ELSE                    ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:)
130         ENDIF
131         !
132         e3t_m(:,:) = e3t_m(:,:) + e3t_n(:,:,1)
133         !
134         frq_m(:,:) = frq_m(:,:) + fraqsr_1lev(:,:)
135
136         !                                                ! ---------------------------------------- !
137         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
138            !                                             ! ---------------------------------------- !
139            zcoef = 1. / REAL( nn_fsbc, wp )
140            sst_m(:,:) = sst_m(:,:) * zcoef     ! mean SST             [Celsius]
141            sss_m(:,:) = sss_m(:,:) * zcoef     ! mean SSS             [psu]
142            ssu_m(:,:) = ssu_m(:,:) * zcoef     ! mean suface current  [m/s]
143            ssv_m(:,:) = ssv_m(:,:) * zcoef     !
144            ssh_m(:,:) = ssh_m(:,:) * zcoef     ! mean SSH             [m]
145            e3t_m(:,:) = e3t_m(:,:) * zcoef     ! mean vertical scale factor [m]
146            frq_m(:,:) = frq_m(:,:) * zcoef     ! mean fraction of solar net radiation absorbed in the 1st T level [-]
147            !
148         ENDIF
149         !                                                ! ---------------------------------------- !
150         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
151            !                                             ! ---------------------------------------- !
152            IF(lwp) WRITE(numout,*)
153            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields written in ocean restart file ',   &
154               &                    'at it= ', kt,' date= ', ndastp
155            IF(lwp) WRITE(numout,*) '~~~~~~~'
156            zf_sbc = REAL( nn_fsbc, wp )
157            IF( lwxios ) CALL iom_swap(      cwxios_context          )
158            CALL iom_rstput( kt, nitrst, numrow, 'nn_fsbc', zf_sbc, ldxios = lwxios )    ! sbc frequency
159            CALL iom_rstput( kt, nitrst, numrow, 'ssu_m'  , ssu_m, ldxios = lwxios  )    ! sea surface mean fields
160            CALL iom_rstput( kt, nitrst, numrow, 'ssv_m'  , ssv_m, ldxios = lwxios  )
161            CALL iom_rstput( kt, nitrst, numrow, 'sst_m'  , sst_m, ldxios = lwxios  )
162            CALL iom_rstput( kt, nitrst, numrow, 'sss_m'  , sss_m, ldxios = lwxios  )
163            CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m, ldxios = lwxios  )
164            CALL iom_rstput( kt, nitrst, numrow, 'e3t_m'  , e3t_m, ldxios = lwxios  )
165            CALL iom_rstput( kt, nitrst, numrow, 'frq_m'  , frq_m, ldxios = lwxios  )
166            !
167            IF( lwxios ) CALL iom_swap(      cxios_context          )
168         ENDIF
169         !
170      ENDIF
171      !
172      IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
173         CALL iom_put( 'ssu_m', ssu_m )
174         CALL iom_put( 'ssv_m', ssv_m )
175         CALL iom_put( 'sst_m', sst_m )
176         CALL iom_put( 'sss_m', sss_m )
177         CALL iom_put( 'ssh_m', ssh_m )
178         CALL iom_put( 'e3t_m', e3t_m )
179         CALL iom_put( 'frq_m', frq_m )
180      ENDIF
181      !
182   END SUBROUTINE sbc_ssm
183
184
185   SUBROUTINE sbc_ssm_init
186      !!----------------------------------------------------------------------
187      !!                  ***  ROUTINE sbc_ssm_init  ***
188      !!
189      !! ** Purpose :   Initialisation of the sbc data
190      !!
191      !! ** Action  : - read parameters
192      !!----------------------------------------------------------------------
193      REAL(wp) ::   zcoef, zf_sbc   ! local scalar
194      !!----------------------------------------------------------------------
195      !
196      IF( nn_fsbc == 1 ) THEN
197         !
198         IF(lwp) WRITE(numout,*)
199         IF(lwp) WRITE(numout,*) 'sbc_ssm_init : sea surface mean fields, nn_fsbc=1 : instantaneous values'
200         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
201         !
202      ELSE
203         !               
204         IF(lwp) WRITE(numout,*)
205         IF(lwp) WRITE(numout,*) 'sbc_ssm_init : sea surface mean fields'
206         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~ '
207         !
208         IF( ln_rstart .AND. iom_varid( numror, 'nn_fsbc', ldstop = .FALSE. ) > 0 ) THEN
209            l_ssm_mean = .TRUE.
210            CALL iom_get( numror               , 'nn_fsbc', zf_sbc, ldxios = lrxios )    ! sbc frequency of previous run
211            CALL iom_get( numror, jpdom_autoglo, 'ssu_m'  , ssu_m, ldxios = lrxios  )    ! sea surface mean velocity    (U-point)
212            CALL iom_get( numror, jpdom_autoglo, 'ssv_m'  , ssv_m, ldxios = lrxios  )    !   "         "    velocity    (V-point)
213            CALL iom_get( numror, jpdom_autoglo, 'sst_m'  , sst_m, ldxios = lrxios  )    !   "         "    temperature (T-point)
214            CALL iom_get( numror, jpdom_autoglo, 'sss_m'  , sss_m, ldxios = lrxios  )    !   "         "    salinity    (T-point)
215            CALL iom_get( numror, jpdom_autoglo, 'ssh_m'  , ssh_m, ldxios = lrxios  )    !   "         "    height      (T-point)
216            CALL iom_get( numror, jpdom_autoglo, 'e3t_m'  , e3t_m, ldxios = lrxios  )    ! 1st level thickness          (T-point)
217            ! fraction of solar net radiation absorbed in 1st T level
218            IF( iom_varid( numror, 'frq_m', ldstop = .FALSE. ) > 0 ) THEN
219               CALL iom_get( numror, jpdom_autoglo, 'frq_m'  , frq_m, ldxios = lrxios  )
220            ELSE
221               frq_m(:,:) = 1._wp   ! default definition
222            ENDIF
223            !
224            IF( zf_sbc /= REAL( nn_fsbc, wp ) ) THEN      ! nn_fsbc has changed between 2 runs
225               IF(lwp) WRITE(numout,*) '   restart with a change in the frequency of mean from ', zf_sbc, ' to ', nn_fsbc 
226               zcoef = REAL( nn_fsbc - 1, wp ) / zf_sbc 
227               ssu_m(:,:) = zcoef * ssu_m(:,:) 
228               ssv_m(:,:) = zcoef * ssv_m(:,:)
229               sst_m(:,:) = zcoef * sst_m(:,:)
230               sss_m(:,:) = zcoef * sss_m(:,:)
231               ssh_m(:,:) = zcoef * ssh_m(:,:)
232               e3t_m(:,:) = zcoef * e3t_m(:,:)
233               frq_m(:,:) = zcoef * frq_m(:,:)
234            ELSE
235               IF(lwp) WRITE(numout,*) '   mean fields read in the ocean restart file'
236            ENDIF
237         ENDIF
238      ENDIF
239      !
240      IF( .NOT.l_ssm_mean ) THEN   ! default initialisation. needed by iceistate
241         !
242         IF(lwp) WRITE(numout,*) '   default initialisation of ss._m arrays'
243         ssu_m(:,:) = ub(:,:,1)
244         ssv_m(:,:) = vb(:,:,1)
245         IF( l_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( tsn(:,:,1,jp_tem), tsn(:,:,1,jp_sal) )
246         ELSE                   ;   sst_m(:,:) = tsn(:,:,1,jp_tem)
247         ENDIF
248         sss_m(:,:) = tsn  (:,:,1,jp_sal)
249         ssh_m(:,:) = sshn (:,:)
250         e3t_m(:,:) = e3t_n(:,:,1)
251         frq_m(:,:) = 1._wp
252         !
253      ENDIF
254      !
255      IF( lwxios.AND.nn_fsbc > 1 ) THEN
256         CALL iom_set_rstw_var_active('nn_fsbc')
257         CALL iom_set_rstw_var_active('ssu_m')
258         CALL iom_set_rstw_var_active('ssv_m')
259         CALL iom_set_rstw_var_active('sst_m')
260         CALL iom_set_rstw_var_active('sss_m')
261         CALL iom_set_rstw_var_active('ssh_m')
262         CALL iom_set_rstw_var_active('e3t_m')
263         CALL iom_set_rstw_var_active('frq_m')
264      ENDIF
265
266   END SUBROUTINE sbc_ssm_init
267
268   !!======================================================================
269END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.