source: NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/TOP/C14/trcsms_c14.F90 @ 10372

Last change on this file since 10372 was 10069, checked in by nicolasmartin, 2 years ago

Fix mistakes of previous commit on SVN keywords property

  • Property svn:keywords set to Id
File size: 7.2 KB
Line 
1MODULE trcsms_c14
2   !!======================================================================
3   !!                      ***  MODULE trcsms_c14  ***
4   !! TOP : Bomb C14 main module
5   !!======================================================================
6   !! History     -   ! 1994-05 ( J. Orr ) original code
7   !!            1.0  ! 2006-02 ( J.M. Molines )  Free form + modularity
8   !!            2.0  ! 2008-12 ( C. Ethe ) reorganisation
9   !!            4.0  ! 2011-02 ( A.R. Porter, STFC Daresbury ) Dynamic memory
10   !!                 ! 2015    (A. Mouchet) general C14 + update formulas
11   !!----------------------------------------------------------------------
12   !!   trc_sms_c14 :  compute and add C14 suface forcing to C14 trends
13   !!----------------------------------------------------------------------
14   USE oce_trc       ! Ocean variables
15   USE par_trc       ! TOP parameters
16   USE trc           ! TOP variables
17   USE trd_oce    ! trends
18   USE trdtrc    ! trends
19   USE sms_c14    ! atmospheric forcing
20   USE trcatm_c14    ! atmospheric forcing
21   USE iom
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   trc_sms_c14       ! called in trcsms.F90
27
28   !!----------------------------------------------------------------------
29   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
30   !! $Id$
31   !! Software governed by the CeCILL license (see ./LICENSE)
32   !!----------------------------------------------------------------------
33CONTAINS
34
35   SUBROUTINE trc_sms_c14( kt )
36      !!----------------------------------------------------------------------
37      !!                  ***  ROUTINE trc_sms_c14  ***
38      !!
39      !! ** Purpose :   Compute the surface boundary contition on C14
40      !!      passive tracer associated with air-sea fluxes and add it to
41      !!      the general trend of tracers equations.
42      !
43      !    Method:
44      !          - transport the ratio C14/C as in Toggweiler et al. (JGR,1989)
45      !          - if on-line a passive tracer (jpcref; NO sms) allows compensating for
46      !            freshwater fluxes which should not impact the C14/C ratio
47      !
48      !        =>   Delta-C14= ( trn(...jp_c14) -1)*1000.
49      !!
50      !!----------------------------------------------------------------------
51      !
52      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
53      !
54      INTEGER  :: ji, jj, jk         ! dummy loop indices
55      REAL(wp) :: zt, ztp, zsk      ! dummy variables
56      REAL(wp) :: zsol              ! solubility
57      REAL(wp) :: zsch              ! schmidt number
58      REAL(wp) :: zv2               ! wind speed ( square)
59      REAL(wp) :: zpv               ! piston velocity
60      !!----------------------------------------------------------------------
61      !
62      IF( ln_timing )   CALL timing_start('trc_sms_c14')
63      !
64      IF( kt ==  nittrc000 ) THEN
65         IF(lwp) WRITE(numout,*)
66         IF(lwp) WRITE(numout,*) ' trc_sms_c14:  C14 model'
67         IF(lwp) WRITE(numout,*) ' ~~~~~~~~~~~~~~'
68      ENDIF
69      !
70      ! Get co2sbc & c14sbc(ji,jj): at 1st iter for all, at each time step for transient
71      IF( kc14typ >= 1 .OR.  kt ==  nittrc000 )   CALL trc_atm_c14( kt, co2sbc, c14sbc ) 
72
73      ! -------------------------------------------------------------------
74      !  Gas exchange coefficient (Wanninkhof, 1992, JGR, 97,7373-7382)
75      !  Schmidt number of CO2 in seawater (Wanninkhof, 1992 & 2014)
76      !  CO2 solubility (Weiss, 1974; Wanninkhof, 2014)
77      ! -------------------------------------------------------------------
78
79      DO jj = 1, jpj
80         DO ji = 1, jpi 
81            IF( tmask(ji,jj,1) >  0. ) THEN
82               !
83               zt   = MIN( 40. , tsn(ji,jj,1,jp_tem) )
84               !
85               !  Computation of solubility zsol in [mol/(L * atm)]
86               !   after Wanninkhof (2014) referencing Weiss (1974)
87               ztp  = ( zt + 273.16 ) * 0.01
88               zsk  = 0.027766 + ztp * ( -0.025888 + 0.0050578 * ztp )   ! [mol/(L * atm)]
89               zsol = EXP( -58.0931 + 90.5069 / ztp  + 22.2940 * LOG( ztp ) + zsk * tsn(ji,jj,1,jp_sal) )
90               ! convert solubilities [mol/(L * atm)] -> [mol/(m^3 * ppm)]
91               zsol = zsol * 1.e-03
92
93               ! Computes the Schmidt number of CO2 in seawater
94               !               Wanninkhof-2014
95               zsch = 2116.8 + zt * ( -136.25 + zt * (4.7353 + zt * (-0.092307 + 0.0007555 * zt ) ) )
96
97               ! Wanninkhof Piston velocity: zpv in units [m/s]
98               zv2 = xkwind * (wndm(ji,jj) * wndm(ji,jj))              ! wind speed module at T points
99               ! chemical enhancement (Wanninkhof & Knox, 1996)
100               IF( ln_chemh ) zv2 = zv2 + 2.5 * ( 0.5246 + zt * (0.016256 + 0.00049946  * zt ) )
101               zv2 = zv2/360000._wp                                    ! conversion cm/h -> m/s
102               !
103               zpv  = ( zv2 * SQRT( 660./ zsch ) ) * ( 1. - fr_i(ji,jj) ) * tmask(ji,jj,1)
104
105               ! CO2 piston velocity (m/s)
106               exch_co2(ji,jj)= zpv
107               ! CO2 invasion rate (mol/ppm/m2/s) = 1st part of 14C/C exchange velocity
108               exch_c14(ji,jj)= zpv * zsol
109            ELSE
110               exch_co2(ji,jj) = 0._wp
111               exch_c14(ji,jj) = 0._wp
112            ENDIF
113         END DO
114      END DO
115
116      ! Exchange velocity for 14C/C ratio (m/s)
117      zt = co2sbc / xdicsur
118      exch_c14(:,:) = zt * exch_c14(:,:)
119      !
120      ! Flux of C-14 from air-to-sea; units: (C14/C ratio) x m/s
121      !                               already masked
122      qtr_c14(:,:) = exch_c14(:,:) * ( c14sbc(:,:) - trb(:,:,1,jp_c14) )
123           
124      ! cumulation of air-to-sea flux at each time step
125      qint_c14(:,:) = qint_c14(:,:) + qtr_c14(:,:) * rdttrc
126      !
127      ! Add the surface flux to the trend of jp_c14
128      DO jj = 1, jpj
129         DO ji = 1, jpi
130            tra(ji,jj,1,jp_c14) = tra(ji,jj,1,jp_c14) + qtr_c14(ji,jj) / e3t_n(ji,jj,1) 
131         END DO
132      END DO
133      !
134      ! Computation of decay effects on jp_c14
135      DO jk = 1, jpk
136         DO jj = 1, jpj
137            DO ji = 1, jpi
138               !
139               tra(ji,jj,jk,jp_c14) = tra(ji,jj,jk,jp_c14) - rlam14 * trb(ji,jj,jk,jp_c14) * tmask(ji,jj,jk) 
140               !
141            END DO
142         END DO
143      END DO
144      !
145      IF( lrst_trc ) THEN
146         IF(lwp) WRITE(numout,*)
147         IF(lwp) WRITE(numout,*) ' trc_rst_wri_c14 : Write specific variables from c14 model '
148         IF(lwp) WRITE(numout,*) ' ~~~~~~~~~~~~~~'
149         !
150         CALL iom_rstput( kt, nitrst, numrtw, 'co2sbc', co2sbc )       ! These five need      &
151         CALL iom_rstput( kt, nitrst, numrtw, 'c14sbc', c14sbc )     ! &    to be written   &
152         CALL iom_rstput( kt, nitrst, numrtw, 'exch_co2', exch_co2 ) ! &    for temporal    &
153         CALL iom_rstput( kt, nitrst, numrtw, 'exch_c14', exch_c14 ) ! &    averages        &
154         CALL iom_rstput( kt, nitrst, numrtw, 'qtr_c14', qtr_c14 )   ! &    to be coherent.
155         CALL iom_rstput( kt, nitrst, numrtw, 'qint_c14', qint_c14 ) ! Cumulative
156         !
157      ENDIF
158
159      IF( l_trdtrc )  CALL trd_trc( tra(:,:,:,jp_c14), 1, jptra_sms, kt )   ! save trends
160      !
161      IF( ln_timing )   CALL timing_stop('trc_sms_c14')
162      !
163   END SUBROUTINE trc_sms_c14
164
165  !!======================================================================
166END MODULE trcsms_c14
Note: See TracBrowser for help on using the repository browser.