New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsink.F90 in NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/TOP/PISCES/P4Z/p4zsink.F90 @ 10297

Last change on this file since 10297 was 10297, checked in by smasson, 5 years ago

dev_r10164_HPC09_ESIWACE_PREP_MERGE: action 2a: add report calls of mppmin/max/sum, see #2133

  • Property svn:keywords set to Id
File size: 16.9 KB
Line 
1MODULE p4zsink
2   !!======================================================================
3   !!                         ***  MODULE p4zsink  ***
4   !! TOP :  PISCES  vertical flux of particulate matter due to gravitational sinking
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Change aggregation formula
9   !!             3.5  !  2012-07  (O. Aumont) Introduce potential time-splitting
10   !!----------------------------------------------------------------------
11   !!   p4z_sink       :  Compute vertical flux of particulate matter due to gravitational sinking
12   !!   p4z_sink_init  :  Unitialisation of sinking speed parameters
13   !!   p4z_sink_alloc :  Allocate sinking speed variables
14   !!----------------------------------------------------------------------
15   USE oce_trc         !  shared variables between ocean and passive tracers
16   USE trc             !  passive tracers common variables
17   USE sms_pisces      !  PISCES Source Minus Sink variables
18   USE prtctl_trc      !  print control for debugging
19   USE iom             !  I/O manager
20   USE lib_mpp
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   p4z_sink         ! called in p4zbio.F90
26   PUBLIC   p4z_sink_init    ! called in trcsms_pisces.F90
27   PUBLIC   p4z_sink_alloc
28
29   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinking, sinking2  !: POC sinking fluxes
30   !                                                          !  (different meanings depending on the parameterization)
31   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkingn, sinking2n  !: POC sinking fluxes
32   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkingp, sinking2p  !: POC sinking fluxes
33   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkcal, sinksil   !: CaCO3 and BSi sinking fluxes
34   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkfer            !: Small BFe sinking fluxes
35   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkfer2           !: Big iron sinking fluxes
36   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkfep      !: Fep sinking fluxes
37
38   INTEGER  :: ik100
39
40   !!----------------------------------------------------------------------
41   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
42   !! $Id$
43   !! Software governed by the CeCILL license (see ./LICENSE)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   !!----------------------------------------------------------------------
48   !!   'standard sinking parameterisation'                  ???
49   !!----------------------------------------------------------------------
50
51   SUBROUTINE p4z_sink ( kt, knt )
52      !!---------------------------------------------------------------------
53      !!                     ***  ROUTINE p4z_sink  ***
54      !!
55      !! ** Purpose :   Compute vertical flux of particulate matter due to
56      !!                gravitational sinking
57      !!
58      !! ** Method  : - ???
59      !!---------------------------------------------------------------------
60      INTEGER, INTENT(in) :: kt, knt
61      INTEGER  ::   ji, jj, jk, jit
62      INTEGER  ::   iiter1, iiter2
63      REAL(wp) ::   zagg1, zagg2, zagg3, zagg4
64      REAL(wp) ::   zagg , zaggfe, zaggdoc, zaggdoc2, zaggdoc3
65      REAL(wp) ::   zfact, zwsmax, zmax
66      CHARACTER (len=25) :: charout
67      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zw3d
68      REAL(wp), ALLOCATABLE, DIMENSION(:,:  ) :: zw2d
69      !!---------------------------------------------------------------------
70      !
71      IF( ln_timing )   CALL timing_start('p4z_sink')
72
73
74      ! Initialization of some global variables
75      ! ---------------------------------------
76      prodpoc(:,:,:) = 0.
77      conspoc(:,:,:) = 0.
78      prodgoc(:,:,:) = 0.
79      consgoc(:,:,:) = 0.
80
81      !
82      !    Sinking speeds of detritus is increased with depth as shown
83      !    by data and from the coagulation theory
84      !    -----------------------------------------------------------
85      DO jk = 1, jpkm1
86         DO jj = 1, jpj
87            DO ji = 1,jpi
88               zmax  = MAX( heup_01(ji,jj), hmld(ji,jj) )
89               zfact = MAX( 0., gdepw_n(ji,jj,jk+1) - zmax ) / wsbio2scale
90               wsbio4(ji,jj,jk) = wsbio2 + MAX(0., ( wsbio2max - wsbio2 )) * zfact
91            END DO
92         END DO
93      END DO
94
95      ! limit the values of the sinking speeds to avoid numerical instabilities 
96      wsbio3(:,:,:) = wsbio
97
98      !
99      ! OA This is (I hope) a temporary solution for the problem that may
100      ! OA arise in specific situation where the CFL criterion is broken
101      ! OA for vertical sedimentation of particles. To avoid this, a time
102      ! OA splitting algorithm has been coded. A specific maximum
103      ! OA iteration number is provided and may be specified in the namelist
104      ! OA This is to avoid very large iteration number when explicit free
105      ! OA surface is used (for instance). When niter?max is set to 1,
106      ! OA this computation is skipped. The crude old threshold method is
107      ! OA then applied. This also happens when niter exceeds nitermax.
108      IF( MAX( niter1max, niter2max ) == 1 ) THEN
109        iiter1 = 1
110        iiter2 = 1
111      ELSE
112        iiter1 = 1
113        iiter2 = 1
114        DO jk = 1, jpkm1
115          DO jj = 1, jpj
116             DO ji = 1, jpi
117                IF( tmask(ji,jj,jk) == 1) THEN
118                   zwsmax =  0.5 * e3t_n(ji,jj,jk) / xstep
119                   iiter1 =  MAX( iiter1, INT( wsbio3(ji,jj,jk) / zwsmax ) )
120                   iiter2 =  MAX( iiter2, INT( wsbio4(ji,jj,jk) / zwsmax ) )
121                ENDIF
122             END DO
123          END DO
124        END DO
125        IF( lk_mpp ) THEN
126           CALL mpp_max( 'p4zsink', iiter1 )
127           CALL mpp_max( 'p4zsink', iiter2 )
128        ENDIF
129        iiter1 = MIN( iiter1, niter1max )
130        iiter2 = MIN( iiter2, niter2max )
131      ENDIF
132
133      DO jk = 1,jpkm1
134         DO jj = 1, jpj
135            DO ji = 1, jpi
136               IF( tmask(ji,jj,jk) == 1 ) THEN
137                 zwsmax = 0.5 * e3t_n(ji,jj,jk) / xstep
138                 wsbio3(ji,jj,jk) = MIN( wsbio3(ji,jj,jk), zwsmax * REAL( iiter1, wp ) )
139                 wsbio4(ji,jj,jk) = MIN( wsbio4(ji,jj,jk), zwsmax * REAL( iiter2, wp ) )
140               ENDIF
141            END DO
142         END DO
143      END DO
144
145      wscal (:,:,:) = wsbio4(:,:,:)
146
147      !  Initializa to zero all the sinking arrays
148      !   -----------------------------------------
149      sinking (:,:,:) = 0.e0
150      sinking2(:,:,:) = 0.e0
151      sinkcal (:,:,:) = 0.e0
152      sinkfer (:,:,:) = 0.e0
153      sinksil (:,:,:) = 0.e0
154      sinkfer2(:,:,:) = 0.e0
155
156      !   Compute the sedimentation term using p4zsink2 for all the sinking particles
157      !   -----------------------------------------------------
158      DO jit = 1, iiter1
159        CALL p4z_sink2( wsbio3, sinking , jppoc, iiter1 )
160        CALL p4z_sink2( wsbio3, sinkfer , jpsfe, iiter1 )
161      END DO
162
163      DO jit = 1, iiter2
164        CALL p4z_sink2( wsbio4, sinking2, jpgoc, iiter2 )
165        CALL p4z_sink2( wsbio4, sinkfer2, jpbfe, iiter2 )
166        CALL p4z_sink2( wsbio4, sinksil , jpgsi, iiter2 )
167        CALL p4z_sink2( wscal , sinkcal , jpcal, iiter2 )
168      END DO
169
170      IF( ln_p5z ) THEN
171         sinkingn (:,:,:) = 0.e0
172         sinking2n(:,:,:) = 0.e0
173         sinkingp (:,:,:) = 0.e0
174         sinking2p(:,:,:) = 0.e0
175
176         !   Compute the sedimentation term using p4zsink2 for all the sinking particles
177         !   -----------------------------------------------------
178         DO jit = 1, iiter1
179           CALL p4z_sink2( wsbio3, sinkingn , jppon, iiter1 )
180           CALL p4z_sink2( wsbio3, sinkingp , jppop, iiter1 )
181         END DO
182
183         DO jit = 1, iiter2
184           CALL p4z_sink2( wsbio4, sinking2n, jpgon, iiter2 )
185           CALL p4z_sink2( wsbio4, sinking2p, jpgop, iiter2 )
186         END DO
187      ENDIF
188
189      IF( ln_ligand ) THEN
190         wsfep (:,:,:) = wfep
191         DO jk = 1,jpkm1
192            DO jj = 1, jpj
193               DO ji = 1, jpi
194                  IF( tmask(ji,jj,jk) == 1 ) THEN
195                    zwsmax = 0.5 * e3t_n(ji,jj,jk) / xstep
196                    wsfep(ji,jj,jk) = MIN( wsfep(ji,jj,jk), zwsmax * REAL( iiter1, wp ) )
197                  ENDIF
198               END DO
199            END DO
200         END DO
201         !
202         sinkfep(:,:,:) = 0.e0
203         DO jit = 1, iiter1
204           CALL p4z_sink2( wsfep, sinkfep , jpfep, iiter1 )
205         END DO
206      ENDIF
207
208     ! Total carbon export per year
209     IF( iom_use( "tcexp" ) .OR. ( ln_check_mass .AND. kt == nitend .AND. knt == nrdttrc )  )  &
210        &   t_oce_co2_exp = glob_sum( ( sinking(:,:,ik100) + sinking2(:,:,ik100) ) * e1e2t(:,:) * tmask(:,:,1) )
211     !
212     IF( lk_iomput ) THEN
213       IF( knt == nrdttrc ) THEN
214          ALLOCATE( zw2d(jpi,jpj), zw3d(jpi,jpj,jpk) )
215          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
216          !
217          IF( iom_use( "EPC100" ) )  THEN
218              zw2d(:,:) = ( sinking(:,:,ik100) + sinking2(:,:,ik100) ) * zfact * tmask(:,:,1) ! Export of carbon at 100m
219              CALL iom_put( "EPC100"  , zw2d )
220          ENDIF
221          IF( iom_use( "EPFE100" ) )  THEN
222              zw2d(:,:) = ( sinkfer(:,:,ik100) + sinkfer2(:,:,ik100) ) * zfact * tmask(:,:,1) ! Export of iron at 100m
223              CALL iom_put( "EPFE100"  , zw2d )
224          ENDIF
225          IF( iom_use( "EPCAL100" ) )  THEN
226              zw2d(:,:) = sinkcal(:,:,ik100) * zfact * tmask(:,:,1) ! Export of calcite at 100m
227              CALL iom_put( "EPCAL100"  , zw2d )
228          ENDIF
229          IF( iom_use( "EPSI100" ) )  THEN
230              zw2d(:,:) =  sinksil(:,:,ik100) * zfact * tmask(:,:,1) ! Export of bigenic silica at 100m
231              CALL iom_put( "EPSI100"  , zw2d )
232          ENDIF
233          IF( iom_use( "EXPC" ) )  THEN
234              zw3d(:,:,:) = ( sinking(:,:,:) + sinking2(:,:,:) ) * zfact * tmask(:,:,:) ! Export of carbon in the water column
235              CALL iom_put( "EXPC"  , zw3d )
236          ENDIF
237          IF( iom_use( "EXPFE" ) )  THEN
238              zw3d(:,:,:) = ( sinkfer(:,:,:) + sinkfer2(:,:,:) ) * zfact * tmask(:,:,:) ! Export of iron
239              CALL iom_put( "EXPFE"  , zw3d )
240          ENDIF
241          IF( iom_use( "EXPCAL" ) )  THEN
242              zw3d(:,:,:) = sinkcal(:,:,:) * zfact * tmask(:,:,:) ! Export of calcite
243              CALL iom_put( "EXPCAL"  , zw3d )
244          ENDIF
245          IF( iom_use( "EXPSI" ) )  THEN
246              zw3d(:,:,:) = sinksil(:,:,:) * zfact * tmask(:,:,:) ! Export of bigenic silica
247              CALL iom_put( "EXPSI"  , zw3d )
248          ENDIF
249          IF( iom_use( "tcexp" ) )  CALL iom_put( "tcexp" , t_oce_co2_exp * zfact )   ! molC/s
250          !
251          DEALLOCATE( zw2d, zw3d )
252        ENDIF
253      ENDIF
254      !
255      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
256         WRITE(charout, FMT="('sink')")
257         CALL prt_ctl_trc_info(charout)
258         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
259      ENDIF
260      !
261      IF( ln_timing )   CALL timing_stop('p4z_sink')
262      !
263   END SUBROUTINE p4z_sink
264
265
266   SUBROUTINE p4z_sink_init
267      !!----------------------------------------------------------------------
268      !!                  ***  ROUTINE p4z_sink_init  ***
269      !!----------------------------------------------------------------------
270      INTEGER :: jk
271      !!----------------------------------------------------------------------
272      !
273      ik100 = 10        !  last level where depth less than 100 m
274      DO jk = jpkm1, 1, -1
275         IF( gdept_1d(jk) > 100. )  ik100 = jk - 1
276      END DO
277      IF (lwp) WRITE(numout,*)
278      IF (lwp) WRITE(numout,*) ' Level corresponding to 100m depth ',  ik100 + 1
279      IF (lwp) WRITE(numout,*)
280      !
281      t_oce_co2_exp = 0._wp
282      !
283   END SUBROUTINE p4z_sink_init
284
285
286   SUBROUTINE p4z_sink2( pwsink, psinkflx, jp_tra, kiter )
287      !!---------------------------------------------------------------------
288      !!                     ***  ROUTINE p4z_sink2  ***
289      !!
290      !! ** Purpose :   Compute the sedimentation terms for the various sinking
291      !!     particles. The scheme used to compute the trends is based
292      !!     on MUSCL.
293      !!
294      !! ** Method  : - this ROUTINE compute not exactly the advection but the
295      !!      transport term, i.e.  div(u*tra).
296      !!---------------------------------------------------------------------
297      INTEGER , INTENT(in   )                         ::   jp_tra    ! tracer index index     
298      INTEGER , INTENT(in   )                         ::   kiter     ! number of iterations for time-splitting
299      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj,jpk) ::   pwsink    ! sinking speed
300      REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) ::   psinkflx  ! sinking fluxe
301      !
302      INTEGER  ::   ji, jj, jk, jn
303      REAL(wp) ::   zigma,zew,zign, zflx, zstep
304      REAL(wp), DIMENSION(jpi,jpj,jpk) :: ztraz, zakz, zwsink2, ztrb 
305      !!---------------------------------------------------------------------
306      !
307      IF( ln_timing )   CALL timing_start('p4z_sink2')
308      !
309      zstep = rfact2 / REAL( kiter, wp ) / 2.
310
311      ztraz(:,:,:) = 0.e0
312      zakz (:,:,:) = 0.e0
313      ztrb (:,:,:) = trb(:,:,:,jp_tra)
314
315      DO jk = 1, jpkm1
316         zwsink2(:,:,jk+1) = -pwsink(:,:,jk) / rday * tmask(:,:,jk+1) 
317      END DO
318      zwsink2(:,:,1) = 0.e0
319
320
321      ! Vertical advective flux
322      DO jn = 1, 2
323         !  first guess of the slopes interior values
324         DO jk = 2, jpkm1
325            ztraz(:,:,jk) = ( trb(:,:,jk-1,jp_tra) - trb(:,:,jk,jp_tra) ) * tmask(:,:,jk)
326         END DO
327         ztraz(:,:,1  ) = 0.0
328         ztraz(:,:,jpk) = 0.0
329
330         ! slopes
331         DO jk = 2, jpkm1
332            DO jj = 1,jpj
333               DO ji = 1, jpi
334                  zign = 0.25 + SIGN( 0.25, ztraz(ji,jj,jk) * ztraz(ji,jj,jk+1) )
335                  zakz(ji,jj,jk) = ( ztraz(ji,jj,jk) + ztraz(ji,jj,jk+1) ) * zign
336               END DO
337            END DO
338         END DO
339         
340         ! Slopes limitation
341         DO jk = 2, jpkm1
342            DO jj = 1, jpj
343               DO ji = 1, jpi
344                  zakz(ji,jj,jk) = SIGN( 1., zakz(ji,jj,jk) ) *        &
345                     &             MIN( ABS( zakz(ji,jj,jk) ), 2. * ABS(ztraz(ji,jj,jk+1)), 2. * ABS(ztraz(ji,jj,jk) ) )
346               END DO
347            END DO
348         END DO
349         
350         ! vertical advective flux
351         DO jk = 1, jpkm1
352            DO jj = 1, jpj     
353               DO ji = 1, jpi   
354                  zigma = zwsink2(ji,jj,jk+1) * zstep / e3w_n(ji,jj,jk+1)
355                  zew   = zwsink2(ji,jj,jk+1)
356                  psinkflx(ji,jj,jk+1) = -zew * ( trb(ji,jj,jk,jp_tra) - 0.5 * ( 1 + zigma ) * zakz(ji,jj,jk) ) * zstep
357               END DO
358            END DO
359         END DO
360         !
361         ! Boundary conditions
362         psinkflx(:,:,1  ) = 0.e0
363         psinkflx(:,:,jpk) = 0.e0
364         
365         DO jk=1,jpkm1
366            DO jj = 1,jpj
367               DO ji = 1, jpi
368                  zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / e3t_n(ji,jj,jk)
369                  trb(ji,jj,jk,jp_tra) = trb(ji,jj,jk,jp_tra) + zflx
370               END DO
371            END DO
372         END DO
373
374      ENDDO
375
376      DO jk = 1,jpkm1
377         DO jj = 1,jpj
378            DO ji = 1, jpi
379               zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / e3t_n(ji,jj,jk)
380               ztrb(ji,jj,jk) = ztrb(ji,jj,jk) + 2. * zflx
381            END DO
382         END DO
383      END DO
384
385      trb(:,:,:,jp_tra) = ztrb(:,:,:)
386      psinkflx(:,:,:)   = 2. * psinkflx(:,:,:)
387      !
388      IF( ln_timing )  CALL timing_stop('p4z_sink2')
389      !
390   END SUBROUTINE p4z_sink2
391
392
393   INTEGER FUNCTION p4z_sink_alloc()
394      !!----------------------------------------------------------------------
395      !!                     ***  ROUTINE p4z_sink_alloc  ***
396      !!----------------------------------------------------------------------
397      INTEGER :: ierr(3)
398      !!----------------------------------------------------------------------
399      !
400      ierr(:) = 0
401      !
402      ALLOCATE( sinking(jpi,jpj,jpk) , sinking2(jpi,jpj,jpk)                    ,     &               
403         &      sinkcal(jpi,jpj,jpk) , sinksil (jpi,jpj,jpk)                    ,     &               
404         &      sinkfer2(jpi,jpj,jpk)                                           ,     &               
405         &      sinkfer(jpi,jpj,jpk)                                            , STAT=ierr(1) )               
406         !
407      IF( ln_ligand ) ALLOCATE( sinkfep(jpi,jpj,jpk)                            , STAT=ierr(2) ) 
408         
409      IF( ln_p5z    ) ALLOCATE( sinkingn(jpi,jpj,jpk), sinking2n(jpi,jpj,jpk)   ,     &
410         &                      sinkingp(jpi,jpj,jpk), sinking2p(jpi,jpj,jpk)   , STAT=ierr(3) )
411      !
412      p4z_sink_alloc = MAXVAL( ierr )
413      IF( p4z_sink_alloc /= 0 ) CALL ctl_warn('p4z_sink_alloc : failed to allocate arrays.')
414      !
415   END FUNCTION p4z_sink_alloc
416   
417   !!======================================================================
418END MODULE p4zsink
Note: See TracBrowser for help on using the repository browser.