New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zprod.F90 in NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/TOP/PISCES/P4Z/p4zprod.F90 @ 10377

Last change on this file since 10377 was 10368, checked in by smasson, 5 years ago

dev_r10164_HPC09_ESIWACE_PREP_MERGE: merge with trunk@10365, see #2133
  • Property svn:keywords set to Id
File size: 28.5 KB
Line 
1MODULE p4zprod
2   !!======================================================================
3   !!                         ***  MODULE p4zprod  ***
4   !! TOP :  Growth Rate of the two phytoplanktons groups
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-05  (O. Aumont, C. Ethe) New parameterization of light limitation
9   !!----------------------------------------------------------------------
10   !!   p4z_prod       : Compute the growth Rate of the two phytoplanktons groups
11   !!   p4z_prod_init  : Initialization of the parameters for growth
12   !!   p4z_prod_alloc : Allocate variables for growth
13   !!----------------------------------------------------------------------
14   USE oce_trc         ! shared variables between ocean and passive tracers
15   USE trc             ! passive tracers common variables
16   USE sms_pisces      ! PISCES Source Minus Sink variables
17   USE p4zlim          ! Co-limitations of differents nutrients
18   USE prtctl_trc      ! print control for debugging
19   USE iom             ! I/O manager
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC   p4z_prod         ! called in p4zbio.F90
25   PUBLIC   p4z_prod_init    ! called in trcsms_pisces.F90
26   PUBLIC   p4z_prod_alloc
27
28   LOGICAL , PUBLIC ::   ln_newprod   !:
29   REAL(wp), PUBLIC ::   pislopen     !:
30   REAL(wp), PUBLIC ::   pisloped     !:
31   REAL(wp), PUBLIC ::   xadap        !:
32   REAL(wp), PUBLIC ::   excretn      !:
33   REAL(wp), PUBLIC ::   excretd      !:
34   REAL(wp), PUBLIC ::   bresp        !:
35   REAL(wp), PUBLIC ::   chlcnm       !:
36   REAL(wp), PUBLIC ::   chlcdm       !:
37   REAL(wp), PUBLIC ::   chlcmin      !:
38   REAL(wp), PUBLIC ::   fecnm        !:
39   REAL(wp), PUBLIC ::   fecdm        !:
40   REAL(wp), PUBLIC ::   grosip       !:
41
42   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotan   !: proxy of N quota in Nanophyto
43   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotad   !: proxy of N quota in diatomee
44   
45   REAL(wp) ::   r1_rday    ! 1 / rday
46   REAL(wp) ::   texcretn   ! 1 - excretn
47   REAL(wp) ::   texcretd   ! 1 - excretd       
48
49   !!----------------------------------------------------------------------
50   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
51   !! $Id$
52   !! Software governed by the CeCILL license (see ./LICENSE)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE p4z_prod( kt , knt )
57      !!---------------------------------------------------------------------
58      !!                     ***  ROUTINE p4z_prod  ***
59      !!
60      !! ** Purpose :   Compute the phytoplankton production depending on
61      !!              light, temperature and nutrient availability
62      !!
63      !! ** Method  : - ???
64      !!---------------------------------------------------------------------
65      INTEGER, INTENT(in) ::   kt, knt   !
66      !
67      INTEGER  ::   ji, jj, jk
68      REAL(wp) ::   zsilfac, znanotot, zdiattot, zconctemp, zconctemp2
69      REAL(wp) ::   zratio, zmax, zsilim, ztn, zadap, zlim, zsilfac2, zsiborn
70      REAL(wp) ::   zprod, zproreg, zproreg2, zprochln, zprochld
71      REAL(wp) ::   zmaxday, zdocprod, zpislopen, zpisloped
72      REAL(wp) ::   zmxltst, zmxlday
73      REAL(wp) ::   zrum, zcodel, zargu, zval, zfeup, chlcnm_n, chlcdm_n
74      REAL(wp) ::   zfact
75      CHARACTER (len=25) :: charout
76      REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: zw2d
77      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zw3d
78      REAL(wp), DIMENSION(jpi,jpj    ) :: zstrn, zmixnano, zmixdiat
79      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprmaxn,zprmaxd
80      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpislopeadn, zpislopeadd, zysopt 
81      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprdia, zprbio, zprdch, zprnch   
82      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprorcan, zprorcad, zprofed, zprofen
83      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpronewn, zpronewd
84      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zmxl_fac, zmxl_chl
85      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpligprod1, zpligprod2
86      !!---------------------------------------------------------------------
87      !
88      IF( ln_timing )   CALL timing_start('p4z_prod')
89      !
90      !  Allocate temporary workspace
91      !
92      zprorcan(:,:,:) = 0._wp ; zprorcad(:,:,:) = 0._wp ; zprofed (:,:,:) = 0._wp
93      zprofen (:,:,:) = 0._wp ; zysopt  (:,:,:) = 0._wp
94      zpronewn(:,:,:) = 0._wp ; zpronewd(:,:,:) = 0._wp ; zprdia  (:,:,:) = 0._wp
95      zprbio  (:,:,:) = 0._wp ; zprdch  (:,:,:) = 0._wp ; zprnch  (:,:,:) = 0._wp 
96      zmxl_fac(:,:,:) = 0._wp ; zmxl_chl(:,:,:) = 0._wp 
97
98      ! Computation of the optimal production
99      zprmaxn(:,:,:) = 0.8_wp * r1_rday * tgfunc(:,:,:)
100      zprmaxd(:,:,:) = zprmaxn(:,:,:)
101
102      ! compute the day length depending on latitude and the day
103      zrum = REAL( nday_year - 80, wp ) / REAL( nyear_len(1), wp )
104      zcodel = ASIN(  SIN( zrum * rpi * 2._wp ) * SIN( rad * 23.5_wp )  )
105
106      ! day length in hours
107      zstrn(:,:) = 0.
108      DO jj = 1, jpj
109         DO ji = 1, jpi
110            zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rad )
111            zargu = MAX( -1., MIN(  1., zargu ) )
112            zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rad / 15. )
113         END DO
114      END DO
115
116      ! Impact of the day duration and light intermittency on phytoplankton growth
117      DO jk = 1, jpkm1
118         DO jj = 1 ,jpj
119            DO ji = 1, jpi
120               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
121                  zval = MAX( 1., zstrn(ji,jj) )
122                  IF( gdept_n(ji,jj,jk) <= hmld(ji,jj) ) THEN
123                     zval = zval * MIN(1., heup_01(ji,jj) / ( hmld(ji,jj) + rtrn ))
124                  ENDIF
125                  zmxl_chl(ji,jj,jk) = zval / 24.
126                  zmxl_fac(ji,jj,jk) = 1.5 * zval / ( 12. + zval )
127               ENDIF
128            END DO
129         END DO
130      END DO
131
132      zprbio(:,:,:) = zprmaxn(:,:,:) * zmxl_fac(:,:,:)
133      zprdia(:,:,:) = zprmaxd(:,:,:) * zmxl_fac(:,:,:)
134
135      ! Maximum light intensity
136      WHERE( zstrn(:,:) < 1.e0 ) zstrn(:,:) = 24.
137
138      ! Computation of the P-I slope for nanos and diatoms
139      DO jk = 1, jpkm1
140         DO jj = 1, jpj
141            DO ji = 1, jpi
142               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
143                  ztn         = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. )
144                  zadap       = xadap * ztn / ( 2.+ ztn )
145                  zconctemp   = MAX( 0.e0 , trb(ji,jj,jk,jpdia) - xsizedia )
146                  zconctemp2  = trb(ji,jj,jk,jpdia) - zconctemp
147                  !
148                  zpislopeadn(ji,jj,jk) = pislopen * ( 1.+ zadap  * EXP( -0.25 * enano(ji,jj,jk) ) )  &
149                  &                   * trb(ji,jj,jk,jpnch) /( trb(ji,jj,jk,jpphy) * 12. + rtrn)
150                  !
151                  zpislopeadd(ji,jj,jk) = (pislopen * zconctemp2 + pisloped * zconctemp) / ( trb(ji,jj,jk,jpdia) + rtrn )   &
152                  &                   * trb(ji,jj,jk,jpdch) /( trb(ji,jj,jk,jpdia) * 12. + rtrn)
153               ENDIF
154            END DO
155         END DO
156      END DO
157
158      IF( ln_newprod ) THEN
159         DO jk = 1, jpkm1
160            DO jj = 1, jpj
161               DO ji = 1, jpi
162                  IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
163                      ! Computation of production function for Carbon
164                      !  ---------------------------------------------
165                      zpislopen = zpislopeadn(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) &
166                      &            * zmxl_fac(ji,jj,jk) * rday + rtrn)
167                      zpisloped = zpislopeadd(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) &
168                      &            * zmxl_fac(ji,jj,jk) * rday + rtrn)
169                      zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) )  )
170                      zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) )  )
171                      !  Computation of production function for Chlorophyll
172                      !--------------------------------------------------
173                      zpislopen = zpislopeadn(ji,jj,jk) / ( zprmaxn(ji,jj,jk) * zmxl_chl(ji,jj,jk) * rday + rtrn )
174                      zpisloped = zpislopeadd(ji,jj,jk) / ( zprmaxd(ji,jj,jk) * zmxl_chl(ji,jj,jk) * rday + rtrn )
175                      zprnch(ji,jj,jk) = zprmaxn(ji,jj,jk) * ( 1.- EXP( -zpislopen * enanom(ji,jj,jk) ) )
176                      zprdch(ji,jj,jk) = zprmaxd(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediatm(ji,jj,jk) ) )
177                  ENDIF
178               END DO
179            END DO
180         END DO
181      ELSE
182         DO jk = 1, jpkm1
183            DO jj = 1, jpj
184               DO ji = 1, jpi
185                  IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
186                      ! Computation of production function for Carbon
187                      !  ---------------------------------------------
188                      zpislopen = zpislopeadn(ji,jj,jk)  / ( zprbio(ji,jj,jk) * rday * xlimphy(ji,jj,jk) + rtrn )
189                      zpisloped = zpislopeadd(ji,jj,jk) / ( zprdia(ji,jj,jk) * rday * xlimdia(ji,jj,jk) + rtrn )
190                      zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) ) )
191                      zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) ) )
192                      !  Computation of production function for Chlorophyll
193                      !--------------------------------------------------
194                      zpislopen = zpislopen * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
195                      zpisloped = zpisloped * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
196                      zprnch(ji,jj,jk) = zprmaxn(ji,jj,jk) * ( 1.- EXP( -zpislopen * enanom(ji,jj,jk) ) )
197                      zprdch(ji,jj,jk) = zprmaxd(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediatm(ji,jj,jk) ) )
198                  ENDIF
199               END DO
200            END DO
201         END DO
202      ENDIF
203
204      !  Computation of a proxy of the N/C ratio
205      !  ---------------------------------------
206      DO jk = 1, jpkm1
207         DO jj = 1, jpj
208            DO ji = 1, jpi
209                zval = MIN( xnanopo4(ji,jj,jk), ( xnanonh4(ji,jj,jk) + xnanono3(ji,jj,jk) ) )   &
210                &      * zprmaxn(ji,jj,jk) / ( zprbio(ji,jj,jk) + rtrn )
211                quotan(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
212                zval = MIN( xdiatpo4(ji,jj,jk), ( xdiatnh4(ji,jj,jk) + xdiatno3(ji,jj,jk) ) )   &
213                &      * zprmaxd(ji,jj,jk) / ( zprdia(ji,jj,jk) + rtrn )
214                quotad(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
215            END DO
216         END DO
217      END DO
218
219
220      DO jk = 1, jpkm1
221         DO jj = 1, jpj
222            DO ji = 1, jpi
223
224                IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
225                   !    Si/C of diatoms
226                   !    ------------------------
227                   !    Si/C increases with iron stress and silicate availability
228                   !    Si/C is arbitrariliy increased for very high Si concentrations
229                   !    to mimic the very high ratios observed in the Southern Ocean (silpot2)
230                  zlim  = trb(ji,jj,jk,jpsil) / ( trb(ji,jj,jk,jpsil) + xksi1 )
231                  zsilim = MIN( zprdia(ji,jj,jk) / ( zprmaxd(ji,jj,jk) + rtrn ), xlimsi(ji,jj,jk) )
232                  zsilfac = 4.4 * EXP( -4.23 * zsilim ) * MAX( 0.e0, MIN( 1., 2.2 * ( zlim - 0.5 ) )  ) + 1.e0
233                  zsiborn = trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil)
234                  IF (gphit(ji,jj) < -30 ) THEN
235                    zsilfac2 = 1. + 2. * zsiborn / ( zsiborn + xksi2**3 )
236                  ELSE
237                    zsilfac2 = 1. +      zsiborn / ( zsiborn + xksi2**3 )
238                  ENDIF
239                  zysopt(ji,jj,jk) = grosip * zlim * zsilfac * zsilfac2
240              ENDIF
241            END DO
242         END DO
243      END DO
244
245      !  Mixed-layer effect on production
246      !  Sea-ice effect on production
247
248      DO jk = 1, jpkm1
249         DO jj = 1, jpj
250            DO ji = 1, jpi
251               zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
252               zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
253               zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
254               zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
255            END DO
256         END DO
257      END DO
258
259      ! Computation of the various production terms
260      DO jk = 1, jpkm1
261         DO jj = 1, jpj
262            DO ji = 1, jpi
263               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
264                  !  production terms for nanophyto. (C)
265                  zprorcan(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * trb(ji,jj,jk,jpphy) * rfact2
266                  zpronewn(ji,jj,jk)  = zprorcan(ji,jj,jk)* xnanono3(ji,jj,jk) / ( xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) + rtrn )
267                  !
268                  zratio = trb(ji,jj,jk,jpnfe) / ( trb(ji,jj,jk,jpphy) * fecnm + rtrn )
269                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
270                  zprofen(ji,jj,jk) = fecnm * zprmaxn(ji,jj,jk) * ( 1.0 - fr_i(ji,jj) )  &
271                  &             * ( 4. - 4.5 * xlimnfe(ji,jj,jk) / ( xlimnfe(ji,jj,jk) + 0.5 ) )    &
272                  &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concnfe(ji,jj,jk) )  &
273                  &             * zmax * trb(ji,jj,jk,jpphy) * rfact2
274                  !  production terms for diatoms (C)
275                  zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * trb(ji,jj,jk,jpdia) * rfact2
276                  zpronewd(ji,jj,jk) = zprorcad(ji,jj,jk) * xdiatno3(ji,jj,jk) / ( xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) + rtrn )
277                  !
278                  zratio = trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) * fecdm + rtrn )
279                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
280                  zprofed(ji,jj,jk) = fecdm * zprmaxd(ji,jj,jk) * ( 1.0 - fr_i(ji,jj) )  &
281                  &             * ( 4. - 4.5 * xlimdfe(ji,jj,jk) / ( xlimdfe(ji,jj,jk) + 0.5 ) )    &
282                  &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concdfe(ji,jj,jk) )  &
283                  &             * zmax * trb(ji,jj,jk,jpdia) * rfact2
284               ENDIF
285            END DO
286         END DO
287      END DO
288
289      ! Computation of the chlorophyll production terms
290      DO jk = 1, jpkm1
291         DO jj = 1, jpj
292            DO ji = 1, jpi
293               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
294                  !  production terms for nanophyto. ( chlorophyll )
295                  znanotot = enanom(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
296                  zprod    = rday * zprorcan(ji,jj,jk) * zprnch(ji,jj,jk) * xlimphy(ji,jj,jk)
297                  zprochln = chlcmin * 12. * zprorcan (ji,jj,jk)
298                  chlcnm_n   = MIN ( chlcnm, ( chlcnm / (1. - 1.14 / 43.4 *tsn(ji,jj,jk,jp_tem))) * (1. - 1.14 / 43.4 * 20.))
299                  zprochln = zprochln + (chlcnm_n-chlcmin) * 12. * zprod / &
300                                        & (  zpislopeadn(ji,jj,jk) * znanotot +rtrn)
301                  !  production terms for diatoms ( chlorophyll )
302                  zdiattot = ediatm(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
303                  zprod    = rday * zprorcad(ji,jj,jk) * zprdch(ji,jj,jk) * xlimdia(ji,jj,jk)
304                  zprochld = chlcmin * 12. * zprorcad(ji,jj,jk)
305                  chlcdm_n   = MIN ( chlcdm, ( chlcdm / (1. - 1.14 / 43.4 * tsn(ji,jj,jk,jp_tem))) * (1. - 1.14 / 43.4 * 20.))
306                  zprochld = zprochld + (chlcdm_n-chlcmin) * 12. * zprod / &
307                                        & ( zpislopeadd(ji,jj,jk) * zdiattot +rtrn )
308                  !   Update the arrays TRA which contain the Chla sources and sinks
309                  tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) + zprochln * texcretn
310                  tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) + zprochld * texcretd
311               ENDIF
312            END DO
313         END DO
314      END DO
315
316      !   Update the arrays TRA which contain the biological sources and sinks
317      DO jk = 1, jpkm1
318         DO jj = 1, jpj
319           DO ji =1 ,jpi
320              IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
321                 zproreg  = zprorcan(ji,jj,jk) - zpronewn(ji,jj,jk)
322                 zproreg2 = zprorcad(ji,jj,jk) - zpronewd(ji,jj,jk)
323                 zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk)
324                 tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk)
325                 tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - zpronewn(ji,jj,jk) - zpronewd(ji,jj,jk)
326                 tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zproreg - zproreg2
327                 tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) + zprorcan(ji,jj,jk) * texcretn
328                 tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) + zprofen(ji,jj,jk) * texcretn
329                 tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) + zprorcad(ji,jj,jk) * texcretd
330                 tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) + zprofed(ji,jj,jk) * texcretd
331                 tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcretd
332                 tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zdocprod
333                 tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2ut * ( zproreg + zproreg2) &
334                 &                   + ( o2ut + o2nit ) * ( zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk) )
335                 !
336                 zfeup = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk)
337                 tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zfeup
338                 tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) - texcretd * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk)
339                 tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk)
340                 tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk) ) &
341                 &                                         - rno3 * ( zproreg + zproreg2 )
342              ENDIF
343           END DO
344        END DO
345     END DO
346     !
347     IF( ln_ligand ) THEN
348         DO jk = 1, jpkm1
349            DO jj = 1, jpj
350              DO ji =1 ,jpi
351                 IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
352                    zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk)
353                    zfeup    = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk)
354                    tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + zdocprod * ldocp - zfeup * plig(ji,jj,jk) * lthet
355                    zpligprod1(ji,jj,jk) = zdocprod * ldocp
356                    zpligprod2(ji,jj,jk) = zfeup * plig(ji,jj,jk) * lthet
357                 ENDIF
358              END DO
359           END DO
360        END DO
361     ENDIF
362
363
364    ! Total primary production per year
365    IF( iom_use( "tintpp" ) .OR. ( ln_check_mass .AND. kt == nitend .AND. knt == nrdttrc )  )  &
366         & tpp = glob_sum( 'p4zprod', ( zprorcan(:,:,:) + zprorcad(:,:,:) ) * cvol(:,:,:) )
367
368    IF( lk_iomput ) THEN
369       IF( knt == nrdttrc ) THEN
370          ALLOCATE( zw2d(jpi,jpj), zw3d(jpi,jpj,jpk) )
371          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
372          !
373          IF( iom_use( "PPPHYN" ) .OR. iom_use( "PPPHYD" ) )  THEN
374              zw3d(:,:,:) = zprorcan(:,:,:) * zfact * tmask(:,:,:)  ! primary production by nanophyto
375              CALL iom_put( "PPPHYN"  , zw3d )
376              !
377              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:)  ! primary production by diatomes
378              CALL iom_put( "PPPHYD"  , zw3d )
379          ENDIF
380          IF( iom_use( "PPNEWN" ) .OR. iom_use( "PPNEWD" ) )  THEN
381              zw3d(:,:,:) = zpronewn(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by nanophyto
382              CALL iom_put( "PPNEWN"  , zw3d )
383              !
384              zw3d(:,:,:) = zpronewd(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by diatomes
385              CALL iom_put( "PPNEWD"  , zw3d )
386          ENDIF
387          IF( iom_use( "PBSi" ) )  THEN
388              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:) ! biogenic silica production
389              CALL iom_put( "PBSi"  , zw3d )
390          ENDIF
391          IF( iom_use( "PFeN" ) .OR. iom_use( "PFeD" ) )  THEN
392              zw3d(:,:,:) = zprofen(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by nanophyto
393              CALL iom_put( "PFeN"  , zw3d )
394              !
395              zw3d(:,:,:) = zprofed(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by  diatomes
396              CALL iom_put( "PFeD"  , zw3d )
397          ENDIF
398          IF( iom_use( "LPRODP" ) )  THEN
399              zw3d(:,:,:) = zpligprod1(:,:,:) * 1e9 * zfact * tmask(:,:,:)
400              CALL iom_put( "LPRODP"  , zw3d )
401          ENDIF
402          IF( iom_use( "LDETP" ) )  THEN
403              zw3d(:,:,:) = zpligprod2(:,:,:) * 1e9 * zfact * tmask(:,:,:)
404              CALL iom_put( "LDETP"  , zw3d )
405          ENDIF
406          IF( iom_use( "Mumax" ) )  THEN
407              zw3d(:,:,:) = zprmaxn(:,:,:) * tmask(:,:,:)   ! Maximum growth rate
408              CALL iom_put( "Mumax"  , zw3d )
409          ENDIF
410          IF( iom_use( "MuN" ) .OR. iom_use( "MuD" ) )  THEN
411              zw3d(:,:,:) = zprbio(:,:,:) * xlimphy(:,:,:) * tmask(:,:,:)  ! Realized growth rate for nanophyto
412              CALL iom_put( "MuN"  , zw3d )
413              !
414              zw3d(:,:,:) =  zprdia(:,:,:) * xlimdia(:,:,:) * tmask(:,:,:)  ! Realized growth rate for diatoms
415              CALL iom_put( "MuD"  , zw3d )
416          ENDIF
417          IF( iom_use( "LNlight" ) .OR. iom_use( "LDlight" ) )  THEN
418              zw3d(:,:,:) = zprbio (:,:,:) / (zprmaxn(:,:,:) + rtrn) * tmask(:,:,:) ! light limitation term
419              CALL iom_put( "LNlight"  , zw3d )
420              !
421              zw3d(:,:,:) = zprdia (:,:,:) / (zprmaxd(:,:,:) + rtrn) * tmask(:,:,:)  ! light limitation term
422              CALL iom_put( "LDlight"  , zw3d )
423          ENDIF
424          IF( iom_use( "TPP" ) )  THEN
425              zw3d(:,:,:) = ( zprorcan(:,:,:) + zprorcad(:,:,:) ) * zfact * tmask(:,:,:)  ! total primary production
426              CALL iom_put( "TPP"  , zw3d )
427          ENDIF
428          IF( iom_use( "TPNEW" ) )  THEN
429              zw3d(:,:,:) = ( zpronewn(:,:,:) + zpronewd(:,:,:) ) * zfact * tmask(:,:,:)  ! total new production
430              CALL iom_put( "TPNEW"  , zw3d )
431          ENDIF
432          IF( iom_use( "TPBFE" ) )  THEN
433              zw3d(:,:,:) = ( zprofen(:,:,:) + zprofed(:,:,:) ) * zfact * tmask(:,:,:)  ! total biogenic iron production
434              CALL iom_put( "TPBFE"  , zw3d )
435          ENDIF
436          IF( iom_use( "INTPPPHYN" ) .OR. iom_use( "INTPPPHYD" ) ) THEN 
437             zw2d(:,:) = 0.
438             DO jk = 1, jpkm1
439               zw2d(:,:) = zw2d(:,:) + zprorcan(:,:,jk) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk)  ! vert. integrated  primary produc. by nano
440             ENDDO
441             CALL iom_put( "INTPPPHYN" , zw2d )
442             !
443             zw2d(:,:) = 0.
444             DO jk = 1, jpkm1
445                zw2d(:,:) = zw2d(:,:) + zprorcad(:,:,jk) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk) ! vert. integrated  primary produc. by diatom
446             ENDDO
447             CALL iom_put( "INTPPPHYD" , zw2d )
448          ENDIF
449          IF( iom_use( "INTPP" ) ) THEN   
450             zw2d(:,:) = 0.
451             DO jk = 1, jpkm1
452                zw2d(:,:) = zw2d(:,:) + ( zprorcan(:,:,jk) + zprorcad(:,:,jk) ) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk) ! vert. integrated pp
453             ENDDO
454             CALL iom_put( "INTPP" , zw2d )
455          ENDIF
456          IF( iom_use( "INTPNEW" ) ) THEN   
457             zw2d(:,:) = 0.
458             DO jk = 1, jpkm1
459                zw2d(:,:) = zw2d(:,:) + ( zpronewn(:,:,jk) + zpronewd(:,:,jk) ) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk)  ! vert. integrated new prod
460             ENDDO
461             CALL iom_put( "INTPNEW" , zw2d )
462          ENDIF
463          IF( iom_use( "INTPBFE" ) ) THEN           !   total biogenic iron production  ( vertically integrated )
464             zw2d(:,:) = 0.
465             DO jk = 1, jpkm1
466                zw2d(:,:) = zw2d(:,:) + ( zprofen(:,:,jk) + zprofed(:,:,jk) ) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk) ! vert integr. bfe prod
467             ENDDO
468            CALL iom_put( "INTPBFE" , zw2d )
469          ENDIF
470          IF( iom_use( "INTPBSI" ) ) THEN           !   total biogenic silica production  ( vertically integrated )
471             zw2d(:,:) = 0.
472             DO jk = 1, jpkm1
473                zw2d(:,:) = zw2d(:,:) + zprorcad(:,:,jk) * zysopt(:,:,jk) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk)  ! vert integr. bsi prod
474             ENDDO
475             CALL iom_put( "INTPBSI" , zw2d )
476          ENDIF
477          IF( iom_use( "tintpp" ) )  CALL iom_put( "tintpp" , tpp * zfact )  !  global total integrated primary production molC/s
478          !
479          DEALLOCATE( zw2d, zw3d )
480       ENDIF
481     ENDIF
482
483     IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
484         WRITE(charout, FMT="('prod')")
485         CALL prt_ctl_trc_info(charout)
486         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
487     ENDIF
488      !
489      IF( ln_timing )  CALL timing_stop('p4z_prod')
490      !
491   END SUBROUTINE p4z_prod
492
493
494   SUBROUTINE p4z_prod_init
495      !!----------------------------------------------------------------------
496      !!                  ***  ROUTINE p4z_prod_init  ***
497      !!
498      !! ** Purpose :   Initialization of phytoplankton production parameters
499      !!
500      !! ** Method  :   Read the nampisprod namelist and check the parameters
501      !!      called at the first timestep (nittrc000)
502      !!
503      !! ** input   :   Namelist nampisprod
504      !!----------------------------------------------------------------------
505      INTEGER ::   ios   ! Local integer
506      !
507      NAMELIST/namp4zprod/ pislopen, pisloped, xadap, ln_newprod, bresp, excretn, excretd,  &
508         &                 chlcnm, chlcdm, chlcmin, fecnm, fecdm, grosip
509      !!----------------------------------------------------------------------
510      !
511      IF(lwp) THEN                         ! control print
512         WRITE(numout,*)
513         WRITE(numout,*) 'p4z_prod_init : phytoplankton growth'
514         WRITE(numout,*) '~~~~~~~~~~~~~'
515      ENDIF
516      !
517      REWIND( numnatp_ref )              ! Namelist nampisprod in reference namelist : Pisces phytoplankton production
518      READ  ( numnatp_ref, namp4zprod, IOSTAT = ios, ERR = 901)
519901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namp4zprod in reference namelist', lwp )
520      REWIND( numnatp_cfg )              ! Namelist nampisprod in configuration namelist : Pisces phytoplankton production
521      READ  ( numnatp_cfg, namp4zprod, IOSTAT = ios, ERR = 902 )
522902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namp4zprod in configuration namelist', lwp )
523      IF(lwm) WRITE( numonp, namp4zprod )
524
525      IF(lwp) THEN                         ! control print
526         WRITE(numout,*) '   Namelist : namp4zprod'
527         WRITE(numout,*) '      Enable new parame. of production (T/F)   ln_newprod    =', ln_newprod
528         WRITE(numout,*) '      mean Si/C ratio                           grosip       =', grosip
529         WRITE(numout,*) '      P-I slope                                 pislopen     =', pislopen
530         WRITE(numout,*) '      Acclimation factor to low light           xadap        =', xadap
531         WRITE(numout,*) '      excretion ratio of nanophytoplankton      excretn      =', excretn
532         WRITE(numout,*) '      excretion ratio of diatoms                excretd      =', excretd
533         IF( ln_newprod )  THEN
534            WRITE(numout,*) '      basal respiration in phytoplankton        bresp        =', bresp
535            WRITE(numout,*) '      Maximum Chl/C in phytoplankton            chlcmin      =', chlcmin
536         ENDIF
537         WRITE(numout,*) '      P-I slope  for diatoms                    pisloped     =', pisloped
538         WRITE(numout,*) '      Minimum Chl/C in nanophytoplankton        chlcnm       =', chlcnm
539         WRITE(numout,*) '      Minimum Chl/C in diatoms                  chlcdm       =', chlcdm
540         WRITE(numout,*) '      Maximum Fe/C in nanophytoplankton         fecnm        =', fecnm
541         WRITE(numout,*) '      Minimum Fe/C in diatoms                   fecdm        =', fecdm
542      ENDIF
543      !
544      r1_rday   = 1._wp / rday 
545      texcretn  = 1._wp - excretn
546      texcretd  = 1._wp - excretd
547      tpp       = 0._wp
548      !
549   END SUBROUTINE p4z_prod_init
550
551
552   INTEGER FUNCTION p4z_prod_alloc()
553      !!----------------------------------------------------------------------
554      !!                     ***  ROUTINE p4z_prod_alloc  ***
555      !!----------------------------------------------------------------------
556      ALLOCATE( quotan(jpi,jpj,jpk), quotad(jpi,jpj,jpk), STAT = p4z_prod_alloc )
557      !
558      IF( p4z_prod_alloc /= 0 ) CALL ctl_warn('p4z_prod_alloc : failed to allocate arrays.')
559      !
560   END FUNCTION p4z_prod_alloc
561
562   !!======================================================================
563END MODULE p4zprod
Note: See TracBrowser for help on using the repository browser.