New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/OCE – NEMO

source: NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/OCE/nemogcm.F90 @ 10368

Last change on this file since 10368 was 10368, checked in by smasson, 5 years ago

dev_r10164_HPC09_ESIWACE_PREP_MERGE: merge with trunk@10365, see #2133

  • Property svn:keywords set to Id
File size: 31.5 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
33   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
34   !!----------------------------------------------------------------------
35
36   !!----------------------------------------------------------------------
37   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
38   !!   nemo_init     : initialization of the NEMO system
39   !!   nemo_ctl      : initialisation of the contol print
40   !!   nemo_closefile: close remaining open files
41   !!   nemo_alloc    : dynamical allocation
42   !!----------------------------------------------------------------------
43   USE step_oce       ! module used in the ocean time stepping module (step.F90)
44   USE phycst         ! physical constant                  (par_cst routine)
45   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
46   USE closea         ! treatment of closed seas (for ln_closea)
47   USE usrdef_nam     ! user defined configuration
48   USE tideini        ! tidal components initialization   (tide_ini routine)
49   USE bdy_oce,  ONLY : ln_bdy
50   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
51   USE istate         ! initial state setting          (istate_init routine)
52   USE ldfdyn         ! lateral viscosity setting      (ldfdyn_init routine)
53   USE ldftra         ! lateral diffusivity setting    (ldftra_init routine)
54   USE trdini         ! dyn/tra trends initialization     (trd_init routine)
55   USE asminc         ! assimilation increments     
56   USE asmbkg         ! writing out state trajectory
57   USE diaptr         ! poleward transports           (dia_ptr_init routine)
58   USE diadct         ! sections transports           (dia_dct_init routine)
59   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
60   USE diacfl         ! CFL diagnostics               (dia_cfl_init routine)
61   USE step           ! NEMO time-stepping                 (stp     routine)
62   USE icbini         ! handle bergs, initialisation
63   USE icbstp         ! handle bergs, calving, themodynamics and transport
64   USE cpl_oasis3     ! OASIS3 coupling
65   USE c1d            ! 1D configuration
66   USE step_c1d       ! Time stepping loop for the 1D configuration
67   USE dyndmp         ! Momentum damping
68   USE stopar         ! Stochastic param.: ???
69   USE stopts         ! Stochastic param.: ???
70   USE diurnal_bulk   ! diurnal bulk SST
71   USE step_diu       ! diurnal bulk SST timestepping (called from here if run offline)
72   USE crsini         ! initialise grid coarsening utility
73   USE diatmb         ! Top,middle,bottom output
74   USE dia25h         ! 25h mean output
75   USE sbc_oce , ONLY : lk_oasis
76   USE wet_dry        ! Wetting and drying setting   (wad_init routine)
77#if defined key_top
78   USE trcini         ! passive tracer initialisation
79#endif
80#if defined key_nemocice_decomp
81   USE ice_domain_size, only: nx_global, ny_global
82#endif
83   !
84   USE lib_mpp        ! distributed memory computing
85   USE mppini         ! shared/distributed memory setting (mpp_init routine)
86   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
87   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
88#if defined key_iomput
89   USE xios           ! xIOserver
90#endif
91#if defined key_agrif
92   USE agrif_all_update   ! Master Agrif update
93#endif
94
95   IMPLICIT NONE
96   PRIVATE
97
98   PUBLIC   nemo_gcm    ! called by model.F90
99   PUBLIC   nemo_init   ! needed by AGRIF
100   PUBLIC   nemo_alloc  ! needed by TAM
101
102   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
103
104#if defined key_mpp_mpi
105   INCLUDE 'mpif.h'
106#endif
107
108   !!----------------------------------------------------------------------
109   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
110   !! $Id$
111   !! Software governed by the CeCILL license (see ./LICENSE)
112   !!----------------------------------------------------------------------
113CONTAINS
114
115   SUBROUTINE nemo_gcm
116      !!----------------------------------------------------------------------
117      !!                     ***  ROUTINE nemo_gcm  ***
118      !!
119      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
120      !!              curvilinear mesh on the sphere.
121      !!
122      !! ** Method  : - model general initialization
123      !!              - launch the time-stepping (stp routine)
124      !!              - finalize the run by closing files and communications
125      !!
126      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
127      !!              Madec, 2008, internal report, IPSL.
128      !!----------------------------------------------------------------------
129      INTEGER ::   istp   ! time step index
130      !!----------------------------------------------------------------------
131      !
132#if defined key_agrif
133      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
134#endif
135      !                            !-----------------------!
136      CALL nemo_init               !==  Initialisations  ==!
137      !                            !-----------------------!
138#if defined key_agrif
139      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
140      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
141# if defined key_top
142      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
143# endif
144# if defined key_si3
145      CALL Agrif_Declare_Var_ice   !  "      "   "   "      "  Sea ice
146# endif
147#endif
148      ! check that all process are still there... If some process have an error,
149      ! they will never enter in step and other processes will wait until the end of the cpu time!
150      IF( lk_mpp )   CALL mpp_max( 'nemogcm', nstop )
151
152      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
153
154      !                            !-----------------------!
155      !                            !==   time stepping   ==!
156      !                            !-----------------------!
157      istp = nit000
158      !
159#if defined key_c1d
160      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  C1D time-stepping  ==!
161         CALL stp_c1d( istp )
162         istp = istp + 1
163      END DO
164#else
165      !
166# if defined key_agrif
167      !                                               !==  AGRIF time-stepping  ==!
168      CALL Agrif_Regrid()
169      !
170      ! Recursive update from highest nested level to lowest:
171      CALL Agrif_step_child_adj(Agrif_Update_All)
172      !
173      DO WHILE( istp <= nitend .AND. nstop == 0 )
174         CALL stp
175         istp = istp + 1
176      END DO
177      !
178      IF( .NOT. Agrif_Root() ) THEN
179         CALL Agrif_ParentGrid_To_ChildGrid()
180         IF( ln_diaobs )   CALL dia_obs_wri
181         IF( ln_timing )   CALL timing_finalize
182         CALL Agrif_ChildGrid_To_ParentGrid()
183      ENDIF
184      !
185# else
186      !
187      IF( .NOT.ln_diurnal_only ) THEN                 !==  Standard time-stepping  ==!
188         !
189         DO WHILE( istp <= nitend .AND. nstop == 0 )
190#if defined key_mpp_mpi
191            ncom_stp = istp
192            IF ( istp == ( nit000 + 1 ) ) elapsed_time = MPI_Wtime()
193            IF ( istp ==         nitend ) elapsed_time = MPI_Wtime() - elapsed_time
194#endif
195            CALL stp        ( istp ) 
196            istp = istp + 1
197         END DO
198         !
199      ELSE                                            !==  diurnal SST time-steeping only  ==!
200         !
201         DO WHILE( istp <= nitend .AND. nstop == 0 )
202            CALL stp_diurnal( istp )   ! time step only the diurnal SST
203            istp = istp + 1
204         END DO
205         !
206      ENDIF
207      !
208# endif
209      !
210#endif
211      !
212      IF( ln_diaobs   )   CALL dia_obs_wri
213      !
214      IF( ln_icebergs )   CALL icb_end( nitend )
215
216      !                            !------------------------!
217      !                            !==  finalize the run  ==!
218      !                            !------------------------!
219      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
220      !
221      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
222         WRITE(numout,cform_err)
223         WRITE(numout,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
224         WRITE(numout,*)
225      ENDIF
226      !
227      IF( ln_timing )   CALL timing_finalize
228      !
229      CALL nemo_closefile
230      !
231#if defined key_iomput
232                                    CALL xios_finalize  ! end mpp communications with xios
233      IF( lk_oasis     )            CALL cpl_finalize   ! end coupling and mpp communications with OASIS
234#else
235      IF    ( lk_oasis ) THEN   ;   CALL cpl_finalize   ! end coupling and mpp communications with OASIS
236      ELSEIF( lk_mpp   ) THEN   ;   CALL mppstop( ldfinal = .TRUE. )   ! end mpp communications
237      ENDIF
238#endif
239      !
240   END SUBROUTINE nemo_gcm
241
242
243   SUBROUTINE nemo_init
244      !!----------------------------------------------------------------------
245      !!                     ***  ROUTINE nemo_init  ***
246      !!
247      !! ** Purpose :   initialization of the NEMO GCM
248      !!----------------------------------------------------------------------
249      INTEGER  ::   ji                 ! dummy loop indices
250      INTEGER  ::   ios, ilocal_comm   ! local integers
251      CHARACTER(len=120), DIMENSION(60) ::   cltxt, cltxt2, clnam
252      !!
253      NAMELIST/namctl/ ln_ctl   , nn_print, nn_ictls, nn_ictle,   &
254         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,   &
255         &             ln_timing, ln_diacfl
256      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
257      !!----------------------------------------------------------------------
258      !
259      cltxt  = ''
260      cltxt2 = ''
261      clnam  = '' 
262      cxios_context = 'nemo'
263      !
264      !                             ! Open reference namelist and configuration namelist files
265      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
266      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
267      !
268      REWIND( numnam_ref )              ! Namelist namctl in reference namelist
269      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
270901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
271      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist
272      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
273902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
274      !
275      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist
276      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
277903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
278      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist
279      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
280904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
281
282      !                             !--------------------------!
283      !                             !  Set global domain size  !   (control print return in cltxt2)
284      !                             !--------------------------!
285      IF( ln_read_cfg ) THEN              ! Read sizes in domain configuration file
286         CALL domain_cfg ( cltxt2,        cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
287         !
288      ELSE                                ! user-defined namelist
289         CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
290      ENDIF
291      !
292      !
293      !                             !--------------------------------------------!
294      !                             !  set communicator & select the local node  !
295      !                             !  NB: mynode also opens output.namelist.dyn !
296      !                             !      on unit number numond on first proc   !
297      !                             !--------------------------------------------!
298#if defined key_iomput
299      IF( Agrif_Root() ) THEN
300         IF( lk_oasis ) THEN
301            CALL cpl_init( "oceanx", ilocal_comm )                               ! nemo local communicator given by oasis
302            CALL xios_initialize( "not used"       ,local_comm= ilocal_comm )    ! send nemo communicator to xios
303         ELSE
304            CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
305         ENDIF
306      ENDIF
307      ! Nodes selection (control print return in cltxt)
308      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
309#else
310      IF( lk_oasis ) THEN
311         IF( Agrif_Root() ) THEN
312            CALL cpl_init( "oceanx", ilocal_comm )          ! nemo local communicator given by oasis
313         ENDIF
314         ! Nodes selection (control print return in cltxt)
315         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
316      ELSE
317         ilocal_comm = 0                                    ! Nodes selection (control print return in cltxt)
318         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
319      ENDIF
320#endif
321
322      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
323
324      lwm = (narea == 1)                                    ! control of output namelists
325      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
326
327      IF(lwm) THEN               ! write merged namelists from earlier to output namelist
328         !                       ! now that the file has been opened in call to mynode.
329         !                       ! NB: nammpp has already been written in mynode (if lk_mpp_mpi)
330         WRITE( numond, namctl )
331         WRITE( numond, namcfg )
332         IF( .NOT.ln_read_cfg ) THEN
333            DO ji = 1, SIZE(clnam)
334               IF( TRIM(clnam(ji)) /= '' )   WRITE(numond, * ) clnam(ji)     ! namusr_def print
335            END DO
336         ENDIF
337      ENDIF
338
339      IF(lwp) THEN                            ! open listing units
340         !
341         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
342         !
343         WRITE(numout,*)
344         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
345         WRITE(numout,*) '                       NEMO team'
346         WRITE(numout,*) '            Ocean General Circulation Model'
347         WRITE(numout,*) '                NEMO version 4.0  (2017) '
348         WRITE(numout,*)
349         WRITE(numout,*)
350         DO ji = 1, SIZE(cltxt)
351            IF( TRIM(cltxt (ji)) /= '' )   WRITE(numout,*) TRIM(cltxt(ji))    ! control print of mynode
352         END DO
353         WRITE(numout,*)
354         WRITE(numout,*)
355         DO ji = 1, SIZE(cltxt2)
356            IF( TRIM(cltxt2(ji)) /= '' )   WRITE(numout,*) TRIM(cltxt2(ji))   ! control print of domain size
357         END DO
358         !
359         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
360         !
361      ENDIF
362      ! open /dev/null file to be able to supress output write easily
363      CALL ctl_opn( numnul, '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
364      !
365      !                                      ! Domain decomposition
366      CALL mpp_init                          ! MPP
367
368      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
369      CALL nemo_alloc()
370
371      !                             !-------------------------------!
372      !                             !  NEMO general initialization  !
373      !                             !-------------------------------!
374
375      CALL nemo_ctl                          ! Control prints
376      !
377      !                                      ! General initialization
378      IF( ln_timing    )   CALL timing_init     ! timing
379      IF( ln_timing    )   CALL timing_start( 'nemo_init')
380      !
381                           CALL     phy_cst         ! Physical constants
382                           CALL     eos_init        ! Equation of state
383      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
384                           CALL     wad_init        ! Wetting and drying options
385                           CALL     dom_init("OPA") ! Domain
386      IF( ln_crs       )   CALL     crs_init        ! coarsened grid: domain initialization
387      IF( ln_ctl       )   CALL prt_ctl_init        ! Print control
388     
389      CALL diurnal_sst_bulk_init                ! diurnal sst
390      IF( ln_diurnal   )   CALL diurnal_sst_coolskin_init   ! cool skin   
391      !                           
392      IF( ln_diurnal_only ) THEN                   ! diurnal only: a subset of the initialisation routines
393         CALL  istate_init                            ! ocean initial state (Dynamics and tracers)
394         CALL     sbc_init                            ! Forcings : surface module
395         CALL tra_qsr_init                            ! penetrative solar radiation qsr
396         IF( ln_diaobs ) THEN                         ! Observation & model comparison
397            CALL dia_obs_init                            ! Initialize observational data
398            CALL dia_obs( nit000 - 1 )                   ! Observation operator for restart
399         ENDIF     
400         IF( lk_asminc )   CALL asm_inc_init          ! Assimilation increments
401         !
402         RETURN                                       ! end of initialization
403      ENDIF
404     
405                           CALL  istate_init    ! ocean initial state (Dynamics and tracers)
406
407      !                                      ! external forcing
408                           CALL    tide_init    ! tidal harmonics
409                           CALL     sbc_init    ! surface boundary conditions (including sea-ice)
410                           CALL     bdy_init    ! Open boundaries initialisation
411
412      !                                      ! Ocean physics
413                           CALL zdf_phy_init    ! Vertical physics
414                                     
415      !                                         ! Lateral physics
416                           CALL ldf_tra_init      ! Lateral ocean tracer physics
417                           CALL ldf_eiv_init      ! eddy induced velocity param.
418                           CALL ldf_dyn_init      ! Lateral ocean momentum physics
419
420      !                                      ! Active tracers
421      IF( ln_traqsr    )   CALL tra_qsr_init      ! penetrative solar radiation qsr
422                           CALL tra_bbc_init      ! bottom heat flux
423                           CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
424                           CALL tra_dmp_init      ! internal tracer damping
425                           CALL tra_adv_init      ! horizontal & vertical advection
426                           CALL tra_ldf_init      ! lateral mixing
427
428      !                                      ! Dynamics
429      IF( lk_c1d       )   CALL dyn_dmp_init      ! internal momentum damping
430                           CALL dyn_adv_init      ! advection (vector or flux form)
431                           CALL dyn_vor_init      ! vorticity term including Coriolis
432                           CALL dyn_ldf_init      ! lateral mixing
433                           CALL dyn_hpg_init      ! horizontal gradient of Hydrostatic pressure
434                           CALL dyn_spg_init      ! surface pressure gradient
435
436#if defined key_top
437      !                                      ! Passive tracers
438                           CALL     trc_init
439#endif
440      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
441
442      !                                      ! Icebergs
443                           CALL icb_init( rdt, nit000)   ! initialise icebergs instance
444
445      !                                      ! Misc. options
446                           CALL sto_par_init    ! Stochastic parametrization
447      IF( ln_sto_eos   )   CALL sto_pts_init    ! RRandom T/S fluctuations
448     
449      !                                      ! Diagnostics
450      IF( lk_floats    )   CALL     flo_init    ! drifting Floats
451      IF( ln_diacfl    )   CALL dia_cfl_init    ! Initialise CFL diagnostics
452                           CALL dia_ptr_init    ! Poleward TRansports initialization
453      IF( lk_diadct    )   CALL dia_dct_init    ! Sections tranports
454                           CALL dia_hsb_init    ! heat content, salt content and volume budgets
455                           CALL     trd_init    ! Mixed-layer/Vorticity/Integral constraints trends
456                           CALL dia_obs_init    ! Initialize observational data
457                           CALL dia_tmb_init    ! TMB outputs
458                           CALL dia_25h_init    ! 25h mean  outputs
459      IF( ln_diaobs    )   CALL dia_obs( nit000-1 )   ! Observation operator for restart
460
461      !                                      ! Assimilation increments
462      IF( lk_asminc    )   CALL asm_inc_init    ! Initialize assimilation increments
463      !
464      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
465      !
466      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
467      !
468   END SUBROUTINE nemo_init
469
470
471   SUBROUTINE nemo_ctl
472      !!----------------------------------------------------------------------
473      !!                     ***  ROUTINE nemo_ctl  ***
474      !!
475      !! ** Purpose :   control print setting
476      !!
477      !! ** Method  : - print namctl information and check some consistencies
478      !!----------------------------------------------------------------------
479      !
480      IF(lwp) THEN                  ! control print
481         WRITE(numout,*)
482         WRITE(numout,*) 'nemo_ctl: Control prints'
483         WRITE(numout,*) '~~~~~~~~'
484         WRITE(numout,*) '   Namelist namctl'
485         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
486         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
487         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
488         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
489         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
490         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
491         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
492         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
493         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
494         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
495      ENDIF
496      !
497      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
498      nictls    = nn_ictls
499      nictle    = nn_ictle
500      njctls    = nn_jctls
501      njctle    = nn_jctle
502      isplt     = nn_isplt
503      jsplt     = nn_jsplt
504
505      IF(lwp) THEN                  ! control print
506         WRITE(numout,*)
507         WRITE(numout,*) '   Namelist namcfg'
508         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
509         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
510         WRITE(numout,*) '         keep closed seas in the domain (if exist)     ln_closea     = ', ln_closea
511         WRITE(numout,*) '      create a configuration definition file        ln_write_cfg     = ', ln_write_cfg
512         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
513         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
514      ENDIF
515      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
516      !
517      !                             ! Parameter control
518      !
519      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
520         IF( lk_mpp .AND. jpnij > 1 ) THEN
521            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
522         ELSE
523            IF( isplt == 1 .AND. jsplt == 1  ) THEN
524               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
525                  &           ' - the print control will be done over the whole domain' )
526            ENDIF
527            ijsplt = isplt * jsplt            ! total number of processors ijsplt
528         ENDIF
529         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
530         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
531         !
532         !                              ! indices used for the SUM control
533         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
534            lsp_area = .FALSE.
535         ELSE                                             ! print control done over a specific  area
536            lsp_area = .TRUE.
537            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
538               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
539               nictls = 1
540            ENDIF
541            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
542               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
543               nictle = jpiglo
544            ENDIF
545            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
546               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
547               njctls = 1
548            ENDIF
549            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
550               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
551               njctle = jpjglo
552            ENDIF
553         ENDIF
554      ENDIF
555      !
556      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
557         &                                                'Compile with key_nosignedzero enabled:',   &
558         &                                                '--> add -Dkey_nosignedzero to the definition of %CPP in your arch file' )
559      !
560#if defined key_agrif
561      IF( ln_timing )   CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
562#endif
563      !
564   END SUBROUTINE nemo_ctl
565
566
567   SUBROUTINE nemo_closefile
568      !!----------------------------------------------------------------------
569      !!                     ***  ROUTINE nemo_closefile  ***
570      !!
571      !! ** Purpose :   Close the files
572      !!----------------------------------------------------------------------
573      !
574      IF( lk_mpp )   CALL mppsync
575      !
576      CALL iom_close                                 ! close all input/output files managed by iom_*
577      !
578      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
579      IF( numrun          /= -1 )   CLOSE( numrun          )   ! run statistics file
580      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
581      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
582      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
583      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
584      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
585      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
586      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
587      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
588      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
589      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
590      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
591      !
592      numout = 6                                     ! redefine numout in case it is used after this point...
593      !
594   END SUBROUTINE nemo_closefile
595
596
597   SUBROUTINE nemo_alloc
598      !!----------------------------------------------------------------------
599      !!                     ***  ROUTINE nemo_alloc  ***
600      !!
601      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
602      !!
603      !! ** Method  :
604      !!----------------------------------------------------------------------
605      USE diawri    , ONLY : dia_wri_alloc
606      USE dom_oce   , ONLY : dom_oce_alloc
607      USE trc_oce   , ONLY : trc_oce_alloc
608      USE bdy_oce   , ONLY : bdy_oce_alloc
609#if defined key_diadct 
610      USE diadct    , ONLY : diadct_alloc 
611#endif 
612      !
613      INTEGER :: ierr
614      !!----------------------------------------------------------------------
615      !
616      ierr =        oce_alloc    ()    ! ocean
617      ierr = ierr + dia_wri_alloc()
618      ierr = ierr + dom_oce_alloc()    ! ocean domain
619      ierr = ierr + zdf_oce_alloc()    ! ocean vertical physics
620      ierr = ierr + trc_oce_alloc()    ! shared TRC / TRA arrays
621      ierr = ierr + bdy_oce_alloc()    ! bdy masks (incl. initialization)
622      !
623#if defined key_diadct 
624      ierr = ierr + diadct_alloc ()    !
625#endif 
626      !
627      IF( lk_mpp    )   CALL mpp_sum( 'nemogcm', ierr )
628      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
629      !
630   END SUBROUTINE nemo_alloc
631
632   !!======================================================================
633END MODULE nemogcm
634
Note: See TracBrowser for help on using the repository browser.