1 | MODULE icedyn_adv_umx |
---|
2 | !!============================================================================== |
---|
3 | !! *** MODULE icedyn_adv_umx *** |
---|
4 | !! sea-ice : advection using the ULTIMATE-MACHO scheme |
---|
5 | !!============================================================================== |
---|
6 | !! History : 3.6 ! 2014-11 (C. Rousset, G. Madec) Original code |
---|
7 | !! 4.0 ! 2018 (many people) SI3 [aka Sea Ice cube] |
---|
8 | !!---------------------------------------------------------------------- |
---|
9 | #if defined key_si3 |
---|
10 | !!---------------------------------------------------------------------- |
---|
11 | !! 'key_si3' SI3 sea-ice model |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | !! ice_dyn_adv_umx : update the tracer trend with the 3D advection trends using a TVD scheme |
---|
14 | !! ultimate_x(_y) : compute a tracer value at velocity points using ULTIMATE scheme at various orders |
---|
15 | !! macho : ??? |
---|
16 | !! nonosc_2d : compute monotonic tracer fluxes by a non-oscillatory algorithm |
---|
17 | !!---------------------------------------------------------------------- |
---|
18 | USE phycst ! physical constant |
---|
19 | USE dom_oce ! ocean domain |
---|
20 | USE sbc_oce , ONLY : nn_fsbc ! update frequency of surface boundary condition |
---|
21 | USE ice ! sea-ice variables |
---|
22 | ! |
---|
23 | USE in_out_manager ! I/O manager |
---|
24 | USE lib_mpp ! MPP library |
---|
25 | USE lib_fortran ! fortran utilities (glob_sum + no signed zero) |
---|
26 | USE lbclnk ! lateral boundary conditions (or mpp links) |
---|
27 | |
---|
28 | IMPLICIT NONE |
---|
29 | PRIVATE |
---|
30 | |
---|
31 | PUBLIC ice_dyn_adv_umx ! called by icedyn_adv.F90 |
---|
32 | |
---|
33 | REAL(wp) :: z1_6 = 1._wp / 6._wp ! =1/6 |
---|
34 | REAL(wp) :: z1_120 = 1._wp / 120._wp ! =1/120 |
---|
35 | |
---|
36 | !! * Substitutions |
---|
37 | # include "vectopt_loop_substitute.h90" |
---|
38 | !!---------------------------------------------------------------------- |
---|
39 | !! NEMO/ICE 4.0 , NEMO Consortium (2018) |
---|
40 | !! $Id$ |
---|
41 | !! Software governed by the CeCILL license (see ./LICENSE) |
---|
42 | !!---------------------------------------------------------------------- |
---|
43 | CONTAINS |
---|
44 | |
---|
45 | SUBROUTINE ice_dyn_adv_umx( k_order, kt, pu_ice, pv_ice, & |
---|
46 | & pato_i, pv_i, pv_s, psv_i, poa_i, pa_i, pa_ip, pv_ip, pe_s, pe_i ) |
---|
47 | !!---------------------------------------------------------------------- |
---|
48 | !! *** ROUTINE ice_dyn_adv_umx *** |
---|
49 | !! |
---|
50 | !! ** Purpose : Compute the now trend due to total advection of |
---|
51 | !! tracers and add it to the general trend of tracer equations |
---|
52 | !! using an "Ultimate-Macho" scheme |
---|
53 | !! |
---|
54 | !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74. |
---|
55 | !!---------------------------------------------------------------------- |
---|
56 | INTEGER , INTENT(in ) :: k_order ! order of the scheme (1-5 or 20) |
---|
57 | INTEGER , INTENT(in ) :: kt ! time step |
---|
58 | REAL(wp), DIMENSION(:,:) , INTENT(in ) :: pu_ice ! ice i-velocity |
---|
59 | REAL(wp), DIMENSION(:,:) , INTENT(in ) :: pv_ice ! ice j-velocity |
---|
60 | REAL(wp), DIMENSION(:,:) , INTENT(inout) :: pato_i ! open water area |
---|
61 | REAL(wp), DIMENSION(:,:,:) , INTENT(inout) :: pv_i ! ice volume |
---|
62 | REAL(wp), DIMENSION(:,:,:) , INTENT(inout) :: pv_s ! snw volume |
---|
63 | REAL(wp), DIMENSION(:,:,:) , INTENT(inout) :: psv_i ! salt content |
---|
64 | REAL(wp), DIMENSION(:,:,:) , INTENT(inout) :: poa_i ! age content |
---|
65 | REAL(wp), DIMENSION(:,:,:) , INTENT(inout) :: pa_i ! ice concentration |
---|
66 | REAL(wp), DIMENSION(:,:,:) , INTENT(inout) :: pa_ip ! melt pond fraction |
---|
67 | REAL(wp), DIMENSION(:,:,:) , INTENT(inout) :: pv_ip ! melt pond volume |
---|
68 | REAL(wp), DIMENSION(:,:,:,:), INTENT(inout) :: pe_s ! snw heat content |
---|
69 | REAL(wp), DIMENSION(:,:,:,:), INTENT(inout) :: pe_i ! ice heat content |
---|
70 | ! |
---|
71 | INTEGER :: ji, jj, jk, jl, jt ! dummy loop indices |
---|
72 | INTEGER :: initad ! number of sub-timestep for the advection |
---|
73 | INTEGER :: ipl ! third dimention of tracer array |
---|
74 | |
---|
75 | REAL(wp) :: zcfl , zusnit, zdt ! - - |
---|
76 | REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: zudy, zvdx, zcu_box, zcv_box |
---|
77 | REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zpato |
---|
78 | !!---------------------------------------------------------------------- |
---|
79 | ! |
---|
80 | IF( kt == nit000 .AND. lwp ) WRITE(numout,*) '-- ice_dyn_adv_umx: Ultimate-Macho advection scheme' |
---|
81 | ! |
---|
82 | ALLOCATE( zudy(jpi,jpj) , zvdx(jpi,jpj) , zcu_box(jpi,jpj) , zcv_box(jpi,jpj) ) |
---|
83 | ALLOCATE( zpato(jpi,jpj,1) ) |
---|
84 | ! |
---|
85 | ! --- If ice drift field is too fast, use an appropriate time step for advection (CFL test for stability) --- ! |
---|
86 | ! When needed, the advection split is applied at the next time-step in order to avoid blocking global comm. |
---|
87 | ! ...this should not affect too much the stability... Was ok on the tests we did... |
---|
88 | zcfl = MAXVAL( ABS( pu_ice(:,:) ) * rdt_ice * r1_e1u(:,:) ) |
---|
89 | zcfl = MAX( zcfl, MAXVAL( ABS( pv_ice(:,:) ) * rdt_ice * r1_e2v(:,:) ) ) |
---|
90 | IF( zcfl > 0.5 ) THEN ; l_split_advumx(1) = .TRUE. ! split advection time-step if CFL violated |
---|
91 | ELSE ; l_split_advumx(1) = .FALSE. |
---|
92 | ENDIF |
---|
93 | |
---|
94 | ! non-blocking global communication send l_split_advumx(1) and receive l_split_advumx(2) |
---|
95 | IF( lk_mpp ) CALL mpp_ilor( l_split_advumx, ldlast = kt == nitend - nn_fsbc + 1 ) |
---|
96 | |
---|
97 | IF( l_split_advumx(2) ) THEN ; initad = 2 ; zusnit = 0.5_wp ! split defined at the previous time-step |
---|
98 | ELSE ; initad = 1 ; zusnit = 1.0_wp |
---|
99 | ENDIF |
---|
100 | |
---|
101 | zdt = rdt_ice / REAL(initad) |
---|
102 | |
---|
103 | ! --- transport --- ! |
---|
104 | zudy(:,:) = pu_ice(:,:) * e2u(:,:) |
---|
105 | zvdx(:,:) = pv_ice(:,:) * e1v(:,:) |
---|
106 | |
---|
107 | ! --- define velocity for advection: u*grad(H) --- ! |
---|
108 | DO jj = 2, jpjm1 |
---|
109 | DO ji = fs_2, fs_jpim1 |
---|
110 | IF ( pu_ice(ji,jj) * pu_ice(ji-1,jj) <= 0._wp ) THEN ; zcu_box(ji,jj) = 0._wp |
---|
111 | ELSEIF( pu_ice(ji,jj) > 0._wp ) THEN ; zcu_box(ji,jj) = pu_ice(ji-1,jj) |
---|
112 | ELSE ; zcu_box(ji,jj) = pu_ice(ji ,jj) |
---|
113 | ENDIF |
---|
114 | |
---|
115 | IF ( pv_ice(ji,jj) * pv_ice(ji,jj-1) <= 0._wp ) THEN ; zcv_box(ji,jj) = 0._wp |
---|
116 | ELSEIF( pv_ice(ji,jj) > 0._wp ) THEN ; zcv_box(ji,jj) = pv_ice(ji,jj-1) |
---|
117 | ELSE ; zcv_box(ji,jj) = pv_ice(ji,jj ) |
---|
118 | ENDIF |
---|
119 | END DO |
---|
120 | END DO |
---|
121 | |
---|
122 | zpato (:,:,1) = pato_i(:,:) |
---|
123 | |
---|
124 | !---------------! |
---|
125 | !== advection ==! |
---|
126 | !---------------! |
---|
127 | DO jt = 1, initad |
---|
128 | CALL adv_umx( k_order, kt, 1, zdt, zudy, zvdx, zcu_box, zcv_box, zpato(:,:,1) ) ! Open water area |
---|
129 | CALL lbc_lnk( 'icedyn_adv_umx', zpato, 'T', 1. ) |
---|
130 | CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, pa_i(:,:,:) ) ! Ice area |
---|
131 | CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, pv_i(:,:,:) ) ! Ice volume |
---|
132 | CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, psv_i(:,:,:) ) ! Salt content |
---|
133 | CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, poa_i(:,:,:) ) ! Age content |
---|
134 | DO jk = 1, nlay_i |
---|
135 | CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, pe_i(:,:,jk,:) ) ! Ice heat content |
---|
136 | END DO |
---|
137 | CALL lbc_lnk( 'icedyn_adv_umx', pe_i, 'T', 1. ) |
---|
138 | |
---|
139 | CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, pv_s(:,:,:) ) ! Snow volume |
---|
140 | DO jk = 1, nlay_s |
---|
141 | CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, pe_s(:,:,jk,:) ) ! Snow heat content |
---|
142 | END DO |
---|
143 | CALL lbc_lnk( 'icedyn_adv_umx', pe_s, 'T', 1. ) |
---|
144 | |
---|
145 | IF ( ln_pnd_H12 ) THEN |
---|
146 | CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, pa_ip(:,:,:) ) ! Melt pond fraction |
---|
147 | CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, pv_ip(:,:,:) ) ! Melt pond volume |
---|
148 | CALL lbc_lnk_multi( 'icedyn_adv_umx', pa_i, 'T', 1., pv_i, 'T', 1., psv_i, 'T', 1., & |
---|
149 | & poa_i, 'T', 1., pv_s, 'T', 1., pa_ip, 'T', 1., & |
---|
150 | & pv_ip, 'T', 1. ) |
---|
151 | ELSE |
---|
152 | CALL lbc_lnk_multi( 'icedyn_adv_umx', pa_i, 'T', 1., pv_i, 'T', 1., psv_i, 'T', 1., & |
---|
153 | & poa_i, 'T', 1., pv_s, 'T', 1. ) |
---|
154 | ENDIF |
---|
155 | END DO |
---|
156 | ! |
---|
157 | pato_i(:,:) = zpato (:,:,1) |
---|
158 | ! |
---|
159 | DEALLOCATE( zudy, zvdx, zcu_box, zcv_box, zpato ) |
---|
160 | ! |
---|
161 | END SUBROUTINE ice_dyn_adv_umx |
---|
162 | |
---|
163 | |
---|
164 | SUBROUTINE adv_umx( k_order, kt, ipl, pdt, puc, pvc, pubox, pvbox, ptc ) |
---|
165 | !!---------------------------------------------------------------------- |
---|
166 | !! *** ROUTINE adv_umx *** |
---|
167 | !! |
---|
168 | !! ** Purpose : Compute the now trend due to total advection of |
---|
169 | !! tracers and add it to the general trend of tracer equations |
---|
170 | !! |
---|
171 | !! ** Method : TVD scheme, i.e. 2nd order centered scheme with |
---|
172 | !! corrected flux (monotonic correction) |
---|
173 | !! note: - this advection scheme needs a leap-frog time scheme |
---|
174 | !! |
---|
175 | !! ** Action : - pt the after advective tracer |
---|
176 | !!---------------------------------------------------------------------- |
---|
177 | INTEGER , INTENT(in ) :: k_order ! order of the ULTIMATE scheme |
---|
178 | INTEGER , INTENT(in ) :: kt ! number of iteration |
---|
179 | INTEGER , INTENT(in ) :: ipl ! third dimension of tracer array |
---|
180 | REAL(wp) , INTENT(in ) :: pdt ! tracer time-step |
---|
181 | REAL(wp), DIMENSION(jpi,jpj) , INTENT(in ) :: puc , pvc ! 2 ice velocity components => u*e2 |
---|
182 | REAL(wp), DIMENSION(jpi,jpj) , INTENT(in ) :: pubox, pvbox ! upstream velocity |
---|
183 | REAL(wp), DIMENSION(jpi,jpj,ipl), INTENT(inout) :: ptc ! tracer content field |
---|
184 | ! |
---|
185 | INTEGER :: ji, jj, jl ! dummy loop indices |
---|
186 | |
---|
187 | REAL(wp) :: ztra ! local scalar |
---|
188 | REAL(wp), DIMENSION(jpi,jpj,ipl) :: zfu_ups, zfu_ho, zt_u, zt_ups |
---|
189 | REAL(wp), DIMENSION(jpi,jpj,ipl) :: zfv_ups, zfv_ho, zt_v, ztrd |
---|
190 | |
---|
191 | DO jl = 1, ipl |
---|
192 | !!---------------------------------------------------------------------- |
---|
193 | ! |
---|
194 | ! upstream advection with initial mass fluxes & intermediate update |
---|
195 | ! -------------------------------------------------------------------- |
---|
196 | DO jj = 1, jpjm1 ! upstream tracer flux in the i and j direction |
---|
197 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
198 | zfu_ups(ji,jj,jl) = MAX( puc(ji,jj), 0._wp ) * ptc(ji,jj,jl) + MIN( puc(ji,jj), 0._wp ) * ptc(ji+1,jj,jl) |
---|
199 | zfv_ups(ji,jj,jl) = MAX( pvc(ji,jj), 0._wp ) * ptc(ji,jj,jl) + MIN( pvc(ji,jj), 0._wp ) * ptc(ji,jj+1,jl) |
---|
200 | END DO |
---|
201 | END DO |
---|
202 | |
---|
203 | DO jj = 2, jpjm1 ! total intermediate advective trends |
---|
204 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
205 | ztra = - ( zfu_ups(ji,jj,jl) - zfu_ups(ji-1,jj ,jl) & |
---|
206 | & + zfv_ups(ji,jj,jl) - zfv_ups(ji ,jj-1,jl) ) * r1_e1e2t(ji,jj) |
---|
207 | ! |
---|
208 | ztrd(ji,jj,jl) = ztra ! upstream trend [ -div(uh) or -div(uhT) ] |
---|
209 | zt_ups (ji,jj,jl) = ( ptc(ji,jj,jl) + pdt * ztra ) * tmask(ji,jj,1) ! guess after content field with monotonic scheme |
---|
210 | END DO |
---|
211 | END DO |
---|
212 | END DO |
---|
213 | |
---|
214 | ! High order (_ho) fluxes |
---|
215 | ! ----------------------- |
---|
216 | SELECT CASE( k_order ) |
---|
217 | CASE ( 20 ) ! centered second order |
---|
218 | DO jl = 1, ipl |
---|
219 | DO jj = 1, jpjm1 |
---|
220 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
221 | zfu_ho(ji,jj,jl) = 0.5 * puc(ji,jj) * ( ptc(ji,jj,jl) + ptc(ji+1,jj,jl) ) |
---|
222 | zfv_ho(ji,jj,jl) = 0.5 * pvc(ji,jj) * ( ptc(ji,jj,jl) + ptc(ji,jj+1,jl) ) |
---|
223 | END DO |
---|
224 | END DO |
---|
225 | END DO |
---|
226 | ! |
---|
227 | CASE ( 1:5 ) ! 1st to 5th order ULTIMATE-MACHO scheme |
---|
228 | CALL macho( k_order, kt, ipl, pdt, ptc, puc, pvc, pubox, pvbox, zt_u, zt_v ) |
---|
229 | ! |
---|
230 | DO jl = 1, ipl |
---|
231 | DO jj = 1, jpjm1 |
---|
232 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
233 | zfu_ho(ji,jj,jl) = puc(ji,jj) * zt_u(ji,jj,jl) |
---|
234 | zfv_ho(ji,jj,jl) = pvc(ji,jj) * zt_v(ji,jj,jl) |
---|
235 | END DO |
---|
236 | END DO |
---|
237 | END DO |
---|
238 | ! |
---|
239 | END SELECT |
---|
240 | |
---|
241 | ! antidiffusive flux : high order minus low order |
---|
242 | ! -------------------------------------------------- |
---|
243 | DO jl = 1, ipl |
---|
244 | DO jj = 1, jpjm1 |
---|
245 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
246 | zfu_ho(ji,jj,jl) = zfu_ho(ji,jj,jl) - zfu_ups(ji,jj,jl) |
---|
247 | zfv_ho(ji,jj,jl) = zfv_ho(ji,jj,jl) - zfv_ups(ji,jj,jl) |
---|
248 | END DO |
---|
249 | END DO |
---|
250 | END DO |
---|
251 | |
---|
252 | CALL lbc_lnk("icedyn_adv_umx",zt_ups, 'T', 1. ) ! Lateral boundary conditions (unchanged sign) |
---|
253 | |
---|
254 | ! monotonicity algorithm |
---|
255 | ! ------------------------- |
---|
256 | CALL nonosc_2d( ipl, ptc, zfu_ho, zfv_ho, zt_ups, pdt ) |
---|
257 | |
---|
258 | ! final trend with corrected fluxes |
---|
259 | ! ------------------------------------ |
---|
260 | DO jl = 1, ipl |
---|
261 | DO jj = 2, jpjm1 |
---|
262 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
263 | ztra = ztrd(ji,jj,jl) - ( zfu_ho(ji,jj,jl) - zfu_ho(ji-1,jj ,jl) & |
---|
264 | & + zfv_ho(ji,jj,jl) - zfv_ho(ji ,jj-1,jl) ) * r1_e1e2t(ji,jj) |
---|
265 | ptc(ji,jj,jl) = ptc(ji,jj,jl) + pdt * ztra * tmask(ji,jj,1) |
---|
266 | END DO |
---|
267 | END DO |
---|
268 | END DO |
---|
269 | ! |
---|
270 | END SUBROUTINE adv_umx |
---|
271 | |
---|
272 | SUBROUTINE macho( k_order, kt, ipl, pdt, ptc, puc, pvc, pubox, pvbox, pt_u, pt_v ) |
---|
273 | !!--------------------------------------------------------------------- |
---|
274 | !! *** ROUTINE ultimate_x *** |
---|
275 | !! |
---|
276 | !! ** Purpose : compute |
---|
277 | !! |
---|
278 | !! ** Method : ... ??? |
---|
279 | !! TIM = transient interpolation Modeling |
---|
280 | !! |
---|
281 | !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74. |
---|
282 | !!---------------------------------------------------------------------- |
---|
283 | INTEGER , INTENT(in ) :: k_order ! order of the ULTIMATE scheme |
---|
284 | INTEGER , INTENT(in ) :: kt ! number of iteration |
---|
285 | INTEGER , INTENT(in ) :: ipl ! third dimension of tracer array |
---|
286 | REAL(wp) , INTENT(in ) :: pdt ! tracer time-step |
---|
287 | REAL(wp), DIMENSION(jpi,jpj,ipl), INTENT(in ) :: ptc ! tracer fields |
---|
288 | REAL(wp), DIMENSION(jpi,jpj) , INTENT(in ) :: puc, pvc ! 2 ice velocity components |
---|
289 | REAL(wp), DIMENSION(jpi,jpj) , INTENT(in ) :: pubox, pvbox ! upstream velocity |
---|
290 | REAL(wp), DIMENSION(jpi,jpj,ipl), INTENT( out) :: pt_u, pt_v ! tracer at u- and v-points |
---|
291 | ! |
---|
292 | INTEGER :: ji, jj, jl ! dummy loop indices |
---|
293 | REAL(wp) :: zc_box ! - - |
---|
294 | REAL(wp), DIMENSION(jpi,jpj,ipl) :: zzt |
---|
295 | !!---------------------------------------------------------------------- |
---|
296 | ! |
---|
297 | IF( MOD( (kt - 1) / nn_fsbc , 2 ) == 0 ) THEN !== odd ice time step: adv_x then adv_y ==! |
---|
298 | ! |
---|
299 | ! !-- ultimate interpolation of pt at u-point --! |
---|
300 | CALL ultimate_x( k_order, ipl, pdt, ptc, puc, pt_u ) |
---|
301 | ! |
---|
302 | ! !-- advective form update in zzt --! |
---|
303 | DO jl = 1, ipl |
---|
304 | DO jj = 2, jpjm1 |
---|
305 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
306 | zzt(ji,jj,jl) = ptc(ji,jj,jl) - pubox(ji,jj) * pdt * ( pt_u(ji,jj,jl) - pt_u(ji-1,jj,jl) ) * r1_e1t(ji,jj) & |
---|
307 | & - ptc(ji,jj,jl) * pdt * ( puc (ji,jj) - puc (ji-1,jj) ) * r1_e1e2t(ji,jj) |
---|
308 | zzt(ji,jj,jl) = zzt(ji,jj,jl) * tmask(ji,jj,1) |
---|
309 | END DO |
---|
310 | END DO |
---|
311 | END DO |
---|
312 | CALL lbc_lnk( 'icedyn_adv_umx', zzt, 'T', 1. ) |
---|
313 | ! |
---|
314 | ! !-- ultimate interpolation of pt at v-point --! |
---|
315 | CALL ultimate_y( k_order, ipl, pdt, zzt, pvc, pt_v ) |
---|
316 | ! |
---|
317 | ELSE !== even ice time step: adv_y then adv_x ==! |
---|
318 | ! |
---|
319 | ! !-- ultimate interpolation of pt at v-point --! |
---|
320 | CALL ultimate_y( k_order, ipl, pdt, ptc, pvc, pt_v ) |
---|
321 | ! |
---|
322 | ! !-- advective form update in zzt --! |
---|
323 | DO jl = 1, ipl |
---|
324 | DO jj = 2, jpjm1 |
---|
325 | DO ji = fs_2, fs_jpim1 |
---|
326 | zzt(ji,jj,jl) = ptc(ji,jj,jl) - pvbox(ji,jj) * pdt * ( pt_v(ji,jj,jl) - pt_v(ji,jj-1,jl) ) * r1_e2t(ji,jj) & |
---|
327 | & - ptc (ji,jj,jl) * pdt * ( pvc (ji,jj) - pvc (ji,jj-1) ) * r1_e1e2t(ji,jj) |
---|
328 | zzt(ji,jj,jl) = zzt(ji,jj,jl) * tmask(ji,jj,1) |
---|
329 | END DO |
---|
330 | END DO |
---|
331 | END DO |
---|
332 | CALL lbc_lnk( 'icedyn_adv_umx', zzt, 'T', 1. ) |
---|
333 | ! |
---|
334 | ! !-- ultimate interpolation of pt at u-point --! |
---|
335 | CALL ultimate_x( k_order, ipl, pdt, zzt, puc, pt_u ) |
---|
336 | ! |
---|
337 | ENDIF |
---|
338 | ! |
---|
339 | END SUBROUTINE macho |
---|
340 | |
---|
341 | |
---|
342 | SUBROUTINE ultimate_x( k_order, ipl, pdt, pt, puc, pt_u ) |
---|
343 | !!--------------------------------------------------------------------- |
---|
344 | !! *** ROUTINE ultimate_x *** |
---|
345 | !! |
---|
346 | !! ** Purpose : compute |
---|
347 | !! |
---|
348 | !! ** Method : ... ??? |
---|
349 | !! TIM = transient interpolation Modeling |
---|
350 | !! |
---|
351 | !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74. |
---|
352 | !!---------------------------------------------------------------------- |
---|
353 | INTEGER , INTENT(in ) :: k_order ! ocean time-step index |
---|
354 | INTEGER , INTENT(in ) :: ipl ! third dimension of tracer array |
---|
355 | REAL(wp) , INTENT(in ) :: pdt ! tracer time-step |
---|
356 | REAL(wp), DIMENSION(jpi,jpj) , INTENT(in ) :: puc ! ice i-velocity component |
---|
357 | REAL(wp), DIMENSION(jpi,jpj,ipl), INTENT(in ) :: pt ! tracer fields |
---|
358 | REAL(wp), DIMENSION(jpi,jpj,ipl), INTENT( out) :: pt_u ! tracer at u-point |
---|
359 | ! |
---|
360 | INTEGER :: ji, jj, jl ! dummy loop indices |
---|
361 | REAL(wp) :: zcu, zdx2, zdx4 ! - - |
---|
362 | REAL(wp), DIMENSION(jpi,jpj) :: ztu1, ztu3 |
---|
363 | REAL(wp), DIMENSION(jpi,jpj,ipl) :: ztu2, ztu4 |
---|
364 | !!---------------------------------------------------------------------- |
---|
365 | ! |
---|
366 | ! !-- Laplacian in i-direction --! |
---|
367 | DO jl = 1, ipl |
---|
368 | DO jj = 2, jpjm1 ! First derivative (gradient) |
---|
369 | DO ji = 1, fs_jpim1 |
---|
370 | ztu1(ji,jj) = ( pt(ji+1,jj,jl) - pt(ji,jj,jl) ) * r1_e1u(ji,jj) * umask(ji,jj,1) |
---|
371 | END DO |
---|
372 | ! ! Second derivative (Laplacian) |
---|
373 | DO ji = fs_2, fs_jpim1 |
---|
374 | ztu2(ji,jj,jl) = ( ztu1(ji,jj) - ztu1(ji-1,jj) ) * r1_e1t(ji,jj) |
---|
375 | END DO |
---|
376 | END DO |
---|
377 | END DO |
---|
378 | CALL lbc_lnk( 'icedyn_adv_umx', ztu2, 'T', 1. ) |
---|
379 | ! |
---|
380 | ! !-- BiLaplacian in i-direction --! |
---|
381 | DO jl = 1, ipl |
---|
382 | DO jj = 2, jpjm1 ! Third derivative |
---|
383 | DO ji = 1, fs_jpim1 |
---|
384 | ztu3(ji,jj) = ( ztu2(ji+1,jj,jl) - ztu2(ji,jj,jl) ) * r1_e1u(ji,jj) * umask(ji,jj,1) |
---|
385 | END DO |
---|
386 | ! ! Fourth derivative |
---|
387 | DO ji = fs_2, fs_jpim1 |
---|
388 | ztu4(ji,jj,jl) = ( ztu3(ji,jj) - ztu3(ji-1,jj) ) * r1_e1t(ji,jj) |
---|
389 | END DO |
---|
390 | END DO |
---|
391 | END DO |
---|
392 | CALL lbc_lnk( 'icedyn_adv_umx', ztu4, 'T', 1. ) |
---|
393 | ! |
---|
394 | ! |
---|
395 | SELECT CASE (k_order ) |
---|
396 | ! |
---|
397 | CASE( 1 ) !== 1st order central TIM ==! (Eq. 21) |
---|
398 | ! |
---|
399 | DO jl = 1, ipl |
---|
400 | DO jj = 2, jpjm1 |
---|
401 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
402 | pt_u(ji,jj,jl) = 0.5_wp * umask(ji,jj,1) * ( pt(ji+1,jj,jl) + pt(ji,jj,jl) & |
---|
403 | & - SIGN( 1._wp, puc(ji,jj) ) * ( pt(ji+1,jj,jl) - pt(ji,jj,jl) ) ) |
---|
404 | END DO |
---|
405 | END DO |
---|
406 | END DO |
---|
407 | ! |
---|
408 | CASE( 2 ) !== 2nd order central TIM ==! (Eq. 23) |
---|
409 | ! |
---|
410 | DO jl = 1, ipl |
---|
411 | DO jj = 2, jpjm1 |
---|
412 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
413 | zcu = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj) |
---|
414 | pt_u(ji,jj,jl) = 0.5_wp * umask(ji,jj,1) * ( pt(ji+1,jj,jl) + pt(ji,jj,jl) & |
---|
415 | & - zcu * ( pt(ji+1,jj,jl) - pt(ji,jj,jl) ) ) |
---|
416 | END DO |
---|
417 | END DO |
---|
418 | END DO |
---|
419 | ! |
---|
420 | CASE( 3 ) !== 3rd order central TIM ==! (Eq. 24) |
---|
421 | ! |
---|
422 | DO jl = 1, ipl |
---|
423 | DO jj = 2, jpjm1 |
---|
424 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
425 | zcu = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj) |
---|
426 | zdx2 = e1u(ji,jj) * e1u(ji,jj) |
---|
427 | !!rachid zdx2 = e1u(ji,jj) * e1t(ji,jj) |
---|
428 | pt_u(ji,jj,jl) = 0.5_wp * umask(ji,jj,1) * ( ( pt (ji+1,jj,jl) + pt (ji,jj,jl) & |
---|
429 | & - zcu * ( pt (ji+1,jj,jl) - pt (ji,jj,jl) ) ) & |
---|
430 | & + z1_6 * zdx2 * ( zcu*zcu - 1._wp ) * ( ztu2(ji+1,jj,jl) + ztu2(ji,jj,jl) & |
---|
431 | & - SIGN( 1._wp, zcu ) * ( ztu2(ji+1,jj,jl) - ztu2(ji,jj,jl) ) ) ) |
---|
432 | END DO |
---|
433 | END DO |
---|
434 | END DO |
---|
435 | ! |
---|
436 | CASE( 4 ) !== 4th order central TIM ==! (Eq. 27) |
---|
437 | ! |
---|
438 | DO jl = 1, ipl |
---|
439 | DO jj = 2, jpjm1 |
---|
440 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
441 | zcu = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj) |
---|
442 | zdx2 = e1u(ji,jj) * e1u(ji,jj) |
---|
443 | !!rachid zdx2 = e1u(ji,jj) * e1t(ji,jj) |
---|
444 | pt_u(ji,jj,jl) = 0.5_wp * umask(ji,jj,1) * ( ( pt (ji+1,jj,jl) + pt (ji,jj,jl) & |
---|
445 | & - zcu * ( pt (ji+1,jj,jl) - pt (ji,jj,jl) ) ) & |
---|
446 | & + z1_6 * zdx2 * ( zcu*zcu - 1._wp ) * ( ztu2(ji+1,jj,jl) + ztu2(ji,jj,jl) & |
---|
447 | & - 0.5_wp * zcu * ( ztu2(ji+1,jj,jl) - ztu2(ji,jj,jl) ) ) ) |
---|
448 | END DO |
---|
449 | END DO |
---|
450 | END DO |
---|
451 | ! |
---|
452 | CASE( 5 ) !== 5th order central TIM ==! (Eq. 29) |
---|
453 | ! |
---|
454 | DO jl = 1, ipl |
---|
455 | DO jj = 2, jpjm1 |
---|
456 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
457 | zcu = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj) |
---|
458 | zdx2 = e1u(ji,jj) * e1u(ji,jj) |
---|
459 | !!rachid zdx2 = e1u(ji,jj) * e1t(ji,jj) |
---|
460 | zdx4 = zdx2 * zdx2 |
---|
461 | pt_u(ji,jj,jl) = 0.5_wp * umask(ji,jj,1) * ( ( pt (ji+1,jj,jl) + pt (ji,jj,jl) & |
---|
462 | & - zcu * ( pt (ji+1,jj,jl) - pt (ji,jj,jl) ) ) & |
---|
463 | & + z1_6 * zdx2 * ( zcu*zcu - 1._wp ) * ( ztu2(ji+1,jj,jl) + ztu2(ji,jj,jl) & |
---|
464 | & - 0.5_wp * zcu * ( ztu2(ji+1,jj,jl) - ztu2(ji,jj,jl) ) ) & |
---|
465 | & + z1_120 * zdx4 * ( zcu*zcu - 1._wp ) * ( zcu*zcu - 4._wp ) * ( ztu4(ji+1,jj,jl) + ztu4(ji,jj,jl) & |
---|
466 | & - SIGN( 1._wp, zcu ) * ( ztu4(ji+1,jj,jl) - ztu4(ji,jj,jl) ) ) ) |
---|
467 | END DO |
---|
468 | END DO |
---|
469 | END DO |
---|
470 | ! |
---|
471 | END SELECT |
---|
472 | ! |
---|
473 | END SUBROUTINE ultimate_x |
---|
474 | |
---|
475 | |
---|
476 | SUBROUTINE ultimate_y( k_order, ipl, pdt, pt, pvc, pt_v ) |
---|
477 | !!--------------------------------------------------------------------- |
---|
478 | !! *** ROUTINE ultimate_y *** |
---|
479 | !! |
---|
480 | !! ** Purpose : compute |
---|
481 | !! |
---|
482 | !! ** Method : ... ??? |
---|
483 | !! TIM = transient interpolation Modeling |
---|
484 | !! |
---|
485 | !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74. |
---|
486 | !!---------------------------------------------------------------------- |
---|
487 | INTEGER , INTENT(in ) :: k_order ! ocean time-step index |
---|
488 | INTEGER , INTENT(in ) :: ipl ! third dimension of tracer array |
---|
489 | REAL(wp) , INTENT(in ) :: pdt ! tracer time-step |
---|
490 | REAL(wp), DIMENSION(jpi,jpj) , INTENT(in ) :: pvc ! ice j-velocity component |
---|
491 | REAL(wp), DIMENSION(jpi,jpj,ipl), INTENT(in ) :: pt ! tracer fields |
---|
492 | REAL(wp), DIMENSION(jpi,jpj,ipl), INTENT( out) :: pt_v ! tracer at v-point |
---|
493 | ! |
---|
494 | INTEGER :: ji, jj, jl ! dummy loop indices |
---|
495 | REAL(wp) :: zcv, zdy2, zdy4 ! - - |
---|
496 | REAL(wp), DIMENSION(jpi,jpj) :: ztv1, ztv3 |
---|
497 | REAL(wp), DIMENSION(jpi,jpj,ipl) :: ztv2, ztv4 |
---|
498 | !!---------------------------------------------------------------------- |
---|
499 | ! |
---|
500 | ! !-- Laplacian in j-direction --! |
---|
501 | DO jl = 1, ipl |
---|
502 | DO jj = 1, jpjm1 ! First derivative (gradient) |
---|
503 | DO ji = fs_2, fs_jpim1 |
---|
504 | ztv1(ji,jj) = ( pt(ji,jj+1,jl) - pt(ji,jj,jl) ) * r1_e2v(ji,jj) * vmask(ji,jj,1) |
---|
505 | END DO |
---|
506 | END DO |
---|
507 | DO jj = 2, jpjm1 ! Second derivative (Laplacian) |
---|
508 | DO ji = fs_2, fs_jpim1 |
---|
509 | ztv2(ji,jj,jl) = ( ztv1(ji,jj) - ztv1(ji,jj-1) ) * r1_e2t(ji,jj) |
---|
510 | END DO |
---|
511 | END DO |
---|
512 | END DO |
---|
513 | CALL lbc_lnk( 'icedyn_adv_umx', ztv2, 'T', 1. ) |
---|
514 | ! |
---|
515 | ! !-- BiLaplacian in j-direction --! |
---|
516 | DO jl = 1, ipl |
---|
517 | DO jj = 1, jpjm1 ! First derivative |
---|
518 | DO ji = fs_2, fs_jpim1 |
---|
519 | ztv3(ji,jj) = ( ztv2(ji,jj+1,jl) - ztv2(ji,jj,jl) ) * r1_e2v(ji,jj) * vmask(ji,jj,1) |
---|
520 | END DO |
---|
521 | END DO |
---|
522 | DO jj = 2, jpjm1 ! Second derivative |
---|
523 | DO ji = fs_2, fs_jpim1 |
---|
524 | ztv4(ji,jj,jl) = ( ztv3(ji,jj) - ztv3(ji,jj-1) ) * r1_e2t(ji,jj) |
---|
525 | END DO |
---|
526 | END DO |
---|
527 | END DO |
---|
528 | CALL lbc_lnk( 'icedyn_adv_umx', ztv4, 'T', 1. ) |
---|
529 | ! |
---|
530 | ! |
---|
531 | SELECT CASE (k_order ) |
---|
532 | ! |
---|
533 | CASE( 1 ) !== 1st order central TIM ==! (Eq. 21) |
---|
534 | DO jl = 1, ipl |
---|
535 | DO jj = 1, jpjm1 |
---|
536 | DO ji = fs_2, fs_jpim1 |
---|
537 | pt_v(ji,jj,jl) = 0.5_wp * vmask(ji,jj,1) * ( ( pt(ji,jj+1,jl) + pt(ji,jj,jl) ) & |
---|
538 | & - SIGN( 1._wp, pvc(ji,jj) ) * ( pt(ji,jj+1,jl) - pt(ji,jj,jl) ) ) |
---|
539 | END DO |
---|
540 | END DO |
---|
541 | END DO |
---|
542 | ! |
---|
543 | CASE( 2 ) !== 2nd order central TIM ==! (Eq. 23) |
---|
544 | DO jl = 1, ipl |
---|
545 | DO jj = 1, jpjm1 |
---|
546 | DO ji = fs_2, fs_jpim1 |
---|
547 | zcv = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj) |
---|
548 | pt_v(ji,jj,jl) = 0.5_wp * vmask(ji,jj,1) * ( ( pt(ji,jj+1,jl) + pt(ji,jj,jl) ) & |
---|
549 | & - zcv * ( pt(ji,jj+1,jl) - pt(ji,jj,jl) ) ) |
---|
550 | END DO |
---|
551 | END DO |
---|
552 | END DO |
---|
553 | CALL lbc_lnk( 'icedyn_adv_umx', pt_v, 'V', 1. ) |
---|
554 | ! |
---|
555 | CASE( 3 ) !== 3rd order central TIM ==! (Eq. 24) |
---|
556 | DO jl = 1, ipl |
---|
557 | DO jj = 1, jpjm1 |
---|
558 | DO ji = fs_2, fs_jpim1 |
---|
559 | zcv = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj) |
---|
560 | zdy2 = e2v(ji,jj) * e2v(ji,jj) |
---|
561 | !!rachid zdy2 = e2v(ji,jj) * e2t(ji,jj) |
---|
562 | pt_v(ji,jj,jl) = 0.5_wp * vmask(ji,jj,1) * ( ( pt (ji,jj+1,jl) + pt (ji,jj,jl) & |
---|
563 | & - zcv * ( pt (ji,jj+1,jl) - pt (ji,jj,jl) ) ) & |
---|
564 | & + z1_6 * zdy2 * ( zcv*zcv - 1._wp ) * ( ztv2(ji,jj+1,jl) + ztv2(ji,jj,jl) & |
---|
565 | & - SIGN( 1._wp, zcv ) * ( ztv2(ji,jj+1,jl) - ztv2(ji,jj,jl) ) ) ) |
---|
566 | END DO |
---|
567 | END DO |
---|
568 | END DO |
---|
569 | ! |
---|
570 | CASE( 4 ) !== 4th order central TIM ==! (Eq. 27) |
---|
571 | DO jl = 1, ipl |
---|
572 | DO jj = 1, jpjm1 |
---|
573 | DO ji = fs_2, fs_jpim1 |
---|
574 | zcv = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj) |
---|
575 | zdy2 = e2v(ji,jj) * e2v(ji,jj) |
---|
576 | !!rachid zdy2 = e2v(ji,jj) * e2t(ji,jj) |
---|
577 | pt_v(ji,jj,jl) = 0.5_wp * vmask(ji,jj,1) * ( ( pt (ji,jj+1,jl) + pt (ji,jj,jl) & |
---|
578 | & - zcv * ( pt (ji,jj+1,jl) - pt (ji,jj,jl) ) ) & |
---|
579 | & + z1_6 * zdy2 * ( zcv*zcv - 1._wp ) * ( ztv2(ji,jj+1,jl) + ztv2(ji,jj,jl) & |
---|
580 | & - 0.5_wp * zcv * ( ztv2(ji,jj+1,jl) - ztv2(ji,jj,jl) ) ) ) |
---|
581 | END DO |
---|
582 | END DO |
---|
583 | END DO |
---|
584 | ! |
---|
585 | CASE( 5 ) !== 5th order central TIM ==! (Eq. 29) |
---|
586 | DO jl = 1, ipl |
---|
587 | DO jj = 1, jpjm1 |
---|
588 | DO ji = fs_2, fs_jpim1 |
---|
589 | zcv = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj) |
---|
590 | zdy2 = e2v(ji,jj) * e2v(ji,jj) |
---|
591 | !!rachid zdy2 = e2v(ji,jj) * e2t(ji,jj) |
---|
592 | zdy4 = zdy2 * zdy2 |
---|
593 | pt_v(ji,jj,jl) = 0.5_wp * vmask(ji,jj,1) * ( ( pt (ji,jj+1,jl) + pt (ji,jj,jl) & |
---|
594 | & - zcv * ( pt (ji,jj+1,jl) - pt (ji,jj,jl) ) ) & |
---|
595 | & + z1_6 * zdy2 * ( zcv*zcv - 1._wp ) * ( ztv2(ji,jj+1,jl) + ztv2(ji,jj,jl) & |
---|
596 | & - 0.5_wp * zcv * ( ztv2(ji,jj+1,jl) - ztv2(ji,jj,jl) ) ) & |
---|
597 | & + z1_120 * zdy4 * ( zcv*zcv - 1._wp ) * ( zcv*zcv - 4._wp ) * ( ztv4(ji,jj+1,jl) + ztv4(ji,jj,jl) & |
---|
598 | & - SIGN( 1._wp, zcv ) * ( ztv4(ji,jj+1,jl) - ztv4(ji,jj,jl) ) ) ) |
---|
599 | END DO |
---|
600 | END DO |
---|
601 | END DO |
---|
602 | ! |
---|
603 | END SELECT |
---|
604 | ! |
---|
605 | END SUBROUTINE ultimate_y |
---|
606 | |
---|
607 | |
---|
608 | SUBROUTINE nonosc_2d( ipl, pbef, paa, pbb, paft, pdt ) |
---|
609 | !!--------------------------------------------------------------------- |
---|
610 | !! *** ROUTINE nonosc *** |
---|
611 | !! |
---|
612 | !! ** Purpose : compute monotonic tracer fluxes from the upstream |
---|
613 | !! scheme and the before field by a nonoscillatory algorithm |
---|
614 | !! |
---|
615 | !! ** Method : ... ??? |
---|
616 | !! warning : pbef and paft must be masked, but the boundaries |
---|
617 | !! conditions on the fluxes are not necessary zalezak (1979) |
---|
618 | !! drange (1995) multi-dimensional forward-in-time and upstream- |
---|
619 | !! in-space based differencing for fluid |
---|
620 | !!---------------------------------------------------------------------- |
---|
621 | INTEGER , INTENT(in ) :: ipl ! third dimension of tracer array |
---|
622 | REAL(wp) , INTENT(in ) :: pdt ! tracer time-step |
---|
623 | REAL(wp), DIMENSION (jpi,jpj,ipl), INTENT(in ) :: pbef, paft ! before & after field |
---|
624 | REAL(wp), DIMENSION (jpi,jpj,ipl), INTENT(inout) :: paa, pbb ! monotonic fluxes in the 2 directions |
---|
625 | ! |
---|
626 | INTEGER :: ji, jj, jl ! dummy loop indices |
---|
627 | INTEGER :: ikm1 ! local integer |
---|
628 | REAL(wp) :: zpos, zneg, zbt, za, zb, zc, zbig, zsml, z1_dt ! local scalars |
---|
629 | REAL(wp) :: zau, zbu, zcu, zav, zbv, zcv, zup, zdo ! - - |
---|
630 | REAL(wp), DIMENSION(jpi,jpj) :: zbup, zbdo, zmsk |
---|
631 | REAL(wp), DIMENSION(jpi,jpj,ipl) :: zbetup, zbetdo, zdiv |
---|
632 | !!---------------------------------------------------------------------- |
---|
633 | ! |
---|
634 | zbig = 1.e+40_wp |
---|
635 | zsml = 1.e-15_wp |
---|
636 | |
---|
637 | ! test on divergence |
---|
638 | DO jl = 1, ipl |
---|
639 | DO jj = 2, jpjm1 |
---|
640 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
641 | zdiv(ji,jj,jl) = - ( paa(ji,jj,jl) - paa(ji-1,jj ,jl) & |
---|
642 | & + pbb(ji,jj,jl) - pbb(ji ,jj-1,jl) ) |
---|
643 | END DO |
---|
644 | END DO |
---|
645 | END DO |
---|
646 | CALL lbc_lnk( 'icedyn_adv_umx', zdiv, 'T', 1. ) ! Lateral boundary conditions (unchanged sign) |
---|
647 | |
---|
648 | DO jl = 1, ipl |
---|
649 | ! Determine ice masks for before and after tracers |
---|
650 | WHERE( pbef(:,:,jl) == 0._wp .AND. paft(:,:,jl) == 0._wp .AND. zdiv(:,:,jl) == 0._wp ) |
---|
651 | zmsk(:,:) = 0._wp |
---|
652 | ELSEWHERE |
---|
653 | zmsk(:,:) = 1._wp * tmask(:,:,1) |
---|
654 | END WHERE |
---|
655 | |
---|
656 | ! Search local extrema |
---|
657 | ! -------------------- |
---|
658 | ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land |
---|
659 | ! zbup(:,:) = MAX( pbef(:,:) * tmask(:,:,1) - zbig * ( 1.e0 - tmask(:,:,1) ), & |
---|
660 | ! & paft(:,:) * tmask(:,:,1) - zbig * ( 1.e0 - tmask(:,:,1) ) ) |
---|
661 | ! zbdo(:,:) = MIN( pbef(:,:) * tmask(:,:,1) + zbig * ( 1.e0 - tmask(:,:,1) ), & |
---|
662 | ! & paft(:,:) * tmask(:,:,1) + zbig * ( 1.e0 - tmask(:,:,1) ) ) |
---|
663 | zbup(:,:) = MAX( pbef(:,:,jl) * zmsk(:,:) - zbig * ( 1.e0 - zmsk(:,:) ), & |
---|
664 | & paft(:,:,jl) * zmsk(:,:) - zbig * ( 1.e0 - zmsk(:,:) ) ) |
---|
665 | zbdo(:,:) = MIN( pbef(:,:,jl) * zmsk(:,:) + zbig * ( 1.e0 - zmsk(:,:) ), & |
---|
666 | & paft(:,:,jl) * zmsk(:,:) + zbig * ( 1.e0 - zmsk(:,:) ) ) |
---|
667 | |
---|
668 | z1_dt = 1._wp / pdt |
---|
669 | DO jj = 2, jpjm1 |
---|
670 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
671 | ! |
---|
672 | zup = MAX( zbup(ji,jj), zbup(ji-1,jj ), zbup(ji+1,jj ), & ! search max/min in neighbourhood |
---|
673 | & zbup(ji ,jj-1), zbup(ji ,jj+1) ) |
---|
674 | zdo = MIN( zbdo(ji,jj), zbdo(ji-1,jj ), zbdo(ji+1,jj ), & |
---|
675 | & zbdo(ji ,jj-1), zbdo(ji ,jj+1) ) |
---|
676 | ! |
---|
677 | zpos = MAX( 0., paa(ji-1,jj ,jl) ) - MIN( 0., paa(ji ,jj ,jl) ) & ! positive/negative part of the flux |
---|
678 | & + MAX( 0., pbb(ji ,jj-1,jl) ) - MIN( 0., pbb(ji ,jj ,jl) ) |
---|
679 | zneg = MAX( 0., paa(ji ,jj ,jl) ) - MIN( 0., paa(ji-1,jj ,jl) ) & |
---|
680 | & + MAX( 0., pbb(ji ,jj ,jl) ) - MIN( 0., pbb(ji ,jj-1,jl) ) |
---|
681 | ! |
---|
682 | zbt = e1e2t(ji,jj) * z1_dt ! up & down beta terms |
---|
683 | zbetup(ji,jj,jl) = ( zup - paft(ji,jj,jl) ) / ( zpos + zsml ) * zbt |
---|
684 | zbetdo(ji,jj,jl) = ( paft(ji,jj,jl) - zdo ) / ( zneg + zsml ) * zbt |
---|
685 | END DO |
---|
686 | END DO |
---|
687 | END DO |
---|
688 | CALL lbc_lnk_multi( 'icedyn_adv_umx', zbetup, 'T', 1., zbetdo, 'T', 1. ) ! lateral boundary cond. (unchanged sign) |
---|
689 | |
---|
690 | DO jl = 1, ipl |
---|
691 | ! monotonic flux in the i & j direction (paa & pbb) |
---|
692 | ! ------------------------------------- |
---|
693 | DO jj = 2, jpjm1 |
---|
694 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
695 | zau = MIN( 1._wp , zbetdo(ji,jj,jl) , zbetup(ji+1,jj,jl) ) |
---|
696 | zbu = MIN( 1._wp , zbetup(ji,jj,jl) , zbetdo(ji+1,jj,jl) ) |
---|
697 | zcu = 0.5 + SIGN( 0.5 , paa(ji,jj,jl) ) |
---|
698 | ! |
---|
699 | paa(ji,jj,jl) = paa(ji,jj,jl) * ( zcu * zau + ( 1._wp - zcu) * zbu ) |
---|
700 | END DO |
---|
701 | END DO |
---|
702 | ! |
---|
703 | DO jj = 1, jpjm1 |
---|
704 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
705 | zav = MIN( 1._wp , zbetdo(ji,jj,jl) , zbetup(ji,jj+1,jl) ) |
---|
706 | zbv = MIN( 1._wp , zbetup(ji,jj,jl) , zbetdo(ji,jj+1,jl) ) |
---|
707 | zcv = 0.5 + SIGN( 0.5 , pbb(ji,jj,jl) ) |
---|
708 | ! |
---|
709 | pbb(ji,jj,jl) = pbb(ji,jj,jl) * ( zcv * zav + ( 1._wp - zcv) * zbv ) |
---|
710 | END DO |
---|
711 | END DO |
---|
712 | END DO |
---|
713 | ! |
---|
714 | END SUBROUTINE nonosc_2d |
---|
715 | |
---|
716 | #else |
---|
717 | !!---------------------------------------------------------------------- |
---|
718 | !! Default option Dummy module NO SI3 sea-ice model |
---|
719 | !!---------------------------------------------------------------------- |
---|
720 | #endif |
---|
721 | |
---|
722 | !!====================================================================== |
---|
723 | END MODULE icedyn_adv_umx |
---|