New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
iom_nf90.F90 in NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/OCE/IOM – NEMO

source: NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/OCE/IOM/iom_nf90.F90 @ 10377

Last change on this file since 10377 was 10377, checked in by smasson, 5 years ago

dev_r10164_HPC09_ESIWACE_PREP_MERGE: merge with trunk@10376, see #2133
  • Property svn:keywords set to Id
File size: 49.3 KB
Line 
1MODULE iom_nf90
2   !!======================================================================
3   !!                    ***  MODULE  iom_nf90 ***
4   !! Input/Output manager :  Library to read input files with NF90 (only fliocom module)
5   !!======================================================================
6   !! History :  9.0  ! 05 12  (J. Belier) Original code
7   !!            9.0  ! 06 02  (S. Masson) Adaptation to NEMO
8   !!             "   ! 07 07  (D. Storkey) Changes to iom_nf90_gettime
9   !!            3.6  ! 2015-15  (J. Harle) Added procedure to read REAL attributes
10   !!            4.0  ! 2017-11 (M. Andrejczuk) Extend IOM interface to write any 3D fields
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   iom_open       : open a file read only
15   !!   iom_close      : close a file or all files opened by iom
16   !!   iom_get        : read a field (interfaced to several routines)
17   !!   iom_gettime    : read the time axis kvid in the file
18   !!   iom_varid      : get the id of a variable in a file
19   !!   iom_rstput     : write a field in a restart file (interfaced to several routines)
20   !!----------------------------------------------------------------------
21   USE dom_oce         ! ocean space and time domain
22   USE lbclnk          ! lateal boundary condition / mpp exchanges
23   USE iom_def         ! iom variables definitions
24   USE netcdf          ! NetCDF library
25   USE in_out_manager  ! I/O manager
26   USE lib_mpp         ! MPP library
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC iom_nf90_open  , iom_nf90_close, iom_nf90_varid, iom_nf90_get, iom_nf90_gettime, iom_nf90_rstput
32   PUBLIC iom_nf90_getatt, iom_nf90_putatt
33
34   INTERFACE iom_nf90_get
35      MODULE PROCEDURE iom_nf90_g0d, iom_nf90_g123d
36   END INTERFACE
37   INTERFACE iom_nf90_getatt
38      MODULE PROCEDURE iom_nf90_giatt, iom_nf90_gratt, iom_nf90_gcatt
39   END INTERFACE
40   INTERFACE iom_nf90_putatt
41      MODULE PROCEDURE iom_nf90_piatt, iom_nf90_pratt, iom_nf90_pcatt
42   END INTERFACE
43   INTERFACE iom_nf90_rstput
44      MODULE PROCEDURE iom_nf90_rp0123d
45   END INTERFACE
46
47   !!----------------------------------------------------------------------
48   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
49   !! $Id$
50   !! Software governed by the CeCILL license (see ./LICENSE)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54   SUBROUTINE iom_nf90_open( cdname, kiomid, ldwrt, ldok, kdompar, kdlev )
55      !!---------------------------------------------------------------------
56      !!                   ***  SUBROUTINE  iom_open  ***
57      !!
58      !! ** Purpose : open an input file with NF90
59      !!---------------------------------------------------------------------
60      CHARACTER(len=*)       , INTENT(inout)           ::   cdname      ! File name
61      INTEGER                , INTENT(  out)           ::   kiomid      ! nf90 identifier of the opened file
62      LOGICAL                , INTENT(in   )           ::   ldwrt       ! read or write the file?
63      LOGICAL                , INTENT(in   )           ::   ldok        ! check the existence
64      INTEGER, DIMENSION(2,5), INTENT(in   ), OPTIONAL ::   kdompar     ! domain parameters:
65      INTEGER                , INTENT(in   ), OPTIONAL ::   kdlev       ! size of the third dimension
66
67      CHARACTER(LEN=256) ::   clinfo           ! info character
68      CHARACTER(LEN=256) ::   cltmp            ! temporary character
69      INTEGER            ::   iln              ! lengths of character
70      INTEGER            ::   istop            ! temporary storage of nstop
71      INTEGER            ::   if90id           ! nf90 identifier of the opened file
72      INTEGER            ::   idmy             ! dummy variable
73      INTEGER            ::   jl               ! loop variable
74      INTEGER            ::   ichunk           ! temporary storage of nn_chunksz
75      INTEGER            ::   imode            ! creation mode flag: NF90_CLOBBER or NF90_NOCLOBBER or NF90_HDF5
76      INTEGER            ::   ihdf5            ! local variable for retrieval of value for NF90_HDF5
77      LOGICAL            ::   llclobber        ! local definition of ln_clobber
78      INTEGER            ::   ilevels           ! vertical levels
79      !---------------------------------------------------------------------
80      !
81      clinfo = '                    iom_nf90_open ~~~  '
82      istop = nstop     ! store the actual value of nstop
83      !
84      !                 !number of vertical levels
85      IF( PRESENT(kdlev) ) THEN   ;   ilevels = kdlev    ! use input value (useful for sea-ice)
86      ELSE                        ;   ilevels = jpk      ! by default jpk
87      ENDIF
88      !
89      IF( nn_chunksz > 0 ) THEN   ;   ichunk = nn_chunksz
90      ELSE                        ;   ichunk = NF90_SIZEHINT_DEFAULT
91      ENDIF
92      !
93      llclobber = ldwrt .AND. ln_clobber
94      IF( ldok .AND. .NOT. llclobber ) THEN      !==  Open existing file ==!
95         !                                       !=========================!
96         IF( ldwrt ) THEN  ! ... in write mode
97            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in WRITE mode'
98            IF( snc4set%luse ) THEN
99               CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_WRITE  , if90id ), clinfo)
100            ELSE
101               CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_WRITE  , if90id, chunksize = ichunk ), clinfo)
102            ENDIF
103            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL, idmy                          ), clinfo)
104         ELSE              ! ... in read mode
105            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in READ mode'
106            CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_NOWRITE, if90id, chunksize = ichunk ), clinfo)
107         ENDIF
108      ELSE                                       !== the file doesn't exist ==!   (or we overwrite it)
109         !                                       !============================!
110         iln = INDEX( cdname, '.nc' )
111         IF( ldwrt ) THEN              !* the file should be open in write mode so we create it...
112            IF( jpnij > 1 ) THEN
113               WRITE(cltmp,'(a,a,i4.4,a)') cdname(1:iln-1), '_', narea-1, '.nc'
114               cdname = TRIM(cltmp)
115            ENDIF
116            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' create new file: '//TRIM(cdname)//' in WRITE mode'
117
118            IF( llclobber ) THEN   ;   imode = IOR( NF90_64BIT_OFFSET, NF90_CLOBBER   )
119            ELSE                   ;   imode = IOR( NF90_64BIT_OFFSET, NF90_NOCLOBBER ) 
120            ENDIF
121            IF( snc4set%luse ) THEN
122               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' creating file: '//TRIM(cdname)//' in hdf5 (netcdf4) mode'
123               CALL GET_NF90_SYMBOL("NF90_HDF5", ihdf5)
124               IF( llclobber ) THEN   ;   imode = IOR(ihdf5, NF90_CLOBBER)
125               ELSE                   ;   imode = IOR(ihdf5, NF90_NOCLOBBER)
126               ENDIF
127               CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), imode, if90id ), clinfo)
128            ELSE
129               CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), imode, if90id, chunksize = ichunk ), clinfo)
130            ENDIF
131            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL,                   idmy ), clinfo)
132            ! define dimensions
133            CALL iom_nf90_check(NF90_DEF_DIM( if90id,            'x',   kdompar(1,1), idmy ), clinfo)
134            CALL iom_nf90_check(NF90_DEF_DIM( if90id,            'y',   kdompar(2,1), idmy ), clinfo)
135            CALL iom_nf90_check(NF90_DEF_DIM( if90id,      'nav_lev',            jpk, idmy ), clinfo)
136            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'time_counter', NF90_UNLIMITED, idmy ), clinfo)
137            IF( PRESENT(kdlev) )   &
138               CALL iom_nf90_check(NF90_DEF_DIM( if90id,    'numcat',          kdlev, idmy ), clinfo)
139            ! global attributes
140            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number_total'   , jpnij              ), clinfo)
141            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number'         , narea-1            ), clinfo)
142            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_dimensions_ids' , (/1     , 2     /) ), clinfo)
143            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_global'    , (/jpiglo, jpjglo/) ), clinfo)
144            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_local'     , kdompar(:,1)       ), clinfo)
145            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_first' , kdompar(:,2)       ), clinfo)
146            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_last'  , kdompar(:,3)       ), clinfo)
147            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_start', kdompar(:,4)       ), clinfo)
148            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_end'  , kdompar(:,5)       ), clinfo)
149            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_type'           , 'BOX'              ), clinfo)
150         ELSE                          !* the file should be open for read mode so it must exist...
151            CALL ctl_stop( TRIM(clinfo), ' should be impossible case...' )
152         ENDIF
153      ENDIF
154      !
155      ! start to fill file informations
156      ! =============
157      IF( istop == nstop ) THEN   ! no error within this routine
158!does not work with some compilers         kiomid = MINLOC(iom_file(:)%nfid, dim = 1)
159         kiomid = 0
160         DO jl = jpmax_files, 1, -1
161            IF( iom_file(jl)%nfid == 0 )   kiomid = jl
162         ENDDO
163         iom_file(kiomid)%name   = TRIM(cdname)
164         iom_file(kiomid)%nfid   = if90id
165         iom_file(kiomid)%iolib  = jpnf90
166         iom_file(kiomid)%nvars  = 0
167         iom_file(kiomid)%irec   = -1   ! useless for NetCDF files, used to know if the file is in define mode
168         iom_file(kiomid)%nlev   = ilevels
169         CALL iom_nf90_check(NF90_Inquire(if90id, unlimitedDimId = iom_file(kiomid)%iduld), clinfo)
170         IF( iom_file(kiomid)%iduld .GE. 0 ) THEN
171            CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, iom_file(kiomid)%iduld,    & 
172               &                                       name = iom_file(kiomid)%uldname,   &
173               &                                       len  = iom_file(kiomid)%lenuld ), clinfo )
174         ENDIF
175         IF(lwp) WRITE(numout,*) '                   ---> '//TRIM(cdname)//' OK'
176      ELSE
177         kiomid = 0               ! return error flag
178      ENDIF
179      !
180   END SUBROUTINE iom_nf90_open
181
182
183   SUBROUTINE iom_nf90_close( kiomid )
184      !!--------------------------------------------------------------------
185      !!                   ***  SUBROUTINE  iom_nf90_close  ***
186      !!
187      !! ** Purpose : close an input file with NF90
188      !!--------------------------------------------------------------------
189      INTEGER, INTENT(in) ::   kiomid   ! iom identifier of the file to be closed
190      CHARACTER(LEN=100)  ::   clinfo   ! info character
191      !---------------------------------------------------------------------
192      clinfo = '      iom_nf90_close    , file: '//TRIM(iom_file(kiomid)%name)
193      CALL iom_nf90_check(NF90_CLOSE(iom_file(kiomid)%nfid), clinfo)
194   END SUBROUTINE iom_nf90_close
195
196
197   FUNCTION iom_nf90_varid ( kiomid, cdvar, kiv, kdimsz, kndims ) 
198      !!-----------------------------------------------------------------------
199      !!                  ***  FUNCTION  iom_varid  ***
200      !!
201      !! ** Purpose : get the id of a variable in a file with NF90
202      !!-----------------------------------------------------------------------
203      INTEGER              , INTENT(in   )           ::   kiomid   ! file Identifier
204      CHARACTER(len=*)     , INTENT(in   )           ::   cdvar    ! name of the variable
205      INTEGER              , INTENT(in   )           ::   kiv   !
206      INTEGER, DIMENSION(:), INTENT(  out), OPTIONAL ::   kdimsz   ! size of the dimensions
207      INTEGER,               INTENT(  out), OPTIONAL ::   kndims   ! size of the dimensions
208      !
209      INTEGER                        ::   iom_nf90_varid   ! iom variable Id
210      INTEGER                        ::   if90id           ! nf90 file identifier
211      INTEGER                        ::   ji               ! dummy loop index
212      INTEGER                        ::   ivarid           ! NetCDF  variable Id
213      INTEGER                        ::   i_nvd            ! number of dimension of the variable
214      INTEGER, DIMENSION(jpmax_dims) ::   idimid           ! dimension ids of the variable
215      LOGICAL                        ::   llok             ! ok  test
216      CHARACTER(LEN=100)             ::   clinfo           ! info character
217      !!-----------------------------------------------------------------------
218      clinfo = '          iom_nf90_varid, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
219      iom_nf90_varid = 0                    ! default definition
220      IF( PRESENT(kdimsz) ) kdimsz(:) = 0   ! default definition
221      if90id = iom_file(kiomid)%nfid        ! get back NetCDF file id
222      !
223      llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr   ! does the variable exist in the file
224      IF( llok ) THEN
225         iom_nf90_varid = kiv
226         iom_file(kiomid)%nvars       = kiv
227         iom_file(kiomid)%nvid(kiv)   = ivarid
228         iom_file(kiomid)%cn_var(kiv) = TRIM(cdvar)
229         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, ndims = i_nvd), clinfo)   ! number of dimensions
230         iom_file(kiomid)%ndims(kiv)  = i_nvd
231         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, dimids = idimid(1:i_nvd)), clinfo)   ! dimensions ids
232         iom_file(kiomid)%luld(kiv) = .FALSE.   ! default value
233         iom_file(kiomid)%dimsz(:,kiv) = 0      ! reset dimsz in case previously used
234         DO ji = 1, i_nvd                       ! dimensions size
235            CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, idimid(ji), len = iom_file(kiomid)%dimsz(ji,kiv)), clinfo)   
236            IF( idimid(ji) == iom_file(kiomid)%iduld ) iom_file(kiomid)%luld(kiv) = .TRUE.   ! unlimited dimension?
237         END DO
238         !---------- Deal with scale_factor and add_offset
239         llok = NF90_Inquire_attribute(if90id, ivarid, 'scale_factor') == nf90_noerr
240         IF( llok) THEN
241            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'scale_factor', iom_file(kiomid)%scf(kiv)), clinfo)
242         ELSE
243            iom_file(kiomid)%scf(kiv) = 1.
244         END IF
245         llok = NF90_Inquire_attribute(if90id, ivarid, 'add_offset') == nf90_noerr
246         IF( llok ) THEN
247            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'add_offset', iom_file(kiomid)%ofs(kiv)), clinfo)
248         ELSE
249            iom_file(kiomid)%ofs(kiv) = 0.
250         END IF
251         ! return the simension size
252         IF( PRESENT(kdimsz) ) THEN
253            IF( i_nvd <= SIZE(kdimsz) ) THEN
254               kdimsz(1:i_nvd) = iom_file(kiomid)%dimsz(1:i_nvd,kiv)
255            ELSE
256               WRITE(ctmp1,*) i_nvd, SIZE(kdimsz)
257               CALL ctl_stop( TRIM(clinfo), 'error in kdimsz size'//TRIM(ctmp1) )
258            ENDIF
259         ENDIF
260         IF( PRESENT(kndims) )  kndims = iom_file(kiomid)%ndims(kiv)
261      ELSE 
262         iom_nf90_varid = -1   !   variable not found, return error code: -1
263      ENDIF
264      !
265   END FUNCTION iom_nf90_varid
266
267   !!----------------------------------------------------------------------
268   !!                   INTERFACE iom_nf90_get
269   !!----------------------------------------------------------------------
270
271   SUBROUTINE iom_nf90_g0d( kiomid, kvid, pvar, kstart )
272      !!-----------------------------------------------------------------------
273      !!                  ***  ROUTINE  iom_nf90_g0d  ***
274      !!
275      !! ** Purpose : read a scalar with NF90
276      !!-----------------------------------------------------------------------
277      INTEGER ,               INTENT(in   )            ::   kiomid   ! Identifier of the file
278      INTEGER ,               INTENT(in   )            ::   kvid     ! variable id
279      REAL(wp),               INTENT(  out)            ::   pvar     ! read field
280      INTEGER , DIMENSION(1), INTENT(in   ), OPTIONAL  ::   kstart   ! start position of the reading in each axis
281      !
282      CHARACTER(LEN=100)      ::   clinfo   ! info character
283      !---------------------------------------------------------------------
284      clinfo = 'iom_nf90_g0d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
285      CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), pvar, start = kstart), clinfo )
286   END SUBROUTINE iom_nf90_g0d
287
288
289   SUBROUTINE iom_nf90_g123d( kiomid, kvid, knbdim, kstart, kcount, kx1, kx2, ky1, ky2,   &
290         &                    pv_r1d, pv_r2d, pv_r3d )
291      !!-----------------------------------------------------------------------
292      !!                  ***  ROUTINE  iom_nf90_g123d  ***
293      !!
294      !! ** Purpose : read a 1D/2D/3D variable with NF90
295      !!
296      !! ** Method : read ONE record at each CALL
297      !!-----------------------------------------------------------------------
298      INTEGER                    , INTENT(in   )           ::   kiomid    ! iom identifier of the file
299      INTEGER                    , INTENT(in   )           ::   kvid      ! Name of the variable
300      INTEGER                    , INTENT(in   )           ::   knbdim    ! number of dimensions of the variable
301      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kstart    ! start position of the reading in each axis
302      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kcount    ! number of points to be read in each axis
303      INTEGER ,                    INTENT(in   )           ::   kx1, kx2, ky1, ky2   ! subdomain indexes
304      REAL(wp), DIMENSION(:)     , INTENT(  out), OPTIONAL ::   pv_r1d    ! read field (1D case)
305      REAL(wp), DIMENSION(:,:)   , INTENT(  out), OPTIONAL ::   pv_r2d    ! read field (2D case)
306      REAL(wp), DIMENSION(:,:,:) , INTENT(  out), OPTIONAL ::   pv_r3d    ! read field (3D case)
307      !
308      CHARACTER(LEN=100) ::   clinfo               ! info character
309      INTEGER            ::   if90id               ! nf90 identifier of the opened file
310      INTEGER            ::   ivid                 ! nf90 variable id
311      !---------------------------------------------------------------------
312      clinfo = 'iom_nf90_g123d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
313      if90id = iom_file(kiomid)%nfid         ! get back NetCDF file id
314      ivid   = iom_file(kiomid)%nvid(kvid)   ! get back NetCDF var id
315      !
316      IF(     PRESENT(pv_r1d) ) THEN
317         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r1d(:                ), start = kstart(1:knbdim),   &
318            &                                                                       count = kcount(1:knbdim)), clinfo )
319      ELSEIF( PRESENT(pv_r2d) ) THEN
320         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r2d(kx1:kx2,ky1:ky2  ), start = kstart(1:knbdim),   &
321            &                                                                       count = kcount(1:knbdim)), clinfo )
322      ELSEIF( PRESENT(pv_r3d) ) THEN
323         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r3d(kx1:kx2,ky1:ky2,:), start = kstart(1:knbdim),   &
324            &                                                                       count = kcount(1:knbdim)), clinfo )
325      ENDIF
326      !
327   END SUBROUTINE iom_nf90_g123d
328
329   !!----------------------------------------------------------------------
330   !!                   INTERFACE iom_nf90_getatt
331   !!----------------------------------------------------------------------
332
333   SUBROUTINE iom_nf90_giatt( kiomid, cdatt, pv_i0d, cdvar)
334      !!-----------------------------------------------------------------------
335      !!                  ***  ROUTINE  iom_nf90_giatt  ***
336      !!
337      !! ** Purpose : read an integer attribute with NF90
338      !!              (either a global attribute (default) or a variable
339      !!               attribute if optional variable name is supplied (cdvar))
340      !!-----------------------------------------------------------------------
341      INTEGER         , INTENT(in   ) ::   kiomid   ! Identifier of the file
342      CHARACTER(len=*), INTENT(in   ) ::   cdatt    ! attribute name
343      INTEGER         , INTENT(  out) ::   pv_i0d   ! read field
344      CHARACTER(len=*), INTENT(in   ), OPTIONAL     &
345                      &               ::   cdvar    ! name of the variable
346      !
347      INTEGER                         ::   if90id   ! temporary integer
348      INTEGER                         ::   ivarid   ! NetCDF variable Id
349      LOGICAL                         ::   llok     ! temporary logical
350      CHARACTER(LEN=100)              ::   clinfo   ! info character
351      !---------------------------------------------------------------------
352      !
353      if90id = iom_file(kiomid)%nfid
354      IF( PRESENT(cdvar) ) THEN
355         ! check the variable exists in the file
356         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
357         IF( llok ) THEN
358            ! check the variable has the attribute required
359            llok = NF90_Inquire_attribute(if90id, ivarid, cdatt) == nf90_noerr
360         ELSE
361            CALL ctl_warn('iom_nf90_getatt: no variable '//cdvar//' found')
362         ENDIF
363      ELSE
364         llok = NF90_Inquire_attribute(if90id, NF90_GLOBAL, cdatt) == nf90_noerr
365         ivarid = NF90_GLOBAL
366      ENDIF
367      !
368      IF( llok) THEN
369         clinfo = 'iom_nf90_getatt, file: '//TRIM(iom_file(kiomid)%name)//', giatt: '//TRIM(cdatt)
370         CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values=pv_i0d), clinfo)
371      ELSE
372         CALL ctl_warn('iom_nf90_getatt: no attribute '//cdatt//' found')
373         pv_i0d = -999
374      ENDIF
375      !
376   END SUBROUTINE iom_nf90_giatt
377
378
379   SUBROUTINE iom_nf90_gratt( kiomid, cdatt, pv_r0d, cdvar )
380      !!-----------------------------------------------------------------------
381      !!                  ***  ROUTINE  iom_nf90_gratt  ***
382      !!
383      !! ** Purpose : read a real attribute with NF90
384      !!              (either a global attribute (default) or a variable
385      !!               attribute if optional variable name is supplied (cdvar))
386      !!-----------------------------------------------------------------------
387      INTEGER                   , INTENT(in   ) ::   kiomid   ! Identifier of the file
388      CHARACTER(len=*)          , INTENT(in   ) ::   cdatt    ! attribute name
389      REAL(wp)                  , INTENT(  out) ::   pv_r0d   ! read field
390      CHARACTER(len=*), OPTIONAL, INTENT(in   ) ::   cdvar    ! name of the variable
391      !
392      INTEGER            ::   if90id   ! temporary integer
393      INTEGER            ::   ivarid   ! NetCDF variable Id
394      LOGICAL            ::   llok     ! temporary logical
395      CHARACTER(LEN=100) ::   clinfo   ! info character
396      !---------------------------------------------------------------------
397      !
398      if90id = iom_file(kiomid)%nfid
399      IF( PRESENT(cdvar) ) THEN
400         ! check the variable exists in the file
401         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
402         IF( llok ) THEN
403            ! check the variable has the attribute required
404            llok = NF90_Inquire_attribute(if90id, ivarid, cdatt) == nf90_noerr
405         ELSE
406            CALL ctl_warn('iom_nf90_getatt: no variable '//cdvar//' found')
407         ENDIF
408      ELSE
409         llok = NF90_Inquire_attribute(if90id, NF90_GLOBAL, cdatt) == nf90_noerr
410         ivarid = NF90_GLOBAL
411      ENDIF
412      !
413      IF( llok) THEN
414         clinfo = 'iom_nf90_getatt, file: '//TRIM(iom_file(kiomid)%name)//', gratt: '//TRIM(cdatt)
415         CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values=pv_r0d), clinfo)
416      ELSE
417         CALL ctl_warn('iom_nf90_getatt: no attribute '//cdatt//' found')
418         pv_r0d = -999._wp
419      ENDIF
420      !
421   END SUBROUTINE iom_nf90_gratt
422
423
424   SUBROUTINE iom_nf90_gcatt( kiomid, cdatt, pv_c0d, cdvar )
425      !!-----------------------------------------------------------------------
426      !!                  ***  ROUTINE  iom_nf90_gcatt  ***
427      !!
428      !! ** Purpose : read a character attribute with NF90
429      !!              (either a global attribute (default) or a variable
430      !!               attribute if optional variable name is supplied (cdvar))
431      !!-----------------------------------------------------------------------
432      INTEGER                   , INTENT(in   ) ::   kiomid   ! Identifier of the file
433      CHARACTER(len=*)          , INTENT(in   ) ::   cdatt    ! attribute name
434      CHARACTER(len=*)          , INTENT(  out) ::   pv_c0d   ! read field
435      CHARACTER(len=*), OPTIONAL, INTENT(in   ) ::   cdvar    ! name of the variable
436      !
437      INTEGER            ::   if90id   ! temporary integer
438      INTEGER            ::   ivarid   ! NetCDF variable Id
439      LOGICAL            ::   llok     ! temporary logical
440      CHARACTER(LEN=100) ::   clinfo   ! info character
441      !---------------------------------------------------------------------
442      !
443      if90id = iom_file(kiomid)%nfid
444      IF( PRESENT(cdvar) ) THEN
445         ! check the variable exists in the file
446         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
447         IF( llok ) THEN
448            ! check the variable has the attribute required
449            llok = NF90_Inquire_attribute(if90id, ivarid, cdatt) == nf90_noerr
450         ELSE
451            CALL ctl_warn('iom_nf90_getatt: no variable '//cdvar//' found')
452         ENDIF
453      ELSE
454         llok = NF90_Inquire_attribute(if90id, NF90_GLOBAL, cdatt) == nf90_noerr
455         ivarid = NF90_GLOBAL
456      ENDIF
457!
458      IF( llok) THEN
459         clinfo = 'iom_nf90_getatt, file: '//TRIM(iom_file(kiomid)%name)//', gcatt: '//TRIM(cdatt)
460         CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values=pv_c0d), clinfo)
461      ELSE
462         CALL ctl_warn('iom_nf90_getatt: no attribute '//cdatt//' found')
463         pv_c0d = '!'
464      ENDIF
465      !
466   END SUBROUTINE iom_nf90_gcatt
467
468
469   !!----------------------------------------------------------------------
470   !!                   INTERFACE iom_nf90_putatt
471   !!----------------------------------------------------------------------
472
473   SUBROUTINE iom_nf90_piatt( kiomid, cdatt, pv_i0d, cdvar)
474      !!-----------------------------------------------------------------------
475      !!                  ***  ROUTINE  iom_nf90_piatt  ***
476      !!
477      !! ** Purpose : write an integer attribute with NF90
478      !!              (either a global attribute (default) or a variable
479      !!               attribute if optional variable name is supplied (cdvar))
480      !!-----------------------------------------------------------------------
481      INTEGER         , INTENT(in   ) ::   kiomid   ! Identifier of the file
482      CHARACTER(len=*), INTENT(in   ) ::   cdatt    ! attribute name
483      INTEGER         , INTENT(in   ) ::   pv_i0d   ! write field
484      CHARACTER(len=*), INTENT(in   ), OPTIONAL     &
485                      &               ::   cdvar    ! name of the variable
486      !
487      INTEGER                         ::   if90id   ! temporary integer
488      INTEGER                         ::   ivarid   ! NetCDF variable Id
489      LOGICAL                         ::   llok     ! temporary logical
490      LOGICAL                         ::   lenddef  ! temporary logical
491      CHARACTER(LEN=100)              ::   clinfo   ! info character
492      !---------------------------------------------------------------------
493      !
494      if90id = iom_file(kiomid)%nfid
495      lenddef = .false.
496      IF( PRESENT(cdvar) ) THEN
497         ! check the variable exists in the file
498         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
499         IF( .NOT. llok ) THEN
500            CALL ctl_warn('iom_nf90_putatt: no variable '//cdvar//' found')
501         ENDIF
502      ELSE
503         llok = .true.
504         ivarid = NF90_GLOBAL
505      ENDIF
506      !
507      IF( llok) THEN
508         clinfo = 'iom_nf90_putatt, file: '//TRIM(iom_file(kiomid)%name)//', piatt: '//TRIM(cdatt)
509         IF( iom_file(kiomid)%irec /= -1 ) THEN   
510            ! trick: irec used to know if the file is in define mode or not
511            ! if it is not then temporarily put it into define mode
512            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)
513            lenddef = .true.
514         ENDIF
515         !
516         CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values=pv_i0d), clinfo)
517         !
518         IF( lenddef ) THEN   
519            ! file was in data mode on entry; put it back in that mode
520            CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)
521         ENDIF
522      ELSE
523         CALL ctl_warn('iom_nf90_putatt: no attribute '//cdatt//' written')
524      ENDIF
525      !
526   END SUBROUTINE iom_nf90_piatt
527
528
529   SUBROUTINE iom_nf90_pratt( kiomid, cdatt, pv_r0d, cdvar )
530      !!-----------------------------------------------------------------------
531      !!                  ***  ROUTINE  iom_nf90_pratt  ***
532      !!
533      !! ** Purpose : write a real attribute with NF90
534      !!              (either a global attribute (default) or a variable
535      !!               attribute if optional variable name is supplied (cdvar))
536      !!-----------------------------------------------------------------------
537      INTEGER                   , INTENT(in   ) ::   kiomid   ! Identifier of the file
538      CHARACTER(len=*)          , INTENT(in   ) ::   cdatt    ! attribute name
539      REAL(wp)                  , INTENT(in   ) ::   pv_r0d   ! write field
540      CHARACTER(len=*), OPTIONAL, INTENT(in   ) ::   cdvar    ! name of the variable
541      !
542      INTEGER            ::   if90id   ! temporary integer
543      INTEGER            ::   ivarid   ! NetCDF variable Id
544      LOGICAL            ::   llok     ! temporary logical
545      LOGICAL            ::   lenddef  ! temporary logical
546      CHARACTER(LEN=100) ::   clinfo   ! info character
547      !---------------------------------------------------------------------
548      !
549      if90id = iom_file(kiomid)%nfid
550      lenddef = .false.
551      IF( PRESENT(cdvar) ) THEN
552         ! check the variable exists in the file
553         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
554         IF( .NOT. llok ) THEN
555            CALL ctl_warn('iom_nf90_putatt: no variable '//cdvar//' found')
556         ENDIF
557      ELSE
558         llok = .true.
559         ivarid = NF90_GLOBAL
560      ENDIF
561      !
562      IF( llok) THEN
563         clinfo = 'iom_nf90_putatt, file: '//TRIM(iom_file(kiomid)%name)//', pratt: '//TRIM(cdatt)
564         IF( iom_file(kiomid)%irec /= -1 ) THEN   
565            ! trick: irec used to know if the file is in define mode or not
566            ! if it is not then temporarily put it into define mode
567            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)
568            lenddef = .true.
569         ENDIF
570         !
571         CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values=pv_r0d), clinfo)
572         !
573         IF( lenddef ) THEN   
574            ! file was in data mode on entry; put it back in that mode
575            CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)
576         ENDIF
577      ELSE
578         CALL ctl_warn('iom_nf90_putatt: no attribute '//cdatt//' written')
579      ENDIF
580      !
581   END SUBROUTINE iom_nf90_pratt
582
583
584   SUBROUTINE iom_nf90_pcatt( kiomid, cdatt, pv_c0d, cdvar )
585      !!-----------------------------------------------------------------------
586      !!                  ***  ROUTINE  iom_nf90_pcatt  ***
587      !!
588      !! ** Purpose : write a character attribute with NF90
589      !!              (either a global attribute (default) or a variable
590      !!               attribute if optional variable name is supplied (cdvar))
591      !!-----------------------------------------------------------------------
592      INTEGER                   , INTENT(in   ) ::   kiomid   ! Identifier of the file
593      CHARACTER(len=*)          , INTENT(in   ) ::   cdatt    ! attribute name
594      CHARACTER(len=*)          , INTENT(in   ) ::   pv_c0d   ! write field
595      CHARACTER(len=*), OPTIONAL, INTENT(in   ) ::   cdvar    ! name of the variable
596      !
597      INTEGER            ::   if90id   ! temporary integer
598      INTEGER            ::   ivarid   ! NetCDF variable Id
599      LOGICAL            ::   llok     ! temporary logical
600      LOGICAL            ::   lenddef  ! temporary logical
601      CHARACTER(LEN=100) ::   clinfo   ! info character
602      !---------------------------------------------------------------------
603      !
604      if90id = iom_file(kiomid)%nfid
605      lenddef = .false.
606      IF( PRESENT(cdvar) ) THEN
607         ! check the variable exists in the file
608         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
609         IF( .NOT. llok ) THEN
610            CALL ctl_warn('iom_nf90_putatt: no variable '//cdvar//' found')
611         ENDIF
612      ELSE
613         llok = .true.
614         ivarid = NF90_GLOBAL
615      ENDIF
616      !
617      IF( llok) THEN
618         clinfo = 'iom_nf90_putatt, file: '//TRIM(iom_file(kiomid)%name)//', pcatt: '//TRIM(cdatt)
619         IF( iom_file(kiomid)%irec /= -1 ) THEN   
620            ! trick: irec used to know if the file is in define mode or not
621            ! if it is not then temporarily put it into define mode
622            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)
623            lenddef = .true.
624         ENDIF
625         !
626         CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values=pv_c0d), clinfo)
627         !
628         IF( lenddef ) THEN   
629            ! file was in data mode on entry; put it back in that mode
630            CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)
631         ENDIF
632      ELSE
633         CALL ctl_warn('iom_nf90_putatt: no attribute '//cdatt//' written')
634      ENDIF
635      !
636   END SUBROUTINE iom_nf90_pcatt
637
638
639   SUBROUTINE iom_nf90_gettime( kiomid, kvid, ptime, cdunits, cdcalendar )
640      !!--------------------------------------------------------------------
641      !!                   ***  SUBROUTINE iom_gettime  ***
642      !!
643      !! ** Purpose : read the time axis kvid in the file with NF90
644      !!--------------------------------------------------------------------
645      INTEGER                   , INTENT(in   ) ::   kiomid     ! file Identifier
646      INTEGER                   , INTENT(in   ) ::   kvid       ! variable id
647      REAL(wp), DIMENSION(:)    , INTENT(  out) ::   ptime      ! the time axis
648      CHARACTER(len=*), OPTIONAL, INTENT(  out) ::   cdunits    ! units attribute
649      CHARACTER(len=*), OPTIONAL, INTENT(  out) ::   cdcalendar ! calendar attribute
650      !
651      CHARACTER(LEN=100) ::   clinfo     ! info character
652      !---------------------------------------------------------------------
653      clinfo = 'iom_nf90_gettime, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
654      CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), ptime(:),   &
655            &                           start=(/ 1 /), count=(/ iom_file(kiomid)%dimsz(1, kvid) /)), clinfo)
656      IF ( PRESENT(cdunits) ) THEN
657         CALL iom_nf90_check(NF90_GET_ATT(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), "units", &
658            &                           values=cdunits), clinfo)
659      ENDIF
660      IF ( PRESENT(cdcalendar) ) THEN
661         CALL iom_nf90_check(NF90_GET_ATT(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), "calendar", &
662            &                           values=cdcalendar), clinfo)
663      ENDIF
664      !
665   END SUBROUTINE iom_nf90_gettime
666
667
668   SUBROUTINE iom_nf90_rp0123d( kt, kwrite, kiomid, cdvar , kvid  , ktype,   &
669         &                                  pv_r0d, pv_r1d, pv_r2d, pv_r3d )
670      !!--------------------------------------------------------------------
671      !!                   ***  SUBROUTINE  iom_nf90_rstput  ***
672      !!
673      !! ** Purpose : read the time axis cdvar in the file
674      !!--------------------------------------------------------------------
675      INTEGER                     , INTENT(in)           ::   kt       ! ocean time-step
676      INTEGER                     , INTENT(in)           ::   kwrite   ! writing time-step
677      INTEGER                     , INTENT(in)           ::   kiomid   ! Identifier of the file
678      CHARACTER(len=*)            , INTENT(in)           ::   cdvar    ! variable name
679      INTEGER                     , INTENT(in)           ::   kvid     ! variable id
680      INTEGER                     , INTENT(in), OPTIONAL ::   ktype    ! variable type (default R8)
681      REAL(wp)                    , INTENT(in), OPTIONAL ::   pv_r0d   ! written Od field
682      REAL(wp), DIMENSION(      :), INTENT(in), OPTIONAL ::   pv_r1d   ! written 1d field
683      REAL(wp), DIMENSION(:, :   ), INTENT(in), OPTIONAL ::   pv_r2d   ! written 2d field
684      REAL(wp), DIMENSION(:, :, :), INTENT(in), OPTIONAL ::   pv_r3d   ! written 3d field
685      !
686      INTEGER               :: idims                ! number of dimension
687      INTEGER               :: idvar                ! variable id
688      INTEGER               :: jd                   ! dimension loop counter   
689      INTEGER               :: ix1, ix2, iy1, iy2   ! subdomain indexes   
690      INTEGER, DIMENSION(4) :: idimsz               ! dimensions size 
691      INTEGER, DIMENSION(4) :: idimid               ! dimensions id
692      CHARACTER(LEN=256)    :: clinfo               ! info character
693      CHARACTER(LEN= 12), DIMENSION(5) :: cltmp     ! temporary character
694      INTEGER               :: if90id               ! nf90 file identifier
695      INTEGER               :: idmy                 ! dummy variable
696      INTEGER               :: itype                ! variable type
697      INTEGER, DIMENSION(4) :: ichunksz             ! NetCDF4 chunk sizes. Will be computed using
698      !                                             ! nn_nchunks_[i,j,k,t] namelist parameters
699      INTEGER               :: ichunkalg, ishuffle, ideflate, ideflate_level
700      !                                             ! NetCDF4 internally fixed parameters
701      LOGICAL               :: lchunk               ! logical switch to activate chunking and compression
702      !                                             ! when appropriate (currently chunking is applied to 4d fields only)
703      INTEGER               :: idlv                 ! local variable
704      INTEGER               :: idim3                ! id of the third dimension
705      !---------------------------------------------------------------------
706      !
707      clinfo = '          iom_nf90_rp0123d, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
708      if90id = iom_file(kiomid)%nfid
709      !
710      ! define dimension variables if it is not already done
711      ! ==========================
712      IF( iom_file(kiomid)%nvars == 0 ) THEN
713         ! are we in define mode?
714         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
715            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
716         ENDIF
717         ! define the dimension variables if it is not already done
718         cltmp = (/ 'nav_lon', 'nav_lat', 'nav_lev', 'time_counter', 'numcat' /)
719         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(1)), NF90_FLOAT , (/ 1, 2 /), iom_file(kiomid)%nvid(1) ), clinfo)
720         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(2)), NF90_FLOAT , (/ 1, 2 /), iom_file(kiomid)%nvid(2) ), clinfo)
721         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(3)), NF90_FLOAT , (/ 3    /), iom_file(kiomid)%nvid(3) ), clinfo)
722         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(4)), NF90_DOUBLE, (/ 4    /), iom_file(kiomid)%nvid(4) ), clinfo)
723         ! update informations structure related the dimension variable we just added...
724         iom_file(kiomid)%nvars       = 4
725         iom_file(kiomid)%luld(1:4)   = (/ .FALSE., .FALSE., .FALSE., .TRUE. /)
726         iom_file(kiomid)%cn_var(1:4) = cltmp(1:4)
727         iom_file(kiomid)%ndims(1:4)  = (/ 2, 2, 1, 1 /)
728         IF( NF90_INQ_DIMID( if90id, 'numcat', idmy ) == nf90_noerr ) THEN   ! add a 5th variable corresponding to the 5th dimension
729            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(5)), NF90_FLOAT , (/ 5 /), iom_file(kiomid)%nvid(5) ), clinfo)
730            iom_file(kiomid)%nvars     = 5
731            iom_file(kiomid)%luld(5)   = .FALSE.
732            iom_file(kiomid)%cn_var(5) = cltmp(5)
733            iom_file(kiomid)%ndims(5)  = 1
734         ENDIF
735         ! trick: defined to 0 to say that dimension variables are defined but not yet written
736         iom_file(kiomid)%dimsz(1, 1)  = 0   
737         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' define dimension variables done'
738      ENDIF
739      ! define the data if it is not already done
740      ! ===============
741      IF( kvid <= 0 ) THEN
742         !
743         ! NetCDF4 chunking and compression fixed settings
744         ichunkalg = 0
745         ishuffle = 1
746         ideflate = 1
747         ideflate_level = 1
748         !
749         idvar = iom_file(kiomid)%nvars + 1
750         ! are we in define mode?
751         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
752            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
753         ENDIF
754         ! variable definition
755         IF(     PRESENT(pv_r0d) ) THEN   ;   idims = 0
756         ELSEIF( PRESENT(pv_r1d) ) THEN
757            IF( SIZE(pv_r1d,1) == jpk ) THEN   ;   idim3 = 3
758            ELSE                               ;   idim3 = 5
759            ENDIF
760                                              idims = 2   ;   idimid(1:idims) = (/idim3,4/)
761         ELSEIF( PRESENT(pv_r2d) ) THEN   ;   idims = 3   ;   idimid(1:idims) = (/1,2  ,4/)
762         ELSEIF( PRESENT(pv_r3d) ) THEN
763            IF( SIZE(pv_r3d,3) == jpk ) THEN   ;   idim3 = 3
764            ELSE                               ;   idim3 = 5
765            ENDIF
766                                              idims = 4   ;   idimid(1:idims) = (/1,2,idim3,4/)
767         ENDIF
768         IF( PRESENT(ktype) ) THEN   ! variable external type
769            SELECT CASE (ktype)
770            CASE (jp_r8)   ;   itype = NF90_DOUBLE
771            CASE (jp_r4)   ;   itype = NF90_FLOAT
772            CASE (jp_i4)   ;   itype = NF90_INT
773            CASE (jp_i2)   ;   itype = NF90_SHORT
774            CASE (jp_i1)   ;   itype = NF90_BYTE
775            CASE DEFAULT   ;   CALL ctl_stop( TRIM(clinfo)//' unknown variable type' )
776            END SELECT
777         ELSE
778            itype = NF90_DOUBLE
779         ENDIF
780         IF( PRESENT(pv_r0d) ) THEN
781            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype,                    &
782               &                              iom_file(kiomid)%nvid(idvar) ), clinfo )
783         ELSE
784            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype, idimid(1:idims),   &
785               &                              iom_file(kiomid)%nvid(idvar) ), clinfo )
786         ENDIF
787         lchunk = .false.
788         IF( snc4set%luse .AND. idims == 4 )   lchunk = .true.
789         ! update informations structure related the new variable we want to add...
790         iom_file(kiomid)%nvars         = idvar
791         iom_file(kiomid)%cn_var(idvar) = TRIM(cdvar)
792         iom_file(kiomid)%scf(idvar)    = 1.
793         iom_file(kiomid)%ofs(idvar)    = 0.
794         iom_file(kiomid)%ndims(idvar)  = idims
795         IF( .NOT. PRESENT(pv_r0d) ) THEN   ;   iom_file(kiomid)%luld(idvar) = .TRUE.
796         ELSE                               ;   iom_file(kiomid)%luld(idvar) = .FALSE.
797         ENDIF
798         DO jd = 1, idims
799            CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, idimid(jd), len = iom_file(kiomid)%dimsz(jd,idvar) ), clinfo)
800            IF ( lchunk ) ichunksz(jd) = iom_file(kiomid)%dimsz(jd,idvar)
801         END DO
802         IF ( lchunk ) THEN
803            ! Calculate chunk sizes by partitioning each dimension as requested in namnc4 namelist
804            ! Disallow very small chunk sizes and prevent chunk sizes larger than each individual dimension
805            ichunksz(1) = MIN( ichunksz(1),MAX( (ichunksz(1)-1)/snc4set%ni + 1 ,16 ) ) ! Suggested default nc4set%ni=4
806            ichunksz(2) = MIN( ichunksz(2),MAX( (ichunksz(2)-1)/snc4set%nj + 1 ,16 ) ) ! Suggested default nc4set%nj=2
807            ichunksz(3) = MIN( ichunksz(3),MAX( (ichunksz(3)-1)/snc4set%nk + 1 , 1 ) ) ! Suggested default nc4set%nk=6
808            ichunksz(4) = 1                                                            ! Do not allow chunks to span the
809            !                                                                          ! unlimited dimension
810            CALL iom_nf90_check(SET_NF90_DEF_VAR_CHUNKING(if90id, idvar, ichunkalg, ichunksz), clinfo)
811            CALL iom_nf90_check(SET_NF90_DEF_VAR_DEFLATE(if90id, idvar, ishuffle, ideflate, ideflate_level), clinfo)
812            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' chunked ok. Chunks sizes: ', ichunksz
813         ENDIF
814         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' defined ok'
815      ELSE
816         idvar = kvid
817      ENDIF
818      !
819      ! time step kwrite : write the variable
820      IF( kt == kwrite ) THEN
821         ! are we in write mode?
822         IF( iom_file(kiomid)%irec == -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
823            CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = 0
824         ENDIF
825         ! on what kind of domain must the data be written?
826         IF( PRESENT(pv_r2d) .OR. PRESENT(pv_r3d) ) THEN
827            idimsz(1:2) = iom_file(kiomid)%dimsz(1:2,idvar)
828            IF(     idimsz(1) == (nlei - nldi + 1) .AND. idimsz(2) == (nlej - nldj + 1) ) THEN
829               ix1 = nldi   ;   ix2 = nlei   ;   iy1 = nldj   ;   iy2 = nlej
830            ELSEIF( idimsz(1) == nlci              .AND. idimsz(2) == nlcj              ) THEN
831               ix1 = 1      ;   ix2 = nlci   ;   iy1 = 1      ;   iy2 = nlcj
832            ELSEIF( idimsz(1) == jpi               .AND. idimsz(2) == jpj               ) THEN
833               ix1 = 1      ;   ix2 = jpi    ;   iy1 = 1      ;   iy2 = jpj
834            ELSE
835               CALL ctl_stop( 'iom_nf90_rp0123d: should have been an impossible case...' )
836            ENDIF
837
838            ! write dimension variables if it is not already done
839            ! =============
840            ! trick: is defined to 0 => dimension variable are defined but not yet written
841            IF( iom_file(kiomid)%dimsz(1, 1) == 0 ) THEN
842               CALL iom_nf90_check( NF90_INQ_VARID( if90id, 'nav_lon'     , idmy )         , clinfo )
843               CALL iom_nf90_check( NF90_PUT_VAR  ( if90id, idmy, glamt(ix1:ix2, iy1:iy2) ), clinfo )
844               CALL iom_nf90_check( NF90_INQ_VARID( if90id, 'nav_lat'     , idmy )         , clinfo )
845               CALL iom_nf90_check( NF90_PUT_VAR  ( if90id, idmy, gphit(ix1:ix2, iy1:iy2) ), clinfo )
846               CALL iom_nf90_check( NF90_INQ_VARID( if90id, 'nav_lev'     , idmy ), clinfo )
847               CALL iom_nf90_check( NF90_PUT_VAR  ( if90id, idmy, gdept_1d       ), clinfo )
848               IF( NF90_INQ_VARID( if90id, 'numcat', idmy ) == nf90_noerr ) THEN
849                  CALL iom_nf90_check( NF90_PUT_VAR  ( if90id, idmy, (/ (idlv, idlv = 1,iom_file(kiomid)%nlev) /)), clinfo )
850               ENDIF
851               ! +++ WRONG VALUE: to be improved but not really useful...
852               CALL iom_nf90_check( NF90_INQ_VARID( if90id, 'time_counter', idmy ), clinfo )
853               CALL iom_nf90_check( NF90_PUT_VAR( if90id, idmy, kt                      ), clinfo )   
854               ! update the values of the variables dimensions size
855               CALL iom_nf90_check( NF90_INQUIRE_DIMENSION( if90id, 1, len = iom_file(kiomid)%dimsz(1,1) ), clinfo )
856               CALL iom_nf90_check( NF90_INQUIRE_DIMENSION( if90id, 2, len = iom_file(kiomid)%dimsz(2,1) ), clinfo )
857               iom_file(kiomid)%dimsz(1:2, 2) = iom_file(kiomid)%dimsz(1:2, 1)
858               CALL iom_nf90_check( NF90_INQUIRE_DIMENSION( if90id, 3, len = iom_file(kiomid)%dimsz(1,3) ), clinfo )
859               iom_file(kiomid)%dimsz(1  , 4) = 1   ! unlimited dimension
860               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' write dimension variables done'
861            ENDIF
862         ENDIF
863
864         ! write the data
865         ! =============
866         IF(     PRESENT(pv_r0d) ) THEN
867            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r0d                    ), clinfo )
868         ELSEIF( PRESENT(pv_r1d) ) THEN
869            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r1d(:)                 ), clinfo )
870         ELSEIF( PRESENT(pv_r2d) ) THEN
871            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r2d(ix1:ix2,iy1:iy2)   ), clinfo )
872         ELSEIF( PRESENT(pv_r3d) ) THEN
873            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r3d(ix1:ix2,iy1:iy2,:) ), clinfo )
874         ENDIF
875         ! add 1 to the size of the temporal dimension (not really useful...)
876         IF( iom_file(kiomid)%luld(idvar) )   iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar)    &
877               &                            = iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar) + 1
878         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' written ok'
879      ENDIF
880      !     
881   END SUBROUTINE iom_nf90_rp0123d
882
883
884   SUBROUTINE iom_nf90_check( kstatus, cdinfo )
885      !!--------------------------------------------------------------------
886      !!                   ***  SUBROUTINE iom_nf90_check  ***
887      !!
888      !! ** Purpose :   check nf90 errors
889      !!--------------------------------------------------------------------
890      INTEGER,          INTENT(in) :: kstatus
891      CHARACTER(LEN=*), INTENT(in) :: cdinfo
892      !---------------------------------------------------------------------
893      IF(kstatus /= nf90_noerr)   CALL ctl_stop( 'iom_nf90_check : '//TRIM(nf90_strerror(kstatus)), TRIM(cdinfo) )
894   END SUBROUTINE iom_nf90_check
895
896   !!======================================================================
897END MODULE iom_nf90
Note: See TracBrowser for help on using the repository browser.