source: NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/OCE/nemogcm.F90

Last change on this file was 10407, checked in by smasson, 22 months ago

dev_r10164_HPC09_ESIWACE_PREP_MERGE: send back error code, see #2181

  • Property svn:keywords set to Id
File size: 31.6 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
33   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
34   !!----------------------------------------------------------------------
35
36   !!----------------------------------------------------------------------
37   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
38   !!   nemo_init     : initialization of the NEMO system
39   !!   nemo_ctl      : initialisation of the contol print
40   !!   nemo_closefile: close remaining open files
41   !!   nemo_alloc    : dynamical allocation
42   !!----------------------------------------------------------------------
43   USE step_oce       ! module used in the ocean time stepping module (step.F90)
44   USE phycst         ! physical constant                  (par_cst routine)
45   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
46   USE closea         ! treatment of closed seas (for ln_closea)
47   USE usrdef_nam     ! user defined configuration
48   USE tideini        ! tidal components initialization   (tide_ini routine)
49   USE bdy_oce,  ONLY : ln_bdy
50   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
51   USE istate         ! initial state setting          (istate_init routine)
52   USE ldfdyn         ! lateral viscosity setting      (ldfdyn_init routine)
53   USE ldftra         ! lateral diffusivity setting    (ldftra_init routine)
54   USE trdini         ! dyn/tra trends initialization     (trd_init routine)
55   USE asminc         ! assimilation increments     
56   USE asmbkg         ! writing out state trajectory
57   USE diaptr         ! poleward transports           (dia_ptr_init routine)
58   USE diadct         ! sections transports           (dia_dct_init routine)
59   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
60   USE diacfl         ! CFL diagnostics               (dia_cfl_init routine)
61   USE step           ! NEMO time-stepping                 (stp     routine)
62   USE icbini         ! handle bergs, initialisation
63   USE icbstp         ! handle bergs, calving, themodynamics and transport
64   USE cpl_oasis3     ! OASIS3 coupling
65   USE c1d            ! 1D configuration
66   USE step_c1d       ! Time stepping loop for the 1D configuration
67   USE dyndmp         ! Momentum damping
68   USE stopar         ! Stochastic param.: ???
69   USE stopts         ! Stochastic param.: ???
70   USE diurnal_bulk   ! diurnal bulk SST
71   USE step_diu       ! diurnal bulk SST timestepping (called from here if run offline)
72   USE crsini         ! initialise grid coarsening utility
73   USE diatmb         ! Top,middle,bottom output
74   USE dia25h         ! 25h mean output
75   USE sbc_oce , ONLY : lk_oasis
76   USE wet_dry        ! Wetting and drying setting   (wad_init routine)
77#if defined key_top
78   USE trcini         ! passive tracer initialisation
79#endif
80#if defined key_nemocice_decomp
81   USE ice_domain_size, only: nx_global, ny_global
82#endif
83   !
84   USE lib_mpp        ! distributed memory computing
85   USE mppini         ! shared/distributed memory setting (mpp_init routine)
86   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
87   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
88#if defined key_iomput
89   USE xios           ! xIOserver
90#endif
91#if defined key_agrif
92   USE agrif_all_update   ! Master Agrif update
93#endif
94
95   IMPLICIT NONE
96   PRIVATE
97
98   PUBLIC   nemo_gcm    ! called by model.F90
99   PUBLIC   nemo_init   ! needed by AGRIF
100   PUBLIC   nemo_alloc  ! needed by TAM
101
102   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
103
104#if defined key_mpp_mpi
105   INCLUDE 'mpif.h'
106#endif
107
108   !!----------------------------------------------------------------------
109   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
110   !! $Id$
111   !! Software governed by the CeCILL license (see ./LICENSE)
112   !!----------------------------------------------------------------------
113CONTAINS
114
115   SUBROUTINE nemo_gcm
116      !!----------------------------------------------------------------------
117      !!                     ***  ROUTINE nemo_gcm  ***
118      !!
119      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
120      !!              curvilinear mesh on the sphere.
121      !!
122      !! ** Method  : - model general initialization
123      !!              - launch the time-stepping (stp routine)
124      !!              - finalize the run by closing files and communications
125      !!
126      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
127      !!              Madec, 2008, internal report, IPSL.
128      !!----------------------------------------------------------------------
129      INTEGER ::   istp   ! time step index
130      !!----------------------------------------------------------------------
131      !
132#if defined key_agrif
133      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
134#endif
135      !                            !-----------------------!
136      CALL nemo_init               !==  Initialisations  ==!
137      !                            !-----------------------!
138#if defined key_agrif
139      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
140      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
141# if defined key_top
142      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
143# endif
144# if defined key_si3
145      CALL Agrif_Declare_Var_ice   !  "      "   "   "      "  Sea ice
146# endif
147#endif
148      ! check that all process are still there... If some process have an error,
149      ! they will never enter in step and other processes will wait until the end of the cpu time!
150      CALL mpp_max( 'nemogcm', nstop )
151
152      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
153
154      !                            !-----------------------!
155      !                            !==   time stepping   ==!
156      !                            !-----------------------!
157      istp = nit000
158      !
159#if defined key_c1d
160      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  C1D time-stepping  ==!
161         CALL stp_c1d( istp )
162         istp = istp + 1
163      END DO
164#else
165      !
166# if defined key_agrif
167      !                                               !==  AGRIF time-stepping  ==!
168      CALL Agrif_Regrid()
169      !
170      ! Recursive update from highest nested level to lowest:
171      CALL Agrif_step_child_adj(Agrif_Update_All)
172      !
173      DO WHILE( istp <= nitend .AND. nstop == 0 )
174         CALL stp
175         istp = istp + 1
176      END DO
177      !
178      IF( .NOT. Agrif_Root() ) THEN
179         CALL Agrif_ParentGrid_To_ChildGrid()
180         IF( ln_diaobs )   CALL dia_obs_wri
181         IF( ln_timing )   CALL timing_finalize
182         CALL Agrif_ChildGrid_To_ParentGrid()
183      ENDIF
184      !
185# else
186      !
187      IF( .NOT.ln_diurnal_only ) THEN                 !==  Standard time-stepping  ==!
188         !
189         DO WHILE( istp <= nitend .AND. nstop == 0 )
190#if defined key_mpp_mpi
191            ncom_stp = istp
192            IF ( istp == ( nit000 + 1 ) ) elapsed_time = MPI_Wtime()
193            IF ( istp ==         nitend ) elapsed_time = MPI_Wtime() - elapsed_time
194#endif
195            CALL stp        ( istp ) 
196            istp = istp + 1
197         END DO
198         !
199      ELSE                                            !==  diurnal SST time-steeping only  ==!
200         !
201         DO WHILE( istp <= nitend .AND. nstop == 0 )
202            CALL stp_diurnal( istp )   ! time step only the diurnal SST
203            istp = istp + 1
204         END DO
205         !
206      ENDIF
207      !
208# endif
209      !
210#endif
211      !
212      IF( ln_diaobs   )   CALL dia_obs_wri
213      !
214      IF( ln_icebergs )   CALL icb_end( nitend )
215
216      !                            !------------------------!
217      !                            !==  finalize the run  ==!
218      !                            !------------------------!
219      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
220      !
221      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
222         WRITE(numout,cform_err)
223         WRITE(numout,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
224         WRITE(numout,*)
225      ENDIF
226      !
227      IF( ln_timing )   CALL timing_finalize
228      !
229      CALL nemo_closefile
230      !
231#if defined key_iomput
232                                    CALL xios_finalize  ! end mpp communications with xios
233      IF( lk_oasis     )            CALL cpl_finalize   ! end coupling and mpp communications with OASIS
234#else
235      IF    ( lk_oasis ) THEN   ;   CALL cpl_finalize   ! end coupling and mpp communications with OASIS
236      ELSEIF( lk_mpp   ) THEN   ;   CALL mppstop( ldfinal = .TRUE. )   ! end mpp communications
237      ENDIF
238#endif
239      !
240      IF( nstop == 0 ) THEN   ;   STOP 0
241      ELSE                    ;   STOP 999
242      ENDIF
243      !
244   END SUBROUTINE nemo_gcm
245
246
247   SUBROUTINE nemo_init
248      !!----------------------------------------------------------------------
249      !!                     ***  ROUTINE nemo_init  ***
250      !!
251      !! ** Purpose :   initialization of the NEMO GCM
252      !!----------------------------------------------------------------------
253      INTEGER  ::   ji                 ! dummy loop indices
254      INTEGER  ::   ios, ilocal_comm   ! local integers
255      CHARACTER(len=120), DIMENSION(60) ::   cltxt, cltxt2, clnam
256      !!
257      NAMELIST/namctl/ ln_ctl   , nn_print, nn_ictls, nn_ictle,   &
258         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,   &
259         &             ln_timing, ln_diacfl
260      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
261      !!----------------------------------------------------------------------
262      !
263      cltxt  = ''
264      cltxt2 = ''
265      clnam  = '' 
266      cxios_context = 'nemo'
267      !
268      !                             ! Open reference namelist and configuration namelist files
269      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
270      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
271      !
272      REWIND( numnam_ref )              ! Namelist namctl in reference namelist
273      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
274901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
275      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist
276      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
277902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
278      !
279      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist
280      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
281903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
282      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist
283      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
284904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
285
286      !                             !--------------------------!
287      !                             !  Set global domain size  !   (control print return in cltxt2)
288      !                             !--------------------------!
289      IF( ln_read_cfg ) THEN              ! Read sizes in domain configuration file
290         CALL domain_cfg ( cltxt2,        cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
291         !
292      ELSE                                ! user-defined namelist
293         CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
294      ENDIF
295      !
296      !
297      !                             !--------------------------------------------!
298      !                             !  set communicator & select the local node  !
299      !                             !  NB: mynode also opens output.namelist.dyn !
300      !                             !      on unit number numond on first proc   !
301      !                             !--------------------------------------------!
302#if defined key_iomput
303      IF( Agrif_Root() ) THEN
304         IF( lk_oasis ) THEN
305            CALL cpl_init( "oceanx", ilocal_comm )                               ! nemo local communicator given by oasis
306            CALL xios_initialize( "not used"       ,local_comm= ilocal_comm )    ! send nemo communicator to xios
307         ELSE
308            CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
309         ENDIF
310      ENDIF
311      ! Nodes selection (control print return in cltxt)
312      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
313#else
314      IF( lk_oasis ) THEN
315         IF( Agrif_Root() ) THEN
316            CALL cpl_init( "oceanx", ilocal_comm )          ! nemo local communicator given by oasis
317         ENDIF
318         ! Nodes selection (control print return in cltxt)
319         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
320      ELSE
321         ilocal_comm = 0                                    ! Nodes selection (control print return in cltxt)
322         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
323      ENDIF
324#endif
325
326      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
327
328      lwm = (narea == 1)                                    ! control of output namelists
329      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
330
331      IF(lwm) THEN               ! write merged namelists from earlier to output namelist
332         !                       ! now that the file has been opened in call to mynode.
333         !                       ! NB: nammpp has already been written in mynode (if lk_mpp_mpi)
334         WRITE( numond, namctl )
335         WRITE( numond, namcfg )
336         IF( .NOT.ln_read_cfg ) THEN
337            DO ji = 1, SIZE(clnam)
338               IF( TRIM(clnam(ji)) /= '' )   WRITE(numond, * ) clnam(ji)     ! namusr_def print
339            END DO
340         ENDIF
341      ENDIF
342
343      IF(lwp) THEN                            ! open listing units
344         !
345         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
346         !
347         WRITE(numout,*)
348         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
349         WRITE(numout,*) '                       NEMO team'
350         WRITE(numout,*) '            Ocean General Circulation Model'
351         WRITE(numout,*) '                NEMO version 4.0  (2017) '
352         WRITE(numout,*)
353         WRITE(numout,*)
354         DO ji = 1, SIZE(cltxt)
355            IF( TRIM(cltxt (ji)) /= '' )   WRITE(numout,*) TRIM(cltxt(ji))    ! control print of mynode
356         END DO
357         WRITE(numout,*)
358         WRITE(numout,*)
359         DO ji = 1, SIZE(cltxt2)
360            IF( TRIM(cltxt2(ji)) /= '' )   WRITE(numout,*) TRIM(cltxt2(ji))   ! control print of domain size
361         END DO
362         !
363         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
364         !
365      ENDIF
366      ! open /dev/null file to be able to supress output write easily
367      CALL ctl_opn( numnul, '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
368      !
369      !                                      ! Domain decomposition
370      CALL mpp_init                          ! MPP
371
372      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
373      CALL nemo_alloc()
374
375      !                             !-------------------------------!
376      !                             !  NEMO general initialization  !
377      !                             !-------------------------------!
378
379      CALL nemo_ctl                          ! Control prints
380      !
381      !                                      ! General initialization
382      IF( ln_timing    )   CALL timing_init     ! timing
383      IF( ln_timing    )   CALL timing_start( 'nemo_init')
384      !
385                           CALL     phy_cst         ! Physical constants
386                           CALL     eos_init        ! Equation of state
387      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
388                           CALL     wad_init        ! Wetting and drying options
389                           CALL     dom_init("OPA") ! Domain
390      IF( ln_crs       )   CALL     crs_init        ! coarsened grid: domain initialization
391      IF( ln_ctl       )   CALL prt_ctl_init        ! Print control
392     
393      CALL diurnal_sst_bulk_init                ! diurnal sst
394      IF( ln_diurnal   )   CALL diurnal_sst_coolskin_init   ! cool skin   
395      !                           
396      IF( ln_diurnal_only ) THEN                   ! diurnal only: a subset of the initialisation routines
397         CALL  istate_init                            ! ocean initial state (Dynamics and tracers)
398         CALL     sbc_init                            ! Forcings : surface module
399         CALL tra_qsr_init                            ! penetrative solar radiation qsr
400         IF( ln_diaobs ) THEN                         ! Observation & model comparison
401            CALL dia_obs_init                            ! Initialize observational data
402            CALL dia_obs( nit000 - 1 )                   ! Observation operator for restart
403         ENDIF     
404         IF( lk_asminc )   CALL asm_inc_init          ! Assimilation increments
405         !
406         RETURN                                       ! end of initialization
407      ENDIF
408     
409                           CALL  istate_init    ! ocean initial state (Dynamics and tracers)
410
411      !                                      ! external forcing
412                           CALL    tide_init    ! tidal harmonics
413                           CALL     sbc_init    ! surface boundary conditions (including sea-ice)
414                           CALL     bdy_init    ! Open boundaries initialisation
415
416      !                                      ! Ocean physics
417                           CALL zdf_phy_init    ! Vertical physics
418                                     
419      !                                         ! Lateral physics
420                           CALL ldf_tra_init      ! Lateral ocean tracer physics
421                           CALL ldf_eiv_init      ! eddy induced velocity param.
422                           CALL ldf_dyn_init      ! Lateral ocean momentum physics
423
424      !                                      ! Active tracers
425      IF( ln_traqsr    )   CALL tra_qsr_init      ! penetrative solar radiation qsr
426                           CALL tra_bbc_init      ! bottom heat flux
427                           CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
428                           CALL tra_dmp_init      ! internal tracer damping
429                           CALL tra_adv_init      ! horizontal & vertical advection
430                           CALL tra_ldf_init      ! lateral mixing
431
432      !                                      ! Dynamics
433      IF( lk_c1d       )   CALL dyn_dmp_init      ! internal momentum damping
434                           CALL dyn_adv_init      ! advection (vector or flux form)
435                           CALL dyn_vor_init      ! vorticity term including Coriolis
436                           CALL dyn_ldf_init      ! lateral mixing
437                           CALL dyn_hpg_init      ! horizontal gradient of Hydrostatic pressure
438                           CALL dyn_spg_init      ! surface pressure gradient
439
440#if defined key_top
441      !                                      ! Passive tracers
442                           CALL     trc_init
443#endif
444      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
445
446      !                                      ! Icebergs
447                           CALL icb_init( rdt, nit000)   ! initialise icebergs instance
448
449      !                                      ! Misc. options
450                           CALL sto_par_init    ! Stochastic parametrization
451      IF( ln_sto_eos   )   CALL sto_pts_init    ! RRandom T/S fluctuations
452     
453      !                                      ! Diagnostics
454      IF( lk_floats    )   CALL     flo_init    ! drifting Floats
455      IF( ln_diacfl    )   CALL dia_cfl_init    ! Initialise CFL diagnostics
456                           CALL dia_ptr_init    ! Poleward TRansports initialization
457      IF( lk_diadct    )   CALL dia_dct_init    ! Sections tranports
458                           CALL dia_hsb_init    ! heat content, salt content and volume budgets
459                           CALL     trd_init    ! Mixed-layer/Vorticity/Integral constraints trends
460                           CALL dia_obs_init    ! Initialize observational data
461                           CALL dia_tmb_init    ! TMB outputs
462                           CALL dia_25h_init    ! 25h mean  outputs
463      IF( ln_diaobs    )   CALL dia_obs( nit000-1 )   ! Observation operator for restart
464
465      !                                      ! Assimilation increments
466      IF( lk_asminc    )   CALL asm_inc_init    ! Initialize assimilation increments
467      !
468      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
469      !
470      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
471      !
472   END SUBROUTINE nemo_init
473
474
475   SUBROUTINE nemo_ctl
476      !!----------------------------------------------------------------------
477      !!                     ***  ROUTINE nemo_ctl  ***
478      !!
479      !! ** Purpose :   control print setting
480      !!
481      !! ** Method  : - print namctl information and check some consistencies
482      !!----------------------------------------------------------------------
483      !
484      IF(lwp) THEN                  ! control print
485         WRITE(numout,*)
486         WRITE(numout,*) 'nemo_ctl: Control prints'
487         WRITE(numout,*) '~~~~~~~~'
488         WRITE(numout,*) '   Namelist namctl'
489         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
490         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
491         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
492         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
493         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
494         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
495         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
496         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
497         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
498         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
499      ENDIF
500      !
501      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
502      nictls    = nn_ictls
503      nictle    = nn_ictle
504      njctls    = nn_jctls
505      njctle    = nn_jctle
506      isplt     = nn_isplt
507      jsplt     = nn_jsplt
508
509      IF(lwp) THEN                  ! control print
510         WRITE(numout,*)
511         WRITE(numout,*) '   Namelist namcfg'
512         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
513         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
514         WRITE(numout,*) '         keep closed seas in the domain (if exist)     ln_closea     = ', ln_closea
515         WRITE(numout,*) '      create a configuration definition file        ln_write_cfg     = ', ln_write_cfg
516         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
517         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
518      ENDIF
519      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
520      !
521      !                             ! Parameter control
522      !
523      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
524         IF( lk_mpp .AND. jpnij > 1 ) THEN
525            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
526         ELSE
527            IF( isplt == 1 .AND. jsplt == 1  ) THEN
528               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
529                  &           ' - the print control will be done over the whole domain' )
530            ENDIF
531            ijsplt = isplt * jsplt            ! total number of processors ijsplt
532         ENDIF
533         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
534         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
535         !
536         !                              ! indices used for the SUM control
537         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
538            lsp_area = .FALSE.
539         ELSE                                             ! print control done over a specific  area
540            lsp_area = .TRUE.
541            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
542               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
543               nictls = 1
544            ENDIF
545            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
546               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
547               nictle = jpiglo
548            ENDIF
549            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
550               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
551               njctls = 1
552            ENDIF
553            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
554               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
555               njctle = jpjglo
556            ENDIF
557         ENDIF
558      ENDIF
559      !
560      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
561         &                                                'Compile with key_nosignedzero enabled:',   &
562         &                                                '--> add -Dkey_nosignedzero to the definition of %CPP in your arch file' )
563      !
564#if defined key_agrif
565      IF( ln_timing )   CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
566#endif
567      !
568   END SUBROUTINE nemo_ctl
569
570
571   SUBROUTINE nemo_closefile
572      !!----------------------------------------------------------------------
573      !!                     ***  ROUTINE nemo_closefile  ***
574      !!
575      !! ** Purpose :   Close the files
576      !!----------------------------------------------------------------------
577      !
578      IF( lk_mpp )   CALL mppsync
579      !
580      CALL iom_close                                 ! close all input/output files managed by iom_*
581      !
582      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
583      IF( numrun          /= -1 )   CLOSE( numrun          )   ! run statistics file
584      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
585      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
586      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
587      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
588      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
589      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
590      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
591      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
592      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
593      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
594      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
595      !
596      numout = 6                                     ! redefine numout in case it is used after this point...
597      !
598   END SUBROUTINE nemo_closefile
599
600
601   SUBROUTINE nemo_alloc
602      !!----------------------------------------------------------------------
603      !!                     ***  ROUTINE nemo_alloc  ***
604      !!
605      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
606      !!
607      !! ** Method  :
608      !!----------------------------------------------------------------------
609      USE diawri    , ONLY : dia_wri_alloc
610      USE dom_oce   , ONLY : dom_oce_alloc
611      USE trc_oce   , ONLY : trc_oce_alloc
612      USE bdy_oce   , ONLY : bdy_oce_alloc
613#if defined key_diadct 
614      USE diadct    , ONLY : diadct_alloc 
615#endif 
616      !
617      INTEGER :: ierr
618      !!----------------------------------------------------------------------
619      !
620      ierr =        oce_alloc    ()    ! ocean
621      ierr = ierr + dia_wri_alloc()
622      ierr = ierr + dom_oce_alloc()    ! ocean domain
623      ierr = ierr + zdf_oce_alloc()    ! ocean vertical physics
624      ierr = ierr + trc_oce_alloc()    ! shared TRC / TRA arrays
625      ierr = ierr + bdy_oce_alloc()    ! bdy masks (incl. initialization)
626      !
627#if defined key_diadct 
628      ierr = ierr + diadct_alloc ()    !
629#endif 
630      !
631      CALL mpp_sum( 'nemogcm', ierr )
632      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
633      !
634   END SUBROUTINE nemo_alloc
635
636   !!======================================================================
637END MODULE nemogcm
638
Note: See TracBrowser for help on using the repository browser.