New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/OFF – NEMO

source: NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/OFF/nemogcm.F90 @ 10345

Last change on this file since 10345 was 10345, checked in by smasson, 5 years ago

dev_r10164_HPC09_ESIWACE_PREP_MERGE: merge with trunk@10344, see #2133

  • Property svn:keywords set to Id
File size: 24.4 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Off-line Ocean   : passive tracer evolution, dynamics read in files
5   !!======================================================================
6   !! History :  3.3  ! 2010-05  (C. Ethe)  Full reorganization of the off-line: phasing with the on-line
7   !!            3.4  ! 2011-01  (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation
8   !!            4.0  ! 2016-10  (C. Ethe, G. Madec, S. Flavoni)  domain configuration / user defined interface
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   nemo_gcm      : off-line: solve ocean tracer only
13   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
14   !!   nemo_init     : initialization of the NEMO system
15   !!   nemo_ctl      : initialisation of the contol print
16   !!   nemo_closefile: close remaining open files
17   !!   nemo_alloc    : dynamical allocation
18   !!   istate_init   : simple initialization to zero of ocean fields
19   !!   stp_ctl       : reduced step control (no dynamics in off-line)
20   !!----------------------------------------------------------------------
21   USE dom_oce        ! ocean space domain variables
22   USE oce            ! dynamics and tracers variables
23   USE trc_oce        ! Shared ocean/passive tracers variables
24   USE c1d            ! 1D configuration
25   USE domain         ! domain initialization from coordinate & bathymetry (dom_init routine)
26   USE closea         ! treatment of closed seas (for ln_closea)
27   USE usrdef_nam     ! user defined configuration
28   USE eosbn2         ! equation of state            (eos bn2 routine)
29   !              ! ocean physics
30   USE ldftra         ! lateral diffusivity setting    (ldf_tra_init routine)
31   USE ldfslp         ! slopes of neutral surfaces     (ldf_slp_init routine)
32   USE traqsr         ! solar radiation penetration    (tra_qsr_init routine)
33   USE trabbl         ! bottom boundary layer          (tra_bbl_init routine)
34   USE traldf         ! lateral physics                (tra_ldf_init routine)
35   USE sbcmod         ! surface boundary condition     (sbc_init     routine)
36   USE phycst         ! physical constant                   (par_cst routine)
37   USE dtadyn         ! Lecture and Interpolation of the dynamical fields
38   USE trcini         ! Initilization of the passive tracers
39   USE daymod         ! calendar                            (day     routine)
40   USE trcstp         ! passive tracer time-stepping        (trc_stp routine)
41   USE dtadyn         ! Lecture and interpolation of the dynamical fields
42   !              ! Passive tracers needs
43   USE trc            ! passive tracer : variables
44   USE trcnam         ! passive tracer : namelist
45   USE trcrst         ! passive tracer restart
46   USE diaptr         ! Need to initialise this as some variables are used in if statements later
47   USE sbc_oce , ONLY : ln_rnf
48   USE sbcrnf         ! surface boundary condition : runoffs
49   !              ! I/O & MPP
50   USE iom            ! I/O library
51   USE in_out_manager ! I/O manager
52   USE mppini         ! shared/distributed memory setting (mpp_init routine)
53   USE lib_mpp        ! distributed memory computing
54#if defined key_iomput
55   USE xios           ! xIOserver
56#endif
57   USE prtctl         ! Print control                    (prt_ctl_init routine)
58   USE timing         ! Timing
59   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
60   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
61
62   IMPLICIT NONE
63   PRIVATE
64   
65   PUBLIC   nemo_gcm   ! called by nemo.F90
66
67   CHARACTER (len=64) ::   cform_aaa="( /, 'AAAAAAAA', / ) "   ! flag for output listing
68
69   !!----------------------------------------------------------------------
70   !! NEMO/OFF 4.0 , NEMO Consortium (2018)
71   !! $Id$
72   !! Software governed by the CeCILL license (see ./LICENSE)
73   !!----------------------------------------------------------------------
74CONTAINS
75
76   SUBROUTINE nemo_gcm
77      !!----------------------------------------------------------------------
78      !!                     ***  ROUTINE nemo_gcm  ***
79      !!
80      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
81      !!              curvilinear mesh on the sphere.
82      !!
83      !! ** Method  : - model general initialization
84      !!              - launch the time-stepping (dta_dyn and trc_stp)
85      !!              - finalize the run by closing files and communications
86      !!
87      !! References : Madec, Delecluse,Imbard, and Levy, 1997:  internal report, IPSL.
88      !!              Madec, 2008, internal report, IPSL.
89      !!----------------------------------------------------------------------
90      INTEGER :: istp, indic       ! time step index
91      !!----------------------------------------------------------------------
92
93      CALL nemo_init  ! Initializations
94
95      ! check that all process are still there... If some process have an error,
96      ! they will never enter in step and other processes will wait until the end of the cpu time!
97      IF( lk_mpp )   CALL mpp_max( 'nemogcm', nstop )
98
99      !                            !-----------------------!
100      !                            !==   time stepping   ==!
101      !                            !-----------------------!
102      istp = nit000
103      !
104      IF( ln_rnf )   CALL sbc_rnf(istp)   ! runoffs initialization
105      !
106      CALL iom_init( cxios_context )      ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS)
107      !
108      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  OFF time-stepping  ==!
109         !
110         IF( istp /= nit000 )   CALL day        ( istp )         ! Calendar (day was already called at nit000 in day_init)
111                                CALL iom_setkt  ( istp - nit000 + 1, cxios_context )   ! say to iom that we are at time step kstp
112#if defined key_sed_off
113                                CALL dta_dyn_sed( istp )         ! Interpolation of the dynamical fields
114#else
115                                CALL dta_dyn    ( istp )         ! Interpolation of the dynamical fields
116         IF( .NOT.ln_linssh )   CALL dta_dyn_swp( istp )         ! swap of sea  surface height and vertical scale factors
117#endif
118                                CALL trc_stp    ( istp )         ! time-stepping
119                                CALL stp_ctl    ( istp, indic )  ! Time loop: control and print
120         istp = istp + 1
121      END DO
122      !
123#if defined key_iomput
124      CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF
125#endif
126
127      !                            !------------------------!
128      !                            !==  finalize the run  ==!
129      !                            !------------------------!
130      IF(lwp) WRITE(numout,cform_aaa)                 ! Flag AAAAAAA
131
132      IF( nstop /= 0 .AND. lwp ) THEN                 ! error print
133         WRITE(numout,cform_err)
134         WRITE(numout,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
135         WRITE(numout,*)
136      ENDIF
137      !
138      IF( ln_timing )   CALL timing_finalize
139      !
140      CALL nemo_closefile
141      !
142#if defined key_iomput
143                     CALL xios_finalize   ! end mpp communications with xios
144#else
145      IF( lk_mpp )   CALL mppstop         ! end mpp communications
146#endif
147      !
148   END SUBROUTINE nemo_gcm
149
150
151   SUBROUTINE nemo_init
152      !!----------------------------------------------------------------------
153      !!                     ***  ROUTINE nemo_init  ***
154      !!
155      !! ** Purpose :   initialization of the nemo model in off-line mode
156      !!----------------------------------------------------------------------
157      INTEGER  ::   ji                 ! dummy loop indices
158      INTEGER  ::   ios, ilocal_comm   ! local integers
159      CHARACTER(len=120), DIMENSION(30) ::   cltxt, cltxt2, clnam
160      !!
161      NAMELIST/namctl/ ln_ctl   , nn_print, nn_ictls, nn_ictle,   &
162         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,   &
163         &             ln_timing, ln_diacfl
164      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
165      !!----------------------------------------------------------------------
166      !
167      cltxt  = ''
168      cltxt2 = ''
169      clnam  = '' 
170      cxios_context = 'nemo'
171      !
172      !                             ! Open reference namelist and configuration namelist files
173      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
174      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
175      !
176      REWIND( numnam_ref )              ! Namelist namctl in reference namelist
177      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
178901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
179      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist
180      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
181902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
182      !
183      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist
184      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
185903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
186      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist
187      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
188904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
189
190      !                             !--------------------------!
191      !                             !  Set global domain size  !   (control print return in cltxt2)
192      !                             !--------------------------!
193      IF( ln_read_cfg ) THEN              ! Read sizes in domain configuration file
194         CALL domain_cfg ( cltxt2,        cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
195         !
196      ELSE                                ! user-defined namelist
197         CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
198      ENDIF
199      !
200      l_offline = .true.                  ! passive tracers are run offline
201      !
202      !                             !--------------------------------------------!
203      !                             !  set communicator & select the local node  !
204      !                             !  NB: mynode also opens output.namelist.dyn !
205      !                             !      on unit number numond on first proc   !
206      !                             !--------------------------------------------!
207#if defined key_iomput
208      CALL  xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )
209      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )   ! Nodes selection
210#else
211      ilocal_comm = 0
212      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )                ! Nodes selection (control print return in cltxt)
213#endif
214
215      narea = narea + 1                       ! mynode return the rank of proc (0 --> jpnij -1 )
216
217      lwm = (narea == 1)                      ! control of output namelists
218      lwp = (narea == 1) .OR. ln_ctl          ! control of all listing output print
219
220      IF(lwm) THEN               ! write merged namelists from earlier to output namelist
221         !                       ! now that the file has been opened in call to mynode.
222         !                       ! NB: nammpp has already been written in mynode (if lk_mpp_mpi)
223         WRITE( numond, namctl )
224         WRITE( numond, namcfg )
225         IF( .NOT.ln_read_cfg ) THEN
226            DO ji = 1, SIZE(clnam)
227               IF( TRIM(clnam(ji)) /= '' )   WRITE(numond, * ) clnam(ji)     ! namusr_def print
228            END DO
229         ENDIF
230      ENDIF
231
232      IF(lwp) THEN                            ! open listing units
233         !
234         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
235         !
236         WRITE(numout,*)
237         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
238         WRITE(numout,*) '                       NEMO team'
239         WRITE(numout,*) '                   Off-line TOP Model'
240         WRITE(numout,*) '                NEMO version 4.0  (2017) '
241         WRITE(numout,*)
242         WRITE(numout,*)
243         DO ji = 1, SIZE(cltxt)
244            IF( TRIM(cltxt (ji)) /= '' )   WRITE(numout,*) cltxt(ji)    ! control print of mynode
245         END DO
246         WRITE(numout,*)
247         WRITE(numout,*)
248         DO ji = 1, SIZE(cltxt2)
249            IF( TRIM(cltxt2(ji)) /= '' )   WRITE(numout,*) cltxt2(ji)   ! control print of domain size
250         END DO
251         !
252         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
253         !
254      ENDIF
255      !                                      ! Domain decomposition
256      CALL mpp_init                          ! MPP
257
258      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
259      CALL nemo_alloc()
260
261      !                             !-------------------------------!
262      !                             !  NEMO general initialization  !
263      !                             !-------------------------------!
264
265      CALL nemo_ctl                          ! Control prints
266      !
267      !                                      ! General initialization
268      IF( ln_timing    )   CALL timing_init
269      IF( ln_timing    )   CALL timing_start( 'nemo_init')
270      !
271                           CALL     phy_cst         ! Physical constants
272                           CALL     eos_init        ! Equation of state
273      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
274                           CALL     dom_init("OPA") ! Domain
275      IF( ln_ctl       )   CALL prt_ctl_init        ! Print control
276
277                           CALL  istate_init    ! ocean initial state (Dynamics and tracers)
278
279                           CALL     sbc_init    ! Forcings : surface module
280
281      !                                      ! Tracer physics
282                           CALL ldf_tra_init    ! Lateral ocean tracer physics
283                           CALL ldf_eiv_init    ! Eddy induced velocity param
284                           CALL tra_ldf_init    ! lateral mixing
285      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
286      IF( ln_traqsr    )   CALL tra_qsr_init    ! penetrative solar radiation
287      IF( ln_trabbl    )   CALL tra_bbl_init    ! advective (and/or diffusive) bottom boundary layer scheme
288
289      !                                      ! Passive tracers
290                           CALL trc_nam_run    ! Needed to get restart parameters for passive tracers
291                           CALL trc_rst_cal( nit000, 'READ' )   ! calendar
292#if defined key_sed_off
293                           CALL dta_dyn_sed_init ! Initialization for the dynamics
294#else
295                           CALL dta_dyn_init   ! Initialization for the dynamics
296#endif
297
298                           CALL     trc_init   ! Passive tracers initialization
299                           CALL dia_ptr_init   ! Poleward TRansports initialization
300                           
301      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
302      !
303      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
304      !
305   END SUBROUTINE nemo_init
306
307
308   SUBROUTINE nemo_ctl
309      !!----------------------------------------------------------------------
310      !!                     ***  ROUTINE nemo_ctl  ***
311      !!
312      !! ** Purpose :   control print setting
313      !!
314      !! ** Method  : - print namctl information and check some consistencies
315      !!----------------------------------------------------------------------
316      !
317      IF(lwp) THEN                  ! control print
318         WRITE(numout,*)
319         WRITE(numout,*) 'nemo_ctl: Control prints'
320         WRITE(numout,*) '~~~~~~~~'
321         WRITE(numout,*) '   Namelist namctl'
322         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
323         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
324         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
325         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
326         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
327         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
328         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
329         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
330         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
331         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
332      ENDIF
333      !
334      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
335      nictls    = nn_ictls
336      nictle    = nn_ictle
337      njctls    = nn_jctls
338      njctle    = nn_jctle
339      isplt     = nn_isplt
340      jsplt     = nn_jsplt
341
342      IF(lwp) THEN                  ! control print
343         WRITE(numout,*)
344         WRITE(numout,*) '   Namelist namcfg'
345         WRITE(numout,*) '      read domain configuration file              ln_read_cfg      = ', ln_read_cfg
346         WRITE(numout,*) '         filename to be read                         cn_domcfg     = ', TRIM(cn_domcfg)
347         WRITE(numout,*) '         keep closed seas in the domain (if exist)   ln_closea     = ', ln_closea
348         WRITE(numout,*) '      create a configuration definition file      ln_write_cfg     = ', ln_write_cfg
349         WRITE(numout,*) '         filename to be written                      cn_domcfg_out = ', TRIM(cn_domcfg_out)
350         WRITE(numout,*) '      use file attribute if exists as i/p j-start ln_use_jattr     = ', ln_use_jattr
351      ENDIF
352      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
353      !
354      !                             ! Parameter control
355      !
356      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
357         IF( lk_mpp .AND. jpnij > 1 ) THEN
358            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
359         ELSE
360            IF( isplt == 1 .AND. jsplt == 1  ) THEN
361               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
362                  &           ' - the print control will be done over the whole domain' )
363            ENDIF
364            ijsplt = isplt * jsplt            ! total number of processors ijsplt
365         ENDIF
366         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
367         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
368         !
369         !                              ! indices used for the SUM control
370         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
371            lsp_area = .FALSE.
372         ELSE                                             ! print control done over a specific  area
373            lsp_area = .TRUE.
374            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
375               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
376               nictls = 1
377            ENDIF
378            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
379               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
380               nictle = jpiglo
381            ENDIF
382            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
383               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
384               njctls = 1
385            ENDIF
386            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
387               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
388               njctle = jpjglo
389            ENDIF
390         ENDIF
391      ENDIF
392      !
393      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
394         &                                                'Compile with key_nosignedzero enabled' )
395      !
396   END SUBROUTINE nemo_ctl
397
398
399   SUBROUTINE nemo_closefile
400      !!----------------------------------------------------------------------
401      !!                     ***  ROUTINE nemo_closefile  ***
402      !!
403      !! ** Purpose :   Close the files
404      !!----------------------------------------------------------------------
405      !
406      IF( lk_mpp )   CALL mppsync
407      !
408      CALL iom_close                                 ! close all input/output files managed by iom_*
409      !
410      IF( numstp     /= -1 )   CLOSE( numstp     )   ! time-step file
411      IF( numnam_ref /= -1 )   CLOSE( numnam_ref )   ! oce reference namelist
412      IF( numnam_cfg /= -1 )   CLOSE( numnam_cfg )   ! oce configuration namelist
413      IF( numout     /=  6 )   CLOSE( numout     )   ! standard model output file
414      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
415      !
416      numout = 6                                     ! redefine numout in case it is used after this point...
417      !
418   END SUBROUTINE nemo_closefile
419
420
421   SUBROUTINE nemo_alloc
422      !!----------------------------------------------------------------------
423      !!                     ***  ROUTINE nemo_alloc  ***
424      !!
425      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
426      !!
427      !! ** Method  :
428      !!----------------------------------------------------------------------
429      USE diawri ,   ONLY : dia_wri_alloc
430      USE dom_oce,   ONLY : dom_oce_alloc
431      USE zdf_oce,   ONLY : zdf_oce_alloc
432      USE trc_oce,   ONLY : trc_oce_alloc
433      !
434      INTEGER :: ierr
435      !!----------------------------------------------------------------------
436      !
437      ierr =        oce_alloc    ()          ! ocean
438      ierr = ierr + dia_wri_alloc()
439      ierr = ierr + dom_oce_alloc()          ! ocean domain
440      ierr = ierr + zdf_oce_alloc()          ! ocean vertical physics
441      ierr = ierr + trc_oce_alloc()          ! shared TRC / TRA arrays
442      !
443      IF( lk_mpp    )   CALL mpp_sum( 'nemogcm', ierr )
444      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
445      !
446   END SUBROUTINE nemo_alloc
447
448   SUBROUTINE istate_init
449      !!----------------------------------------------------------------------
450      !!                   ***  ROUTINE istate_init  ***
451      !!
452      !! ** Purpose :   Initialization to zero of the dynamics and tracers.
453      !!----------------------------------------------------------------------
454      !
455      !     now fields         !     after fields      !
456      un   (:,:,:)   = 0._wp   ;   ua(:,:,:) = 0._wp   !
457      vn   (:,:,:)   = 0._wp   ;   va(:,:,:) = 0._wp   !
458      wn   (:,:,:)   = 0._wp   !                       !
459      hdivn(:,:,:)   = 0._wp   !                       !
460      tsn  (:,:,:,:) = 0._wp   !                       !
461      !
462      rhd  (:,:,:) = 0.e0
463      rhop (:,:,:) = 0.e0
464      rn2  (:,:,:) = 0.e0
465      !
466   END SUBROUTINE istate_init
467
468
469   SUBROUTINE stp_ctl( kt, kindic )
470      !!----------------------------------------------------------------------
471      !!                    ***  ROUTINE stp_ctl  ***
472      !!
473      !! ** Purpose :   Control the run
474      !!
475      !! ** Method  : - Save the time step in numstp
476      !!
477      !! ** Actions :   'time.step' file containing the last ocean time-step
478      !!----------------------------------------------------------------------
479      INTEGER, INTENT(in   ) ::   kt      ! ocean time-step index
480      INTEGER, INTENT(inout) ::   kindic  ! indicator of solver convergence
481      !!----------------------------------------------------------------------
482      !
483      IF( kt == nit000 .AND. lwp ) THEN
484         WRITE(numout,*)
485         WRITE(numout,*) 'stp_ctl : time-stepping control'
486         WRITE(numout,*) '~~~~~~~'
487         ! open time.step file
488         CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
489      ENDIF
490      !
491      IF(lwp) WRITE ( numstp, '(1x, i8)' )   kt      !* save the current time step in numstp
492      IF(lwp) REWIND( numstp )                       ! --------------------------
493      !
494   END SUBROUTINE stp_ctl
495   !!======================================================================
496END MODULE nemogcm
Note: See TracBrowser for help on using the repository browser.