New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcsbc.F90 in NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/TOP/TRP – NEMO

source: NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/TOP/TRP/trcsbc.F90 @ 10372

Last change on this file since 10372 was 10372, checked in by smasson, 5 years ago

dev_r10164_HPC09_ESIWACE_PREP_MERGE: action 8: remove communications in TOP, see #2133

  • Property svn:keywords set to Id
File size: 9.4 KB
Line 
1MODULE trcsbc
2   !!==============================================================================
3   !!                       ***  MODULE  trcsbc  ***
4   !! Ocean passive tracers:  surface boundary condition
5   !!======================================================================
6   !! History :  8.2  !  1998-10  (G. Madec, G. Roullet, M. Imbard)  Original code
7   !!            8.2  !  2001-02  (D. Ludicone)  sea ice and free surface
8   !!            8.5  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            9.0  !  2004-03  (C. Ethe)  adapted for passive tracers
10   !!                 !  2006-08  (C. Deltel) Diagnose ML trends for passive tracers
11   !!==============================================================================
12#if defined key_top
13   !!----------------------------------------------------------------------
14   !!   'key_top'                                                TOP models
15   !!----------------------------------------------------------------------
16   !!   trc_sbc      : update the tracer trend at ocean surface
17   !!----------------------------------------------------------------------
18   USE oce_trc         ! ocean dynamics and active tracers variables
19   USE trc             ! ocean  passive tracers variables
20   USE prtctl_trc      ! Print control for debbuging
21   USE iom
22   USE trd_oce
23   USE trdtra
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   trc_sbc   ! routine called by step.F90
29
30   !! * Substitutions
31#  include "vectopt_loop_substitute.h90"
32   !!----------------------------------------------------------------------
33   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
34   !! $Id$
35   !! Software governed by the CeCILL license (see ./LICENSE)
36   !!----------------------------------------------------------------------
37CONTAINS
38
39   SUBROUTINE trc_sbc ( kt )
40      !!----------------------------------------------------------------------
41      !!                  ***  ROUTINE trc_sbc  ***
42      !!                   
43      !! ** Purpose :   Compute the tracer surface boundary condition trend of
44      !!      (concentration/dilution effect) and add it to the general
45      !!       trend of tracer equations.
46      !!
47      !! ** Method :
48      !!      * concentration/dilution effect:
49      !!            The surface freshwater flux modify the ocean volume
50      !!         and thus the concentration of a tracer as :
51      !!            tra = tra + emp * trn / e3t   for k=1
52      !!         where emp, the surface freshwater budget (evaporation minus
53      !!         precipitation ) given in kg/m2/s is divided
54      !!         by 1035 kg/m3 (density of ocean water) to obtain m/s.
55      !!
56      !! ** Action  : - Update the 1st level of tra with the trend associated
57      !!                with the tracer surface boundary condition
58      !!
59      !!----------------------------------------------------------------------
60      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
61      !
62      INTEGER  ::   ji, jj, jn                      ! dummy loop indices
63      REAL(wp) ::   zse3t, zrtrn, zratio, zfact     ! local scalars
64      REAL(wp) ::   zftra, zcd, zdtra, ztfx, ztra   !   -      -
65      CHARACTER (len=22) :: charout
66      REAL(wp), DIMENSION(jpi,jpj)   ::   zsfx
67      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrtrd
68      !!---------------------------------------------------------------------
69      !
70      IF( ln_timing )   CALL timing_start('trc_sbc')
71      !
72      ! Allocate temporary workspace
73      IF( l_trdtrc )  ALLOCATE( ztrtrd(jpi,jpj,jpk) )
74      !
75      zrtrn = 1.e-15_wp
76
77      IF( kt == nittrc000 ) THEN
78         IF(lwp) WRITE(numout,*)
79         IF(lwp) WRITE(numout,*) 'trc_sbc : Passive tracers surface boundary condition'
80         IF(lwp) WRITE(numout,*) '~~~~~~~ '
81         !
82         IF( ln_rsttr .AND. .NOT.ln_top_euler .AND.   &                     ! Restart: read in restart  file
83            iom_varid( numrtr, 'sbc_'//TRIM(ctrcnm(1))//'_b', ldstop = .FALSE. ) > 0 ) THEN
84            IF(lwp) WRITE(numout,*) '          nittrc000-nn_dttrc surface tracer content forcing fields red in the restart file'
85            zfact = 0.5_wp
86            DO jn = 1, jptra
87               CALL iom_get( numrtr, jpdom_autoglo, 'sbc_'//TRIM(ctrcnm(jn))//'_b', sbc_trc_b(:,:,jn) )   ! before tracer content sbc
88            END DO
89         ELSE                                         ! No restart or restart not found: Euler forward time stepping
90           zfact = 1._wp
91           sbc_trc_b(:,:,:) = 0._wp
92         ENDIF
93      ELSE                                         ! Swap of forcing fields
94         IF( ln_top_euler ) THEN
95            zfact = 1._wp
96            sbc_trc_b(:,:,:) = 0._wp
97         ELSE
98            zfact = 0.5_wp
99            sbc_trc_b(:,:,:) = sbc_trc(:,:,:)
100         ENDIF
101         !
102      ENDIF
103
104      ! Coupling online : river runoff is added to the horizontal divergence (hdivn) in the subroutine sbc_rnf_div
105      ! one only consider the concentration/dilution effect due to evaporation minus precipitation + freezing/melting of sea-ice
106      ! Coupling offline : runoff are in emp which contains E-P-R
107      !
108      IF( .NOT.ln_linssh ) THEN  ! online coupling with vvl
109         zsfx(:,:) = 0._wp
110      ELSE                                      ! online coupling free surface or offline with free surface
111         zsfx(:,:) = emp(:,:)
112      ENDIF
113
114      ! 0. initialization
115      IF( nn_ice_tr == -1 ) THEN    ! No tracers in sea ice (null concentration in sea ice)
116         !
117         DO jn = 1, jptra
118            DO jj = 2, jpj
119               DO ji = fs_2, fs_jpim1   ! vector opt.
120                  sbc_trc(ji,jj,jn) = zsfx(ji,jj) * r1_rau0 * trn(ji,jj,1,jn)
121               END DO
122            END DO
123         END DO
124         !
125       ELSE
126         !
127         DO jn = 1, jptra
128            DO jj = 2, jpj
129               DO ji = fs_2, fs_jpim1   ! vector opt.
130                  zse3t = 1. / e3t_n(ji,jj,1)
131                  ! tracer flux at the ice/ocean interface (tracer/m2/s)
132                  zftra = - trc_i(ji,jj,jn) * fmmflx(ji,jj) ! uptake of tracer in the sea ice
133                  zcd   =   trc_o(ji,jj,jn) * fmmflx(ji,jj) ! concentration dilution due to freezing-melting,
134                  !                                         ! only used in the levitating sea ice case
135                  ! tracer flux only       : add concentration dilution term in net tracer flux, no F-M in volume flux
136                  ! tracer and mass fluxes : no concentration dilution term in net tracer flux, F-M term in volume flux
137                  ztfx  = zftra                             ! net tracer flux
138                  !
139                  zdtra = r1_rau0 * ( ztfx + zsfx(ji,jj) * trn(ji,jj,1,jn) ) 
140                  IF ( zdtra < 0. ) THEN
141                     zratio = -zdtra * zse3t * r2dttrc / ( trn(ji,jj,1,jn) + zrtrn )
142                     zdtra = MIN(1.0, zratio) * zdtra ! avoid negative concentrations to arise
143                  ENDIF
144                  sbc_trc(ji,jj,jn) =  zdtra 
145               END DO
146            END DO
147         END DO
148      ENDIF
149      !
150      CALL lbc_lnk( 'trcsbc', sbc_trc(:,:,:), 'T', 1. )
151      !                                       Concentration dilution effect on tracers due to evaporation & precipitation
152      DO jn = 1, jptra
153         !
154         IF( l_trdtrc )   ztrtrd(:,:,:) = tra(:,:,:,jn)  ! save trends
155         !
156         DO jj = 2, jpj
157            DO ji = fs_2, fs_jpim1   ! vector opt.
158               zse3t = zfact / e3t_n(ji,jj,1)
159               tra(ji,jj,1,jn) = tra(ji,jj,1,jn) + ( sbc_trc_b(ji,jj,jn) + sbc_trc(ji,jj,jn) ) * zse3t
160            END DO
161         END DO
162         !
163         IF( l_trdtrc ) THEN
164            ztrtrd(:,:,:) = tra(:,:,:,jn) - ztrtrd(:,:,:)
165            CALL trd_tra( kt, 'TRC', jn, jptra_nsr, ztrtrd )
166         END IF
167         !                                                       ! ===========
168      END DO                                                     ! tracer loop
169      !                                                          ! ===========
170      !
171      !                                           Write in the tracer restar  file
172      !                                          *******************************
173      IF( lrst_trc .AND. .NOT.ln_top_euler ) THEN
174         IF(lwp) WRITE(numout,*)
175         IF(lwp) WRITE(numout,*) 'sbc : ocean surface tracer content forcing fields written in tracer restart file ',   &
176            &                    'at it= ', kt,' date= ', ndastp
177         IF(lwp) WRITE(numout,*) '~~~~'
178         DO jn = 1, jptra
179            CALL iom_rstput( kt, nitrst, numrtw, 'sbc_'//TRIM(ctrcnm(jn))//'_b', sbc_trc(:,:,jn) )
180         END DO
181      ENDIF
182      !
183      IF( ln_ctl )   THEN
184         WRITE(charout, FMT="('sbc ')") ;  CALL prt_ctl_trc_info(charout)
185                                           CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm, clinfo2='trd' )
186      ENDIF
187      IF( l_trdtrc )  DEALLOCATE( ztrtrd )
188      !
189      IF( ln_timing )   CALL timing_stop('trc_sbc')
190      !
191   END SUBROUTINE trc_sbc
192
193#else
194   !!----------------------------------------------------------------------
195   !!   Dummy module :                      NO passive tracer
196   !!----------------------------------------------------------------------
197CONTAINS
198   SUBROUTINE trc_sbc (kt)              ! Empty routine
199      INTEGER, INTENT(in) :: kt
200      WRITE(*,*) 'trc_sbc: You should not have seen this print! error?', kt
201   END SUBROUTINE trc_sbc
202#endif
203   
204   !!======================================================================
205END MODULE trcsbc
Note: See TracBrowser for help on using the repository browser.