New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
restart.F90 in NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/OCE/IOM – NEMO

source: NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/OCE/IOM/restart.F90 @ 10380

Last change on this file since 10380 was 10380, checked in by smasson, 5 years ago

dev_r10164_HPC09_ESIWACE_PREP_MERGE: iom cleaning: (1) get rid of jpnf90, jprstlib, jlibalt, iolib and (2) improve iom_getatt and iom_putatt, see #2133
  • Property svn:keywords set to Id
File size: 16.1 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :  OPA  !  1999-11  (M. Imbard)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form
8   !!            2.0  !  2006-07  (S. Masson)  use IOM for restart
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  modified LF-RA
10   !!            - -  !  2010-10  (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11   !!            3.7  !  2014-01  (G. Madec) suppression of curl and hdiv from the restart
12   !!             -   !  2014-12  (G. Madec) remove KPP scheme
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   rst_opn    : open the ocean restart file
17   !!   rst_write  : write the ocean restart file
18   !!   rst_read   : read the ocean restart file
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and tracers
21   USE dom_oce         ! ocean space and time domain
22   USE sbc_ice         ! only lk_si3
23   USE phycst          ! physical constants
24   USE eosbn2          ! equation of state            (eos bn2 routine)
25   USE trdmxl_oce      ! ocean active mixed layer tracers trends variables
26   !
27   USE in_out_manager  ! I/O manager
28   USE iom             ! I/O module
29   USE diurnal_bulk
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   rst_opn         ! routine called by step module
35   PUBLIC   rst_write       ! routine called by step module
36   PUBLIC   rst_read        ! routine called by istate module
37   PUBLIC   rst_read_open   ! routine called in rst_read and (possibly) in dom_vvl_init
38
39   !! * Substitutions
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
43   !! $Id$
44   !! Software governed by the CeCILL license (see ./LICENSE)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE rst_opn( kt )
49      !!---------------------------------------------------------------------
50      !!                   ***  ROUTINE rst_opn  ***
51      !!                     
52      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
53      !!              + open the restart when we are one time step before nitrst
54      !!                   - restart header is defined when kt = nitrst-1
55      !!                   - restart data  are written when kt = nitrst
56      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
57      !!----------------------------------------------------------------------
58      INTEGER, INTENT(in) ::   kt     ! ocean time-step
59      !!
60      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
61      CHARACTER(LEN=50)   ::   clname   ! ocean output restart file name
62      CHARACTER(lc)       ::   clpath   ! full path to ocean output restart file
63      CHARACTER(LEN=52)   ::   clpname   ! ocean output restart file name including prefix for AGRIF
64      CHARACTER(LEN=256)  ::   clinfo    ! info character
65      !!----------------------------------------------------------------------
66      !
67      IF( kt == nit000 ) THEN   ! default definitions
68         lrst_oce = .FALSE.   
69         IF( ln_rst_list ) THEN
70            nrst_lst = 1
71            nitrst = nstocklist( nrst_lst )
72         ELSE
73            nitrst = nitend
74         ENDIF
75      ENDIF
76
77      ! frequency-based restart dumping (nn_stock)
78      IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nstock ) == 0 ) THEN   
79         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
80         nitrst = kt + nstock - 1                  ! define the next value of nitrst for restart writing
81         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
82      ENDIF
83      ! to get better performances with NetCDF format:
84      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
85      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
86      IF( kt == nitrst - 1 .OR. nstock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
87         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN 
88            ! beware of the format used to write kt (default is i8.8, that should be large enough...)
89            IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
90            ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst
91            ENDIF
92            ! create the file
93            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
94            clpath = TRIM(cn_ocerst_outdir)
95            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
96            IF(lwp) THEN
97               WRITE(numout,*)
98               IF(.NOT.lwxios) THEN
99                  WRITE(numout,*) '             open ocean restart NetCDF file: ',TRIM(clpath)//TRIM(clname)
100                  IF ( snc4set%luse )      WRITE(numout,*) '             opened for NetCDF4 chunking and compression'
101                  IF( kt == nitrst - 1 ) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
102                  ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
103                  ENDIF
104               ENDIF
105            ENDIF
106            !
107            IF(.NOT.lwxios) THEN
108               CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE. )
109            ELSE
110#if defined key_iomput
111               cwxios_context = "rstw_"//TRIM(ADJUSTL(clkt))
112               IF( TRIM(Agrif_CFixed()) == '0' ) THEN
113                  clpname = clname
114               ELSE
115                  clpname = TRIM(Agrif_CFixed())//"_"//clname   
116               ENDIF
117               CALL iom_init( cwxios_context, TRIM(clpath)//TRIM(clpname), .false. )
118               CALL xios_update_calendar(nitrst)
119               CALL iom_swap(      cxios_context          )
120#else
121               clinfo = 'Can not use XIOS in rst_opn'
122               CALL ctl_stop(TRIM(clinfo))
123#endif
124            ENDIF
125            lrst_oce = .TRUE.
126         ENDIF
127      ENDIF
128      !
129   END SUBROUTINE rst_opn
130
131
132   SUBROUTINE rst_write( kt )
133      !!---------------------------------------------------------------------
134      !!                   ***  ROUTINE rstwrite  ***
135      !!                     
136      !! ** Purpose :   Write restart fields in NetCDF format
137      !!
138      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
139      !!              file, save fields which are necessary for restart
140      !!----------------------------------------------------------------------
141      INTEGER, INTENT(in) ::   kt   ! ocean time-step
142      INTEGER             :: ji
143      !!----------------------------------------------------------------------
144                     IF(lwxios) CALL iom_swap(      cwxios_context          )
145                     CALL iom_rstput( kt, nitrst, numrow, 'rdt'    , rdt       , ldxios = lwxios)   ! dynamics time step
146                     DO ji = 1, nbdelay
147                        CALL iom_rstput( kt, nitrst, numrow, c_delaylist(ji), todelay(ji), ldxios = lwxios)
148                     END DO
149
150      IF ( .NOT. ln_diurnal_only ) THEN
151                     CALL iom_rstput( kt, nitrst, numrow, 'ub'     , ub, ldxios = lwxios        )     ! before fields
152                     CALL iom_rstput( kt, nitrst, numrow, 'vb'     , vb, ldxios = lwxios        )
153                     CALL iom_rstput( kt, nitrst, numrow, 'tb'     , tsb(:,:,:,jp_tem), ldxios = lwxios )
154                     CALL iom_rstput( kt, nitrst, numrow, 'sb'     , tsb(:,:,:,jp_sal), ldxios = lwxios )
155                     CALL iom_rstput( kt, nitrst, numrow, 'sshb'   , sshb, ldxios = lwxios      )
156                     !
157                     CALL iom_rstput( kt, nitrst, numrow, 'un'     , un, ldxios = lwxios        )     ! now fields
158                     CALL iom_rstput( kt, nitrst, numrow, 'vn'     , vn, ldxios = lwxios        )
159                     CALL iom_rstput( kt, nitrst, numrow, 'tn'     , tsn(:,:,:,jp_tem), ldxios = lwxios )
160                     CALL iom_rstput( kt, nitrst, numrow, 'sn'     , tsn(:,:,:,jp_sal), ldxios = lwxios )
161                     CALL iom_rstput( kt, nitrst, numrow, 'sshn'   , sshn, ldxios = lwxios      )
162                     CALL iom_rstput( kt, nitrst, numrow, 'rhop'   , rhop, ldxios = lwxios      )
163                  ! extra variable needed for the ice sheet coupling
164                  IF ( ln_iscpl ) THEN
165                     CALL iom_rstput( kt, nitrst, numrow, 'tmask'  , tmask, ldxios = lwxios ) ! need to extrapolate T/S
166                     CALL iom_rstput( kt, nitrst, numrow, 'umask'  , umask, ldxios = lwxios ) ! need to correct barotropic velocity
167                     CALL iom_rstput( kt, nitrst, numrow, 'vmask'  , vmask, ldxios = lwxios ) ! need to correct barotropic velocity
168                     CALL iom_rstput( kt, nitrst, numrow, 'smask'  , ssmask, ldxios = lwxios) ! need to correct barotropic velocity
169                     CALL iom_rstput( kt, nitrst, numrow, 'e3t_n', e3t_n(:,:,:), ldxios = lwxios )   ! need to compute temperature correction
170                     CALL iom_rstput( kt, nitrst, numrow, 'e3u_n', e3u_n(:,:,:), ldxios = lwxios )   ! need to compute bt conservation
171                     CALL iom_rstput( kt, nitrst, numrow, 'e3v_n', e3v_n(:,:,:), ldxios = lwxios )   ! need to compute bt conservation
172                     CALL iom_rstput( kt, nitrst, numrow, 'gdepw_n', gdepw_n(:,:,:), ldxios = lwxios ) ! need to compute extrapolation if vvl
173                  END IF
174      ENDIF
175     
176      IF (ln_diurnal) CALL iom_rstput( kt, nitrst, numrow, 'Dsst', x_dsst, ldxios = lwxios ) 
177      IF(lwxios) CALL iom_swap(      cxios_context          )
178      IF( kt == nitrst ) THEN
179         IF(.NOT.lwxios) THEN
180            CALL iom_close( numrow )     ! close the restart file (only at last time step)
181         ELSE
182            CALL iom_context_finalize(      cwxios_context          )
183         ENDIF
184!!gm         IF( .NOT. lk_trdmld )   lrst_oce = .FALSE.
185!!gm  not sure what to do here   ===>>>  ask to Sebastian
186         lrst_oce = .FALSE.
187            IF( ln_rst_list ) THEN
188               nrst_lst = MIN(nrst_lst + 1, SIZE(nstocklist,1))
189               nitrst = nstocklist( nrst_lst )
190            ENDIF
191      ENDIF
192      !
193   END SUBROUTINE rst_write
194
195
196   SUBROUTINE rst_read_open
197      !!----------------------------------------------------------------------
198      !!                   ***  ROUTINE rst_read_open  ***
199      !!
200      !! ** Purpose :   Open read files for NetCDF restart
201      !!
202      !! ** Method  :   Use a non-zero, positive value of numror to assess whether or not
203      !!                the file has already been opened
204      !!----------------------------------------------------------------------
205      LOGICAL        ::   llok
206      CHARACTER(lc)  ::   clpath   ! full path to ocean output restart file
207      !!----------------------------------------------------------------------
208      !
209      IF( numror <= 0 ) THEN
210         IF(lwp) THEN                                             ! Contol prints
211            WRITE(numout,*)
212            WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
213            IF ( snc4set%luse )      WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
214            WRITE(numout,*) '~~~~~~~~'
215         ENDIF
216         lxios_sini = .FALSE.
217         clpath = TRIM(cn_ocerst_indir)
218         IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
219         CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror )
220! are we using XIOS to read the data? Part above will have to modified once XIOS
221! can handle checking if variable is in the restart file (there will be no need to open
222! restart)
223         IF(.NOT.lxios_set) lrxios = lrxios.AND.lxios_sini
224         IF( lrxios) THEN
225             crxios_context = 'nemo_rst'
226             IF( .NOT.lxios_set ) THEN
227                 IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS'
228                 CALL iom_init( crxios_context, ld_tmppatch = .false. )
229                 lxios_set = .TRUE.
230             ENDIF
231         ENDIF
232         IF( TRIM(Agrif_CFixed()) /= '0' .AND. lrxios) THEN
233             CALL iom_init( crxios_context, ld_tmppatch = .false. )
234             IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS for AGRIF'
235             lxios_set = .TRUE.
236         ENDIF
237      ENDIF
238
239   END SUBROUTINE rst_read_open
240
241
242   SUBROUTINE rst_read
243      !!----------------------------------------------------------------------
244      !!                   ***  ROUTINE rst_read  ***
245      !!
246      !! ** Purpose :   Read files for NetCDF restart
247      !!
248      !! ** Method  :   Read in restart.nc file fields which are necessary for restart
249      !!----------------------------------------------------------------------
250      REAL(wp) ::   zrdt
251      INTEGER  ::   ji, jk
252      REAL(wp), DIMENSION(jpi, jpj, jpk) :: w3d
253      !!----------------------------------------------------------------------
254
255      CALL rst_read_open           ! open restart for reading (if not already opened)
256
257      ! Check dynamics and tracer time-step consistency and force Euler restart if changed
258      IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 )   THEN
259         CALL iom_get( numror, 'rdt', zrdt, ldxios = lrxios )
260         IF( zrdt /= rdt )   neuler = 0
261      ENDIF
262
263      DO ji = 1, nbdelay
264         IF( iom_varid( numror, c_delaylist(ji), ldstop = .FALSE. ) > 0 )  THEN
265            CALL iom_get( numror, c_delaylist(ji), todelay(ji), ldxios = lrxios )
266            ndelayid(ji) = 0   ! set to 0 to speficy that the value was read in the restart
267         ENDIF
268      END DO
269     
270      ! Diurnal DSST
271      IF( ln_diurnal ) CALL iom_get( numror, jpdom_autoglo, 'Dsst' , x_dsst, ldxios = lrxios ) 
272      IF ( ln_diurnal_only ) THEN
273         IF(lwp) WRITE( numout, * ) &
274         &   "rst_read:- ln_diurnal_only set, setting rhop=rau0" 
275         rhop = rau0
276         CALL iom_get( numror, jpdom_autoglo, 'tn'     , w3d, ldxios = lrxios ) 
277         tsn(:,:,1,jp_tem) = w3d(:,:,1)
278         RETURN
279      ENDIF 
280     
281      IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
282         CALL iom_get( numror, jpdom_autoglo, 'ub'     , ub, ldxios = lrxios                )   ! before fields
283         CALL iom_get( numror, jpdom_autoglo, 'vb'     , vb, ldxios = lrxios                )
284         CALL iom_get( numror, jpdom_autoglo, 'tb'     , tsb(:,:,:,jp_tem), ldxios = lrxios )
285         CALL iom_get( numror, jpdom_autoglo, 'sb'     , tsb(:,:,:,jp_sal), ldxios = lrxios )
286         CALL iom_get( numror, jpdom_autoglo, 'sshb'   , sshb, ldxios = lrxios              )
287      ELSE
288         neuler = 0
289      ENDIF
290      !
291      CALL iom_get( numror, jpdom_autoglo, 'un'     , un, ldxios = lrxios )   ! now    fields
292      CALL iom_get( numror, jpdom_autoglo, 'vn'     , vn, ldxios = lrxios )
293      CALL iom_get( numror, jpdom_autoglo, 'tn'     , tsn(:,:,:,jp_tem), ldxios = lrxios )
294      CALL iom_get( numror, jpdom_autoglo, 'sn'     , tsn(:,:,:,jp_sal), ldxios = lrxios )
295      CALL iom_get( numror, jpdom_autoglo, 'sshn'   , sshn, ldxios = lrxios )
296      IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
297         CALL iom_get( numror, jpdom_autoglo, 'rhop'   , rhop, ldxios = lrxios )   ! now    potential density
298      ELSE
299         CALL eos( tsn, rhd, rhop, gdept_n(:,:,:) )   
300      ENDIF
301      !
302      IF( neuler == 0 ) THEN                                  ! Euler restart (neuler=0)
303         tsb  (:,:,:,:) = tsn  (:,:,:,:)                             ! all before fields set to now values
304         ub   (:,:,:)   = un   (:,:,:)
305         vb   (:,:,:)   = vn   (:,:,:)
306         sshb (:,:)     = sshn (:,:)
307         !
308         IF( .NOT.ln_linssh ) THEN
309            DO jk = 1, jpk
310               e3t_b(:,:,jk) = e3t_n(:,:,jk)
311            END DO
312         ENDIF
313         !
314      ENDIF
315      !
316   END SUBROUTINE rst_read
317
318   !!=====================================================================
319END MODULE restart
Note: See TracBrowser for help on using the repository browser.