New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icethd.F90 in NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/ICE – NEMO

source: NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/ICE/icethd.F90 @ 10410

Last change on this file since 10410 was 10180, checked in by smasson, 5 years ago

dev_r10164_HPC09_ESIWACE_PREP_MERGE: action 4b: reduce communications in si3, see #2133

  • Property svn:keywords set to Id
File size: 34.2 KB
Line 
1MODULE icethd
2   !!======================================================================
3   !!                  ***  MODULE icethd   ***
4   !!   sea-ice : master routine for thermodynamics
5   !!======================================================================
6   !! History :  1.0  !  2000-01  (M.A. Morales Maqueda, H. Goosse, T. Fichefet) original code 1D
7   !!            4.0  !  2018     (many people)       SI3 [aka Sea Ice cube]
8   !!----------------------------------------------------------------------
9#if defined key_si3
10   !!----------------------------------------------------------------------
11   !!   'key_si3'                                       SI3 sea-ice model
12   !!----------------------------------------------------------------------
13   !!   ice_thd       : thermodynamics of sea ice
14   !!   ice_thd_init  : initialisation of sea-ice thermodynamics
15   !!----------------------------------------------------------------------
16   USE phycst         ! physical constants
17   USE dom_oce        ! ocean space and time domain variables
18   USE ice            ! sea-ice: variables
19!!gm list trop longue ==>>> why not passage en argument d'appel ?
20   USE sbc_oce , ONLY : sss_m, sst_m, e3t_m, utau, vtau, ssu_m, ssv_m, frq_m, qns_tot, qsr_tot, sprecip, ln_cpl
21   USE sbc_ice , ONLY : qsr_oce, qns_oce, qemp_oce, qsr_ice, qns_ice, dqns_ice, evap_ice, qprec_ice, qevap_ice, &
22      &                 qml_ice, qcn_ice, qtr_ice_top
23   USE ice1D          ! sea-ice: thermodynamics variables
24   USE icethd_zdf     ! sea-ice: vertical heat diffusion
25   USE icethd_dh      ! sea-ice: ice-snow growth and melt
26   USE icethd_da      ! sea-ice: lateral melting
27   USE icethd_sal     ! sea-ice: salinity
28   USE icethd_ent     ! sea-ice: enthalpy redistribution
29   USE icethd_do      ! sea-ice: growth in open water
30   USE icethd_pnd     ! sea-ice: melt ponds
31   USE iceitd         ! sea-ice: remapping thickness distribution
32   USE icetab         ! sea-ice: 1D <==> 2D transformation
33   USE icevar         ! sea-ice: operations
34   USE icectl         ! sea-ice: control print
35   !
36   USE in_out_manager ! I/O manager
37   USE lib_mpp        ! MPP library
38   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
39   USE lbclnk         ! lateral boundary conditions (or mpp links)
40   USE timing         ! Timing
41
42   IMPLICIT NONE
43   PRIVATE
44
45   PUBLIC   ice_thd         ! called by limstp module
46   PUBLIC   ice_thd_init    ! called by ice_init
47
48   !!** namelist (namthd) **
49   LOGICAL ::   ln_icedH         ! activate ice thickness change from growing/melting (T) or not (F)
50   LOGICAL ::   ln_icedA         ! activate lateral melting param. (T) or not (F)
51   LOGICAL ::   ln_icedO         ! activate ice growth in open-water (T) or not (F)
52   LOGICAL ::   ln_icedS         ! activate gravity drainage and flushing (T) or not (F)
53
54   !! * Substitutions
55#  include "vectopt_loop_substitute.h90"
56   !!----------------------------------------------------------------------
57   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
58   !! $Id$
59   !! Software governed by the CeCILL license (see ./LICENSE)
60   !!----------------------------------------------------------------------
61CONTAINS
62
63   SUBROUTINE ice_thd( kt )
64      !!-------------------------------------------------------------------
65      !!                ***  ROUTINE ice_thd  ***       
66      !! 
67      !! ** Purpose : This routine manages ice thermodynamics
68      !!         
69      !! ** Action : - computation of oceanic sensible heat flux at the ice base
70      !!                              energy budget in the leads
71      !!                              net fluxes on top of ice and of ocean
72      !!             - selection of grid cells with ice
73      !!                - call ice_thd_zdf  for vertical heat diffusion
74      !!                - call ice_thd_dh   for vertical ice growth and melt
75      !!                - call ice_thd_pnd  for melt ponds
76      !!                - call ice_thd_ent  for enthalpy remapping
77      !!                - call ice_thd_sal  for ice desalination
78      !!                - call ice_thd_temp to  retrieve temperature from ice enthalpy
79      !!                - call ice_thd_mono for extra lateral ice melt if active virtual thickness distribution
80      !!                - call ice_thd_da   for lateral ice melt
81      !!             - back to the geographic grid
82      !!                - call ice_thd_rem  for remapping thickness distribution
83      !!                - call ice_thd_do   for ice growth in leads
84      !!-------------------------------------------------------------------
85      INTEGER, INTENT(in) :: kt    ! number of iteration
86      !
87      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
88      REAL(wp) :: zfric_u, zqld, zqfr, zqfr_neg
89      REAL(wp), PARAMETER :: zfric_umin = 0._wp           ! lower bound for the friction velocity (cice value=5.e-04)
90      REAL(wp), PARAMETER :: zch        = 0.0057_wp       ! heat transfer coefficient
91      REAL(wp), DIMENSION(jpi,jpj) ::   zu_io, zv_io, zfric   ! ice-ocean velocity (m/s) and frictional velocity (m2/s2)
92      !
93      !!-------------------------------------------------------------------
94      ! controls
95      IF( ln_timing    )   CALL timing_start('icethd')                                                             ! timing
96      IF( ln_icediachk )   CALL ice_cons_hsm(0, 'icethd', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft) ! conservation
97
98      IF( kt == nit000 .AND. lwp ) THEN
99         WRITE(numout,*)
100         WRITE(numout,*) 'ice_thd: sea-ice thermodynamics'
101         WRITE(numout,*) '~~~~~~~'
102      ENDIF
103     
104      CALL ice_var_glo2eqv
105
106      !---------------------------------------------!
107      ! computation of friction velocity at T points
108      !---------------------------------------------!
109      IF( ln_icedyn ) THEN
110         zu_io(:,:) = u_ice(:,:) - ssu_m(:,:)
111         zv_io(:,:) = v_ice(:,:) - ssv_m(:,:)
112         DO jj = 2, jpjm1 
113            DO ji = fs_2, fs_jpim1
114               zfric(ji,jj) = rn_cio * ( 0.5_wp *  &
115                  &                    (  zu_io(ji,jj) * zu_io(ji,jj) + zu_io(ji-1,jj) * zu_io(ji-1,jj)   &
116                  &                     + zv_io(ji,jj) * zv_io(ji,jj) + zv_io(ji,jj-1) * zv_io(ji,jj-1) ) ) * tmask(ji,jj,1)
117            END DO
118         END DO
119      ELSE      !  if no ice dynamics => transmit directly the atmospheric stress to the ocean
120         DO jj = 2, jpjm1
121            DO ji = fs_2, fs_jpim1
122               zfric(ji,jj) = r1_rau0 * SQRT( 0.5_wp *  &
123                  &                         (  utau(ji,jj) * utau(ji,jj) + utau(ji-1,jj) * utau(ji-1,jj)   &
124                  &                          + vtau(ji,jj) * vtau(ji,jj) + vtau(ji,jj-1) * vtau(ji,jj-1) ) ) * tmask(ji,jj,1)
125            END DO
126         END DO
127      ENDIF
128      CALL lbc_lnk( 'icethd', zfric, 'T',  1. )
129      !
130      !--------------------------------------------------------------------!
131      ! Partial computation of forcing for the thermodynamic sea ice model
132      !--------------------------------------------------------------------!
133      DO jj = 1, jpj
134         DO ji = 1, jpi
135            rswitch  = tmask(ji,jj,1) * MAX( 0._wp , SIGN( 1._wp , at_i(ji,jj) - epsi10 ) ) ! 0 if no ice
136            !
137            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
138            !           !  practically no "direct lateral ablation"
139            !           
140            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
141            !           !  temperature and turbulent mixing (McPhee, 1992)
142            !
143            ! --- Energy received in the lead from atm-oce exchanges, zqld is defined everywhere (J.m-2) --- !
144            zqld =  tmask(ji,jj,1) * rdt_ice *  &
145               &    ( ( 1._wp - at_i_b(ji,jj) ) * qsr_oce(ji,jj) * frq_m(ji,jj) +  &
146               &      ( 1._wp - at_i_b(ji,jj) ) * qns_oce(ji,jj) + qemp_oce(ji,jj) )
147
148            ! --- Energy needed to bring ocean surface layer until its freezing (mostly<0 but >0 if supercooling, J.m-2) --- !
149            zqfr     = rau0 * rcp * e3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) ) * tmask(ji,jj,1)  ! both < 0 (t_bo < sst) and > 0 (t_bo > sst)
150            zqfr_neg = MIN( zqfr , 0._wp )                                                                    ! only < 0
151
152            ! --- Sensible ocean-to-ice heat flux (mostly>0 but <0 if supercooling, W/m2)
153            zfric_u            = MAX( SQRT( zfric(ji,jj) ), zfric_umin ) 
154            qsb_ice_bot(ji,jj) = rswitch * rau0 * rcp * zch  * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) ) ! W.m-2
155
156            qsb_ice_bot(ji,jj) = rswitch * MIN( qsb_ice_bot(ji,jj), - zqfr_neg * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
157            ! upper bound for qsb_ice_bot: the heat retrieved from the ocean must be smaller than the heat necessary to reach
158            !                              the freezing point, so that we do not have SST < T_freeze
159            !                              This implies: - ( qsb_ice_bot(ji,jj) * at_i(ji,jj) * rtdice ) - zqfr >= 0
160
161            !-- Energy Budget of the leads (J.m-2), source of ice growth in open water. Must be < 0 to form ice
162            qlead(ji,jj) = MIN( 0._wp , zqld - ( qsb_ice_bot(ji,jj) * at_i(ji,jj) * rdt_ice ) - zqfr )
163
164            ! If there is ice and leads are warming, then transfer energy from the lead budget and use it for bottom melting
165            IF( zqld > 0._wp ) THEN
166               fhld (ji,jj) = rswitch * zqld * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) ! divided by at_i since this is (re)multiplied by a_i in icethd_dh.F90
167               qlead(ji,jj) = 0._wp
168            ELSE
169               fhld (ji,jj) = 0._wp
170            ENDIF
171            !
172            ! Net heat flux on top of the ice-ocean [W.m-2]
173            ! ---------------------------------------------
174            qt_atm_oi(ji,jj) = qns_tot(ji,jj) + qsr_tot(ji,jj) 
175         END DO
176      END DO
177     
178      ! In case we bypass open-water ice formation
179      IF( .NOT. ln_icedO )  qlead(:,:) = 0._wp
180      ! In case we bypass growing/melting from top and bottom: we suppose ice is impermeable => ocean is isolated from atmosphere
181      IF( .NOT. ln_icedH ) THEN
182         qt_atm_oi  (:,:) = ( 1._wp - at_i_b(:,:) ) * ( qns_oce(:,:) + qsr_oce(:,:) ) + qemp_oce(:,:)
183         qsb_ice_bot(:,:) = 0._wp
184         fhld       (:,:) = 0._wp
185      ENDIF
186
187      ! ---------------------------------------------------------------------
188      ! Net heat flux on top of the ocean after ice thermo (1st step) [W.m-2]
189      ! ---------------------------------------------------------------------
190      !     First  step here              :  non solar + precip - qlead - qsensible
191      !     Second step in icethd_dh      :  heat remaining if total melt (zq_rema)
192      !     Third  step in iceupdate.F90  :  heat from ice-ocean mass exchange (zf_mass) + solar
193      qt_oce_ai(:,:) = ( 1._wp - at_i_b(:,:) ) * qns_oce(:,:) + qemp_oce(:,:)  &  ! Non solar heat flux received by the ocean               
194         &             - qlead(:,:) * r1_rdtice                                &  ! heat flux taken from the ocean where there is open water ice formation
195         &             - at_i (:,:) * qsb_ice_bot(:,:)                         &  ! heat flux taken by sensible flux
196         &             - at_i (:,:) * fhld       (:,:)                            ! heat flux taken during bottom growth/melt
197      !                                                                           !    (fhld should be 0 while bott growth)
198      !-------------------------------------------------------------------------------------------!
199      ! Thermodynamic computation (only on grid points covered by ice) => loop over ice categories
200      !-------------------------------------------------------------------------------------------!
201      DO jl = 1, jpl
202
203         ! select ice covered grid points
204         npti = 0 ; nptidx(:) = 0
205         DO jj = 1, jpj
206            DO ji = 1, jpi
207               IF ( a_i(ji,jj,jl) > epsi10 ) THEN     
208                  npti         = npti  + 1
209                  nptidx(npti) = (jj - 1) * jpi + ji
210               ENDIF
211            END DO
212         END DO
213
214         IF( npti > 0 ) THEN  ! If there is no ice, do nothing.
215            !                                                               
216                              CALL ice_thd_1d2d( jl, 1 )            ! --- Move to 1D arrays --- !
217            !                                                       ! --- & Change units of e_i, e_s from J/m2 to J/m3 --- !
218            !
219            s_i_new   (1:npti) = 0._wp ; dh_s_tot(1:npti) = 0._wp  ! --- some init --- !  (important to have them here)
220            dh_i_sum  (1:npti) = 0._wp ; dh_i_bom(1:npti) = 0._wp ; dh_i_itm  (1:npti) = 0._wp 
221            dh_i_sub  (1:npti) = 0._wp ; dh_i_bog(1:npti) = 0._wp
222            dh_snowice(1:npti) = 0._wp ; dh_s_mlt(1:npti) = 0._wp
223            !
224            IF( ln_icedH ) THEN                                     ! --- growing/melting --- !
225                              CALL ice_thd_zdf                             ! Ice/Snow Temperature profile
226                              CALL ice_thd_dh                              ! Ice/Snow thickness   
227                              CALL ice_thd_pnd                             ! Melt ponds formation
228                              CALL ice_thd_ent( e_i_1d(1:npti,:) )         ! Ice enthalpy remapping
229            ENDIF
230            !
231                              CALL ice_thd_sal( ln_icedS )          ! --- Ice salinity --- !   
232            !
233                              CALL ice_thd_temp                     ! --- temperature update --- !
234            !
235!!gm please create a new logical (l_thd_mono or a better explicit name) set one for all in icestp.F90 module
236!!gm        l_thd_mono = ln_icedH .AND. ( ( nn_virtual_itd == 1 .OR. nn_virtual_itd == 4 ) .AND. jpl == 1 )
237!!gm        by the way, the different options associated with nn_virtual_itd =1 to 4  are quite impossible to identify
238!!gm        more comment to add when ready the namelist, with an explicit print in the ocean.output
239            IF( ln_icedH ) THEN
240               IF ( ( nn_virtual_itd == 1 .OR. nn_virtual_itd == 3 ) .AND. jpl == 1 ) THEN
241                              CALL ice_thd_mono                      ! --- extra lateral melting if virtual_itd --- !
242               END IF
243            END IF
244            !
245            IF( ln_icedA )    CALL ice_thd_da                       ! --- lateral melting --- !
246            !
247                              CALL ice_thd_1d2d( jl, 2 )            ! --- Change units of e_i, e_s from J/m3 to J/m2 --- !
248            !                                                       ! --- & Move to 2D arrays --- !
249            !
250         ENDIF
251         !
252      END DO
253      ! update ice age (in case a_i changed, i.e. becomes 0 or lateral melting)
254      oa_i(:,:,:) = o_i(:,:,:) * a_i(:,:,:)
255
256      IF( ln_icediachk )   CALL ice_cons_hsm(1, 'icethd', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft)
257      !
258                           CALL ice_var_zapsmall           ! --- remove very small ice concentration (<1e-10) --- !
259      !                                                    !     & make sure at_i=SUM(a_i) & ato_i=1 where at_i=0
260      !                   
261      IF( jpl > 1      )   CALL ice_itd_rem( kt )          ! --- Transport ice between thickness categories --- !
262      !
263      IF( ln_icedO     )   CALL ice_thd_do                 ! --- frazil ice growing in leads --- !
264      !
265      ! controls
266      IF( ln_icectl )   CALL ice_prt    (kt, iiceprt, jiceprt, 1, ' - ice thermodyn. - ') ! prints
267      IF( ln_ctl    )   CALL ice_prt3D  ('icethd')                                        ! prints
268      IF( ln_timing )   CALL timing_stop('icethd')                                        ! timing
269      !
270   END SUBROUTINE ice_thd 
271
272 
273   SUBROUTINE ice_thd_temp
274      !!-----------------------------------------------------------------------
275      !!                   ***  ROUTINE ice_thd_temp ***
276      !!                 
277      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
278      !!
279      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
280      !!-------------------------------------------------------------------
281      INTEGER  ::   ji, jk   ! dummy loop indices
282      REAL(wp) ::   ztmelts, zbbb, zccc  ! local scalar
283      !!-------------------------------------------------------------------
284      ! Recover ice temperature
285      DO jk = 1, nlay_i
286         DO ji = 1, npti
287            ztmelts       = -rTmlt * sz_i_1d(ji,jk)
288            ! Conversion q(S,T) -> T (second order equation)
289            zbbb          = ( rcp - rcpi ) * ztmelts + e_i_1d(ji,jk) * r1_rhoi - rLfus
290            zccc          = SQRT( MAX( zbbb * zbbb - 4._wp * rcpi * rLfus * ztmelts, 0._wp ) )
291            t_i_1d(ji,jk) = rt0 - ( zbbb + zccc ) * 0.5_wp * r1_rcpi
292           
293            ! mask temperature
294            rswitch       = 1._wp - MAX( 0._wp , SIGN( 1._wp , - h_i_1d(ji) ) ) 
295            t_i_1d(ji,jk) = rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rt0
296         END DO
297      END DO 
298      !
299   END SUBROUTINE ice_thd_temp
300
301
302   SUBROUTINE ice_thd_mono
303      !!-----------------------------------------------------------------------
304      !!                   ***  ROUTINE ice_thd_mono ***
305      !!                 
306      !! ** Purpose :   Lateral melting in case virtual_itd
307      !!                          ( dA = A/2h dh )
308      !!-----------------------------------------------------------------------
309      INTEGER  ::   ji                 ! dummy loop indices
310      REAL(wp) ::   zhi_bef            ! ice thickness before thermo
311      REAL(wp) ::   zdh_mel, zda_mel   ! net melting
312      REAL(wp) ::   zvi, zvs           ! ice/snow volumes
313      !!-----------------------------------------------------------------------
314      !
315      DO ji = 1, npti
316         zdh_mel = MIN( 0._wp, dh_i_itm(ji) + dh_i_sum(ji) + dh_i_bom(ji) + dh_snowice(ji) + dh_i_sub(ji) )
317         IF( zdh_mel < 0._wp .AND. a_i_1d(ji) > 0._wp )  THEN
318            zvi          = a_i_1d(ji) * h_i_1d(ji)
319            zvs          = a_i_1d(ji) * h_s_1d(ji)
320            ! lateral melting = concentration change
321            zhi_bef     = h_i_1d(ji) - zdh_mel
322            rswitch     = MAX( 0._wp , SIGN( 1._wp , zhi_bef - epsi20 ) )
323            zda_mel     = rswitch * a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi20 ) )
324            a_i_1d(ji)  = MAX( epsi20, a_i_1d(ji) + zda_mel ) 
325            ! adjust thickness
326            h_i_1d(ji) = zvi / a_i_1d(ji)           
327            h_s_1d(ji) = zvs / a_i_1d(ji)           
328            ! retrieve total concentration
329            at_i_1d(ji) = a_i_1d(ji)
330         END IF
331      END DO
332      !
333   END SUBROUTINE ice_thd_mono
334
335
336   SUBROUTINE ice_thd_1d2d( kl, kn )
337      !!-----------------------------------------------------------------------
338      !!                   ***  ROUTINE ice_thd_1d2d ***
339      !!                 
340      !! ** Purpose :   move arrays from 1d to 2d and the reverse
341      !!-----------------------------------------------------------------------
342      INTEGER, INTENT(in) ::   kl   ! index of the ice category
343      INTEGER, INTENT(in) ::   kn   ! 1= from 2D to 1D   ;   2= from 1D to 2D
344      !
345      INTEGER ::   jk   ! dummy loop indices
346      !!-----------------------------------------------------------------------
347      !
348      SELECT CASE( kn )
349      !                    !---------------------!
350      CASE( 1 )            !==  from 2D to 1D  ==!
351         !                 !---------------------!
352         CALL tab_2d_1d( npti, nptidx(1:npti), at_i_1d(1:npti), at_i             )
353         CALL tab_2d_1d( npti, nptidx(1:npti), a_i_1d (1:npti), a_i (:,:,kl)     )
354         CALL tab_2d_1d( npti, nptidx(1:npti), h_i_1d (1:npti), h_i (:,:,kl)     )
355         CALL tab_2d_1d( npti, nptidx(1:npti), h_s_1d (1:npti), h_s (:,:,kl)     )
356         CALL tab_2d_1d( npti, nptidx(1:npti), t_su_1d(1:npti), t_su(:,:,kl)     )
357         CALL tab_2d_1d( npti, nptidx(1:npti), s_i_1d (1:npti), s_i (:,:,kl)     )
358         DO jk = 1, nlay_s
359            CALL tab_2d_1d( npti, nptidx(1:npti), t_s_1d(1:npti,jk), t_s(:,:,jk,kl)    )
360            CALL tab_2d_1d( npti, nptidx(1:npti), e_s_1d(1:npti,jk), e_s(:,:,jk,kl)    )
361         END DO
362         DO jk = 1, nlay_i
363            CALL tab_2d_1d( npti, nptidx(1:npti), t_i_1d (1:npti,jk), t_i (:,:,jk,kl)  )
364            CALL tab_2d_1d( npti, nptidx(1:npti), e_i_1d (1:npti,jk), e_i (:,:,jk,kl)  )
365            CALL tab_2d_1d( npti, nptidx(1:npti), sz_i_1d(1:npti,jk), sz_i(:,:,jk,kl)  )
366         END DO
367         CALL tab_2d_1d( npti, nptidx(1:npti), a_ip_1d     (1:npti), a_ip     (:,:,kl) )
368         CALL tab_2d_1d( npti, nptidx(1:npti), h_ip_1d     (1:npti), h_ip     (:,:,kl) )
369         CALL tab_2d_1d( npti, nptidx(1:npti), a_ip_frac_1d(1:npti), a_ip_frac(:,:,kl) )
370         !
371         CALL tab_2d_1d( npti, nptidx(1:npti), qprec_ice_1d  (1:npti), qprec_ice            )
372         CALL tab_2d_1d( npti, nptidx(1:npti), qsr_ice_1d    (1:npti), qsr_ice (:,:,kl)     )
373         CALL tab_2d_1d( npti, nptidx(1:npti), qns_ice_1d    (1:npti), qns_ice (:,:,kl)     )
374         CALL tab_2d_1d( npti, nptidx(1:npti), evap_ice_1d   (1:npti), evap_ice(:,:,kl)     )
375         CALL tab_2d_1d( npti, nptidx(1:npti), dqns_ice_1d   (1:npti), dqns_ice(:,:,kl)     )
376         CALL tab_2d_1d( npti, nptidx(1:npti), t_bo_1d       (1:npti), t_bo                 )
377         CALL tab_2d_1d( npti, nptidx(1:npti), sprecip_1d    (1:npti), sprecip              ) 
378         CALL tab_2d_1d( npti, nptidx(1:npti), qsb_ice_bot_1d(1:npti), qsb_ice_bot          )
379         CALL tab_2d_1d( npti, nptidx(1:npti), fhld_1d       (1:npti), fhld                 )
380         
381         CALL tab_2d_1d( npti, nptidx(1:npti), qml_ice_1d    (1:npti), qml_ice    (:,:,kl) )
382         CALL tab_2d_1d( npti, nptidx(1:npti), qcn_ice_1d    (1:npti), qcn_ice    (:,:,kl) )
383         CALL tab_2d_1d( npti, nptidx(1:npti), qtr_ice_top_1d(1:npti), qtr_ice_top(:,:,kl) )
384         !
385         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_snw_sni_1d(1:npti), wfx_snw_sni   )
386         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_snw_sum_1d(1:npti), wfx_snw_sum   )
387         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_sub_1d    (1:npti), wfx_sub       )
388         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_snw_sub_1d(1:npti), wfx_snw_sub   )
389         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_ice_sub_1d(1:npti), wfx_ice_sub   )
390         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_err_sub_1d(1:npti), wfx_err_sub   )
391         !
392         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_bog_1d (1:npti), wfx_bog          )
393         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_bom_1d (1:npti), wfx_bom          )
394         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_sum_1d (1:npti), wfx_sum          )
395         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_sni_1d (1:npti), wfx_sni          )
396         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_res_1d (1:npti), wfx_res          )
397         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_spr_1d (1:npti), wfx_spr          )
398         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_lam_1d (1:npti), wfx_lam          )
399         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_pnd_1d (1:npti), wfx_pnd          )
400         !
401         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_bog_1d (1:npti), sfx_bog          )
402         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_bom_1d (1:npti), sfx_bom          )
403         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_sum_1d (1:npti), sfx_sum          )
404         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_sni_1d (1:npti), sfx_sni          )
405         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_bri_1d (1:npti), sfx_bri          )
406         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_res_1d (1:npti), sfx_res          )
407         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_sub_1d (1:npti), sfx_sub          )
408         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_lam_1d (1:npti), sfx_lam          )
409         !
410         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_thd_1d    (1:npti), hfx_thd       )
411         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_spr_1d    (1:npti), hfx_spr       )
412         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_sum_1d    (1:npti), hfx_sum       )
413         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_bom_1d    (1:npti), hfx_bom       )
414         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_bog_1d    (1:npti), hfx_bog       )
415         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_dif_1d    (1:npti), hfx_dif       )
416         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_opw_1d    (1:npti), hfx_opw       )
417         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_snw_1d    (1:npti), hfx_snw       )
418         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_sub_1d    (1:npti), hfx_sub       )
419         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_res_1d    (1:npti), hfx_res       )
420         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_err_dif_1d(1:npti), hfx_err_dif   )
421         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_err_rem_1d(1:npti), hfx_err_rem   )
422         CALL tab_2d_1d( npti, nptidx(1:npti), qt_oce_ai_1d  (1:npti), qt_oce_ai     )
423         !
424         ! ocean surface fields
425         CALL tab_2d_1d( npti, nptidx(1:npti), sst_1d(1:npti), sst_m )
426         CALL tab_2d_1d( npti, nptidx(1:npti), sss_1d(1:npti), sss_m )
427
428         ! --- Change units of e_i, e_s from J/m2 to J/m3 --- !
429         DO jk = 1, nlay_i
430            WHERE( h_i_1d(1:npti)>0._wp ) e_i_1d(1:npti,jk) = e_i_1d(1:npti,jk) / (h_i_1d(1:npti) * a_i_1d(1:npti)) * nlay_i
431         END DO
432         DO jk = 1, nlay_s
433            WHERE( h_s_1d(1:npti)>0._wp ) e_s_1d(1:npti,jk) = e_s_1d(1:npti,jk) / (h_s_1d(1:npti) * a_i_1d(1:npti)) * nlay_s
434         END DO
435         !
436         !                 !---------------------!
437      CASE( 2 )            !==  from 1D to 2D  ==!
438         !                 !---------------------!
439         ! --- Change units of e_i, e_s from J/m3 to J/m2 --- !
440         DO jk = 1, nlay_i
441            e_i_1d(1:npti,jk) = e_i_1d(1:npti,jk) * h_i_1d(1:npti) * a_i_1d(1:npti) * r1_nlay_i
442         END DO
443         DO jk = 1, nlay_s
444            e_s_1d(1:npti,jk) = e_s_1d(1:npti,jk) * h_s_1d(1:npti) * a_i_1d(1:npti) * r1_nlay_s
445         END DO
446         !
447         ! Change thickness to volume (replaces routine ice_var_eqv2glo)
448         v_i_1d (1:npti) = h_i_1d (1:npti) * a_i_1d (1:npti)
449         v_s_1d (1:npti) = h_s_1d (1:npti) * a_i_1d (1:npti)
450         sv_i_1d(1:npti) = s_i_1d (1:npti) * v_i_1d (1:npti)
451         v_ip_1d(1:npti) = h_ip_1d(1:npti) * a_ip_1d(1:npti)
452         
453         CALL tab_1d_2d( npti, nptidx(1:npti), at_i_1d(1:npti), at_i             )
454         CALL tab_1d_2d( npti, nptidx(1:npti), a_i_1d (1:npti), a_i (:,:,kl)     )
455         CALL tab_1d_2d( npti, nptidx(1:npti), h_i_1d (1:npti), h_i (:,:,kl)     )
456         CALL tab_1d_2d( npti, nptidx(1:npti), h_s_1d (1:npti), h_s (:,:,kl)     )
457         CALL tab_1d_2d( npti, nptidx(1:npti), t_su_1d(1:npti), t_su(:,:,kl)     )
458         CALL tab_1d_2d( npti, nptidx(1:npti), s_i_1d (1:npti), s_i (:,:,kl)     )
459         DO jk = 1, nlay_s
460            CALL tab_1d_2d( npti, nptidx(1:npti), t_s_1d(1:npti,jk), t_s(:,:,jk,kl)    )
461            CALL tab_1d_2d( npti, nptidx(1:npti), e_s_1d(1:npti,jk), e_s(:,:,jk,kl)    )
462         END DO
463         DO jk = 1, nlay_i
464            CALL tab_1d_2d( npti, nptidx(1:npti), t_i_1d (1:npti,jk), t_i (:,:,jk,kl)  )
465            CALL tab_1d_2d( npti, nptidx(1:npti), e_i_1d (1:npti,jk), e_i (:,:,jk,kl)  )
466            CALL tab_1d_2d( npti, nptidx(1:npti), sz_i_1d(1:npti,jk), sz_i(:,:,jk,kl)  )
467         END DO
468         CALL tab_1d_2d( npti, nptidx(1:npti), a_ip_1d     (1:npti), a_ip     (:,:,kl) )
469         CALL tab_1d_2d( npti, nptidx(1:npti), h_ip_1d     (1:npti), h_ip     (:,:,kl) )
470         CALL tab_1d_2d( npti, nptidx(1:npti), a_ip_frac_1d(1:npti), a_ip_frac(:,:,kl) )
471         !
472         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_snw_sni_1d(1:npti), wfx_snw_sni )
473         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_snw_sum_1d(1:npti), wfx_snw_sum )
474         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_sub_1d    (1:npti), wfx_sub     )
475         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_snw_sub_1d(1:npti), wfx_snw_sub )
476         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_ice_sub_1d(1:npti), wfx_ice_sub )
477         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_err_sub_1d(1:npti), wfx_err_sub )
478         !
479         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_bog_1d (1:npti), wfx_bog        )
480         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_bom_1d (1:npti), wfx_bom        )
481         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_sum_1d (1:npti), wfx_sum        )
482         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_sni_1d (1:npti), wfx_sni        )
483         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_res_1d (1:npti), wfx_res        )
484         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_spr_1d (1:npti), wfx_spr        )
485         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_lam_1d (1:npti), wfx_lam        )
486         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_pnd_1d (1:npti), wfx_pnd        )
487         !
488         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_bog_1d (1:npti), sfx_bog        )
489         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_bom_1d (1:npti), sfx_bom        )
490         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_sum_1d (1:npti), sfx_sum        )
491         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_sni_1d (1:npti), sfx_sni        )
492         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_bri_1d (1:npti), sfx_bri        )
493         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_res_1d (1:npti), sfx_res        )
494         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_sub_1d (1:npti), sfx_sub        )
495         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_lam_1d (1:npti), sfx_lam        )
496         !
497         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_thd_1d    (1:npti), hfx_thd     )
498         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_spr_1d    (1:npti), hfx_spr     )
499         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_sum_1d    (1:npti), hfx_sum     )
500         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_bom_1d    (1:npti), hfx_bom     )
501         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_bog_1d    (1:npti), hfx_bog     )
502         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_dif_1d    (1:npti), hfx_dif     )
503         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_opw_1d    (1:npti), hfx_opw     )
504         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_snw_1d    (1:npti), hfx_snw     )
505         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_sub_1d    (1:npti), hfx_sub     )
506         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_res_1d    (1:npti), hfx_res     )
507         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_err_dif_1d(1:npti), hfx_err_dif )
508         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_err_rem_1d(1:npti), hfx_err_rem )
509         CALL tab_1d_2d( npti, nptidx(1:npti), qt_oce_ai_1d  (1:npti), qt_oce_ai   )
510         !
511         CALL tab_1d_2d( npti, nptidx(1:npti), qns_ice_1d    (1:npti), qns_ice    (:,:,kl) )
512         CALL tab_1d_2d( npti, nptidx(1:npti), qtr_ice_bot_1d(1:npti), qtr_ice_bot(:,:,kl) )
513         ! effective conductivity and 1st layer temperature (for Jules coupling)
514         CALL tab_1d_2d( npti, nptidx(1:npti), cnd_ice_1d(1:npti), cnd_ice(:,:,kl) )
515         CALL tab_1d_2d( npti, nptidx(1:npti), t1_ice_1d (1:npti), t1_ice (:,:,kl) )
516         ! SIMIP diagnostics         
517         CALL tab_1d_2d( npti, nptidx(1:npti), t_si_1d       (1:npti), t_si       (:,:,kl) )
518         CALL tab_1d_2d( npti, nptidx(1:npti), qcn_ice_bot_1d(1:npti), qcn_ice_bot(:,:,kl) )
519         CALL tab_1d_2d( npti, nptidx(1:npti), qcn_ice_top_1d(1:npti), qcn_ice_top(:,:,kl) )
520         ! extensive variables
521         CALL tab_1d_2d( npti, nptidx(1:npti), v_i_1d (1:npti), v_i (:,:,kl) )
522         CALL tab_1d_2d( npti, nptidx(1:npti), v_s_1d (1:npti), v_s (:,:,kl) )
523         CALL tab_1d_2d( npti, nptidx(1:npti), sv_i_1d(1:npti), sv_i(:,:,kl) )
524         CALL tab_1d_2d( npti, nptidx(1:npti), v_ip_1d(1:npti), v_ip(:,:,kl) )
525         !
526      END SELECT
527      !
528   END SUBROUTINE ice_thd_1d2d
529
530
531   SUBROUTINE ice_thd_init
532      !!-------------------------------------------------------------------
533      !!                   ***  ROUTINE ice_thd_init ***
534      !!                 
535      !! ** Purpose :   Physical constants and parameters associated with
536      !!                ice thermodynamics
537      !!
538      !! ** Method  :   Read the namthd namelist and check the parameters
539      !!                called at the first timestep (nit000)
540      !!
541      !! ** input   :   Namelist namthd
542      !!-------------------------------------------------------------------
543      INTEGER  ::   ios   ! Local integer output status for namelist read
544      !!
545      NAMELIST/namthd/ ln_icedH, ln_icedA, ln_icedO, ln_icedS
546      !!-------------------------------------------------------------------
547      !
548      REWIND( numnam_ice_ref )              ! Namelist namthd in reference namelist : Ice thermodynamics
549      READ  ( numnam_ice_ref, namthd, IOSTAT = ios, ERR = 901)
550901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namthd in reference namelist', lwp )
551      REWIND( numnam_ice_cfg )              ! Namelist namthd in configuration namelist : Ice thermodynamics
552      READ  ( numnam_ice_cfg, namthd, IOSTAT = ios, ERR = 902 )
553902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namthd in configuration namelist', lwp )
554      IF(lwm) WRITE( numoni, namthd )
555      !
556      IF(lwp) THEN                          ! control print
557         WRITE(numout,*)
558         WRITE(numout,*) 'ice_thd_init: Ice Thermodynamics'
559         WRITE(numout,*) '~~~~~~~~~~~~'
560         WRITE(numout,*) '   Namelist namthd:'
561         WRITE(numout,*) '      activate ice thick change from top/bot (T) or not (F)   ln_icedH  = ', ln_icedH
562         WRITE(numout,*) '      activate lateral melting (T) or not (F)                 ln_icedA  = ', ln_icedA
563         WRITE(numout,*) '      activate ice growth in open-water (T) or not (F)        ln_icedO  = ', ln_icedO
564         WRITE(numout,*) '      activate gravity drainage and flushing (T) or not (F)   ln_icedS  = ', ln_icedS
565     ENDIF
566      !
567                       CALL ice_thd_zdf_init   ! set ice heat diffusion parameters
568      IF( ln_icedA )   CALL ice_thd_da_init    ! set ice lateral melting parameters
569      IF( ln_icedO )   CALL ice_thd_do_init    ! set ice growth in open water parameters
570                       CALL ice_thd_sal_init   ! set ice salinity parameters
571                       CALL ice_thd_pnd_init   ! set melt ponds parameters
572      !
573   END SUBROUTINE ice_thd_init
574
575#else
576   !!----------------------------------------------------------------------
577   !!   Default option         Dummy module          NO  SI3 sea-ice model
578   !!----------------------------------------------------------------------
579#endif
580
581   !!======================================================================
582END MODULE icethd
Note: See TracBrowser for help on using the repository browser.