source: NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/OCE/nemogcm.F90 @ 10297

Last change on this file since 10297 was 10297, checked in by smasson, 23 months ago

dev_r10164_HPC09_ESIWACE_PREP_MERGE: action 2a: add report calls of mppmin/max/sum, see #2133

  • Property svn:keywords set to Id
File size: 31.2 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
33   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
34   !!----------------------------------------------------------------------
35
36   !!----------------------------------------------------------------------
37   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
38   !!   nemo_init     : initialization of the NEMO system
39   !!   nemo_ctl      : initialisation of the contol print
40   !!   nemo_closefile: close remaining open files
41   !!   nemo_alloc    : dynamical allocation
42   !!----------------------------------------------------------------------
43   USE step_oce       ! module used in the ocean time stepping module (step.F90)
44   USE phycst         ! physical constant                  (par_cst routine)
45   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
46   USE closea         ! treatment of closed seas (for ln_closea)
47   USE usrdef_nam     ! user defined configuration
48   USE tideini        ! tidal components initialization   (tide_ini routine)
49   USE bdy_oce,  ONLY : ln_bdy
50   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
51   USE istate         ! initial state setting          (istate_init routine)
52   USE ldfdyn         ! lateral viscosity setting      (ldfdyn_init routine)
53   USE ldftra         ! lateral diffusivity setting    (ldftra_init routine)
54   USE trdini         ! dyn/tra trends initialization     (trd_init routine)
55   USE asminc         ! assimilation increments     
56   USE asmbkg         ! writing out state trajectory
57   USE diaptr         ! poleward transports           (dia_ptr_init routine)
58   USE diadct         ! sections transports           (dia_dct_init routine)
59   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
60   USE diacfl         ! CFL diagnostics               (dia_cfl_init routine)
61   USE step           ! NEMO time-stepping                 (stp     routine)
62   USE icbini         ! handle bergs, initialisation
63   USE icbstp         ! handle bergs, calving, themodynamics and transport
64   USE cpl_oasis3     ! OASIS3 coupling
65   USE c1d            ! 1D configuration
66   USE step_c1d       ! Time stepping loop for the 1D configuration
67   USE dyndmp         ! Momentum damping
68   USE stopar         ! Stochastic param.: ???
69   USE stopts         ! Stochastic param.: ???
70   USE diurnal_bulk   ! diurnal bulk SST
71   USE step_diu       ! diurnal bulk SST timestepping (called from here if run offline)
72   USE crsini         ! initialise grid coarsening utility
73   USE diatmb         ! Top,middle,bottom output
74   USE dia25h         ! 25h mean output
75   USE sbc_oce , ONLY : lk_oasis
76   USE wet_dry        ! Wetting and drying setting   (wad_init routine)
77#if defined key_top
78   USE trcini         ! passive tracer initialisation
79#endif
80#if defined key_nemocice_decomp
81   USE ice_domain_size, only: nx_global, ny_global
82#endif
83   !
84   USE lib_mpp        ! distributed memory computing
85   USE mppini         ! shared/distributed memory setting (mpp_init routine)
86   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
87   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
88#if defined key_iomput
89   USE xios           ! xIOserver
90#endif
91#if defined key_agrif
92   USE agrif_all_update   ! Master Agrif update
93#endif
94
95   IMPLICIT NONE
96   PRIVATE
97
98   PUBLIC   nemo_gcm    ! called by model.F90
99   PUBLIC   nemo_init   ! needed by AGRIF
100   PUBLIC   nemo_alloc  ! needed by TAM
101
102   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
103
104#if defined key_mpp_mpi
105   INCLUDE 'mpif.h'
106#endif
107
108   !!----------------------------------------------------------------------
109   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
110   !! $Id$
111   !! Software governed by the CeCILL license (see ./LICENSE)
112   !!----------------------------------------------------------------------
113CONTAINS
114
115   SUBROUTINE nemo_gcm
116      !!----------------------------------------------------------------------
117      !!                     ***  ROUTINE nemo_gcm  ***
118      !!
119      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
120      !!              curvilinear mesh on the sphere.
121      !!
122      !! ** Method  : - model general initialization
123      !!              - launch the time-stepping (stp routine)
124      !!              - finalize the run by closing files and communications
125      !!
126      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
127      !!              Madec, 2008, internal report, IPSL.
128      !!----------------------------------------------------------------------
129      INTEGER ::   istp   ! time step index
130      !!----------------------------------------------------------------------
131      !
132#if defined key_agrif
133      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
134#endif
135      !                            !-----------------------!
136      CALL nemo_init               !==  Initialisations  ==!
137      !                            !-----------------------!
138#if defined key_agrif
139      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
140      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
141# if defined key_top
142      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
143# endif
144# if defined key_si3
145      CALL Agrif_Declare_Var_ice   !  "      "   "   "      "  Sea ice
146# endif
147#endif
148      ! check that all process are still there... If some process have an error,
149      ! they will never enter in step and other processes will wait until the end of the cpu time!
150      IF( lk_mpp )   CALL mpp_max( 'nemogcm', nstop )
151
152      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
153
154      !                            !-----------------------!
155      !                            !==   time stepping   ==!
156      !                            !-----------------------!
157      istp = nit000
158      !
159#if defined key_c1d
160      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  C1D time-stepping  ==!
161         CALL stp_c1d( istp )
162         istp = istp + 1
163      END DO
164#else
165      !
166# if defined key_agrif
167      !                                               !==  AGRIF time-stepping  ==!
168      CALL Agrif_Regrid()
169      !
170      ! Recursive update from highest nested level to lowest:
171      CALL Agrif_step_child_adj(Agrif_Update_All)
172      !
173      DO WHILE( istp <= nitend .AND. nstop == 0 )
174         CALL stp
175         istp = istp + 1
176      END DO
177      !
178      IF( .NOT. Agrif_Root() ) THEN
179         CALL Agrif_ParentGrid_To_ChildGrid()
180         IF( ln_diaobs )   CALL dia_obs_wri
181         IF( ln_timing )   CALL timing_finalize
182         CALL Agrif_ChildGrid_To_ParentGrid()
183      ENDIF
184      !
185# else
186      !
187      IF( .NOT.ln_diurnal_only ) THEN                 !==  Standard time-stepping  ==!
188         !
189         DO WHILE( istp <= nitend .AND. nstop == 0 )
190#if defined key_mpp_mpi
191            ncom_stp = istp
192            IF ( istp == ( nit000 + 1 ) ) elapsed_time = MPI_Wtime()
193            IF ( istp ==         nitend ) elapsed_time = MPI_Wtime() - elapsed_time
194#endif
195            CALL stp        ( istp ) 
196            istp = istp + 1
197         END DO
198         !
199      ELSE                                            !==  diurnal SST time-steeping only  ==!
200         !
201         DO WHILE( istp <= nitend .AND. nstop == 0 )
202            CALL stp_diurnal( istp )   ! time step only the diurnal SST
203            istp = istp + 1
204         END DO
205         !
206      ENDIF
207      !
208# endif
209      !
210#endif
211      !
212      IF( ln_diaobs   )   CALL dia_obs_wri
213      !
214      IF( ln_icebergs )   CALL icb_end( nitend )
215
216      !                            !------------------------!
217      !                            !==  finalize the run  ==!
218      !                            !------------------------!
219      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
220      !
221      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
222         WRITE(numout,cform_err)
223         WRITE(numout,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
224         WRITE(numout,*)
225      ENDIF
226      !
227      IF( ln_timing )   CALL timing_finalize
228      !
229      CALL nemo_closefile
230      !
231#if defined key_iomput
232                                    CALL xios_finalize  ! end mpp communications with xios
233      IF( lk_oasis     )            CALL cpl_finalize   ! end coupling and mpp communications with OASIS
234#else
235      IF    ( lk_oasis ) THEN   ;   CALL cpl_finalize   ! end coupling and mpp communications with OASIS
236      ELSEIF( lk_mpp   ) THEN   ;   CALL mppstop        ! end mpp communications
237      ENDIF
238#endif
239      !
240   END SUBROUTINE nemo_gcm
241
242
243   SUBROUTINE nemo_init
244      !!----------------------------------------------------------------------
245      !!                     ***  ROUTINE nemo_init  ***
246      !!
247      !! ** Purpose :   initialization of the NEMO GCM
248      !!----------------------------------------------------------------------
249      INTEGER  ::   ji                 ! dummy loop indices
250      INTEGER  ::   ios, ilocal_comm   ! local integers
251      CHARACTER(len=120), DIMENSION(60) ::   cltxt, cltxt2, clnam
252      !!
253      NAMELIST/namctl/ ln_ctl   , nn_print, nn_ictls, nn_ictle,   &
254         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,   &
255         &             ln_timing, ln_diacfl
256      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
257      !!----------------------------------------------------------------------
258      !
259      cltxt  = ''
260      cltxt2 = ''
261      clnam  = '' 
262      cxios_context = 'nemo'
263      !
264      !                             ! Open reference namelist and configuration namelist files
265      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
266      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
267      !
268      REWIND( numnam_ref )              ! Namelist namctl in reference namelist
269      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
270901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
271      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist
272      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
273902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
274      !
275      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist
276      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
277903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
278      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist
279      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
280904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
281
282      !                             !--------------------------!
283      !                             !  Set global domain size  !   (control print return in cltxt2)
284      !                             !--------------------------!
285      IF( ln_read_cfg ) THEN              ! Read sizes in domain configuration file
286         CALL domain_cfg ( cltxt2,        cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
287         !
288      ELSE                                ! user-defined namelist
289         CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
290      ENDIF
291      !
292      !
293      !                             !--------------------------------------------!
294      !                             !  set communicator & select the local node  !
295      !                             !  NB: mynode also opens output.namelist.dyn !
296      !                             !      on unit number numond on first proc   !
297      !                             !--------------------------------------------!
298#if defined key_iomput
299      IF( Agrif_Root() ) THEN
300         IF( lk_oasis ) THEN
301            CALL cpl_init( "oceanx", ilocal_comm )                               ! nemo local communicator given by oasis
302            CALL xios_initialize( "not used"       ,local_comm= ilocal_comm )    ! send nemo communicator to xios
303         ELSE
304            CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
305         ENDIF
306      ENDIF
307      ! Nodes selection (control print return in cltxt)
308      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
309#else
310      IF( lk_oasis ) THEN
311         IF( Agrif_Root() ) THEN
312            CALL cpl_init( "oceanx", ilocal_comm )          ! nemo local communicator given by oasis
313         ENDIF
314         ! Nodes selection (control print return in cltxt)
315         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
316      ELSE
317         ilocal_comm = 0                                    ! Nodes selection (control print return in cltxt)
318         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
319      ENDIF
320#endif
321
322      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
323
324      lwm = (narea == 1)                                    ! control of output namelists
325      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
326
327      IF(lwm) THEN               ! write merged namelists from earlier to output namelist
328         !                       ! now that the file has been opened in call to mynode.
329         !                       ! NB: nammpp has already been written in mynode (if lk_mpp_mpi)
330         WRITE( numond, namctl )
331         WRITE( numond, namcfg )
332         IF( .NOT.ln_read_cfg ) THEN
333            DO ji = 1, SIZE(clnam)
334               IF( TRIM(clnam(ji)) /= '' )   WRITE(numond, * ) clnam(ji)     ! namusr_def print
335            END DO
336         ENDIF
337      ENDIF
338
339      IF(lwp) THEN                            ! open listing units
340         !
341         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
342         !
343         WRITE(numout,*)
344         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
345         WRITE(numout,*) '                       NEMO team'
346         WRITE(numout,*) '            Ocean General Circulation Model'
347         WRITE(numout,*) '                NEMO version 4.0  (2017) '
348         WRITE(numout,*)
349         WRITE(numout,*)
350         DO ji = 1, SIZE(cltxt)
351            IF( TRIM(cltxt (ji)) /= '' )   WRITE(numout,*) cltxt(ji)    ! control print of mynode
352         END DO
353         WRITE(numout,*)
354         WRITE(numout,*)
355         DO ji = 1, SIZE(cltxt2)
356            IF( TRIM(cltxt2(ji)) /= '' )   WRITE(numout,*) cltxt2(ji)   ! control print of domain size
357         END DO
358         !
359         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
360         !
361      ENDIF
362      !                                      ! Domain decomposition
363      CALL mpp_init                          ! MPP
364
365      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
366      CALL nemo_alloc()
367
368      !                             !-------------------------------!
369      !                             !  NEMO general initialization  !
370      !                             !-------------------------------!
371
372      CALL nemo_ctl                          ! Control prints
373      !
374      !                                      ! General initialization
375      IF( ln_timing    )   CALL timing_init     ! timing
376      IF( ln_timing    )   CALL timing_start( 'nemo_init')
377      !
378                           CALL     phy_cst         ! Physical constants
379                           CALL     eos_init        ! Equation of state
380      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
381                           CALL     wad_init        ! Wetting and drying options
382                           CALL     dom_init("OPA") ! Domain
383      IF( ln_crs       )   CALL     crs_init        ! coarsened grid: domain initialization
384      IF( ln_ctl       )   CALL prt_ctl_init        ! Print control
385     
386      CALL diurnal_sst_bulk_init                ! diurnal sst
387      IF( ln_diurnal   )   CALL diurnal_sst_coolskin_init   ! cool skin   
388      !                           
389      IF( ln_diurnal_only ) THEN                   ! diurnal only: a subset of the initialisation routines
390         CALL  istate_init                            ! ocean initial state (Dynamics and tracers)
391         CALL     sbc_init                            ! Forcings : surface module
392         CALL tra_qsr_init                            ! penetrative solar radiation qsr
393         IF( ln_diaobs ) THEN                         ! Observation & model comparison
394            CALL dia_obs_init                            ! Initialize observational data
395            CALL dia_obs( nit000 - 1 )                   ! Observation operator for restart
396         ENDIF     
397         IF( lk_asminc )   CALL asm_inc_init          ! Assimilation increments
398         !
399         RETURN                                       ! end of initialization
400      ENDIF
401     
402                           CALL  istate_init    ! ocean initial state (Dynamics and tracers)
403
404      !                                      ! external forcing
405                           CALL    tide_init    ! tidal harmonics
406                           CALL     sbc_init    ! surface boundary conditions (including sea-ice)
407                           CALL     bdy_init    ! Open boundaries initialisation
408
409      !                                      ! Ocean physics
410                           CALL zdf_phy_init    ! Vertical physics
411                                     
412      !                                         ! Lateral physics
413                           CALL ldf_tra_init      ! Lateral ocean tracer physics
414                           CALL ldf_eiv_init      ! eddy induced velocity param.
415                           CALL ldf_dyn_init      ! Lateral ocean momentum physics
416
417      !                                      ! Active tracers
418      IF( ln_traqsr    )   CALL tra_qsr_init      ! penetrative solar radiation qsr
419                           CALL tra_bbc_init      ! bottom heat flux
420      IF( ln_trabbl    )   CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
421                           CALL tra_dmp_init      ! internal tracer damping
422                           CALL tra_adv_init      ! horizontal & vertical advection
423                           CALL tra_ldf_init      ! lateral mixing
424
425      !                                      ! Dynamics
426      IF( lk_c1d       )   CALL dyn_dmp_init      ! internal momentum damping
427                           CALL dyn_adv_init      ! advection (vector or flux form)
428                           CALL dyn_vor_init      ! vorticity term including Coriolis
429                           CALL dyn_ldf_init      ! lateral mixing
430                           CALL dyn_hpg_init      ! horizontal gradient of Hydrostatic pressure
431                           CALL dyn_spg_init      ! surface pressure gradient
432
433#if defined key_top
434      !                                      ! Passive tracers
435                           CALL     trc_init
436#endif
437      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
438
439      !                                      ! Icebergs
440                           CALL icb_init( rdt, nit000)   ! initialise icebergs instance
441
442      !                                      ! Misc. options
443                           CALL sto_par_init    ! Stochastic parametrization
444      IF( ln_sto_eos   )   CALL sto_pts_init    ! RRandom T/S fluctuations
445     
446      !                                      ! Diagnostics
447      IF( lk_floats    )   CALL     flo_init    ! drifting Floats
448      IF( ln_diacfl    )   CALL dia_cfl_init    ! Initialise CFL diagnostics
449                           CALL dia_ptr_init    ! Poleward TRansports initialization
450      IF( lk_diadct    )   CALL dia_dct_init    ! Sections tranports
451                           CALL dia_hsb_init    ! heat content, salt content and volume budgets
452                           CALL     trd_init    ! Mixed-layer/Vorticity/Integral constraints trends
453                           CALL dia_obs_init    ! Initialize observational data
454                           CALL dia_tmb_init    ! TMB outputs
455                           CALL dia_25h_init    ! 25h mean  outputs
456      IF( ln_diaobs    )   CALL dia_obs( nit000-1 )   ! Observation operator for restart
457
458      !                                      ! Assimilation increments
459      IF( lk_asminc    )   CALL asm_inc_init    ! Initialize assimilation increments
460      !
461      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
462      !
463      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
464      !
465   END SUBROUTINE nemo_init
466
467
468   SUBROUTINE nemo_ctl
469      !!----------------------------------------------------------------------
470      !!                     ***  ROUTINE nemo_ctl  ***
471      !!
472      !! ** Purpose :   control print setting
473      !!
474      !! ** Method  : - print namctl information and check some consistencies
475      !!----------------------------------------------------------------------
476      !
477      IF(lwp) THEN                  ! control print
478         WRITE(numout,*)
479         WRITE(numout,*) 'nemo_ctl: Control prints'
480         WRITE(numout,*) '~~~~~~~~'
481         WRITE(numout,*) '   Namelist namctl'
482         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
483         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
484         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
485         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
486         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
487         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
488         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
489         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
490         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
491         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
492      ENDIF
493      !
494      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
495      nictls    = nn_ictls
496      nictle    = nn_ictle
497      njctls    = nn_jctls
498      njctle    = nn_jctle
499      isplt     = nn_isplt
500      jsplt     = nn_jsplt
501
502      IF(lwp) THEN                  ! control print
503         WRITE(numout,*)
504         WRITE(numout,*) '   Namelist namcfg'
505         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
506         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
507         WRITE(numout,*) '         keep closed seas in the domain (if exist)     ln_closea     = ', ln_closea
508         WRITE(numout,*) '      create a configuration definition file        ln_write_cfg     = ', ln_write_cfg
509         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
510         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
511      ENDIF
512      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
513      !
514      !                             ! Parameter control
515      !
516      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
517         IF( lk_mpp .AND. jpnij > 1 ) THEN
518            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
519         ELSE
520            IF( isplt == 1 .AND. jsplt == 1  ) THEN
521               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
522                  &           ' - the print control will be done over the whole domain' )
523            ENDIF
524            ijsplt = isplt * jsplt            ! total number of processors ijsplt
525         ENDIF
526         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
527         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
528         !
529         !                              ! indices used for the SUM control
530         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
531            lsp_area = .FALSE.
532         ELSE                                             ! print control done over a specific  area
533            lsp_area = .TRUE.
534            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
535               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
536               nictls = 1
537            ENDIF
538            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
539               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
540               nictle = jpiglo
541            ENDIF
542            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
543               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
544               njctls = 1
545            ENDIF
546            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
547               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
548               njctle = jpjglo
549            ENDIF
550         ENDIF
551      ENDIF
552      !
553      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
554         &                                                'Compile with key_nosignedzero enabled' )
555      !
556#if defined key_agrif
557      IF( ln_timing )   CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
558#endif
559      !
560   END SUBROUTINE nemo_ctl
561
562
563   SUBROUTINE nemo_closefile
564      !!----------------------------------------------------------------------
565      !!                     ***  ROUTINE nemo_closefile  ***
566      !!
567      !! ** Purpose :   Close the files
568      !!----------------------------------------------------------------------
569      !
570      IF( lk_mpp )   CALL mppsync
571      !
572      CALL iom_close                                 ! close all input/output files managed by iom_*
573      !
574      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
575      IF( numrun          /= -1 )   CLOSE( numrun          )   ! run statistics file
576      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
577      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
578      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
579      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
580      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
581      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
582      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
583      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
584      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
585      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
586      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
587      !
588      numout = 6                                     ! redefine numout in case it is used after this point...
589      !
590   END SUBROUTINE nemo_closefile
591
592
593   SUBROUTINE nemo_alloc
594      !!----------------------------------------------------------------------
595      !!                     ***  ROUTINE nemo_alloc  ***
596      !!
597      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
598      !!
599      !! ** Method  :
600      !!----------------------------------------------------------------------
601      USE diawri    , ONLY : dia_wri_alloc
602      USE dom_oce   , ONLY : dom_oce_alloc
603      USE trc_oce   , ONLY : trc_oce_alloc
604      USE bdy_oce   , ONLY : bdy_oce_alloc
605#if defined key_diadct 
606      USE diadct    , ONLY : diadct_alloc 
607#endif 
608      !
609      INTEGER :: ierr
610      !!----------------------------------------------------------------------
611      !
612      ierr =        oce_alloc    ()    ! ocean
613      ierr = ierr + dia_wri_alloc()
614      ierr = ierr + dom_oce_alloc()    ! ocean domain
615      ierr = ierr + zdf_oce_alloc()    ! ocean vertical physics
616      ierr = ierr + trc_oce_alloc()    ! shared TRC / TRA arrays
617      ierr = ierr + bdy_oce_alloc()    ! bdy masks (incl. initialization)
618      !
619#if defined key_diadct 
620      ierr = ierr + diadct_alloc ()    !
621#endif 
622      !
623      IF( lk_mpp    )   CALL mpp_sum( 'nemogcm', ierr )
624      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
625      !
626   END SUBROUTINE nemo_alloc
627
628   !!======================================================================
629END MODULE nemogcm
630
Note: See TracBrowser for help on using the repository browser.