New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
domzgr.F90 in NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/OCE/DOM – NEMO

source: NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/OCE/DOM/domzgr.F90 @ 10314

Last change on this file since 10314 was 10170, checked in by smasson, 5 years ago

dev_r10164_HPC09_ESIWACE_PREP_MERGE: action 2a: add report calls of lbc_lnk, see #2133

  • Property svn:keywords set to Id
File size: 18.3 KB
Line 
1MODULE domzgr
2   !!==============================================================================
3   !!                       ***  MODULE domzgr   ***
4   !! Ocean domain : definition of the vertical coordinate system
5   !!==============================================================================
6   !! History :  OPA  ! 1995-12  (G. Madec)  Original code : s vertical coordinate
7   !!                 ! 1997-07  (G. Madec)  lbc_lnk call
8   !!                 ! 1997-04  (J.-O. Beismann)
9   !!            8.5  ! 2002-09  (A. Bozec, G. Madec)  F90: Free form and module
10   !!             -   ! 2002-09  (A. de Miranda)  rigid-lid + islands
11   !!  NEMO      1.0  ! 2003-08  (G. Madec)  F90: Free form and module
12   !!             -   ! 2005-10  (A. Beckmann)  modifications for hybrid s-ccordinates & new stretching function
13   !!            2.0  ! 2006-04  (R. Benshila, G. Madec)  add zgr_zco
14   !!            3.0  ! 2008-06  (G. Madec)  insertion of domzgr_zps.h90 & conding style
15   !!            3.2  ! 2009-07  (R. Benshila) Suppression of rigid-lid option
16   !!            3.3  ! 2010-11  (G. Madec) add mbk. arrays associated to the deepest ocean level
17   !!            3.4  ! 2012-08  (J. Siddorn) added Siddorn and Furner stretching function
18   !!            3.4  ! 2012-12  (R. Bourdalle-Badie and G. Reffray)  modify C1D case 
19   !!            3.6  ! 2014-11  (P. Mathiot and C. Harris) add ice shelf capabilitye 
20   !!            3.?  ! 2015-11  (H. Liu) Modifications for Wetting/Drying
21   !!----------------------------------------------------------------------
22
23   !!----------------------------------------------------------------------
24   !!   dom_zgr       : read or set the ocean vertical coordinate system
25   !!   zgr_read      : read the vertical information in the domain configuration file
26   !!   zgr_top_bot   : ocean top and bottom level for t-, u, and v-points with 1 as minimum value
27   !!---------------------------------------------------------------------
28   USE oce            ! ocean variables
29   USE dom_oce        ! ocean domain
30   USE usrdef_zgr     ! user defined vertical coordinate system
31   USE closea         ! closed seas
32   USE depth_e3       ! depth <=> e3
33   USE wet_dry,   ONLY: ll_wd, ssh_ref  ! Wetting and drying
34   !
35   USE in_out_manager ! I/O manager
36   USE iom            ! I/O library
37   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
38   USE lib_mpp        ! distributed memory computing library
39
40   IMPLICIT NONE
41   PRIVATE
42
43   PUBLIC   dom_zgr        ! called by dom_init.F90
44
45  !! * Substitutions
46#  include "vectopt_loop_substitute.h90"
47   !!----------------------------------------------------------------------
48   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
49   !! $Id$
50   !! Software governed by the CeCILL license (see ./LICENSE)
51   !!----------------------------------------------------------------------
52CONTAINS       
53
54   SUBROUTINE dom_zgr( k_top, k_bot )
55      !!----------------------------------------------------------------------
56      !!                ***  ROUTINE dom_zgr  ***
57      !!                   
58      !! ** Purpose :   set the depth of model levels and the resulting
59      !!              vertical scale factors.
60      !!
61      !! ** Method  : - reference 1D vertical coordinate (gdep._1d, e3._1d)
62      !!              - read/set ocean depth and ocean levels (bathy, mbathy)
63      !!              - vertical coordinate (gdep., e3.) depending on the
64      !!                coordinate chosen :
65      !!                   ln_zco=T   z-coordinate   
66      !!                   ln_zps=T   z-coordinate with partial steps
67      !!                   ln_zco=T   s-coordinate
68      !!
69      !! ** Action  :   define gdep., e3., mbathy and bathy
70      !!----------------------------------------------------------------------
71      INTEGER, DIMENSION(:,:), INTENT(out) ::   k_top, k_bot   ! ocean first and last level indices
72      !
73      INTEGER  ::   jk                  ! dummy loop index
74      INTEGER  ::   ioptio, ibat, ios   ! local integer
75      REAL(wp) ::   zrefdep             ! depth of the reference level (~10m)
76      !!----------------------------------------------------------------------
77      !
78      IF(lwp) THEN                     ! Control print
79         WRITE(numout,*)
80         WRITE(numout,*) 'dom_zgr : vertical coordinate'
81         WRITE(numout,*) '~~~~~~~'
82      ENDIF
83
84      IF( ln_linssh .AND. lwp) WRITE(numout,*) '   linear free surface: the vertical mesh does not change in time'
85
86
87      IF( ln_read_cfg ) THEN        !==  read in mesh_mask.nc file  ==!
88         IF(lwp) WRITE(numout,*)
89         IF(lwp) WRITE(numout,*) '   ==>>>   Read vertical mesh in ', TRIM( cn_domcfg ), ' file'
90         !
91         CALL zgr_read   ( ln_zco  , ln_zps  , ln_sco, ln_isfcav,   & 
92            &              gdept_1d, gdepw_1d, e3t_1d, e3w_1d   ,   &    ! 1D gridpoints depth
93            &              gdept_0 , gdepw_0                    ,   &    ! gridpoints depth
94            &              e3t_0   , e3u_0   , e3v_0 , e3f_0    ,   &    ! vertical scale factors
95            &              e3w_0   , e3uw_0  , e3vw_0           ,   &    ! vertical scale factors
96            &              k_top   , k_bot            )                  ! 1st & last ocean level
97            !
98      ELSE                          !==  User defined configuration  ==!
99         IF(lwp) WRITE(numout,*)
100         IF(lwp) WRITE(numout,*) '          User defined vertical mesh (usr_def_zgr)'
101         !
102         CALL usr_def_zgr( ln_zco  , ln_zps  , ln_sco, ln_isfcav,   & 
103            &              gdept_1d, gdepw_1d, e3t_1d, e3w_1d   ,   &    ! 1D gridpoints depth
104            &              gdept_0 , gdepw_0                    ,   &    ! gridpoints depth
105            &              e3t_0   , e3u_0   , e3v_0 , e3f_0    ,   &    ! vertical scale factors
106            &              e3w_0   , e3uw_0  , e3vw_0           ,   &    ! vertical scale factors
107            &              k_top   , k_bot            )                  ! 1st & last ocean level
108         !
109      ENDIF
110      !
111!!gm to be remove when removing the OLD definition of e3 scale factors so that gde3w disappears
112      ! Compute gde3w_0 (vertical sum of e3w)
113      gde3w_0(:,:,1) = 0.5_wp * e3w_0(:,:,1)
114      DO jk = 2, jpk
115         gde3w_0(:,:,jk) = gde3w_0(:,:,jk-1) + e3w_0(:,:,jk)
116      END DO
117      !
118      ! Any closed seas (defined by closea_mask > 0 in domain_cfg file) to be filled
119      ! in at runtime if ln_closea=.false.
120      IF( .NOT.ln_closea )   CALL clo_bat( k_top, k_bot )
121      !
122      IF(lwp) THEN                     ! Control print
123         WRITE(numout,*)
124         WRITE(numout,*) '   Type of vertical coordinate (read in ', TRIM( cn_domcfg ), ' file or set in userdef_nam) :'
125         WRITE(numout,*) '      z-coordinate - full steps      ln_zco    = ', ln_zco
126         WRITE(numout,*) '      z-coordinate - partial steps   ln_zps    = ', ln_zps
127         WRITE(numout,*) '      s- or hybrid z-s-coordinate    ln_sco    = ', ln_sco
128         WRITE(numout,*) '      ice shelf cavities             ln_isfcav = ', ln_isfcav
129      ENDIF
130
131      ioptio = 0                       ! Check Vertical coordinate options
132      IF( ln_zco      )   ioptio = ioptio + 1
133      IF( ln_zps      )   ioptio = ioptio + 1
134      IF( ln_sco      )   ioptio = ioptio + 1
135      IF( ioptio /= 1 )   CALL ctl_stop( ' none or several vertical coordinate options used' )
136
137
138      !                                ! top/bottom ocean level indices for t-, u- and v-points (f-point also for top)
139      CALL zgr_top_bot( k_top, k_bot )      ! with a minimum value set to 1
140     
141
142      !                                ! deepest/shallowest W level Above/Below ~10m
143!!gm BUG in s-coordinate this does not work!
144      zrefdep = 10._wp - 0.1_wp * MINVAL( e3w_1d )                   ! ref. depth with tolerance (10% of minimum layer thickness)
145      nlb10 = MINLOC( gdepw_1d, mask = gdepw_1d > zrefdep, dim = 1 ) ! shallowest W level Below ~10m
146      nla10 = nlb10 - 1                                              ! deepest    W level Above ~10m
147!!gm end bug
148      !
149      IF( nprint == 1 .AND. lwp )   THEN
150         WRITE(numout,*) ' MIN val k_top   ', MINVAL(   k_top(:,:) ), ' MAX ', MAXVAL( k_top(:,:) )
151         WRITE(numout,*) ' MIN val k_bot   ', MINVAL(   k_bot(:,:) ), ' MAX ', MAXVAL( k_bot(:,:) )
152         WRITE(numout,*) ' MIN val depth t ', MINVAL( gdept_0(:,:,:) ),   &
153            &                          ' w ', MINVAL( gdepw_0(:,:,:) ), '3w ', MINVAL( gde3w_0(:,:,:) )
154         WRITE(numout,*) ' MIN val e3    t ', MINVAL(   e3t_0(:,:,:) ), ' f ', MINVAL(   e3f_0(:,:,:) ),  &
155            &                          ' u ', MINVAL(   e3u_0(:,:,:) ), ' u ', MINVAL(   e3v_0(:,:,:) ),  &
156            &                          ' uw', MINVAL(  e3uw_0(:,:,:) ), ' vw', MINVAL(  e3vw_0(:,:,:)),   &
157            &                          ' w ', MINVAL(   e3w_0(:,:,:) )
158
159         WRITE(numout,*) ' MAX val depth t ', MAXVAL( gdept_0(:,:,:) ),   &
160            &                          ' w ', MAXVAL( gdepw_0(:,:,:) ), '3w ', MAXVAL( gde3w_0(:,:,:) )
161         WRITE(numout,*) ' MAX val e3    t ', MAXVAL(   e3t_0(:,:,:) ), ' f ', MAXVAL(   e3f_0(:,:,:) ),  &
162            &                          ' u ', MAXVAL(   e3u_0(:,:,:) ), ' u ', MAXVAL(   e3v_0(:,:,:) ),  &
163            &                          ' uw', MAXVAL(  e3uw_0(:,:,:) ), ' vw', MAXVAL(  e3vw_0(:,:,:) ),  &
164            &                          ' w ', MAXVAL(   e3w_0(:,:,:) )
165      ENDIF
166      !
167   END SUBROUTINE dom_zgr
168
169
170   SUBROUTINE zgr_read( ld_zco  , ld_zps  , ld_sco  , ld_isfcav,   &   ! type of vertical coordinate
171      &                 pdept_1d, pdepw_1d, pe3t_1d , pe3w_1d  ,   &   ! 1D reference vertical coordinate
172      &                 pdept , pdepw ,                            &   ! 3D t & w-points depth
173      &                 pe3t  , pe3u  , pe3v   , pe3f ,            &   ! vertical scale factors
174      &                 pe3w  , pe3uw , pe3vw         ,            &   !     -      -      -
175      &                 k_top  , k_bot    )                            ! top & bottom ocean level
176      !!---------------------------------------------------------------------
177      !!              ***  ROUTINE zgr_read  ***
178      !!
179      !! ** Purpose :   Read the vertical information in the domain configuration file
180      !!
181      !!----------------------------------------------------------------------
182      LOGICAL                   , INTENT(out) ::   ld_zco, ld_zps, ld_sco      ! vertical coordinate flags
183      LOGICAL                   , INTENT(out) ::   ld_isfcav                   ! under iceshelf cavity flag
184      REAL(wp), DIMENSION(:)    , INTENT(out) ::   pdept_1d, pdepw_1d          ! 1D grid-point depth       [m]
185      REAL(wp), DIMENSION(:)    , INTENT(out) ::   pe3t_1d , pe3w_1d           ! 1D vertical scale factors [m]
186      REAL(wp), DIMENSION(:,:,:), INTENT(out) ::   pdept, pdepw                ! grid-point depth          [m]
187      REAL(wp), DIMENSION(:,:,:), INTENT(out) ::   pe3t , pe3u , pe3v , pe3f   ! vertical scale factors    [m]
188      REAL(wp), DIMENSION(:,:,:), INTENT(out) ::   pe3w , pe3uw, pe3vw         !    -       -      -
189      INTEGER , DIMENSION(:,:)  , INTENT(out) ::   k_top , k_bot               ! first & last ocean level
190      !
191      INTEGER  ::   jk     ! dummy loop index
192      INTEGER  ::   inum   ! local logical unit
193      REAL(WP) ::   z_zco, z_zps, z_sco, z_cav
194      REAL(wp), DIMENSION(jpi,jpj) ::   z2d   ! 2D workspace
195      !!----------------------------------------------------------------------
196      !
197      IF(lwp) THEN
198         WRITE(numout,*)
199         WRITE(numout,*) '   zgr_read : read the vertical coordinates in ', TRIM( cn_domcfg ), ' file'
200         WRITE(numout,*) '   ~~~~~~~~'
201      ENDIF
202      !
203      CALL iom_open( cn_domcfg, inum )
204      !
205      !                          !* type of vertical coordinate
206      CALL iom_get( inum, 'ln_zco'   , z_zco )
207      CALL iom_get( inum, 'ln_zps'   , z_zps )
208      CALL iom_get( inum, 'ln_sco'   , z_sco )
209      IF( z_zco == 0._wp ) THEN   ;   ld_zco = .false.   ;   ELSE   ;   ld_zco = .true.   ;   ENDIF
210      IF( z_zps == 0._wp ) THEN   ;   ld_zps = .false.   ;   ELSE   ;   ld_zps = .true.   ;   ENDIF
211      IF( z_sco == 0._wp ) THEN   ;   ld_sco = .false.   ;   ELSE   ;   ld_sco = .true.   ;   ENDIF
212      !
213      !                          !* ocean cavities under iceshelves
214      CALL iom_get( inum, 'ln_isfcav', z_cav )
215      IF( z_cav == 0._wp ) THEN   ;   ld_isfcav = .false.   ;   ELSE   ;   ld_isfcav = .true.   ;   ENDIF
216      !
217      !                          !* vertical scale factors
218      CALL iom_get( inum, jpdom_unknown, 'e3t_1d'  , pe3t_1d  )                     ! 1D reference coordinate
219      CALL iom_get( inum, jpdom_unknown, 'e3w_1d'  , pe3w_1d  )
220      !
221      CALL iom_get( inum, jpdom_data, 'e3t_0'  , pe3t  , lrowattr=ln_use_jattr )    ! 3D coordinate
222      CALL iom_get( inum, jpdom_data, 'e3u_0'  , pe3u  , lrowattr=ln_use_jattr )
223      CALL iom_get( inum, jpdom_data, 'e3v_0'  , pe3v  , lrowattr=ln_use_jattr )
224      CALL iom_get( inum, jpdom_data, 'e3f_0'  , pe3f  , lrowattr=ln_use_jattr )
225      CALL iom_get( inum, jpdom_data, 'e3w_0'  , pe3w  , lrowattr=ln_use_jattr )
226      CALL iom_get( inum, jpdom_data, 'e3uw_0' , pe3uw , lrowattr=ln_use_jattr )
227      CALL iom_get( inum, jpdom_data, 'e3vw_0' , pe3vw , lrowattr=ln_use_jattr )
228      !
229      !                          !* depths
230      !                                   !- old depth definition (obsolescent feature)
231      IF(  iom_varid( inum, 'gdept_1d', ldstop = .FALSE. ) > 0  .AND.  &
232         & iom_varid( inum, 'gdepw_1d', ldstop = .FALSE. ) > 0  .AND.  &
233         & iom_varid( inum, 'gdept_0' , ldstop = .FALSE. ) > 0  .AND.  &
234         & iom_varid( inum, 'gdepw_0' , ldstop = .FALSE. ) > 0    ) THEN
235         CALL ctl_warn( 'zgr_read : old definition of depths and scale factors used ', & 
236            &           '           depths at t- and w-points read in the domain configuration file')
237         CALL iom_get( inum, jpdom_unknown, 'gdept_1d', pdept_1d )   
238         CALL iom_get( inum, jpdom_unknown, 'gdepw_1d', pdepw_1d )
239         CALL iom_get( inum, jpdom_data   , 'gdept_0' , pdept , lrowattr=ln_use_jattr )
240         CALL iom_get( inum, jpdom_data   , 'gdepw_0' , pdepw , lrowattr=ln_use_jattr )
241         !
242      ELSE                                !- depths computed from e3. scale factors
243         CALL e3_to_depth( pe3t_1d, pe3w_1d, pdept_1d, pdepw_1d )    ! 1D reference depth
244         CALL e3_to_depth( pe3t   , pe3w   , pdept   , pdepw    )    ! 3D depths
245         IF(lwp) THEN
246            WRITE(numout,*)
247            WRITE(numout,*) '              Reference 1D z-coordinate depth and scale factors:'
248            WRITE(numout, "(9x,' level  gdept_1d  gdepw_1d  e3t_1d   e3w_1d  ')" )
249            WRITE(numout, "(10x, i4, 4f9.2)" ) ( jk, pdept_1d(jk), pdepw_1d(jk), pe3t_1d(jk), pe3w_1d(jk), jk = 1, jpk )
250         ENDIF
251      ENDIF
252      !
253      !                          !* ocean top and bottom level
254      CALL iom_get( inum, jpdom_data, 'top_level'    , z2d  , lrowattr=ln_use_jattr )   ! 1st wet T-points (ISF)
255      k_top(:,:) = NINT( z2d(:,:) )
256      CALL iom_get( inum, jpdom_data, 'bottom_level' , z2d  , lrowattr=ln_use_jattr )   ! last wet T-points
257      k_bot(:,:) = NINT( z2d(:,:) )
258      !
259      ! reference depth for negative bathy (wetting and drying only)
260      IF( ll_wd )  CALL iom_get( inum,  'rn_wd_ref_depth' , ssh_ref   )
261      !
262      CALL iom_close( inum )
263      !
264   END SUBROUTINE zgr_read
265
266
267   SUBROUTINE zgr_top_bot( k_top, k_bot )
268      !!----------------------------------------------------------------------
269      !!                    ***  ROUTINE zgr_top_bot  ***
270      !!
271      !! ** Purpose :   defines the vertical index of ocean bottom (mbk. arrays)
272      !!
273      !! ** Method  :   computes from k_top and k_bot with a minimum value of 1 over land
274      !!
275      !! ** Action  :   mikt, miku, mikv :   vertical indices of the shallowest
276      !!                                     ocean level at t-, u- & v-points
277      !!                                     (min value = 1)
278      !! ** Action  :   mbkt, mbku, mbkv :   vertical indices of the deeptest
279      !!                                     ocean level at t-, u- & v-points
280      !!                                     (min value = 1 over land)
281      !!----------------------------------------------------------------------
282      INTEGER , DIMENSION(:,:), INTENT(in) ::   k_top, k_bot   ! top & bottom ocean level indices
283      !
284      INTEGER ::   ji, jj   ! dummy loop indices
285      REAL(wp), DIMENSION(jpi,jpj) ::   zk   ! workspace
286      !!----------------------------------------------------------------------
287      !
288      IF(lwp) WRITE(numout,*)
289      IF(lwp) WRITE(numout,*) '    zgr_top_bot : ocean top and bottom k-index of T-, U-, V- and W-levels '
290      IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~'
291      !
292      mikt(:,:) = MAX( k_top(:,:) , 1 )    ! top    ocean k-index of T-level (=1 over land)
293      !
294      mbkt(:,:) = MAX( k_bot(:,:) , 1 )    ! bottom ocean k-index of T-level (=1 over land)
295 
296      !                                    ! N.B.  top     k-index of W-level = mikt
297      !                                    !       bottom  k-index of W-level = mbkt+1
298      DO jj = 1, jpjm1
299         DO ji = 1, jpim1
300            miku(ji,jj) = MAX(  mikt(ji+1,jj  ) , mikt(ji,jj)  )
301            mikv(ji,jj) = MAX(  mikt(ji  ,jj+1) , mikt(ji,jj)  )
302            mikf(ji,jj) = MAX(  mikt(ji  ,jj+1) , mikt(ji,jj), mikt(ji+1,jj  ), mikt(ji+1,jj+1)  )
303            !
304            mbku(ji,jj) = MIN(  mbkt(ji+1,jj  ) , mbkt(ji,jj)  )
305            mbkv(ji,jj) = MIN(  mbkt(ji  ,jj+1) , mbkt(ji,jj)  )
306         END DO
307      END DO
308      ! converte into REAL to use lbc_lnk ; impose a min value of 1 as a zero can be set in lbclnk
309      zk(:,:) = REAL( miku(:,:), wp )   ;   CALL lbc_lnk( 'domzgr', zk, 'U', 1. )   ;   miku(:,:) = MAX( NINT( zk(:,:) ), 1 )
310      zk(:,:) = REAL( mikv(:,:), wp )   ;   CALL lbc_lnk( 'domzgr', zk, 'V', 1. )   ;   mikv(:,:) = MAX( NINT( zk(:,:) ), 1 )
311      zk(:,:) = REAL( mikf(:,:), wp )   ;   CALL lbc_lnk( 'domzgr', zk, 'F', 1. )   ;   mikf(:,:) = MAX( NINT( zk(:,:) ), 1 )
312      !
313      zk(:,:) = REAL( mbku(:,:), wp )   ;   CALL lbc_lnk( 'domzgr', zk, 'U', 1. )   ;   mbku(:,:) = MAX( NINT( zk(:,:) ), 1 )
314      zk(:,:) = REAL( mbkv(:,:), wp )   ;   CALL lbc_lnk( 'domzgr', zk, 'V', 1. )   ;   mbkv(:,:) = MAX( NINT( zk(:,:) ), 1 )
315      !
316   END SUBROUTINE zgr_top_bot
317
318   !!======================================================================
319END MODULE domzgr
Note: See TracBrowser for help on using the repository browser.