New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/OCE – NEMO

source: NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/OCE/nemogcm.F90 @ 10170

Last change on this file since 10170 was 10170, checked in by smasson, 5 years ago

dev_r10164_HPC09_ESIWACE_PREP_MERGE: action 2a: add report calls of lbc_lnk, see #2133

  • Property svn:keywords set to Id
File size: 31.0 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
33   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
34   !!----------------------------------------------------------------------
35
36   !!----------------------------------------------------------------------
37   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
38   !!   nemo_init     : initialization of the NEMO system
39   !!   nemo_ctl      : initialisation of the contol print
40   !!   nemo_closefile: close remaining open files
41   !!   nemo_alloc    : dynamical allocation
42   !!----------------------------------------------------------------------
43   USE step_oce       ! module used in the ocean time stepping module (step.F90)
44   USE phycst         ! physical constant                  (par_cst routine)
45   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
46   USE closea         ! treatment of closed seas (for ln_closea)
47   USE usrdef_nam     ! user defined configuration
48   USE tideini        ! tidal components initialization   (tide_ini routine)
49   USE bdy_oce,  ONLY : ln_bdy
50   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
51   USE istate         ! initial state setting          (istate_init routine)
52   USE ldfdyn         ! lateral viscosity setting      (ldfdyn_init routine)
53   USE ldftra         ! lateral diffusivity setting    (ldftra_init routine)
54   USE trdini         ! dyn/tra trends initialization     (trd_init routine)
55   USE asminc         ! assimilation increments     
56   USE asmbkg         ! writing out state trajectory
57   USE diaptr         ! poleward transports           (dia_ptr_init routine)
58   USE diadct         ! sections transports           (dia_dct_init routine)
59   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
60   USE diacfl         ! CFL diagnostics               (dia_cfl_init routine)
61   USE step           ! NEMO time-stepping                 (stp     routine)
62   USE icbini         ! handle bergs, initialisation
63   USE icbstp         ! handle bergs, calving, themodynamics and transport
64   USE cpl_oasis3     ! OASIS3 coupling
65   USE c1d            ! 1D configuration
66   USE step_c1d       ! Time stepping loop for the 1D configuration
67   USE dyndmp         ! Momentum damping
68   USE stopar         ! Stochastic param.: ???
69   USE stopts         ! Stochastic param.: ???
70   USE diurnal_bulk   ! diurnal bulk SST
71   USE step_diu       ! diurnal bulk SST timestepping (called from here if run offline)
72   USE crsini         ! initialise grid coarsening utility
73   USE diatmb         ! Top,middle,bottom output
74   USE dia25h         ! 25h mean output
75   USE sbc_oce , ONLY : lk_oasis
76   USE wet_dry        ! Wetting and drying setting   (wad_init routine)
77#if defined key_top
78   USE trcini         ! passive tracer initialisation
79#endif
80#if defined key_nemocice_decomp
81   USE ice_domain_size, only: nx_global, ny_global
82#endif
83   !
84   USE lib_mpp        ! distributed memory computing
85   USE mppini         ! shared/distributed memory setting (mpp_init routine)
86   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
87   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
88#if defined key_iomput
89   USE xios           ! xIOserver
90#endif
91#if defined key_agrif
92   USE agrif_all_update   ! Master Agrif update
93#endif
94
95   IMPLICIT NONE
96   PRIVATE
97
98   PUBLIC   nemo_gcm    ! called by model.F90
99   PUBLIC   nemo_init   ! needed by AGRIF
100   PUBLIC   nemo_alloc  ! needed by TAM
101
102   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
103
104   !!----------------------------------------------------------------------
105   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
106   !! $Id$
107   !! Software governed by the CeCILL license (see ./LICENSE)
108   !!----------------------------------------------------------------------
109CONTAINS
110
111   SUBROUTINE nemo_gcm
112      !!----------------------------------------------------------------------
113      !!                     ***  ROUTINE nemo_gcm  ***
114      !!
115      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
116      !!              curvilinear mesh on the sphere.
117      !!
118      !! ** Method  : - model general initialization
119      !!              - launch the time-stepping (stp routine)
120      !!              - finalize the run by closing files and communications
121      !!
122      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
123      !!              Madec, 2008, internal report, IPSL.
124      !!----------------------------------------------------------------------
125      INTEGER ::   istp   ! time step index
126      !!----------------------------------------------------------------------
127      !
128#if defined key_agrif
129      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
130#endif
131      !                            !-----------------------!
132      CALL nemo_init               !==  Initialisations  ==!
133      !                            !-----------------------!
134#if defined key_agrif
135      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
136      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
137# if defined key_top
138      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
139# endif
140# if defined key_si3
141      CALL Agrif_Declare_Var_ice   !  "      "   "   "      "  Sea ice
142# endif
143#endif
144      ! check that all process are still there... If some process have an error,
145      ! they will never enter in step and other processes will wait until the end of the cpu time!
146      IF( lk_mpp )   CALL mpp_max( nstop )
147
148      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
149
150      !                            !-----------------------!
151      !                            !==   time stepping   ==!
152      !                            !-----------------------!
153      istp = nit000
154      !
155#if defined key_c1d
156      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  C1D time-stepping  ==!
157         CALL stp_c1d( istp )
158         istp = istp + 1
159      END DO
160#else
161      !
162# if defined key_agrif
163      !                                               !==  AGRIF time-stepping  ==!
164      CALL Agrif_Regrid()
165      !
166      ! Recursive update from highest nested level to lowest:
167      CALL Agrif_step_child_adj(Agrif_Update_All)
168      !
169      DO WHILE( istp <= nitend .AND. nstop == 0 )
170         CALL stp
171         istp = istp + 1
172      END DO
173      !
174      IF( .NOT. Agrif_Root() ) THEN
175         CALL Agrif_ParentGrid_To_ChildGrid()
176         IF( ln_diaobs )   CALL dia_obs_wri
177         IF( ln_timing )   CALL timing_finalize
178         CALL Agrif_ChildGrid_To_ParentGrid()
179      ENDIF
180      !
181# else
182      !
183      IF( .NOT.ln_diurnal_only ) THEN                 !==  Standard time-stepping  ==!
184         !
185         DO WHILE( istp <= nitend .AND. nstop == 0 )
186#if   defined key_mpp_mpi
187            ncom_stp = istp
188#endif
189            CALL stp        ( istp ) 
190            istp = istp + 1
191         END DO
192         !
193      ELSE                                            !==  diurnal SST time-steeping only  ==!
194         !
195         DO WHILE( istp <= nitend .AND. nstop == 0 )
196            CALL stp_diurnal( istp )   ! time step only the diurnal SST
197            istp = istp + 1
198         END DO
199         !
200      ENDIF
201      !
202# endif
203      !
204#endif
205      !
206      IF( ln_diaobs   )   CALL dia_obs_wri
207      !
208      IF( ln_icebergs )   CALL icb_end( nitend )
209
210      !                            !------------------------!
211      !                            !==  finalize the run  ==!
212      !                            !------------------------!
213      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
214      !
215      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
216         WRITE(numout,cform_err)
217         WRITE(numout,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
218         WRITE(numout,*)
219      ENDIF
220      !
221      IF( ln_timing )   CALL timing_finalize
222      !
223      CALL nemo_closefile
224      !
225#if defined key_iomput
226                                    CALL xios_finalize  ! end mpp communications with xios
227      IF( lk_oasis     )            CALL cpl_finalize   ! end coupling and mpp communications with OASIS
228#else
229      IF    ( lk_oasis ) THEN   ;   CALL cpl_finalize   ! end coupling and mpp communications with OASIS
230      ELSEIF( lk_mpp   ) THEN   ;   CALL mppstop        ! end mpp communications
231      ENDIF
232#endif
233      !
234   END SUBROUTINE nemo_gcm
235
236
237   SUBROUTINE nemo_init
238      !!----------------------------------------------------------------------
239      !!                     ***  ROUTINE nemo_init  ***
240      !!
241      !! ** Purpose :   initialization of the NEMO GCM
242      !!----------------------------------------------------------------------
243      INTEGER  ::   ji                 ! dummy loop indices
244      INTEGER  ::   ios, ilocal_comm   ! local integers
245      CHARACTER(len=120), DIMENSION(60) ::   cltxt, cltxt2, clnam
246      !!
247      NAMELIST/namctl/ ln_ctl   , nn_print, nn_ictls, nn_ictle,   &
248         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,   &
249         &             ln_timing, ln_diacfl
250      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
251      !!----------------------------------------------------------------------
252      !
253      cltxt  = ''
254      cltxt2 = ''
255      clnam  = '' 
256      cxios_context = 'nemo'
257      !
258      !                             ! Open reference namelist and configuration namelist files
259      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
260      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
261      !
262      REWIND( numnam_ref )              ! Namelist namctl in reference namelist
263      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
264901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
265      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist
266      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
267902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
268      !
269      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist
270      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
271903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
272      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist
273      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
274904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
275
276      !                             !--------------------------!
277      !                             !  Set global domain size  !   (control print return in cltxt2)
278      !                             !--------------------------!
279      IF( ln_read_cfg ) THEN              ! Read sizes in domain configuration file
280         CALL domain_cfg ( cltxt2,        cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
281         !
282      ELSE                                ! user-defined namelist
283         CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
284      ENDIF
285      !
286      !
287      !                             !--------------------------------------------!
288      !                             !  set communicator & select the local node  !
289      !                             !  NB: mynode also opens output.namelist.dyn !
290      !                             !      on unit number numond on first proc   !
291      !                             !--------------------------------------------!
292#if defined key_iomput
293      IF( Agrif_Root() ) THEN
294         IF( lk_oasis ) THEN
295            CALL cpl_init( "oceanx", ilocal_comm )                               ! nemo local communicator given by oasis
296            CALL xios_initialize( "not used"       ,local_comm= ilocal_comm )    ! send nemo communicator to xios
297         ELSE
298            CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
299         ENDIF
300      ENDIF
301      ! Nodes selection (control print return in cltxt)
302      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
303#else
304      IF( lk_oasis ) THEN
305         IF( Agrif_Root() ) THEN
306            CALL cpl_init( "oceanx", ilocal_comm )          ! nemo local communicator given by oasis
307         ENDIF
308         ! Nodes selection (control print return in cltxt)
309         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
310      ELSE
311         ilocal_comm = 0                                    ! Nodes selection (control print return in cltxt)
312         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
313      ENDIF
314#endif
315
316      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
317
318      lwm = (narea == 1)                                    ! control of output namelists
319      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
320
321      IF(lwm) THEN               ! write merged namelists from earlier to output namelist
322         !                       ! now that the file has been opened in call to mynode.
323         !                       ! NB: nammpp has already been written in mynode (if lk_mpp_mpi)
324         WRITE( numond, namctl )
325         WRITE( numond, namcfg )
326         IF( .NOT.ln_read_cfg ) THEN
327            DO ji = 1, SIZE(clnam)
328               IF( TRIM(clnam(ji)) /= '' )   WRITE(numond, * ) clnam(ji)     ! namusr_def print
329            END DO
330         ENDIF
331      ENDIF
332
333      IF(lwp) THEN                            ! open listing units
334         !
335         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
336         !
337         WRITE(numout,*)
338         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
339         WRITE(numout,*) '                       NEMO team'
340         WRITE(numout,*) '            Ocean General Circulation Model'
341         WRITE(numout,*) '                NEMO version 4.0  (2017) '
342         WRITE(numout,*)
343         WRITE(numout,*)
344         DO ji = 1, SIZE(cltxt)
345            IF( TRIM(cltxt (ji)) /= '' )   WRITE(numout,*) cltxt(ji)    ! control print of mynode
346         END DO
347         WRITE(numout,*)
348         WRITE(numout,*)
349         DO ji = 1, SIZE(cltxt2)
350            IF( TRIM(cltxt2(ji)) /= '' )   WRITE(numout,*) cltxt2(ji)   ! control print of domain size
351         END DO
352         !
353         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
354         !
355      ENDIF
356      !                                      ! Domain decomposition
357      CALL mpp_init                          ! MPP
358
359      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
360      CALL nemo_alloc()
361
362      !                             !-------------------------------!
363      !                             !  NEMO general initialization  !
364      !                             !-------------------------------!
365
366      CALL nemo_ctl                          ! Control prints
367      !
368      !                                      ! General initialization
369      IF( ln_timing    )   CALL timing_init     ! timing
370      IF( ln_timing    )   CALL timing_start( 'nemo_init')
371      !
372                           CALL     phy_cst         ! Physical constants
373                           CALL     eos_init        ! Equation of state
374      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
375                           CALL     wad_init        ! Wetting and drying options
376                           CALL     dom_init("OPA") ! Domain
377      IF( ln_crs       )   CALL     crs_init        ! coarsened grid: domain initialization
378      IF( ln_ctl       )   CALL prt_ctl_init        ! Print control
379     
380      CALL diurnal_sst_bulk_init                ! diurnal sst
381      IF( ln_diurnal   )   CALL diurnal_sst_coolskin_init   ! cool skin   
382      !                           
383      IF( ln_diurnal_only ) THEN                   ! diurnal only: a subset of the initialisation routines
384         CALL  istate_init                            ! ocean initial state (Dynamics and tracers)
385         CALL     sbc_init                            ! Forcings : surface module
386         CALL tra_qsr_init                            ! penetrative solar radiation qsr
387         IF( ln_diaobs ) THEN                         ! Observation & model comparison
388            CALL dia_obs_init                            ! Initialize observational data
389            CALL dia_obs( nit000 - 1 )                   ! Observation operator for restart
390         ENDIF     
391         IF( lk_asminc )   CALL asm_inc_init          ! Assimilation increments
392         !
393         RETURN                                       ! end of initialization
394      ENDIF
395     
396                           CALL  istate_init    ! ocean initial state (Dynamics and tracers)
397
398      !                                      ! external forcing
399                           CALL    tide_init    ! tidal harmonics
400                           CALL     sbc_init    ! surface boundary conditions (including sea-ice)
401                           CALL     bdy_init    ! Open boundaries initialisation
402
403      !                                      ! Ocean physics
404                           CALL zdf_phy_init    ! Vertical physics
405                                     
406      !                                         ! Lateral physics
407                           CALL ldf_tra_init      ! Lateral ocean tracer physics
408                           CALL ldf_eiv_init      ! eddy induced velocity param.
409                           CALL ldf_dyn_init      ! Lateral ocean momentum physics
410
411      !                                      ! Active tracers
412      IF( ln_traqsr    )   CALL tra_qsr_init      ! penetrative solar radiation qsr
413                           CALL tra_bbc_init      ! bottom heat flux
414      IF( ln_trabbl    )   CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
415                           CALL tra_dmp_init      ! internal tracer damping
416                           CALL tra_adv_init      ! horizontal & vertical advection
417                           CALL tra_ldf_init      ! lateral mixing
418
419      !                                      ! Dynamics
420      IF( lk_c1d       )   CALL dyn_dmp_init      ! internal momentum damping
421                           CALL dyn_adv_init      ! advection (vector or flux form)
422                           CALL dyn_vor_init      ! vorticity term including Coriolis
423                           CALL dyn_ldf_init      ! lateral mixing
424                           CALL dyn_hpg_init      ! horizontal gradient of Hydrostatic pressure
425                           CALL dyn_spg_init      ! surface pressure gradient
426
427#if defined key_top
428      !                                      ! Passive tracers
429                           CALL     trc_init
430#endif
431      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
432
433      !                                      ! Icebergs
434                           CALL icb_init( rdt, nit000)   ! initialise icebergs instance
435
436      !                                      ! Misc. options
437                           CALL sto_par_init    ! Stochastic parametrization
438      IF( ln_sto_eos   )   CALL sto_pts_init    ! RRandom T/S fluctuations
439     
440      !                                      ! Diagnostics
441      IF( lk_floats    )   CALL     flo_init    ! drifting Floats
442      IF( ln_diacfl    )   CALL dia_cfl_init    ! Initialise CFL diagnostics
443                           CALL dia_ptr_init    ! Poleward TRansports initialization
444      IF( lk_diadct    )   CALL dia_dct_init    ! Sections tranports
445                           CALL dia_hsb_init    ! heat content, salt content and volume budgets
446                           CALL     trd_init    ! Mixed-layer/Vorticity/Integral constraints trends
447                           CALL dia_obs_init    ! Initialize observational data
448                           CALL dia_tmb_init    ! TMB outputs
449                           CALL dia_25h_init    ! 25h mean  outputs
450      IF( ln_diaobs    )   CALL dia_obs( nit000-1 )   ! Observation operator for restart
451
452      !                                      ! Assimilation increments
453      IF( lk_asminc    )   CALL asm_inc_init    ! Initialize assimilation increments
454      !
455      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
456      !
457      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
458      !
459   END SUBROUTINE nemo_init
460
461
462   SUBROUTINE nemo_ctl
463      !!----------------------------------------------------------------------
464      !!                     ***  ROUTINE nemo_ctl  ***
465      !!
466      !! ** Purpose :   control print setting
467      !!
468      !! ** Method  : - print namctl information and check some consistencies
469      !!----------------------------------------------------------------------
470      !
471      IF(lwp) THEN                  ! control print
472         WRITE(numout,*)
473         WRITE(numout,*) 'nemo_ctl: Control prints'
474         WRITE(numout,*) '~~~~~~~~'
475         WRITE(numout,*) '   Namelist namctl'
476         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
477         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
478         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
479         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
480         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
481         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
482         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
483         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
484         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
485         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
486      ENDIF
487      !
488      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
489      nictls    = nn_ictls
490      nictle    = nn_ictle
491      njctls    = nn_jctls
492      njctle    = nn_jctle
493      isplt     = nn_isplt
494      jsplt     = nn_jsplt
495
496      IF(lwp) THEN                  ! control print
497         WRITE(numout,*)
498         WRITE(numout,*) '   Namelist namcfg'
499         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
500         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
501         WRITE(numout,*) '         keep closed seas in the domain (if exist)     ln_closea     = ', ln_closea
502         WRITE(numout,*) '      create a configuration definition file        ln_write_cfg     = ', ln_write_cfg
503         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
504         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
505      ENDIF
506      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
507      !
508      !                             ! Parameter control
509      !
510      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
511         IF( lk_mpp .AND. jpnij > 1 ) THEN
512            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
513         ELSE
514            IF( isplt == 1 .AND. jsplt == 1  ) THEN
515               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
516                  &           ' - the print control will be done over the whole domain' )
517            ENDIF
518            ijsplt = isplt * jsplt            ! total number of processors ijsplt
519         ENDIF
520         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
521         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
522         !
523         !                              ! indices used for the SUM control
524         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
525            lsp_area = .FALSE.
526         ELSE                                             ! print control done over a specific  area
527            lsp_area = .TRUE.
528            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
529               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
530               nictls = 1
531            ENDIF
532            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
533               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
534               nictle = jpiglo
535            ENDIF
536            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
537               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
538               njctls = 1
539            ENDIF
540            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
541               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
542               njctle = jpjglo
543            ENDIF
544         ENDIF
545      ENDIF
546      !
547      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
548         &                                                'Compile with key_nosignedzero enabled' )
549      !
550#if defined key_agrif
551      IF( ln_timing )   CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
552#endif
553      !
554   END SUBROUTINE nemo_ctl
555
556
557   SUBROUTINE nemo_closefile
558      !!----------------------------------------------------------------------
559      !!                     ***  ROUTINE nemo_closefile  ***
560      !!
561      !! ** Purpose :   Close the files
562      !!----------------------------------------------------------------------
563      !
564      IF( lk_mpp )   CALL mppsync
565      !
566      CALL iom_close                                 ! close all input/output files managed by iom_*
567      !
568      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
569      IF( numrun          /= -1 )   CLOSE( numrun          )   ! run statistics file
570      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
571      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
572      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
573      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
574      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
575      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
576      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
577      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
578      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
579      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
580      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
581      !
582      numout = 6                                     ! redefine numout in case it is used after this point...
583      !
584   END SUBROUTINE nemo_closefile
585
586
587   SUBROUTINE nemo_alloc
588      !!----------------------------------------------------------------------
589      !!                     ***  ROUTINE nemo_alloc  ***
590      !!
591      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
592      !!
593      !! ** Method  :
594      !!----------------------------------------------------------------------
595      USE diawri    , ONLY : dia_wri_alloc
596      USE dom_oce   , ONLY : dom_oce_alloc
597      USE trc_oce   , ONLY : trc_oce_alloc
598      USE bdy_oce   , ONLY : bdy_oce_alloc
599#if defined key_diadct 
600      USE diadct    , ONLY : diadct_alloc 
601#endif 
602      !
603      INTEGER :: ierr
604      !!----------------------------------------------------------------------
605      !
606      ierr =        oce_alloc    ()    ! ocean
607      ierr = ierr + dia_wri_alloc()
608      ierr = ierr + dom_oce_alloc()    ! ocean domain
609      ierr = ierr + zdf_oce_alloc()    ! ocean vertical physics
610      ierr = ierr + trc_oce_alloc()    ! shared TRC / TRA arrays
611      ierr = ierr + bdy_oce_alloc()    ! bdy masks (incl. initialization)
612      !
613#if defined key_diadct 
614      ierr = ierr + diadct_alloc ()    !
615#endif 
616      !
617      IF( lk_mpp    )   CALL mpp_sum( ierr )
618      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
619      !
620   END SUBROUTINE nemo_alloc
621
622   !!======================================================================
623END MODULE nemogcm
624
Note: See TracBrowser for help on using the repository browser.