New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icedyn_adv_umx.F90 in NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/ICE – NEMO

source: NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/ICE/icedyn_adv_umx.F90 @ 10345

Last change on this file since 10345 was 10345, checked in by smasson, 5 years ago

dev_r10164_HPC09_ESIWACE_PREP_MERGE: merge with trunk@10344, see #2133
  • Property svn:keywords set to Id
File size: 37.8 KB
Line 
1MODULE icedyn_adv_umx
2   !!==============================================================================
3   !!                       ***  MODULE  icedyn_adv_umx  ***
4   !! sea-ice : advection using the ULTIMATE-MACHO scheme
5   !!==============================================================================
6   !! History :  3.6  !  2014-11  (C. Rousset, G. Madec)  Original code
7   !!            4.0  !  2018     (many people)           SI3 [aka Sea Ice cube]
8   !!----------------------------------------------------------------------
9#if defined key_si3
10   !!----------------------------------------------------------------------
11   !!   'key_si3'                                       SI3 sea-ice model
12   !!----------------------------------------------------------------------
13   !!   ice_dyn_adv_umx   : update the tracer trend with the 3D advection trends using a TVD scheme
14   !!   ultimate_x(_y)    : compute a tracer value at velocity points using ULTIMATE scheme at various orders
15   !!   macho             : ???
16   !!   nonosc_2d         : compute monotonic tracer fluxes by a non-oscillatory algorithm
17   !!----------------------------------------------------------------------
18   USE phycst         ! physical constant
19   USE dom_oce        ! ocean domain
20   USE sbc_oce , ONLY : nn_fsbc   ! update frequency of surface boundary condition
21   USE ice            ! sea-ice variables
22   !
23   USE in_out_manager ! I/O manager
24   USE lib_mpp        ! MPP library
25   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
26   USE lbclnk         ! lateral boundary conditions (or mpp links)
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   ice_dyn_adv_umx   ! called by icedyn_adv.F90
32     
33   REAL(wp) ::   z1_6   = 1._wp /   6._wp   ! =1/6
34   REAL(wp) ::   z1_120 = 1._wp / 120._wp   ! =1/120
35
36   !! * Substitutions
37#  include "vectopt_loop_substitute.h90"
38   !!----------------------------------------------------------------------
39   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
40   !! $Id$
41   !! Software governed by the CeCILL license (see ./LICENSE)
42   !!----------------------------------------------------------------------
43CONTAINS
44
45   SUBROUTINE ice_dyn_adv_umx( k_order, kt, pu_ice, pv_ice,  &
46      &                    pato_i, pv_i, pv_s, psv_i, poa_i, pa_i, pa_ip, pv_ip, pe_s, pe_i )
47      !!----------------------------------------------------------------------
48      !!                  ***  ROUTINE ice_dyn_adv_umx  ***
49      !!
50      !! **  Purpose :   Compute the now trend due to total advection of
51      !!                 tracers and add it to the general trend of tracer equations
52      !!                 using an "Ultimate-Macho" scheme
53      !!
54      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
55      !!----------------------------------------------------------------------
56      INTEGER                     , INTENT(in   ) ::   k_order    ! order of the scheme (1-5 or 20)
57      INTEGER                     , INTENT(in   ) ::   kt         ! time step
58      REAL(wp), DIMENSION(:,:)    , INTENT(in   ) ::   pu_ice     ! ice i-velocity
59      REAL(wp), DIMENSION(:,:)    , INTENT(in   ) ::   pv_ice     ! ice j-velocity
60      REAL(wp), DIMENSION(:,:)    , INTENT(inout) ::   pato_i     ! open water area
61      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pv_i       ! ice volume
62      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pv_s       ! snw volume
63      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   psv_i      ! salt content
64      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   poa_i      ! age content
65      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pa_i       ! ice concentration
66      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pa_ip      ! melt pond fraction
67      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pv_ip      ! melt pond volume
68      REAL(wp), DIMENSION(:,:,:,:), INTENT(inout) ::   pe_s       ! snw heat content
69      REAL(wp), DIMENSION(:,:,:,:), INTENT(inout) ::   pe_i       ! ice heat content
70      !
71      INTEGER  ::   ji, jj, jk, jl, jt      ! dummy loop indices
72      INTEGER  ::   initad                  ! number of sub-timestep for the advection
73      INTEGER  ::   ipl                     ! third dimention of tracer array
74
75      REAL(wp) ::   zcfl , zusnit, zdt      !   -      -
76      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   zudy, zvdx, zcu_box, zcv_box
77      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   zpato
78      !!----------------------------------------------------------------------
79      !
80      IF( kt == nit000 .AND. lwp )   WRITE(numout,*) '-- ice_dyn_adv_umx: Ultimate-Macho advection scheme'
81      !
82      ALLOCATE( zudy(jpi,jpj) , zvdx(jpi,jpj) , zcu_box(jpi,jpj) , zcv_box(jpi,jpj) )
83      ALLOCATE( zpato(jpi,jpj,1) )
84      !
85      ! --- If ice drift field is too fast, use an appropriate time step for advection (CFL test for stability) --- !
86      !     When needed, the advection split is applied at the next time-step in order to avoid blocking global comm.
87      !     ...this should not affect too much the stability... Was ok on the tests we did...
88      zcfl =            MAXVAL( ABS( pu_ice(:,:) ) * rdt_ice * r1_e1u(:,:) )
89      zcfl = MAX( zcfl, MAXVAL( ABS( pv_ice(:,:) ) * rdt_ice * r1_e2v(:,:) ) )
90      IF( zcfl > 0.5 ) THEN   ;   l_split_advumx(1) = .TRUE.    ! split advection time-step if CFL violated
91      ELSE                    ;   l_split_advumx(1) = .FALSE.
92      ENDIF
93     
94      ! non-blocking global communication send l_split_advumx(1) and receive l_split_advumx(2)
95      IF( lk_mpp )   CALL mpp_ilor( l_split_advumx, ldlast = kt == nitend - nn_fsbc + 1 )
96
97      IF( l_split_advumx(2) ) THEN   ;   initad = 2   ;   zusnit = 0.5_wp    ! split defined at the previous time-step
98      ELSE                           ;   initad = 1   ;   zusnit = 1.0_wp
99      ENDIF
100
101      zdt = rdt_ice / REAL(initad)
102
103      ! --- transport --- !
104      zudy(:,:) = pu_ice(:,:) * e2u(:,:)
105      zvdx(:,:) = pv_ice(:,:) * e1v(:,:)
106
107      ! --- define velocity for advection: u*grad(H) --- !
108      DO jj = 2, jpjm1
109         DO ji = fs_2, fs_jpim1
110            IF    ( pu_ice(ji,jj) * pu_ice(ji-1,jj) <= 0._wp ) THEN   ;   zcu_box(ji,jj) = 0._wp
111            ELSEIF( pu_ice(ji,jj)                   >  0._wp ) THEN   ;   zcu_box(ji,jj) = pu_ice(ji-1,jj)
112            ELSE                                                      ;   zcu_box(ji,jj) = pu_ice(ji  ,jj)
113            ENDIF
114
115            IF    ( pv_ice(ji,jj) * pv_ice(ji,jj-1) <= 0._wp ) THEN   ;   zcv_box(ji,jj) = 0._wp
116            ELSEIF( pv_ice(ji,jj)                   >  0._wp ) THEN   ;   zcv_box(ji,jj) = pv_ice(ji,jj-1)
117            ELSE                                                      ;   zcv_box(ji,jj) = pv_ice(ji,jj  )
118            ENDIF
119         END DO
120      END DO
121
122      zpato (:,:,1) = pato_i(:,:)
123
124      !---------------!
125      !== advection ==!
126      !---------------!
127      DO jt = 1, initad
128         CALL adv_umx( k_order, kt,   1, zdt, zudy, zvdx, zcu_box, zcv_box, zpato(:,:,1) )        ! Open water area
129         CALL lbc_lnk( 'icedyn_adv_umx', zpato, 'T',  1. )
130         CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, pa_i(:,:,:) )         ! Ice area
131         CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, pv_i(:,:,:) )         ! Ice  volume
132         CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, psv_i(:,:,:) )        ! Salt content
133         CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, poa_i(:,:,:) )        ! Age content
134         DO jk = 1, nlay_i
135            CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, pe_i(:,:,jk,:) )   ! Ice  heat content
136         END DO
137         CALL lbc_lnk( 'icedyn_adv_umx', pe_i, 'T',  1. )
138
139         CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, pv_s(:,:,:) )         ! Snow volume
140         DO jk = 1, nlay_s
141            CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, pe_s(:,:,jk,:) )   ! Snow heat content
142         END DO
143         CALL lbc_lnk( 'icedyn_adv_umx', pe_s, 'T',  1. )
144
145         IF ( ln_pnd_H12 ) THEN
146            CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, pa_ip(:,:,:) )     ! Melt pond fraction
147            CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, pv_ip(:,:,:) )     ! Melt pond volume
148            CALL lbc_lnk_multi( 'icedyn_adv_umx', pa_i, 'T',  1., pv_i, 'T',  1., psv_i, 'T',  1., &
149                                                & poa_i, 'T',  1., pv_s, 'T',  1., pa_ip, 'T',  1., &
150                                                & pv_ip, 'T',  1. )
151         ELSE
152            CALL lbc_lnk_multi( 'icedyn_adv_umx', pa_i, 'T',  1., pv_i, 'T',  1., psv_i, 'T',  1., &
153                                                & poa_i, 'T',  1., pv_s, 'T',  1. )
154         ENDIF
155      END DO
156      !
157      pato_i(:,:) = zpato (:,:,1)
158      !
159      DEALLOCATE( zudy, zvdx, zcu_box, zcv_box, zpato )
160      !
161   END SUBROUTINE ice_dyn_adv_umx
162
163   
164   SUBROUTINE adv_umx( k_order, kt, ipl, pdt, puc, pvc, pubox, pvbox, ptc )
165      !!----------------------------------------------------------------------
166      !!                  ***  ROUTINE adv_umx  ***
167      !!
168      !! **  Purpose :   Compute the now trend due to total advection of
169      !!       tracers and add it to the general trend of tracer equations
170      !!
171      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
172      !!       corrected flux (monotonic correction)
173      !!       note: - this advection scheme needs a leap-frog time scheme
174      !!
175      !! ** Action : - pt  the after advective tracer
176      !!----------------------------------------------------------------------
177      INTEGER                         , INTENT(in   ) ::   k_order        ! order of the ULTIMATE scheme
178      INTEGER                         , INTENT(in   ) ::   kt             ! number of iteration
179      INTEGER                         , INTENT(in   ) ::   ipl            ! third dimension of tracer array
180      REAL(wp)                        , INTENT(in   ) ::   pdt            ! tracer time-step
181      REAL(wp), DIMENSION(jpi,jpj)    , INTENT(in   ) ::   puc  , pvc     ! 2 ice velocity components => u*e2
182      REAL(wp), DIMENSION(jpi,jpj)    , INTENT(in   ) ::   pubox, pvbox   ! upstream velocity
183      REAL(wp), DIMENSION(jpi,jpj,ipl), INTENT(inout) ::   ptc            ! tracer content field
184      !
185      INTEGER  ::   ji, jj, jl       ! dummy loop indices 
186
187      REAL(wp) ::   ztra             ! local scalar
188      REAL(wp), DIMENSION(jpi,jpj,ipl) ::   zfu_ups, zfu_ho, zt_u, zt_ups
189      REAL(wp), DIMENSION(jpi,jpj,ipl) ::   zfv_ups, zfv_ho, zt_v, ztrd
190
191      DO jl = 1, ipl
192      !!----------------------------------------------------------------------
193      !
194      !  upstream advection with initial mass fluxes & intermediate update
195      ! --------------------------------------------------------------------
196      DO jj = 1, jpjm1         ! upstream tracer flux in the i and j direction
197         DO ji = 1, fs_jpim1   ! vector opt.
198            zfu_ups(ji,jj,jl) = MAX( puc(ji,jj), 0._wp ) * ptc(ji,jj,jl) + MIN( puc(ji,jj), 0._wp ) * ptc(ji+1,jj,jl)
199            zfv_ups(ji,jj,jl) = MAX( pvc(ji,jj), 0._wp ) * ptc(ji,jj,jl) + MIN( pvc(ji,jj), 0._wp ) * ptc(ji,jj+1,jl)
200         END DO
201      END DO
202     
203         DO jj = 2, jpjm1            ! total intermediate advective trends
204            DO ji = fs_2, fs_jpim1   ! vector opt.
205               ztra = - (   zfu_ups(ji,jj,jl) - zfu_ups(ji-1,jj  ,jl)   &
206                  &       + zfv_ups(ji,jj,jl) - zfv_ups(ji  ,jj-1,jl)   ) * r1_e1e2t(ji,jj)
207            !
208               ztrd(ji,jj,jl) =                         ztra                         ! upstream trend [ -div(uh) or -div(uhT) ] 
209               zt_ups (ji,jj,jl) = ( ptc(ji,jj,jl) + pdt * ztra ) * tmask(ji,jj,1)   ! guess after content field with monotonic scheme
210            END DO
211         END DO
212      END DO
213     
214      ! High order (_ho) fluxes
215      ! -----------------------
216      SELECT CASE( k_order )
217      CASE ( 20 )                          ! centered second order
218         DO jl = 1, ipl
219            DO jj = 1, jpjm1
220               DO ji = 1, fs_jpim1   ! vector opt.
221                  zfu_ho(ji,jj,jl) = 0.5 * puc(ji,jj) * ( ptc(ji,jj,jl) + ptc(ji+1,jj,jl) )
222                  zfv_ho(ji,jj,jl) = 0.5 * pvc(ji,jj) * ( ptc(ji,jj,jl) + ptc(ji,jj+1,jl) )
223               END DO
224            END DO
225         END DO
226         !
227      CASE ( 1:5 )                      ! 1st to 5th order ULTIMATE-MACHO scheme
228         CALL macho( k_order, kt, ipl, pdt, ptc, puc, pvc, pubox, pvbox, zt_u, zt_v )
229         !
230         DO jl = 1, ipl
231            DO jj = 2, jpjm1
232               DO ji = 1, fs_jpim1   ! vector opt.
233                  zfu_ho(ji,jj,jl) = puc(ji,jj) * zt_u(ji,jj,jl)
234               END DO
235            END DO
236         END DO
237         DO jl = 1, ipl
238            DO jj = 1, jpjm1
239               DO ji = fs_2, fs_jpim1   ! vector opt.
240                  zfv_ho(ji,jj,jl) = pvc(ji,jj) * zt_v(ji,jj,jl)
241               END DO
242            END DO
243         END DO
244         !
245      END SELECT
246         
247      ! antidiffusive flux : high order minus low order
248      ! --------------------------------------------------
249      DO jl = 1, ipl
250         DO jj = 2, jpjm1
251            DO ji = 1, fs_jpim1   ! vector opt.
252               zfu_ho(ji,jj,jl) = zfu_ho(ji,jj,jl) - zfu_ups(ji,jj,jl)
253            END DO
254         END DO
255      END DO
256      DO jl = 1, ipl
257         DO jj = 1, jpjm1
258            DO ji = fs_2, fs_jpim1   ! vector opt.
259               zfv_ho(ji,jj,jl) = zfv_ho(ji,jj,jl) - zfv_ups(ji,jj,jl)
260            END DO
261         END DO
262      END DO
263
264      CALL lbc_lnk("icedyn_adv_umx",zt_ups, 'T', 1. )        ! Lateral boundary conditions   (unchanged sign)
265     
266      ! monotonicity algorithm
267      ! -------------------------
268      CALL nonosc_2d( ipl, ptc, zfu_ho, zfv_ho, zt_ups, pdt )
269     
270      ! final trend with corrected fluxes
271      ! ------------------------------------
272      DO jl = 1, ipl
273         DO jj = 2, jpjm1
274            DO ji = fs_2, fs_jpim1   ! vector opt. 
275               ztra       = ztrd(ji,jj,jl)  - (  zfu_ho(ji,jj,jl) - zfu_ho(ji-1,jj  ,jl)   &
276                  &                         +    zfv_ho(ji,jj,jl) - zfv_ho(ji  ,jj-1,jl) ) * r1_e1e2t(ji,jj) 
277               ptc(ji,jj,jl) = ptc(ji,jj,jl) + pdt * ztra * tmask(ji,jj,1)
278            END DO
279         END DO
280      END DO
281      !
282   END SUBROUTINE adv_umx
283
284   SUBROUTINE macho( k_order, kt, ipl, pdt, ptc, puc, pvc, pubox, pvbox, pt_u, pt_v )
285      !!---------------------------------------------------------------------
286      !!                    ***  ROUTINE ultimate_x  ***
287      !!     
288      !! **  Purpose :   compute 
289      !!
290      !! **  Method  :   ... ???
291      !!                 TIM = transient interpolation Modeling
292      !!
293      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
294      !!----------------------------------------------------------------------
295      INTEGER                         , INTENT(in   ) ::   k_order    ! order of the ULTIMATE scheme
296      INTEGER                         , INTENT(in   ) ::   kt         ! number of iteration
297      INTEGER                         , INTENT(in   ) ::   ipl        ! third dimension of tracer array
298      REAL(wp)                        , INTENT(in   ) ::   pdt        ! tracer time-step
299      REAL(wp), DIMENSION(jpi,jpj,ipl), INTENT(in   ) ::   ptc        ! tracer fields
300      REAL(wp), DIMENSION(jpi,jpj)    , INTENT(in   ) ::   puc, pvc   ! 2 ice velocity components
301      REAL(wp), DIMENSION(jpi,jpj)    , INTENT(in   ) ::   pubox, pvbox   ! upstream velocity
302      REAL(wp), DIMENSION(jpi,jpj,ipl), INTENT(  out) ::   pt_u, pt_v ! tracer at u- and v-points
303      !
304      INTEGER  ::   ji, jj, jl    ! dummy loop indices
305      REAL(wp) ::   zc_box    !   -      -
306      REAL(wp), DIMENSION(jpi,jpj,ipl) :: zzt
307      !!----------------------------------------------------------------------
308      !
309      IF( MOD( (kt - 1) / nn_fsbc , 2 ) == 0 ) THEN         !==  odd ice time step:  adv_x then adv_y  ==!
310         !
311         !                                                           !--  ultimate interpolation of pt at u-point  --!
312         CALL ultimate_x( k_order, ipl, pdt, ptc, puc, pt_u )
313         !
314         !                                                           !--  advective form update in zzt  --!
315         DO jl = 1, ipl
316            DO jj = 2, jpjm1
317               DO ji = fs_2, fs_jpim1   ! vector opt.
318                  zzt(ji,jj,jl) = ptc(ji,jj,jl) - pubox(ji,jj) * pdt * ( pt_u(ji,jj,jl) - pt_u(ji-1,jj,jl) ) * r1_e1t(ji,jj)  &
319                   &            - ptc(ji,jj,jl) * pdt * ( puc (ji,jj) - puc (ji-1,jj) ) * r1_e1e2t(ji,jj)
320                  zzt(ji,jj,jl) = zzt(ji,jj,jl) * tmask(ji,jj,1)
321               END DO
322            END DO
323         END DO
324         CALL lbc_lnk( 'icedyn_adv_umx', zzt, 'T', 1. )
325         !
326         !                                                           !--  ultimate interpolation of pt at v-point  --!
327         CALL ultimate_y( k_order, ipl, pdt, zzt, pvc, pt_v )
328         !
329      ELSE                                                  !==  even ice time step:  adv_y then adv_x  ==!
330         !
331         !                                                           !--  ultimate interpolation of pt at v-point  --!
332         CALL ultimate_y( k_order, ipl, pdt, ptc, pvc, pt_v )
333         !
334         !                                                           !--  advective form update in zzt  --!
335         DO jl = 1, ipl
336            DO jj = 2, jpjm1
337               DO ji = fs_2, fs_jpim1
338                  zzt(ji,jj,jl) = ptc(ji,jj,jl) - pvbox(ji,jj) * pdt * ( pt_v(ji,jj,jl) - pt_v(ji,jj-1,jl) ) * r1_e2t(ji,jj)  &
339                     &                    - ptc  (ji,jj,jl) * pdt * ( pvc (ji,jj) - pvc (ji,jj-1) ) * r1_e1e2t(ji,jj)
340                  zzt(ji,jj,jl) = zzt(ji,jj,jl) * tmask(ji,jj,1)
341               END DO
342            END DO
343         END DO
344         CALL lbc_lnk( 'icedyn_adv_umx', zzt, 'T', 1. )
345         !
346         !                                                           !--  ultimate interpolation of pt at u-point  --!
347         CALL ultimate_x( k_order, ipl, pdt, zzt, puc, pt_u )
348         !     
349      ENDIF     
350      !
351   END SUBROUTINE macho
352
353
354   SUBROUTINE ultimate_x( k_order, ipl, pdt, pt, puc, pt_u )
355      !!---------------------------------------------------------------------
356      !!                    ***  ROUTINE ultimate_x  ***
357      !!     
358      !! **  Purpose :   compute 
359      !!
360      !! **  Method  :   ... ???
361      !!                 TIM = transient interpolation Modeling
362      !!
363      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
364      !!----------------------------------------------------------------------
365      INTEGER                         , INTENT(in   ) ::   k_order   ! ocean time-step index
366      INTEGER                         , INTENT(in   ) ::   ipl        ! third dimension of tracer array
367      REAL(wp)                        , INTENT(in   ) ::   pdt       ! tracer time-step
368      REAL(wp), DIMENSION(jpi,jpj)    , INTENT(in   ) ::   puc       ! ice i-velocity component
369      REAL(wp), DIMENSION(jpi,jpj,ipl), INTENT(in   ) ::   pt        ! tracer fields
370      REAL(wp), DIMENSION(jpi,jpj,ipl), INTENT(  out) ::   pt_u      ! tracer at u-point
371      !
372      INTEGER  ::   ji, jj, jl       ! dummy loop indices
373      REAL(wp) ::   zcu, zdx2, zdx4    !   -      -
374      REAL(wp), DIMENSION(jpi,jpj) :: ztu1, ztu3
375      REAL(wp), DIMENSION(jpi,jpj,ipl) :: ztu2, ztu4
376      !!----------------------------------------------------------------------
377      !
378      !                                                     !--  Laplacian in i-direction  --!
379      DO jl = 1, ipl
380         DO jj = 2, jpjm1         ! First derivative (gradient)
381            DO ji = 1, fs_jpim1
382               ztu1(ji,jj) = ( pt(ji+1,jj,jl) - pt(ji,jj,jl) ) * r1_e1u(ji,jj) * umask(ji,jj,1)
383            END DO
384            !                     ! Second derivative (Laplacian)
385            DO ji = fs_2, fs_jpim1
386               ztu2(ji,jj,jl) = ( ztu1(ji,jj) - ztu1(ji-1,jj) ) * r1_e1t(ji,jj)
387            END DO
388         END DO
389      END DO
390      CALL lbc_lnk( 'icedyn_adv_umx', ztu2, 'T', 1. )
391      !
392      !                                                     !--  BiLaplacian in i-direction  --!
393      DO jl = 1, ipl
394         DO jj = 2, jpjm1         ! Third derivative
395            DO ji = 1, fs_jpim1
396               ztu3(ji,jj) = ( ztu2(ji+1,jj,jl) - ztu2(ji,jj,jl) ) * r1_e1u(ji,jj) * umask(ji,jj,1)
397            END DO
398            !                     ! Fourth derivative
399            DO ji = fs_2, fs_jpim1
400               ztu4(ji,jj,jl) = ( ztu3(ji,jj) - ztu3(ji-1,jj) ) * r1_e1t(ji,jj)
401            END DO
402         END DO
403      END DO
404      CALL lbc_lnk( 'icedyn_adv_umx', ztu4, 'T', 1. )
405      !
406      !
407      SELECT CASE (k_order )
408      !
409      CASE( 1 )                                                   !==  1st order central TIM  ==! (Eq. 21)
410         !       
411         DO jl = 1, ipl
412            DO jj = 2, jpjm1
413               DO ji = 1, fs_jpim1   ! vector opt.
414                  pt_u(ji,jj,jl) = 0.5_wp * umask(ji,jj,1) * (                               pt(ji+1,jj,jl) + pt(ji,jj,jl)   &
415                     &                                       - SIGN( 1._wp, puc(ji,jj) ) * ( pt(ji+1,jj,jl) - pt(ji,jj,jl) ) )
416               END DO
417            END DO
418         END DO
419         !
420      CASE( 2 )                                                   !==  2nd order central TIM  ==! (Eq. 23)
421         !
422         DO jl = 1, ipl
423            DO jj = 2, jpjm1
424               DO ji = 1, fs_jpim1   ! vector opt.
425                  zcu  = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
426                  pt_u(ji,jj,jl) = 0.5_wp * umask(ji,jj,1) * (                               pt(ji+1,jj,jl) + pt(ji,jj,jl)   &
427                     &                                              -              zcu   * ( pt(ji+1,jj,jl) - pt(ji,jj,jl) ) ) 
428               END DO
429            END DO
430         END DO
431         ! 
432      CASE( 3 )                                                   !==  3rd order central TIM  ==! (Eq. 24)
433         !
434         DO jl = 1, ipl
435            DO jj = 2, jpjm1
436               DO ji = 1, fs_jpim1   ! vector opt.
437                  zcu  = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
438                  zdx2 = e1u(ji,jj) * e1u(ji,jj)
439!!rachid       zdx2 = e1u(ji,jj) * e1t(ji,jj)
440                  pt_u(ji,jj,jl) = 0.5_wp * umask(ji,jj,1) * (         (                     pt  (ji+1,jj,jl) + pt  (ji,jj,jl)        &
441                     &                                              -              zcu   * ( pt  (ji+1,jj,jl) - pt  (ji,jj,jl) )  )   &
442                     &        + z1_6 * zdx2 * ( zcu*zcu - 1._wp ) * (                        ztu2(ji+1,jj,jl) + ztu2(ji,jj,jl)        &
443                     &                                              - SIGN( 1._wp, zcu ) * ( ztu2(ji+1,jj,jl) - ztu2(ji,jj,jl) )  )   )
444               END DO
445            END DO
446         END DO
447         !
448      CASE( 4 )                                                   !==  4th order central TIM  ==! (Eq. 27)
449         !
450         DO jl = 1, ipl
451            DO jj = 2, jpjm1
452               DO ji = 1, fs_jpim1   ! vector opt.
453                  zcu  = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
454                  zdx2 = e1u(ji,jj) * e1u(ji,jj)
455!!rachid       zdx2 = e1u(ji,jj) * e1t(ji,jj)
456                  pt_u(ji,jj,jl) = 0.5_wp * umask(ji,jj,1) * (         (                     pt  (ji+1,jj,jl) + pt  (ji,jj,jl)        &
457                     &                                                    -          zcu * ( pt  (ji+1,jj,jl) - pt  (ji,jj,jl) )  )   &
458                     &        + z1_6 * zdx2 * ( zcu*zcu - 1._wp ) * (                        ztu2(ji+1,jj,jl) + ztu2(ji,jj,jl)        &
459                     &                                                    - 0.5_wp * zcu * ( ztu2(ji+1,jj,jl) - ztu2(ji,jj,jl) )  )   )
460               END DO
461            END DO
462         END DO
463         !
464      CASE( 5 )                                                   !==  5th order central TIM  ==! (Eq. 29)
465         !
466         DO jl = 1, ipl
467            DO jj = 2, jpjm1
468               DO ji = 1, fs_jpim1   ! vector opt.
469                  zcu  = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
470                  zdx2 = e1u(ji,jj) * e1u(ji,jj)
471!!rachid       zdx2 = e1u(ji,jj) * e1t(ji,jj)
472                  zdx4 = zdx2 * zdx2
473                  pt_u(ji,jj,jl) = 0.5_wp * umask(ji,jj,1) * (           (                   pt  (ji+1,jj,jl) + pt  (ji,jj,jl)       &
474                     &                                                    -          zcu * ( pt  (ji+1,jj,jl) - pt  (ji,jj,jl) ) )   &
475                     &        + z1_6   * zdx2 * ( zcu*zcu - 1._wp ) *    (                   ztu2(ji+1,jj,jl) + ztu2(ji,jj,jl)       &
476                     &                                                    - 0.5_wp * zcu * ( ztu2(ji+1,jj,jl) - ztu2(ji,jj,jl) ) )   &
477                     &       + z1_120 * zdx4 * ( zcu*zcu - 1._wp ) * ( zcu*zcu - 4._wp ) * ( ztu4(ji+1,jj,jl) + ztu4(ji,jj,jl)       &
478                     &                                              - SIGN( 1._wp, zcu ) * ( ztu4(ji+1,jj,jl) - ztu4(ji,jj,jl) ) ) )
479               END DO
480            END DO
481         END DO
482         !
483      END SELECT
484      !
485   END SUBROUTINE ultimate_x
486   
487 
488   SUBROUTINE ultimate_y( k_order, ipl, pdt, pt, pvc, pt_v )
489      !!---------------------------------------------------------------------
490      !!                    ***  ROUTINE ultimate_y  ***
491      !!     
492      !! **  Purpose :   compute 
493      !!
494      !! **  Method  :   ... ???
495      !!                 TIM = transient interpolation Modeling
496      !!
497      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
498      !!----------------------------------------------------------------------
499      INTEGER                         , INTENT(in   ) ::   k_order   ! ocean time-step index
500      INTEGER                         , INTENT(in   ) ::   ipl       ! third dimension of tracer array
501      REAL(wp)                        , INTENT(in   ) ::   pdt       ! tracer time-step
502      REAL(wp), DIMENSION(jpi,jpj)    , INTENT(in   ) ::   pvc       ! ice j-velocity component
503      REAL(wp), DIMENSION(jpi,jpj,ipl), INTENT(in   ) ::   pt        ! tracer fields
504      REAL(wp), DIMENSION(jpi,jpj,ipl), INTENT(  out) ::   pt_v      ! tracer at v-point
505      !
506      INTEGER  ::   ji, jj, jl       ! dummy loop indices
507      REAL(wp) ::   zcv, zdy2, zdy4    !   -      -
508      REAL(wp), DIMENSION(jpi,jpj) :: ztv1, ztv3
509      REAL(wp), DIMENSION(jpi,jpj,ipl) :: ztv2, ztv4
510      !!----------------------------------------------------------------------
511      !
512      !                                                     !--  Laplacian in j-direction  --!
513      DO jl = 1, ipl
514         DO jj = 1, jpjm1         ! First derivative (gradient)
515            DO ji = fs_2, fs_jpim1
516               ztv1(ji,jj) = ( pt(ji,jj+1,jl) - pt(ji,jj,jl) ) * r1_e2v(ji,jj) * vmask(ji,jj,1)
517            END DO
518         END DO
519         DO jj = 2, jpjm1         ! Second derivative (Laplacian)
520            DO ji = fs_2, fs_jpim1
521               ztv2(ji,jj,jl) = ( ztv1(ji,jj) - ztv1(ji,jj-1) ) * r1_e2t(ji,jj)
522            END DO
523         END DO
524      END DO
525      CALL lbc_lnk( 'icedyn_adv_umx', ztv2, 'T', 1. )
526      !
527      !                                                     !--  BiLaplacian in j-direction  --!
528      DO jl = 1, ipl
529         DO jj = 1, jpjm1         ! First derivative
530            DO ji = fs_2, fs_jpim1
531            ztv3(ji,jj) = ( ztv2(ji,jj+1,jl) - ztv2(ji,jj,jl) ) * r1_e2v(ji,jj) * vmask(ji,jj,1)
532            END DO
533         END DO
534         DO jj = 2, jpjm1         ! Second derivative
535            DO ji = fs_2, fs_jpim1
536               ztv4(ji,jj,jl) = ( ztv3(ji,jj) - ztv3(ji,jj-1) ) * r1_e2t(ji,jj)
537            END DO
538         END DO
539      END DO
540      CALL lbc_lnk( 'icedyn_adv_umx', ztv4, 'T', 1. )
541      !
542      !
543      SELECT CASE (k_order )
544      !
545      CASE( 1 )                                                !==  1st order central TIM  ==! (Eq. 21)
546         DO jl = 1, ipl
547            DO jj = 1, jpjm1
548               DO ji = fs_2, fs_jpim1
549                  pt_v(ji,jj,jl) = 0.5_wp * vmask(ji,jj,1) * (                           ( pt(ji,jj+1,jl) + pt(ji,jj,jl) )  &
550                     &                                     - SIGN( 1._wp, pvc(ji,jj) ) * ( pt(ji,jj+1,jl) - pt(ji,jj,jl) ) )
551               END DO
552            END DO
553         END DO
554         !
555      CASE( 2 )                                                !==  2nd order central TIM  ==! (Eq. 23)
556         DO jl = 1, ipl
557            DO jj = 1, jpjm1
558               DO ji = fs_2, fs_jpim1
559                  zcv  = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
560                  pt_v(ji,jj,jl) = 0.5_wp * vmask(ji,jj,1) * (     ( pt(ji,jj+1,jl) + pt(ji,jj,jl) )  &
561                     &                                     - zcv * ( pt(ji,jj+1,jl) - pt(ji,jj,jl) ) )
562               END DO
563            END DO
564         END DO
565         CALL lbc_lnk( 'icedyn_adv_umx', pt_v, 'V',  1. )
566         !
567      CASE( 3 )                                                !==  3rd order central TIM  ==! (Eq. 24)
568         DO jl = 1, ipl
569            DO jj = 1, jpjm1
570               DO ji = fs_2, fs_jpim1
571                  zcv  = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
572                  zdy2 = e2v(ji,jj) * e2v(ji,jj)
573!!rachid       zdy2 = e2v(ji,jj) * e2t(ji,jj)
574                  pt_v(ji,jj,jl) = 0.5_wp * vmask(ji,jj,1) * (                              ( pt  (ji,jj+1,jl) + pt  (ji,jj,jl)       &
575                     &                                     -                        zcv   * ( pt  (ji,jj+1,jl) - pt  (ji,jj,jl) ) )   &
576                     &        + z1_6 * zdy2 * ( zcv*zcv - 1._wp ) * (                         ztv2(ji,jj+1,jl) + ztv2(ji,jj,jl)       &
577                     &                                               - SIGN( 1._wp, zcv ) * ( ztv2(ji,jj+1,jl) - ztv2(ji,jj,jl) ) ) )
578               END DO
579            END DO
580         END DO
581         !
582      CASE( 4 )                                                !==  4th order central TIM  ==! (Eq. 27)
583         DO jl = 1, ipl
584            DO jj = 1, jpjm1
585               DO ji = fs_2, fs_jpim1
586                  zcv  = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
587                  zdy2 = e2v(ji,jj) * e2v(ji,jj)
588!!rachid       zdy2 = e2v(ji,jj) * e2t(ji,jj)
589                  pt_v(ji,jj,jl) = 0.5_wp * vmask(ji,jj,1) * (                        ( pt  (ji,jj+1,jl) + pt  (ji,jj,jl)       &
590                     &                                               -          zcv * ( pt  (ji,jj+1,jl) - pt  (ji,jj,jl) ) )   &
591                     &        + z1_6 * zdy2 * ( zcv*zcv - 1._wp ) * (                   ztv2(ji,jj+1,jl) + ztv2(ji,jj,jl)       &
592                     &                                               - 0.5_wp * zcv * ( ztv2(ji,jj+1,jl) - ztv2(ji,jj,jl) ) ) )
593               END DO
594            END DO
595         END DO
596         !
597      CASE( 5 )                                                !==  5th order central TIM  ==! (Eq. 29)
598         DO jl = 1, ipl
599            DO jj = 1, jpjm1
600               DO ji = fs_2, fs_jpim1
601                  zcv  = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
602                  zdy2 = e2v(ji,jj) * e2v(ji,jj)
603!!rachid       zdy2 = e2v(ji,jj) * e2t(ji,jj)
604                  zdy4 = zdy2 * zdy2
605                  pt_v(ji,jj,jl) = 0.5_wp * vmask(ji,jj,1) * (                              ( pt  (ji,jj+1,jl) + pt  (ji,jj,jl)      &
606                     &                                                     -          zcv * ( pt  (ji,jj+1,jl) - pt  (ji,jj,jl) ) )  &
607                     &        + z1_6   * zdy2 * ( zcv*zcv - 1._wp ) *     (                   ztv2(ji,jj+1,jl) + ztv2(ji,jj,jl)      &
608                     &                                                     - 0.5_wp * zcv * ( ztv2(ji,jj+1,jl) - ztv2(ji,jj,jl) ) )  &
609                     &        + z1_120 * zdy4 * ( zcv*zcv - 1._wp ) * ( zcv*zcv - 4._wp ) * ( ztv4(ji,jj+1,jl) + ztv4(ji,jj,jl)      &
610                     &                                               - SIGN( 1._wp, zcv ) * ( ztv4(ji,jj+1,jl) - ztv4(ji,jj,jl) ) ) )
611               END DO
612            END DO
613         END DO
614         !
615      END SELECT
616      !
617   END SUBROUTINE ultimate_y
618   
619 
620   SUBROUTINE nonosc_2d( ipl, pbef, paa, pbb, paft, pdt )
621      !!---------------------------------------------------------------------
622      !!                    ***  ROUTINE nonosc  ***
623      !!     
624      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
625      !!       scheme and the before field by a nonoscillatory algorithm
626      !!
627      !! **  Method  :   ... ???
628      !!       warning : pbef and paft must be masked, but the boundaries
629      !!       conditions on the fluxes are not necessary zalezak (1979)
630      !!       drange (1995) multi-dimensional forward-in-time and upstream-
631      !!       in-space based differencing for fluid
632      !!----------------------------------------------------------------------
633      INTEGER                          , INTENT(in   ) ::   ipl          ! third dimension of tracer array
634      REAL(wp)                         , INTENT(in   ) ::   pdt          ! tracer time-step
635      REAL(wp), DIMENSION (jpi,jpj,ipl), INTENT(in   ) ::   pbef, paft   ! before & after field
636      REAL(wp), DIMENSION (jpi,jpj,ipl), INTENT(inout) ::   paa, pbb     ! monotonic fluxes in the 2 directions
637      !
638      INTEGER  ::   ji, jj, jl    ! dummy loop indices
639      INTEGER  ::   ikm1      ! local integer
640      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zsml, z1_dt   ! local scalars
641      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
642      REAL(wp), DIMENSION(jpi,jpj) :: zbup, zbdo, zmsk
643      REAL(wp), DIMENSION(jpi,jpj,ipl) :: zbetup, zbetdo, zdiv
644      !!----------------------------------------------------------------------
645      !
646      zbig = 1.e+40_wp
647      zsml = 1.e-15_wp
648
649      ! test on divergence
650      DO jl = 1, ipl
651         DO jj = 2, jpjm1
652            DO ji = fs_2, fs_jpim1   ! vector opt. 
653               zdiv(ji,jj,jl) =  - (  paa(ji,jj,jl) - paa(ji-1,jj  ,jl)   &
654                  &              +    pbb(ji,jj,jl) - pbb(ji  ,jj-1,jl) ) 
655            END DO
656         END DO
657      END DO
658      CALL lbc_lnk( 'icedyn_adv_umx', zdiv, 'T', 1. )        ! Lateral boundary conditions   (unchanged sign)
659
660      DO jl = 1, ipl
661         ! Determine ice masks for before and after tracers
662         WHERE( pbef(:,:,jl) == 0._wp .AND. paft(:,:,jl) == 0._wp .AND. zdiv(:,:,jl) == 0._wp ) 
663            zmsk(:,:) = 0._wp
664         ELSEWHERE                                                                                   
665            zmsk(:,:) = 1._wp * tmask(:,:,1)
666         END WHERE
667
668         ! Search local extrema
669         ! --------------------
670         ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
671!         zbup(:,:) = MAX( pbef(:,:) * tmask(:,:,1) - zbig * ( 1.e0 - tmask(:,:,1) ),   &
672!            &             paft(:,:) * tmask(:,:,1) - zbig * ( 1.e0 - tmask(:,:,1) )  )
673!         zbdo(:,:) = MIN( pbef(:,:) * tmask(:,:,1) + zbig * ( 1.e0 - tmask(:,:,1) ),   &
674!            &             paft(:,:) * tmask(:,:,1) + zbig * ( 1.e0 - tmask(:,:,1) )  )
675         zbup(:,:) = MAX( pbef(:,:,jl) * zmsk(:,:) - zbig * ( 1.e0 - zmsk(:,:) ),   &
676            &             paft(:,:,jl) * zmsk(:,:) - zbig * ( 1.e0 - zmsk(:,:) )  )
677         zbdo(:,:) = MIN( pbef(:,:,jl) * zmsk(:,:) + zbig * ( 1.e0 - zmsk(:,:) ),   &
678            &             paft(:,:,jl) * zmsk(:,:) + zbig * ( 1.e0 - zmsk(:,:) )  )
679
680      z1_dt = 1._wp / pdt
681      DO jj = 2, jpjm1
682         DO ji = fs_2, fs_jpim1   ! vector opt.
683            !
684            zup  = MAX(   zbup(ji,jj), zbup(ji-1,jj  ), zbup(ji+1,jj  ),   &        ! search max/min in neighbourhood
685               &                       zbup(ji  ,jj-1), zbup(ji  ,jj+1)    )
686            zdo  = MIN(   zbdo(ji,jj), zbdo(ji-1,jj  ), zbdo(ji+1,jj  ),   &
687               &                       zbdo(ji  ,jj-1), zbdo(ji  ,jj+1)    )
688               !
689               zpos = MAX( 0., paa(ji-1,jj  ,jl) ) - MIN( 0., paa(ji  ,jj  ,jl) )   &        ! positive/negative  part of the flux
690                  & + MAX( 0., pbb(ji  ,jj-1,jl) ) - MIN( 0., pbb(ji  ,jj  ,jl) )
691               zneg = MAX( 0., paa(ji  ,jj  ,jl) ) - MIN( 0., paa(ji-1,jj  ,jl) )   &
692                  & + MAX( 0., pbb(ji  ,jj  ,jl) ) - MIN( 0., pbb(ji  ,jj-1,jl) )
693               !
694               zbt = e1e2t(ji,jj) * z1_dt                                   ! up & down beta terms
695               zbetup(ji,jj,jl) = ( zup            - paft(ji,jj,jl) ) / ( zpos + zsml ) * zbt
696               zbetdo(ji,jj,jl) = ( paft(ji,jj,jl) - zdo         )    / ( zneg + zsml ) * zbt
697            END DO
698         END DO
699      END DO
700      CALL lbc_lnk_multi( 'icedyn_adv_umx', zbetup, 'T', 1., zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
701
702      DO jl = 1, ipl
703         ! monotonic flux in the i & j direction (paa & pbb)
704         ! -------------------------------------
705         DO jj = 2, jpjm1
706            DO ji = 1, fs_jpim1   ! vector opt.
707               zau = MIN( 1._wp , zbetdo(ji,jj,jl) , zbetup(ji+1,jj,jl) )
708               zbu = MIN( 1._wp , zbetup(ji,jj,jl) , zbetdo(ji+1,jj,jl) )
709               zcu = 0.5  + SIGN( 0.5 , paa(ji,jj,jl) )
710               !
711               paa(ji,jj,jl) = paa(ji,jj,jl) * ( zcu * zau + ( 1._wp - zcu) * zbu )
712            END DO
713         END DO
714         !
715         DO jj = 1, jpjm1
716            DO ji = fs_2, fs_jpim1   ! vector opt.
717               zav = MIN( 1._wp , zbetdo(ji,jj,jl) , zbetup(ji,jj+1,jl) )
718               zbv = MIN( 1._wp , zbetup(ji,jj,jl) , zbetdo(ji,jj+1,jl) )
719               zcv = 0.5  + SIGN( 0.5 , pbb(ji,jj,jl) )
720               !
721               pbb(ji,jj,jl) = pbb(ji,jj,jl) * ( zcv * zav + ( 1._wp - zcv) * zbv )
722            END DO
723         END DO
724      END DO
725      !
726   END SUBROUTINE nonosc_2d
727
728#else
729   !!----------------------------------------------------------------------
730   !!   Default option           Dummy module         NO SI3 sea-ice model
731   !!----------------------------------------------------------------------
732#endif
733
734   !!======================================================================
735END MODULE icedyn_adv_umx
Note: See TracBrowser for help on using the repository browser.