source: NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/OCE/SBC/sbcfwb.F90 @ 10365

Last change on this file since 10365 was 10365, checked in by smasson, 22 months ago

dev_r10164_HPC09_ESIWACE_PREP_MERGE: merge with dev_r9866_HPC_03_globcom, see #2133

  • Property svn:keywords set to Id
File size: 11.8 KB
Line 
1MODULE sbcfwb
2   !!======================================================================
3   !!                       ***  MODULE  sbcfwb  ***
4   !! Ocean fluxes   : domain averaged freshwater budget
5   !!======================================================================
6   !! History :  OPA  ! 2001-02  (E. Durand)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-08  (G. Madec)  Surface module
9   !!            3.2  ! 2009-07  (C. Talandier) emp mean s spread over erp area
10   !!            3.6  ! 2014-11  (P. Mathiot  ) add ice shelf melting
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_fwb       : freshwater budget for global ocean configurations (free surface & forced mode)
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and tracers
17   USE dom_oce        ! ocean space and time domain
18   USE sbc_oce        ! surface ocean boundary condition
19   USE sbc_ice , ONLY : snwice_mass, snwice_mass_b, snwice_fmass
20   USE phycst         ! physical constants
21   USE sbcrnf         ! ocean runoffs
22   USE sbcisf         ! ice shelf melting contribution
23   USE sbcssr         ! Sea-Surface damping terms
24   !
25   USE in_out_manager ! I/O manager
26   USE lib_mpp        ! distribued memory computing library
27   USE timing         ! Timing
28   USE lbclnk         ! ocean lateral boundary conditions
29   USE lib_fortran    !
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   sbc_fwb    ! routine called by step
35
36   REAL(wp) ::   a_fwb_b   ! annual domain averaged freshwater budget
37   REAL(wp) ::   a_fwb     ! for 2 year before (_b) and before year.
38   REAL(wp) ::   fwfold    ! fwfold to be suppressed
39   REAL(wp) ::   area      ! global mean ocean surface (interior domain)
40
41   !! * Substitutions
42#  include "vectopt_loop_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
45   !! $Id$
46   !! Software governed by the CeCILL license (see ./LICENSE)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50   SUBROUTINE sbc_fwb( kt, kn_fwb, kn_fsbc )
51      !!---------------------------------------------------------------------
52      !!                  ***  ROUTINE sbc_fwb  ***
53      !!
54      !! ** Purpose :   Control the mean sea surface drift
55      !!
56      !! ** Method  :   several ways  depending on kn_fwb
57      !!                =0 no control
58      !!                =1 global mean of emp set to zero at each nn_fsbc time step
59      !!                =2 annual global mean corrected from previous year
60      !!                =3 global mean of emp set to zero at each nn_fsbc time step
61      !!                   & spread out over erp area depending its sign
62      !! Note: if sea ice is embedded it is taken into account when computing the budget
63      !!----------------------------------------------------------------------
64      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
65      INTEGER, INTENT( in ) ::   kn_fsbc  !
66      INTEGER, INTENT( in ) ::   kn_fwb   ! ocean time-step index
67      !
68      INTEGER  ::   inum, ikty, iyear     ! local integers
69      REAL(wp) ::   z_fwf, z_fwf_nsrf, zsum_fwf, zsum_erp                ! local scalars
70      REAL(wp) ::   zsurf_neg, zsurf_pos, zsurf_tospread, zcoef          !   -      -
71      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   ztmsk_neg, ztmsk_pos, z_wgt ! 2D workspaces
72      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   ztmsk_tospread, zerp_cor    !   -      -
73      !!----------------------------------------------------------------------
74      !
75      IF( kt == nit000 ) THEN
76         IF(lwp) THEN
77            WRITE(numout,*)
78            WRITE(numout,*) 'sbc_fwb : FreshWater Budget correction'
79            WRITE(numout,*) '~~~~~~~'
80            IF( kn_fwb == 1 )   WRITE(numout,*) '          instantaneously set to zero'
81            IF( kn_fwb == 2 )   WRITE(numout,*) '          adjusted from previous year budget'
82            IF( kn_fwb == 3 )   WRITE(numout,*) '          fwf set to zero and spread out over erp area'
83         ENDIF
84         !
85         IF( kn_fwb == 3 .AND. nn_sssr /= 2 )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 requires nn_sssr = 2, we stop ' )
86         IF( kn_fwb == 3 .AND. ln_isfcav    )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 with ln_isfcav = .TRUE. not working, we stop ' )
87         !
88         area = glob_sum( 'sbcfwb', e1e2t(:,:) * tmask(:,:,1))           ! interior global domain surface
89         ! isf cavities are excluded because it can feedback to the melting with generation of inhibition of plumes
90         ! and in case of no melt, it can generate HSSW.
91         !
92#if ! defined key_si3 && ! defined key_cice
93         snwice_mass_b(:,:) = 0.e0               ! no sea-ice model is being used : no snow+ice mass
94         snwice_mass  (:,:) = 0.e0
95#endif
96         !
97      ENDIF
98
99      SELECT CASE ( kn_fwb )
100      !
101      CASE ( 1 )                             !==  global mean fwf set to zero  ==!
102         !
103         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
104            z_fwf = glob_sum( 'sbcfwb', e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + fwfisf(:,:) - snwice_fmass(:,:) ) ) / area   ! sum over the global domain
105            zcoef = z_fwf * rcp
106            emp(:,:) = emp(:,:) - z_fwf              * tmask(:,:,1)
107            qns(:,:) = qns(:,:) + zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction
108         ENDIF
109         !
110      CASE ( 2 )                             !==  fwf budget adjusted from the previous year  ==!
111         !
112         IF( kt == nit000 ) THEN                      ! initialisation
113            !                                         ! Read the corrective factor on precipitations (fwfold)
114            CALL ctl_opn( inum, 'EMPave_old.dat', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE. )
115            READ ( inum, "(24X,I8,2ES24.16)" ) iyear, a_fwb_b, a_fwb
116            CLOSE( inum )
117            fwfold = a_fwb                            ! current year freshwater budget correction
118            !                                         ! estimate from the previous year budget
119            IF(lwp)WRITE(numout,*)
120            IF(lwp)WRITE(numout,*)'sbc_fwb : year = ',iyear  , ' freshwater budget correction = ', fwfold
121            IF(lwp)WRITE(numout,*)'          year = ',iyear-1, ' freshwater budget read       = ', a_fwb
122            IF(lwp)WRITE(numout,*)'          year = ',iyear-2, ' freshwater budget read       = ', a_fwb_b
123         ENDIF   
124         !                                         ! Update fwfold if new year start
125         ikty = 365 * 86400 / rdt                  !!bug  use of 365 days leap year or 360d year !!!!!!!
126         IF( MOD( kt, ikty ) == 0 ) THEN
127            a_fwb_b = a_fwb                           ! mean sea level taking into account the ice+snow
128                                                      ! sum over the global domain
129            a_fwb   = glob_sum( 'sbcfwb', e1e2t(:,:) * ( sshn(:,:) + snwice_mass(:,:) * r1_rau0 ) )
130            a_fwb   = a_fwb * 1.e+3 / ( area * rday * 365. )     ! convert in Kg/m3/s = mm/s
131!!gm        !                                                      !!bug 365d year
132            fwfold =  a_fwb                           ! current year freshwater budget correction
133            !                                         ! estimate from the previous year budget
134         ENDIF
135         !
136         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN         ! correct the freshwater fluxes
137            zcoef = fwfold * rcp
138            emp(:,:) = emp(:,:) + fwfold             * tmask(:,:,1)
139            qns(:,:) = qns(:,:) - zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction
140         ENDIF
141         !
142         IF( kt == nitend .AND. lwp ) THEN            ! save fwfold value in a file
143            CALL ctl_opn( inum, 'EMPave.dat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE., narea )
144            WRITE( inum, "(24X,I8,2ES24.16)" ) nyear, a_fwb_b, a_fwb
145            CLOSE( inum )
146         ENDIF
147         !
148      CASE ( 3 )                             !==  global fwf set to zero and spread out over erp area  ==!
149         !
150         ALLOCATE( ztmsk_neg(jpi,jpj) , ztmsk_pos(jpi,jpj) , ztmsk_tospread(jpi,jpj) , z_wgt(jpi,jpj) , zerp_cor(jpi,jpj) )
151         !
152         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
153            ztmsk_pos(:,:) = tmask_i(:,:)                      ! Select <0 and >0 area of erp
154            WHERE( erp < 0._wp )   ztmsk_pos = 0._wp
155            ztmsk_neg(:,:) = tmask_i(:,:) - ztmsk_pos(:,:)
156            !                                                  ! fwf global mean (excluding ocean to ice/snow exchanges)
157            z_fwf     = glob_sum( 'sbcfwb', e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + fwfisf(:,:) - snwice_fmass(:,:) ) ) / area
158            !           
159            IF( z_fwf < 0._wp ) THEN         ! spread out over >0 erp area to increase evaporation
160               zsurf_pos = glob_sum( 'sbcfwb', e1e2t(:,:)*ztmsk_pos(:,:) )
161               zsurf_tospread      = zsurf_pos
162               ztmsk_tospread(:,:) = ztmsk_pos(:,:)
163            ELSE                             ! spread out over <0 erp area to increase precipitation
164               zsurf_neg = glob_sum( 'sbcfwb', e1e2t(:,:)*ztmsk_neg(:,:) )  ! Area filled by <0 and >0 erp
165               zsurf_tospread      = zsurf_neg
166               ztmsk_tospread(:,:) = ztmsk_neg(:,:)
167            ENDIF
168            !
169            zsum_fwf   = glob_sum( 'sbcfwb', e1e2t(:,:) * z_fwf )         ! fwf global mean over <0 or >0 erp area
170!!gm :  zsum_fwf   = z_fwf * area   ???  it is right?  I think so....
171            z_fwf_nsrf =  zsum_fwf / ( zsurf_tospread + rsmall )
172            !                                                  ! weight to respect erp field 2D structure
173            zsum_erp   = glob_sum( 'sbcfwb', ztmsk_tospread(:,:) * erp(:,:) * e1e2t(:,:) )
174            z_wgt(:,:) = ztmsk_tospread(:,:) * erp(:,:) / ( zsum_erp + rsmall )
175            !                                                  ! final correction term to apply
176            zerp_cor(:,:) = -1. * z_fwf_nsrf * zsurf_tospread * z_wgt(:,:)
177            !
178!!gm   ===>>>>  lbc_lnk should be useless as all the computation is done over the whole domain !
179            CALL lbc_lnk( 'sbcfwb', zerp_cor, 'T', 1. )
180            !
181            emp(:,:) = emp(:,:) + zerp_cor(:,:)
182            qns(:,:) = qns(:,:) - zerp_cor(:,:) * rcp * sst_m(:,:)  ! account for change to the heat budget due to fw correction
183            erp(:,:) = erp(:,:) + zerp_cor(:,:)
184            !
185            IF( nprint == 1 .AND. lwp ) THEN                   ! control print
186               IF( z_fwf < 0._wp ) THEN
187                  WRITE(numout,*)'   z_fwf < 0'
188                  WRITE(numout,*)'   SUM(erp+)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
189               ELSE
190                  WRITE(numout,*)'   z_fwf >= 0'
191                  WRITE(numout,*)'   SUM(erp-)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
192               ENDIF
193               WRITE(numout,*)'   SUM(empG)     = ', SUM( z_fwf*e1e2t(:,:) )*1.e-9,' Sv'
194               WRITE(numout,*)'   z_fwf         = ', z_fwf      ,' Kg/m2/s'
195               WRITE(numout,*)'   z_fwf_nsrf    = ', z_fwf_nsrf ,' Kg/m2/s'
196               WRITE(numout,*)'   MIN(zerp_cor) = ', MINVAL(zerp_cor) 
197               WRITE(numout,*)'   MAX(zerp_cor) = ', MAXVAL(zerp_cor) 
198            ENDIF
199         ENDIF
200         DEALLOCATE( ztmsk_neg , ztmsk_pos , ztmsk_tospread , z_wgt , zerp_cor )
201         !
202      CASE DEFAULT                           !==  you should never be there  ==!
203         CALL ctl_stop( 'sbc_fwb : wrong nn_fwb value for the FreshWater Budget correction, choose either 1, 2 or 3' )
204         !
205      END SELECT
206      !
207   END SUBROUTINE sbc_fwb
208
209   !!======================================================================
210END MODULE sbcfwb
Note: See TracBrowser for help on using the repository browser.