New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p5zlim.F90 in NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/TOP/PISCES/P4Z/p5zlim.F90 @ 10368

Last change on this file since 10368 was 10368, checked in by smasson, 5 years ago

dev_r10164_HPC09_ESIWACE_PREP_MERGE: merge with trunk@10365, see #2133

File size: 33.0 KB
Line 
1MODULE p5zlim
2   !!======================================================================
3   !!                         ***  MODULE p5zlim  ***
4   !! TOP :   PISCES with variable stoichiometry
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-04  (O. Aumont, C. Ethe) Limitation for iron modelled in quota
9   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
10   !!----------------------------------------------------------------------
11   !!   p5z_lim        :   Compute the nutrients limitation terms
12   !!   p5z_lim_init   :   Read the namelist
13   !!----------------------------------------------------------------------
14   USE oce_trc         ! Shared ocean-passive tracers variables
15   USE trc             ! Tracers defined
16   USE p4zlim
17   USE sms_pisces      ! PISCES variables
18   USE iom             !  I/O manager
19
20   IMPLICIT NONE
21   PRIVATE
22
23   PUBLIC p5z_lim   
24   PUBLIC p5z_lim_init   
25   PUBLIC p5z_lim_alloc
26
27   !! * Shared module variables
28   REAL(wp), PUBLIC ::  concpno3    !:  NO3, PO4 half saturation   
29   REAL(wp), PUBLIC ::  concpnh4    !:  NH4 half saturation for phyto 
30   REAL(wp), PUBLIC ::  concnpo4    !:  NH4 half saturation for diatoms
31   REAL(wp), PUBLIC ::  concppo4    !:  NH4 half saturation for diatoms
32   REAL(wp), PUBLIC ::  concdpo4    !:  NH4 half saturation for diatoms
33   REAL(wp), PUBLIC ::  concpfer    !:  Iron half saturation for nanophyto
34   REAL(wp), PUBLIC ::  concbpo4    !:  PO4 half saturation for bacteria
35   REAL(wp), PUBLIC ::  xsizepic    !:  Minimum size criteria for diatoms
36   REAL(wp), PUBLIC ::  xsizerp     !:  Size ratio for nanophytoplankton
37   REAL(wp), PUBLIC ::  qfnopt      !:  optimal Fe quota for nanophyto
38   REAL(wp), PUBLIC ::  qfpopt      !:  optimal Fe quota for nanophyto
39   REAL(wp), PUBLIC ::  qfdopt      !:  optimal Fe quota for diatoms
40   REAL(wp), PUBLIC ::  qnnmin      !:  optimal Fe quota for diatoms
41   REAL(wp), PUBLIC ::  qnnmax      !:  optimal Fe quota for diatoms
42   REAL(wp), PUBLIC ::  qpnmin      !:  optimal Fe quota for diatoms
43   REAL(wp), PUBLIC ::  qpnmax      !:  optimal Fe quota for diatoms
44   REAL(wp), PUBLIC ::  qnpmin      !:  optimal Fe quota for diatoms
45   REAL(wp), PUBLIC ::  qnpmax      !:  optimal Fe quota for diatoms
46   REAL(wp), PUBLIC ::  qppmin      !:  optimal Fe quota for diatoms
47   REAL(wp), PUBLIC ::  qppmax      !:  optimal Fe quota for diatoms
48   REAL(wp), PUBLIC ::  qndmin      !:  optimal Fe quota for diatoms
49   REAL(wp), PUBLIC ::  qndmax      !:  optimal Fe quota for diatoms
50   REAL(wp), PUBLIC ::  qpdmin      !:  optimal Fe quota for diatoms
51   REAL(wp), PUBLIC ::  qpdmax      !:  optimal Fe quota for diatoms
52   REAL(wp), PUBLIC ::  qfnmax      !:  optimal Fe quota for diatoms
53   REAL(wp), PUBLIC ::  qfpmax      !:  optimal Fe quota for diatoms
54   REAL(wp), PUBLIC ::  qfdmax      !:  optimal Fe quota for diatoms
55   REAL(wp), PUBLIC ::  zpsinh4
56   REAL(wp), PUBLIC ::  zpsino3
57   REAL(wp), PUBLIC ::  zpsiuptk
58
59   !!*  Allometric variations of the quotas
60   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:,:)  ::   xqnnmin    !: ???
61   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:,:)  ::   xqnnmax    !: ???
62   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:,:)  ::   xqpnmin    !: ???
63   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:,:)  ::   xqpnmax    !: ???
64   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:,:)  ::   xqnpmin    !: ???
65   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:,:)  ::   xqnpmax    !: ???
66   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:,:)  ::   xqppmin    !: ???
67   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:,:)  ::   xqppmax    !: ???
68   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:,:)  ::   xqndmin    !: ???
69   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:,:)  ::   xqndmax    !: ???
70   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:,:)  ::   xqpdmin    !: ???
71   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:,:)  ::   xqpdmax    !: ???
72
73   !!* Phytoplankton limitation terms
74   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xpicono3   !: ???
75   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xpiconh4   !: ???
76   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xpicopo4   !: ???
77   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xnanodop   !: ???
78   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xpicodop   !: ???
79   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xdiatdop   !: ???
80   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xnanofer   !: ???
81   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xpicofer   !: ???
82   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xdiatfer   !: ???
83   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xlimpic    !: ???
84   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xlimpfe    !: ???
85   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   fvnuptk
86   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   fvpuptk
87   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   fvduptk
88
89   ! Coefficient for iron limitation
90   REAL(wp) ::  xcoef1   = 0.00167  / 55.85
91   REAL(wp) ::  xcoef2   = 1.21E-5 * 14. / 55.85 / 7.625 * 0.5 * 1.5
92   REAL(wp) ::  xcoef3   = 1.15E-4 * 14. / 55.85 / 7.625 * 0.5 
93   !!----------------------------------------------------------------------
94   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
95   !! $Id: p5zlim.F90 10070 2018-08-28 14:30:54Z nicolasmartin $
96   !! Software governed by the CeCILL license (see ./LICENSE)
97   !!----------------------------------------------------------------------
98
99CONTAINS
100
101   SUBROUTINE p5z_lim( kt, knt )
102      !!---------------------------------------------------------------------
103      !!                     ***  ROUTINE p5z_lim  ***
104      !!
105      !! ** Purpose :   Compute the co-limitations by the various nutrients
106      !!              for the various phytoplankton species
107      !!
108      !! ** Method  : - ???
109      !!---------------------------------------------------------------------
110      !
111      INTEGER, INTENT(in)  :: kt, knt
112      !
113      INTEGER  ::   ji, jj, jk
114      REAL(wp) ::   zlim1, zlim2, zlim3, zlim4, zno3, zferlim
115      REAL(wp) ::   z1_trndia, z1_trnpic, z1_trnphy, ztem1, ztem2, zetot1
116      REAL(wp) ::   zratio, zration, zratiof, znutlim, zfalim
117      REAL(wp) ::   zconc1d, zconc1dnh4, zconc0n, zconc0nnh4, zconc0npo4, zconc0dpo4
118      REAL(wp) ::   zconc0p, zconc0pnh4, zconc0ppo4, zconcpfe, zconcnfe, zconcdfe
119      REAL(wp) ::   fanano, fananop, fananof, fadiat, fadiatp, fadiatf
120      REAL(wp) ::   fapico, fapicop, fapicof
121      REAL(wp) ::   zrpho, zrass, zcoef, zfuptk, zratchl
122      REAL(wp) ::   zfvn, zfvp, zfvf, zsizen, zsizep, zsized, znanochl, zpicochl, zdiatchl
123      REAL(wp) ::   zqfemn, zqfemp, zqfemd, zbactno3, zbactnh4
124      !!---------------------------------------------------------------------
125      !
126      IF( ln_timing )   CALL timing_start('p5z_lim')
127      !
128      zratchl = 6.0
129      !
130      DO jk = 1, jpkm1
131         DO jj = 1, jpj
132            DO ji = 1, jpi
133               !
134               ! Tuning of the iron concentration to a minimum level that is set to the detection limit
135               !-------------------------------------
136               zno3    = trb(ji,jj,jk,jpno3) / 40.e-6
137               zferlim = MAX( 3e-11 * zno3 * zno3, 5e-12 )
138               zferlim = MIN( zferlim, 7e-11 )
139               trb(ji,jj,jk,jpfer) = MAX( trb(ji,jj,jk,jpfer), zferlim )
140
141               ! Computation of the mean relative size of each community
142               ! -------------------------------------------------------
143               z1_trnphy   = 1. / ( trb(ji,jj,jk,jpphy) + rtrn )
144               z1_trnpic   = 1. / ( trb(ji,jj,jk,jppic) + rtrn )
145               z1_trndia   = 1. / ( trb(ji,jj,jk,jpdia) + rtrn )
146               znanochl = trb(ji,jj,jk,jpnch) * z1_trnphy
147               zpicochl = trb(ji,jj,jk,jppch) * z1_trnpic
148               zdiatchl = trb(ji,jj,jk,jpdch) * z1_trndia
149
150               ! Computation of a variable Ks for iron on diatoms taking into account
151               ! that increasing biomass is made of generally bigger cells
152               !------------------------------------------------
153               zsized            = sized(ji,jj,jk)**0.81
154               zconcdfe          = concdfer * zsized
155               zconc1d           = concdno3 * zsized
156               zconc1dnh4        = concdnh4 * zsized
157               zconc0dpo4        = concdpo4 * zsized
158
159               zsizep            = 1.
160               zconcpfe          = concpfer * zsizep
161               zconc0p           = concpno3 * zsizep
162               zconc0pnh4        = concpnh4 * zsizep
163               zconc0ppo4        = concppo4 * zsizep
164
165               zsizen            = 1.
166               zconcnfe          = concnfer * zsizen
167               zconc0n           = concnno3 * zsizen
168               zconc0nnh4        = concnnh4 * zsizen
169               zconc0npo4        = concnpo4 * zsizen
170
171               ! Allometric variations of the minimum and maximum quotas
172               ! From Talmy et al. (2014) and Maranon et al. (2013)
173               ! -------------------------------------------------------
174               xqnnmin(ji,jj,jk) = qnnmin
175               xqnnmax(ji,jj,jk) = qnnmax
176               xqndmin(ji,jj,jk) = qndmin * sized(ji,jj,jk)**(-0.27) 
177               xqndmax(ji,jj,jk) = qndmax
178               xqnpmin(ji,jj,jk) = qnpmin
179               xqnpmax(ji,jj,jk) = qnpmax
180
181               ! Computation of the optimal allocation parameters
182               ! Based on the different papers by Pahlow et al., and Smith et al.
183               ! -----------------------------------------------------------------
184               znutlim = MAX( trb(ji,jj,jk,jpnh4) / zconc0nnh4,    &
185                 &         trb(ji,jj,jk,jpno3) / zconc0n)
186               fanano = MAX(0.01, MIN(0.99, 1. / ( SQRT(znutlim) + 1.) ) )
187               znutlim = trb(ji,jj,jk,jppo4) / zconc0npo4
188               fananop = MAX(0.01, MIN(0.99, 1. / ( SQRT(znutlim) + 1.) ) )
189               znutlim = biron(ji,jj,jk) / zconcnfe
190               fananof = MAX(0.01, MIN(0.99, 1. / ( SQRT(znutlim) + 1.) ) )
191               znutlim = MAX( trb(ji,jj,jk,jpnh4) / zconc0pnh4,    &
192                 &         trb(ji,jj,jk,jpno3) / zconc0p)
193               fapico = MAX(0.01, MIN(0.99, 1. / ( SQRT(znutlim) + 1.) ) )
194               znutlim = trb(ji,jj,jk,jppo4) / zconc0ppo4
195               fapicop = MAX(0.01, MIN(0.99, 1. / ( SQRT(znutlim) + 1.) ) )
196               znutlim = biron(ji,jj,jk) / zconcpfe
197               fapicof = MAX(0.01, MIN(0.99, 1. / ( SQRT(znutlim) + 1.) ) )
198               znutlim = MAX( trb(ji,jj,jk,jpnh4) / zconc1dnh4,    &
199                 &         trb(ji,jj,jk,jpno3) / zconc1d )
200               fadiat = MAX(0.01, MIN(0.99, 1. / ( SQRT(znutlim) + 1.) ) )
201               znutlim = trb(ji,jj,jk,jppo4) / zconc0dpo4
202               fadiatp = MAX(0.01, MIN(0.99, 1. / ( SQRT(znutlim) + 1.) ) )
203               znutlim = biron(ji,jj,jk) / zconcdfe
204               fadiatf = MAX(0.01, MIN(0.99, 1. / ( SQRT(znutlim) + 1.) ) )
205               !
206               ! Michaelis-Menten Limitation term for nutrients Small bacteria
207               ! -------------------------------------------------------------
208               zbactnh4 = trb(ji,jj,jk,jpnh4) / ( concbnh4 + trb(ji,jj,jk,jpnh4) )
209               zbactno3 = trb(ji,jj,jk,jpno3) / ( concbno3 + trb(ji,jj,jk,jpno3) ) * (1. - zbactnh4)
210               !
211               zlim1    = zbactno3 + zbactnh4
212               zlim2    = trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + concbpo4)
213               zlim3    = biron(ji,jj,jk) / ( concbfe + biron(ji,jj,jk) )
214               zlim4    = trb(ji,jj,jk,jpdoc) / ( xkdoc   + trb(ji,jj,jk,jpdoc) )
215               xlimbacl(ji,jj,jk) = MIN( zlim1, zlim2, zlim3 )
216               xlimbac (ji,jj,jk) = xlimbacl(ji,jj,jk) * zlim4
217               !
218               ! Michaelis-Menten Limitation term for nutrients Small flagellates
219               ! -----------------------------------------------
220               zfalim = (1.-fanano) / fanano
221               xnanonh4(ji,jj,jk) = (1. - fanano) * trb(ji,jj,jk,jpnh4) / ( zfalim * zconc0nnh4 + trb(ji,jj,jk,jpnh4) )
222               xnanono3(ji,jj,jk) = (1. - fanano) * trb(ji,jj,jk,jpno3) / ( zfalim * zconc0n + trb(ji,jj,jk,jpno3) )  &
223               &                    * (1. - xnanonh4(ji,jj,jk))
224               !
225               zfalim = (1.-fananop) / fananop
226               xnanopo4(ji,jj,jk) = (1. - fananop) * trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + zfalim * zconc0npo4 )
227               xnanodop(ji,jj,jk) = trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdop) + xkdoc )   &
228               &                    * ( 1.0 - xnanopo4(ji,jj,jk) )
229               xnanodop(ji,jj,jk) = 0.
230               !
231               zfalim = (1.-fananof) / fananof
232               xnanofer(ji,jj,jk) = (1. - fananof) * biron(ji,jj,jk) / ( biron(ji,jj,jk) + zfalim * zconcnfe )
233               !
234               zratiof   = trb(ji,jj,jk,jpnfe) * z1_trnphy
235               zqfemn = xcoef1 * znanochl + xcoef2 + xcoef3 * xnanono3(ji,jj,jk)
236               !
237               zration = trb(ji,jj,jk,jpnph) * z1_trnphy
238               zration = MIN(xqnnmax(ji,jj,jk), MAX( 2. * xqnnmin(ji,jj,jk), zration ))
239               fvnuptk(ji,jj,jk) = 1. / zpsiuptk * rno3 * 2. * xqnnmin(ji,jj,jk) / (zration + rtrn)  &
240               &                   * MAX(0., (1. - zratchl * znanochl / 12. ) )
241               !
242               zlim1    = max(0., (zration - 2. * xqnnmin(ji,jj,jk) )  &
243               &          / (xqnnmax(ji,jj,jk) - 2. * xqnnmin(ji,jj,jk) ) ) * xqnnmax(ji,jj,jk)  &
244               &          / (zration + rtrn)
245               zlim3    = MAX( 0.,( zratiof - zqfemn ) / qfnopt ) 
246               xlimnfe(ji,jj,jk) = MIN( 1., zlim3 )
247               xlimphy(ji,jj,jk) = MIN( 1., zlim1, zlim3 )
248               !
249               ! Michaelis-Menten Limitation term for nutrients picophytoplankton
250               ! ----------------------------------------------------------------
251               zfalim = (1.-fapico) / fapico 
252               xpiconh4(ji,jj,jk) = (1. - fapico) * trb(ji,jj,jk,jpnh4) / ( zfalim * zconc0pnh4 + trb(ji,jj,jk,jpnh4) )
253               xpicono3(ji,jj,jk) = (1. - fapico) * trb(ji,jj,jk,jpno3) / ( zfalim * zconc0p + trb(ji,jj,jk,jpno3) )  &
254               &                    * (1. - xpiconh4(ji,jj,jk))
255               !
256               zfalim = (1.-fapicop) / fapicop 
257               xpicopo4(ji,jj,jk) = (1. - fapicop) * trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + zfalim * zconc0ppo4 )
258               xpicodop(ji,jj,jk) = trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdop) + xkdoc )   &
259               &                    * ( 1.0 - xpicopo4(ji,jj,jk) )
260               xpicodop(ji,jj,jk) = 0.
261               !
262               zfalim = (1.-fapicof) / fapicof
263               xpicofer(ji,jj,jk) = (1. - fapicof) * biron(ji,jj,jk) / ( biron(ji,jj,jk) + zfalim * zconcpfe )
264               !
265               zratiof   = trb(ji,jj,jk,jppfe) * z1_trnpic
266               zqfemp = xcoef1 * zpicochl + xcoef2 + xcoef3 * xpicono3(ji,jj,jk)
267               !
268               zration   = trb(ji,jj,jk,jpnpi) * z1_trnpic
269               zration = MIN(xqnpmax(ji,jj,jk), MAX( 2. * xqnpmin(ji,jj,jk), zration ))
270               fvpuptk(ji,jj,jk) = 1. / zpsiuptk * rno3 * 2. * xqnpmin(ji,jj,jk) / (zration + rtrn)  &
271               &                   * MAX(0., (1. - zratchl * zpicochl / 12. ) ) 
272               !
273               zlim1    = max(0., (zration - 2. * xqnpmin(ji,jj,jk) )  &
274               &          / (xqnpmax(ji,jj,jk) - 2. * xqnpmin(ji,jj,jk) ) ) * xqnpmax(ji,jj,jk)  &
275               &          / (zration + rtrn)
276               zlim3    = MAX( 0.,( zratiof - zqfemp ) / qfpopt )
277               xlimpfe(ji,jj,jk) = MIN( 1., zlim3 )
278               xlimpic(ji,jj,jk) = MIN( 1., zlim1, zlim3 )
279               !
280               !   Michaelis-Menten Limitation term for nutrients Diatoms
281               !   ------------------------------------------------------
282               zfalim = (1.-fadiat) / fadiat 
283               xdiatnh4(ji,jj,jk) = (1. - fadiat) * trb(ji,jj,jk,jpnh4) / ( zfalim * zconc1dnh4 + trb(ji,jj,jk,jpnh4) )
284               xdiatno3(ji,jj,jk) = (1. - fadiat) * trb(ji,jj,jk,jpno3) / ( zfalim * zconc1d + trb(ji,jj,jk,jpno3) )  &
285               &                    * (1. - xdiatnh4(ji,jj,jk))
286               !
287               zfalim = (1.-fadiatp) / fadiatp
288               xdiatpo4(ji,jj,jk) = (1. - fadiatp) * trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + zfalim * zconc0dpo4 )
289               xdiatdop(ji,jj,jk) = trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdop) + xkdoc )  &
290               &                    * ( 1.0 - xdiatpo4(ji,jj,jk) )
291               xdiatdop(ji,jj,jk) = 0.
292               !
293               zfalim = (1.-fadiatf) / fadiatf
294               xdiatfer(ji,jj,jk) = (1. - fadiatf) * biron(ji,jj,jk) / ( biron(ji,jj,jk) + zfalim * zconcdfe )
295               !
296               zratiof   = trb(ji,jj,jk,jpdfe) * z1_trndia
297               zqfemd = xcoef1 * zdiatchl + xcoef2 + xcoef3 * xdiatno3(ji,jj,jk)
298               !
299               zration   = trb(ji,jj,jk,jpndi) * z1_trndia
300               zration = MIN(xqndmax(ji,jj,jk), MAX( 2. * xqndmin(ji,jj,jk), zration ))
301               fvduptk(ji,jj,jk) = 1. / zpsiuptk * rno3 * 2. * xqndmin(ji,jj,jk) / (zration + rtrn)   &
302               &                   * MAX(0., (1. - zratchl * zdiatchl / 12. ) ) 
303               !
304               zlim1    = max(0., (zration - 2. * xqndmin(ji,jj,jk) )    &
305               &          / (xqndmax(ji,jj,jk) - 2. * xqndmin(ji,jj,jk) ) )   &
306               &          * xqndmax(ji,jj,jk) / (zration + rtrn)
307               zlim3    = trb(ji,jj,jk,jpsil) / ( trb(ji,jj,jk,jpsil) + xksi(ji,jj) )
308               zlim4    = MAX( 0., ( zratiof - zqfemd ) / qfdopt )
309               xlimdfe(ji,jj,jk) = MIN( 1., zlim4 )
310               xlimdia(ji,jj,jk) = MIN( 1., zlim1, zlim3, zlim4 )
311               xlimsi(ji,jj,jk)  = MIN( zlim1, zlim4 )
312            END DO
313         END DO
314      END DO
315      !
316      ! Compute the phosphorus quota values. It is based on Litchmann et al., 2004 and Daines et al, 2013.
317      ! The relative contribution of three fonctional pools are computed: light harvesting apparatus,
318      ! nutrient uptake pool and assembly machinery. DNA is assumed to represent 1% of the dry mass of
319      ! phytoplankton (see Daines et al., 2013).
320      ! --------------------------------------------------------------------------------------------------
321      DO jk = 1, jpkm1
322         DO jj = 1, jpj
323            DO ji = 1, jpi
324               ! Size estimation of nanophytoplankton
325               ! ------------------------------------
326               zfvn = 2. * fvnuptk(ji,jj,jk)
327               sizen(ji,jj,jk) = MAX(1., MIN(xsizern, 1.0 / ( MAX(rtrn, zfvn) ) ) )
328
329               ! N/P ratio of nanophytoplankton
330               ! ------------------------------
331               zfuptk = 0.23 * zfvn
332               zrpho = 2.24 * trb(ji,jj,jk,jpnch) / ( trb(ji,jj,jk,jpnph) * rno3 * 15. + rtrn )
333               zrass = 1. - 0.2 - zrpho - zfuptk
334               xqpnmax(ji,jj,jk) = ( zfuptk + zrpho ) * 0.0128 * 16. + zrass * 1./ 7.2 * 16.
335               xqpnmax(ji,jj,jk) = xqpnmax(ji,jj,jk) * trb(ji,jj,jk,jpnph) / ( trb(ji,jj,jk,jpphy) + rtrn ) + 0.13
336               xqpnmin(ji,jj,jk) = 0.13 + 0.23 * 0.0128 * 16.
337
338               ! Size estimation of picophytoplankton
339               ! ------------------------------------
340               zfvn = 2. * fvpuptk(ji,jj,jk)
341               sizep(ji,jj,jk) = MAX(1., MIN(xsizerp, 1.0 / ( MAX(rtrn, zfvn) ) ) )
342
343               ! N/P ratio of picophytoplankton
344               ! ------------------------------
345               zfuptk = 0.35 * zfvn
346               zrpho = 2.24 * trb(ji,jj,jk,jppch) / ( trb(ji,jj,jk,jpnpi) * rno3 * 15. + rtrn )
347               zrass = 1. - 0.4 - zrpho - zfuptk
348               xqppmax(ji,jj,jk) =  (zrpho + zfuptk) * 0.0128 * 16. + zrass * 1./ 9. * 16.
349               xqppmax(ji,jj,jk) = xqppmax(ji,jj,jk) * trb(ji,jj,jk,jpnpi) / ( trb(ji,jj,jk,jppic) + rtrn ) + 0.13
350               xqppmin(ji,jj,jk) = 0.13
351
352               ! Size estimation of diatoms
353               ! --------------------------
354               zfvn = 2. * fvduptk(ji,jj,jk)
355               sized(ji,jj,jk) = MAX(1., MIN(xsizerd, 1.0 / ( MAX(rtrn, zfvn) ) ) )
356               zcoef = trb(ji,jj,jk,jpdia) - MIN(xsizedia, trb(ji,jj,jk,jpdia) )
357               sized(ji,jj,jk) = 1. + xsizerd * zcoef *1E6 / ( 1. + zcoef * 1E6 )
358
359               ! N/P ratio of diatoms
360               ! --------------------
361               zfuptk = 0.2 * zfvn
362               zrpho = 2.24 * trb(ji,jj,jk,jpdch) / ( trb(ji,jj,jk,jpndi) * rno3 * 15. + rtrn )
363               zrass = 1. - 0.2 - zrpho - zfuptk
364               xqpdmax(ji,jj,jk) = ( zfuptk + zrpho ) * 0.0128 * 16. + zrass * 1./ 7.2 * 16.
365               xqpdmax(ji,jj,jk) = xqpdmax(ji,jj,jk) * trb(ji,jj,jk,jpndi) / ( trb(ji,jj,jk,jpdia) + rtrn ) + 0.13
366               xqpdmin(ji,jj,jk) = 0.13 + 0.2 * 0.0128 * 16.
367
368            END DO
369         END DO
370      END DO
371
372      ! Compute the fraction of nanophytoplankton that is made of calcifiers
373      ! --------------------------------------------------------------------
374      DO jk = 1, jpkm1
375         DO jj = 1, jpj
376            DO ji = 1, jpi
377               zlim1 =  trb(ji,jj,jk,jpnh4) / ( trb(ji,jj,jk,jpnh4) + concnnh4 ) + trb(ji,jj,jk,jpno3)    &
378               &        / ( trb(ji,jj,jk,jpno3) + concnno3 ) * ( 1.0 - trb(ji,jj,jk,jpnh4)   &
379               &        / ( trb(ji,jj,jk,jpnh4) + concnnh4 ) )
380               zlim2  = trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + concnpo4 )
381               zlim3  = trb(ji,jj,jk,jpfer) / ( trb(ji,jj,jk,jpfer) +  5.E-11 ) 
382               ztem1  = MAX( 0., tsn(ji,jj,jk,jp_tem) )
383               ztem2  = tsn(ji,jj,jk,jp_tem) - 10.
384               zetot1 = MAX( 0., etot(ji,jj,jk) - 1.) / ( 4. + etot(ji,jj,jk) ) * 20. / ( 20. + etot(ji,jj,jk) ) 
385
386!               xfracal(ji,jj,jk) = caco3r * MIN( zlim1, zlim2, zlim3 )                  &
387               xfracal(ji,jj,jk) = caco3r                 &
388               &                   * ztem1 / ( 1. + ztem1 ) * MAX( 1., trb(ji,jj,jk,jpphy)*1E6 )   &
389                  &                * ( 1. + EXP(-ztem2 * ztem2 / 25. ) )         &
390                  &                * zetot1 * MIN( 1., 50. / ( hmld(ji,jj) + rtrn ) )
391               xfracal(ji,jj,jk) = MAX( 0.02, MIN( 0.8 , xfracal(ji,jj,jk) ) )
392            END DO
393         END DO
394      END DO
395      !
396      DO jk = 1, jpkm1
397         DO jj = 1, jpj
398            DO ji = 1, jpi
399               ! denitrification factor computed from O2 levels
400               nitrfac(ji,jj,jk) = MAX(  0.e0, 0.4 * ( 6.e-6  - trb(ji,jj,jk,jpoxy) )    &
401                  &                                / ( oxymin + trb(ji,jj,jk,jpoxy) )  )
402               nitrfac(ji,jj,jk) = MIN( 1., nitrfac(ji,jj,jk) )
403            END DO
404         END DO
405      END DO
406      !
407      IF( lk_iomput .AND. knt == nrdttrc ) THEN        ! save output diagnostics
408        IF( iom_use( "xfracal" ) ) CALL iom_put( "xfracal", xfracal(:,:,:) * tmask(:,:,:) )  ! euphotic layer deptht
409        IF( iom_use( "LNnut"   ) ) CALL iom_put( "LNnut"  , xlimphy(:,:,:) * tmask(:,:,:) )  ! Nutrient limitation term
410        IF( iom_use( "LPnut"   ) ) CALL iom_put( "LPnut"  , xlimpic(:,:,:) * tmask(:,:,:) )  ! Nutrient limitation term
411        IF( iom_use( "LDnut"   ) ) CALL iom_put( "LDnut"  , xlimdia(:,:,:) * tmask(:,:,:) )  ! Nutrient limitation term
412        IF( iom_use( "LNFe"    ) ) CALL iom_put( "LNFe"   , xlimnfe(:,:,:) * tmask(:,:,:) )  ! Iron limitation term
413        IF( iom_use( "LPFe"    ) ) CALL iom_put( "LPFe"   , xlimpfe(:,:,:) * tmask(:,:,:) )  ! Iron limitation term
414        IF( iom_use( "LDFe"    ) ) CALL iom_put( "LDFe"   , xlimdfe(:,:,:) * tmask(:,:,:) )  ! Iron limitation term
415        IF( iom_use( "SIZEN"   ) ) CALL iom_put( "SIZEN"  , sizen(:,:,:) * tmask(:,:,:) )  ! Iron limitation term
416        IF( iom_use( "SIZEP"   ) ) CALL iom_put( "SIZEP"  , sizep(:,:,:) * tmask(:,:,:) )  ! Iron limitation term
417        IF( iom_use( "SIZED"   ) ) CALL iom_put( "SIZED"  , sized(:,:,:) * tmask(:,:,:) )  ! Iron limitation term
418      ENDIF
419      !
420      IF( ln_timing )  CALL timing_stop('p5z_lim')
421      !
422   END SUBROUTINE p5z_lim
423
424
425   SUBROUTINE p5z_lim_init
426      !!----------------------------------------------------------------------
427      !!                  ***  ROUTINE p5z_lim_init  ***
428      !!
429      !! ** Purpose :   Initialization of nutrient limitation parameters
430      !!
431      !! ** Method  :   Read the nampislim and nampisquota namelists and check
432      !!      the parameters called at the first timestep (nittrc000)
433      !!
434      !! ** input   :   Namelist nampislim
435      !!
436      !!----------------------------------------------------------------------
437      INTEGER :: ios                 ! Local integer output status for namelist read
438      !!
439      NAMELIST/namp5zlim/ concnno3, concpno3, concdno3, concnnh4, concpnh4, concdnh4,  &
440         &                concnfer, concpfer, concdfer, concbfe, concnpo4, concppo4,   &
441         &                concdpo4, concbno3, concbnh4, concbpo4, xsizedia, xsizepic,  &
442         &                xsizephy, xsizern, xsizerp, xsizerd, xksi1, xksi2, xkdoc,    &
443         &                caco3r, oxymin
444         !
445      NAMELIST/namp5zquota/ qnnmin, qnnmax, qpnmin, qpnmax, qnpmin, qnpmax, qppmin,      &
446         &                  qppmax, qndmin, qndmax, qpdmin, qpdmax, qfnmax, qfpmax, qfdmax,  &
447         &                  qfnopt, qfpopt, qfdopt
448      !!----------------------------------------------------------------------
449      !
450      REWIND( numnatp_ref )              ! Namelist nampislim in reference namelist : Pisces nutrient limitation parameters
451      READ  ( numnatp_ref, namp5zlim, IOSTAT = ios, ERR = 901)
452901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampislim in reference namelist', lwp )
453      !
454      REWIND( numnatp_cfg )              ! Namelist nampislim in configuration namelist : Pisces nutrient limitation parameters
455      READ  ( numnatp_cfg, namp5zlim, IOSTAT = ios, ERR = 902 )
456902   IF( ios >  0 ) CALL ctl_nam ( ios , 'nampislim in configuration namelist', lwp )
457      IF(lwm) WRITE ( numonp, namp5zlim )
458      !
459      IF(lwp) THEN                         ! control print
460         WRITE(numout,*) ' '
461         WRITE(numout,*) ' Namelist parameters for nutrient limitations, namp5zlim'
462         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
463         WRITE(numout,*) '    mean rainratio                           caco3r    = ', caco3r
464         WRITE(numout,*) '    NO3 half saturation of nanophyto         concnno3  = ', concnno3
465         WRITE(numout,*) '    NO3 half saturation of picophyto         concpno3  = ', concpno3
466         WRITE(numout,*) '    NO3 half saturation of diatoms           concdno3  = ', concdno3
467         WRITE(numout,*) '    NH4 half saturation for phyto            concnnh4  = ', concnnh4
468         WRITE(numout,*) '    NH4 half saturation for pico             concpnh4  = ', concpnh4
469         WRITE(numout,*) '    NH4 half saturation for diatoms          concdnh4  = ', concdnh4
470         WRITE(numout,*) '    PO4 half saturation for phyto            concnpo4  = ', concnpo4
471         WRITE(numout,*) '    PO4 half saturation for pico             concppo4  = ', concppo4
472         WRITE(numout,*) '    PO4 half saturation for diatoms          concdpo4  = ', concdpo4
473         WRITE(numout,*) '    half saturation constant for Si uptake   xksi1     = ', xksi1
474         WRITE(numout,*) '    half saturation constant for Si/C        xksi2     = ', xksi2
475         WRITE(numout,*) '    half-sat. of DOC remineralization        xkdoc     = ', xkdoc
476         WRITE(numout,*) '    Iron half saturation for nanophyto       concnfer  = ', concnfer
477         WRITE(numout,*) '    Iron half saturation for picophyto       concpfer  = ', concpfer
478         WRITE(numout,*) '    Iron half saturation for diatoms         concdfer  = ', concdfer
479         WRITE(numout,*) '    size ratio for nanophytoplankton         xsizern   = ', xsizern
480         WRITE(numout,*) '    size ratio for picophytoplankton         xsizerp   = ', xsizerp
481         WRITE(numout,*) '    size ratio for diatoms                   xsizerd   = ', xsizerd
482         WRITE(numout,*) '    NO3 half saturation of bacteria          concbno3  = ', concbno3
483         WRITE(numout,*) '    NH4 half saturation for bacteria         concbnh4  = ', concbnh4
484         WRITE(numout,*) '    Minimum size criteria for diatoms        xsizedia  = ', xsizedia
485         WRITE(numout,*) '    Minimum size criteria for picophyto      xsizepic  = ', xsizepic
486         WRITE(numout,*) '    Minimum size criteria for nanophyto      xsizephy  = ', xsizephy
487         WRITE(numout,*) '    Fe half saturation for bacteria          concbfe   = ', concbfe
488         WRITE(numout,*) '    halk saturation constant for anoxia       oxymin   =' , oxymin
489      ENDIF
490
491      REWIND( numnatp_ref )              ! Namelist nampislim in reference namelist : Pisces nutrient limitation parameters
492      READ  ( numnatp_ref, namp5zquota, IOSTAT = ios, ERR = 903)
493903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisquota in reference namelist', lwp )
494      !
495      REWIND( numnatp_cfg )              ! Namelist nampislim in configuration namelist : Pisces nutrient limitation parameters
496      READ  ( numnatp_cfg, namp5zquota, IOSTAT = ios, ERR = 904 )
497904   IF( ios >  0 ) CALL ctl_nam ( ios , 'nampisquota in configuration namelist', lwp )
498      IF(lwm) WRITE ( numonp, namp5zquota )
499      !
500      IF(lwp) THEN                         ! control print
501         WRITE(numout,*) ' '
502         WRITE(numout,*) ' Namelist parameters for nutrient limitations, namp5zquota'
503         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
504         WRITE(numout,*) '    optimal Fe quota for nano.               qfnopt    = ', qfnopt
505         WRITE(numout,*) '    optimal Fe quota for pico.               qfpopt    = ', qfpopt
506         WRITE(numout,*) '    Optimal Fe quota for diatoms             qfdopt    = ', qfdopt
507         WRITE(numout,*) '    Minimal N quota for nano                 qnnmin    = ', qnnmin
508         WRITE(numout,*) '    Maximal N quota for nano                 qnnmax    = ', qnnmax
509         WRITE(numout,*) '    Minimal P quota for nano                 qpnmin    = ', qpnmin
510         WRITE(numout,*) '    Maximal P quota for nano                 qpnmax    = ', qpnmax
511         WRITE(numout,*) '    Minimal N quota for pico                 qnpmin    = ', qnpmin
512         WRITE(numout,*) '    Maximal N quota for pico                 qnpmax    = ', qnpmax
513         WRITE(numout,*) '    Minimal P quota for pico                 qppmin    = ', qppmin
514         WRITE(numout,*) '    Maximal P quota for pico                 qppmax    = ', qppmax
515         WRITE(numout,*) '    Minimal N quota for diatoms              qndmin    = ', qndmin
516         WRITE(numout,*) '    Maximal N quota for diatoms              qndmax    = ', qndmax
517         WRITE(numout,*) '    Minimal P quota for diatoms              qpdmin    = ', qpdmin
518         WRITE(numout,*) '    Maximal P quota for diatoms              qpdmax    = ', qpdmax
519         WRITE(numout,*) '    Maximal Fe quota for nanophyto.          qfnmax    = ', qfnmax
520         WRITE(numout,*) '    Maximal Fe quota for picophyto.          qfpmax    = ', qfpmax
521         WRITE(numout,*) '    Maximal Fe quota for diatoms             qfdmax    = ', qfdmax
522      ENDIF
523      !
524      zpsino3 = 2.3 * rno3
525      zpsinh4 = 1.8 * rno3
526      zpsiuptk = 2.3 * rno3
527      !
528      nitrfac (:,:,:) = 0._wp
529      !
530   END SUBROUTINE p5z_lim_init
531
532
533   INTEGER FUNCTION p5z_lim_alloc()
534      !!----------------------------------------------------------------------
535      !!                     ***  ROUTINE p5z_lim_alloc  ***
536      !!----------------------------------------------------------------------
537      USE lib_mpp , ONLY: ctl_warn
538      INTEGER ::   ierr(2)        ! Local variables
539      !!----------------------------------------------------------------------
540      ierr(:) = 0
541      !
542      !*  Biological arrays for phytoplankton growth
543      ALLOCATE( xpicono3(jpi,jpj,jpk), xpiconh4(jpi,jpj,jpk),       &
544         &      xpicopo4(jpi,jpj,jpk), xpicodop(jpi,jpj,jpk),       &
545         &      xnanodop(jpi,jpj,jpk), xdiatdop(jpi,jpj,jpk),       &
546         &      xnanofer(jpi,jpj,jpk), xdiatfer(jpi,jpj,jpk),       &
547         &      xpicofer(jpi,jpj,jpk), xlimpfe (jpi,jpj,jpk),       &
548         &      fvnuptk (jpi,jpj,jpk), fvduptk (jpi,jpj,jpk),       &
549         &      fvpuptk (jpi,jpj,jpk), xlimpic (jpi,jpj,jpk),    STAT=ierr(1) )
550         !
551      !*  Minimum/maximum quotas of phytoplankton
552      ALLOCATE( xqnnmin (jpi,jpj,jpk), xqnnmax(jpi,jpj,jpk),       &
553         &      xqpnmin (jpi,jpj,jpk), xqpnmax(jpi,jpj,jpk),       &
554         &      xqnpmin (jpi,jpj,jpk), xqnpmax(jpi,jpj,jpk),       &
555         &      xqppmin (jpi,jpj,jpk), xqppmax(jpi,jpj,jpk),       &
556         &      xqndmin (jpi,jpj,jpk), xqndmax(jpi,jpj,jpk),       &
557         &      xqpdmin (jpi,jpj,jpk), xqpdmax(jpi,jpj,jpk),     STAT=ierr(2) )
558         !
559      p5z_lim_alloc = MAXVAL( ierr )
560      !
561      IF( p5z_lim_alloc /= 0 ) CALL ctl_warn('p5z_lim_alloc : failed to allocate arrays.')
562      !
563   END FUNCTION p5z_lim_alloc
564   !!======================================================================
565END MODULE p5zlim
Note: See TracBrowser for help on using the repository browser.