New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
stpctl.F90 in NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/OCE – NEMO

source: NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/OCE/stpctl.F90 @ 10165

Last change on this file since 10165 was 10068, checked in by nicolasmartin, 6 years ago

First part of modifications to have a common default header : fix typos and SVN keywords properties

  • Property svn:keywords set to Id
File size: 9.8 KB
Line 
1MODULE stpctl
2   !!======================================================================
3   !!                       ***  MODULE  stpctl  ***
4   !! Ocean run control :  gross check of the ocean time stepping
5   !!======================================================================
6   !! History :  OPA  ! 1991-03  (G. Madec) Original code
7   !!            6.0  ! 1992-06  (M. Imbard)
8   !!            8.0  ! 1997-06  (A.M. Treguier)
9   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
10   !!            2.0  ! 2009-07  (G. Madec)  Add statistic for time-spliting
11   !!            3.7  ! 2016-09  (G. Madec)  Remove solver
12   !!            4.0  ! 2017-04  (G. Madec)  regroup global communications
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   stp_ctl      : Control the run
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and tracers variables
19   USE dom_oce         ! ocean space and time domain variables
20   USE c1d             ! 1D vertical configuration
21   USE diawri          ! Standard run outputs       (dia_wri_state routine)
22   !
23   USE in_out_manager  ! I/O manager
24   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
25   USE lib_mpp         ! distributed memory computing
26   USE wet_dry,   ONLY : ll_wd, ssh_ref    ! reference depth for negative bathy
27
28   USE netcdf          ! NetCDF library
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC stp_ctl           ! routine called by step.F90
33
34   INTEGER  ::   idrun, idtime, idssh, idu, ids1, ids2, istatus
35   !!----------------------------------------------------------------------
36   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
37   !! $Id$
38   !! Software governed by the CeCILL license (see ./LICENSE)
39   !!----------------------------------------------------------------------
40CONTAINS
41
42   SUBROUTINE stp_ctl( kt, kindic )
43      !!----------------------------------------------------------------------
44      !!                    ***  ROUTINE stp_ctl  ***
45      !!                     
46      !! ** Purpose :   Control the run
47      !!
48      !! ** Method  : - Save the time step in numstp
49      !!              - Print it each 50 time steps
50      !!              - Stop the run IF problem encountered by setting indic=-3
51      !!                Problems checked: |ssh| maximum larger than 10 m
52      !!                                  |U|   maximum larger than 10 m/s
53      !!                                  negative sea surface salinity
54      !!
55      !! ** Actions :   "time.step" file = last ocean time-step
56      !!                "run.stat"  file = run statistics
57      !!                nstop indicator sheared among all local domain (lk_mpp=T)
58      !!----------------------------------------------------------------------
59      INTEGER, INTENT(in   ) ::   kt       ! ocean time-step index
60      INTEGER, INTENT(inout) ::   kindic   ! error indicator
61      !!
62      INTEGER  ::   ji, jj, jk             ! dummy loop indices
63      INTEGER  ::   iih, ijh               ! local integers
64      INTEGER  ::   iiu, iju, iku          !   -       -
65      INTEGER  ::   iis1, ijs1, iks1       !   -       -
66      INTEGER  ::   iis2, ijs2, iks2       !   -       -
67      REAL(wp) ::   zzz                    ! local real
68      INTEGER , DIMENSION(3) ::   ilocu, ilocs1, ilocs2
69      INTEGER , DIMENSION(2) ::   iloch
70      REAL(wp), DIMENSION(5) ::   zmax
71      CHARACTER(len=20) :: clname
72      !!----------------------------------------------------------------------
73      !
74      IF( kt == nit000 .AND. lwp ) THEN
75         WRITE(numout,*)
76         WRITE(numout,*) 'stp_ctl : time-stepping control'
77         WRITE(numout,*) '~~~~~~~'
78         !                                ! open time.step file
79         CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
80         !                                ! open run.stat file
81         CALL ctl_opn( numrun, 'run.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
82
83         IF( lwm ) THEN
84            clname = 'run.stat.nc'
85            IF( .NOT. Agrif_Root() )   clname = TRIM(Agrif_CFixed())//"_"//TRIM(clname)
86            istatus = NF90_CREATE( TRIM(clname), NF90_CLOBBER, idrun )
87            istatus = NF90_DEF_DIM( idrun, 'time', NF90_UNLIMITED, idtime )
88            istatus = NF90_DEF_VAR( idrun, 'abs_ssh_max', NF90_DOUBLE, (/ idtime /), idssh )
89            istatus = NF90_DEF_VAR( idrun,   'abs_u_max', NF90_DOUBLE, (/ idtime /), idu   )
90            istatus = NF90_DEF_VAR( idrun,       's_min', NF90_DOUBLE, (/ idtime /), ids1  )
91            istatus = NF90_DEF_VAR( idrun,       's_max', NF90_DOUBLE, (/ idtime /), ids2  )
92            istatus = NF90_ENDDEF(idrun)
93         ENDIF
94         
95      ENDIF
96      !
97      IF(lwp) THEN                        !==  current time step  ==!   ("time.step" file)
98         WRITE ( numstp, '(1x, i8)' )   kt
99         REWIND( numstp )
100      ENDIF
101      !
102      !                                   !==  test of extrema  ==!
103      IF( ll_wd ) THEN
104         zmax(1) = MAXVAL(  ABS( sshn(:,:) + ssh_ref*tmask(:,:,1) )  )        ! ssh max
105      ELSE
106         zmax(1) = MAXVAL(  ABS( sshn(:,:) )  )                               ! ssh max
107      ENDIF
108      zmax(2) = MAXVAL(  ABS( un(:,:,:) )  )                                  ! velocity max (zonal only)
109      zmax(3) = MAXVAL( -tsn(:,:,:,jp_sal) , mask = tmask(:,:,:) == 1._wp )   ! minus salinity max
110      zmax(4) = MAXVAL(  tsn(:,:,:,jp_sal) , mask = tmask(:,:,:) == 1._wp )   !       salinity max
111      zmax(5) = REAL( nstop , wp )                                            ! stop indicator
112      !
113      IF( lk_mpp ) THEN
114         CALL mpp_max_multiple( zmax(:), 5 )    ! max over the global domain
115         !
116         nstop = NINT( zmax(5) )                 ! nstop indicator sheared among all local domains
117      ENDIF
118      !
119      IF( MOD( kt, nwrite ) == 1 .AND. lwp ) THEN
120         WRITE(numout,*) ' ==>> time-step= ', kt, ' |ssh| max: ',   zmax(1), ' |U| max: ', zmax(2),   &
121            &                                     ' S min: '    , - zmax(3), ' S max: ', zmax(4)
122      ENDIF
123      !
124      IF (  zmax(1) >   15._wp .OR.   &                    ! too large sea surface height ( > 15 m )
125         &  zmax(2) >   10._wp .OR.   &                    ! too large velocity ( > 10 m/s)
126         &  zmax(3) >=   0._wp .OR.   &                    ! negative or zero sea surface salinity
127         &  zmax(4) >= 100._wp .OR.   &                    ! too large sea surface salinity ( > 100 )
128         &  zmax(4) <    0._wp .OR.   &                    ! too large sea surface salinity (keep this line for sea-ice)
129         &  ISNAN( zmax(1) + zmax(2) + zmax(3) )  ) THEN   ! NaN encounter in the tests
130         IF( lk_mpp ) THEN
131            CALL mpp_maxloc( ABS(sshn)        , ssmask(:,:)  , zzz, iih , ijh        )
132            CALL mpp_maxloc( ABS(un)          , umask (:,:,:), zzz, iiu , iju , iku  )
133            CALL mpp_minloc( tsn(:,:,:,jp_sal), tmask (:,:,:), zzz, iis1, ijs1, iks1 )
134            CALL mpp_maxloc( tsn(:,:,:,jp_sal), tmask (:,:,:), zzz, iis2, ijs2, iks2 )
135         ELSE
136            iloch  = MINLOC( ABS( sshn(:,:)   )                               )
137            ilocu  = MAXLOC( ABS( un  (:,:,:) )                               )
138            ilocs1 = MINLOC( tsn(:,:,:,jp_sal) , mask = tmask(:,:,:) == 1._wp )
139            ilocs2 = MAXLOC( tsn(:,:,:,jp_sal) , mask = tmask(:,:,:) == 1._wp )
140            iih  = iloch (1) + nimpp - 1   ;   ijh  = iloch (2) + njmpp - 1
141            iiu  = ilocu (1) + nimpp - 1   ;   iju  = ilocu (2) + njmpp - 1   ;   iku  = ilocu (3)
142            iis1 = ilocs1(1) + nimpp - 1   ;   ijs1 = ilocs1(2) + njmpp - 1   ;   iks1 = ilocs1(3)
143            iis2 = ilocs2(1) + nimpp - 1   ;   ijs2 = ilocs2(2) + njmpp - 1   ;   iks2 = ilocs2(3)
144         ENDIF
145         IF(lwp) THEN
146            WRITE(numout,cform_err)
147            WRITE(numout,*) ' stp_ctl: |ssh| > 10 m  or  |U| > 10 m/s  or  S <= 0  or  S >= 100  or  NaN encounter in the tests'
148            WRITE(numout,*) ' ======= '
149            WRITE(numout,9100) kt,   zmax(1), iih , ijh
150            WRITE(numout,9200) kt,   zmax(2), iiu , iju , iku
151            WRITE(numout,9300) kt, - zmax(3), iis1, ijs1, iks1
152            WRITE(numout,9400) kt,   zmax(4), iis2, ijs2, iks2
153            WRITE(numout,*)
154            WRITE(numout,*) '          output of last computed fields in output.abort.nc file'
155         ENDIF
156         kindic = -3
157         !
158         nstop = nstop + 1                            ! increase nstop by 1 (on all local domains)
159         CALL dia_wri_state( 'output.abort', kt )     ! create an output.abort file
160         !
161      ENDIF
1629100  FORMAT (' kt=',i8,'   |ssh| max: ',1pg11.4,', at  i j  : ',2i5)
1639200  FORMAT (' kt=',i8,'   |U|   max: ',1pg11.4,', at  i j k: ',3i5)
1649300  FORMAT (' kt=',i8,'   S     min: ',1pg11.4,', at  i j k: ',3i5)
1659400  FORMAT (' kt=',i8,'   S     max: ',1pg11.4,', at  i j k: ',3i5)
166      !
167      !                                            !==  run statistics  ==!   ("run.stat" file)
168      IF(lwp) WRITE(numrun,9500) kt, zmax(1), zmax(2), -zmax(3), zmax(4)
169      IF( lwm ) THEN
170         istatus = NF90_PUT_VAR( idrun, idssh, (/ zmax(1)/), (/kt/), (/1/) )
171         istatus = NF90_PUT_VAR( idrun,   idu, (/ zmax(2)/), (/kt/), (/1/) )
172         istatus = NF90_PUT_VAR( idrun,  ids1, (/-zmax(3)/), (/kt/), (/1/) )
173         istatus = NF90_PUT_VAR( idrun,  ids2, (/ zmax(4)/), (/kt/), (/1/) )
174         IF( MOD( kt , 100 ) == 0 ) istatus = NF90_SYNC(idrun)
175         IF( kt == nitend         ) istatus = NF90_CLOSE(idrun)
176      END IF
177      !
1789500  FORMAT(' it :', i8, '    |ssh|_max: ', D23.16, ' |U|_max: ', D23.16,' S_min: ', D23.16,' S_max: ', D23.16)
179      !
180   END SUBROUTINE stp_ctl
181
182   !!======================================================================
183END MODULE stpctl
Note: See TracBrowser for help on using the repository browser.